Verständnisfrage zu "Local vs Global" in Bezug auf Geschwindigkeit und Ressourcenbelegung

Slevin

Aloha und nen schönen Feiertag,

ich hab da mal ne allgemeine Frage. Wie ihr im beigefügten Script sehen könnt, belegen die embedded Icons, die als String in einem Dictionary abgelegt sind, ganz schön was an Platz.

In meinem Beispiel würde bei jeder Tray-Icon-Änderung die _fetchIcon() UDF aufgerufen werden, in welcher sämtliche Icons Local deklariert sind - für das Beispiel hier nur 2 Icons, im eigentlichen Scipt sind das dann aber bis zu 20 oder mehr. Diese liefert dann den gewünschten String zurück, der im Anschluss dekodiert und als Icon gesetzt werden kann.

Das bedeutet natürlich, dass jedes Mal alle Icons frisch in den Speicher geladen werden müssen, was natürlich auch Zeit in Anspruch nimmt.

Daher meine Frage: sollte man die Icons lieber Global speichern und zu Beginn des Skripts einlesen? Würde das einen Geschwindigkeitsvorteil bringen? Vor allem, wenn die String-Variablen, wie in diesem Beispiel, eine ganz schöne Länge haben.

AutoIt

#include <GDIPlus.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()
Global $hBmp, $hIcon

Global $hGUI = GUICreate("Display embedded ico file in tray", 320, 100)
Global $idButton_1 = GUICtrlCreateButton("live", 90, 40, 60, 20)
Global $idButton_2 = GUICtrlCreateButton("lock", 170, 40, 60, 20)

GUISetState()

While 1
    $idMsg = GUIGetMsg()
    Select
        Case $idMsg = -3
            ExitLoop
        Case $idMsg = $idButton_1
            _setTrayIcon("live")
        Case $idMsg = $idButton_2
            _SetTrayIcon("lock")
    EndSelect
WEnd

_GDIPlus_BitmapDispose($hBmp)
_WinAPI_DestroyIcon($hIcon)
_GDIPlus_Shutdown()
Exit

Func _setTrayIcon($icon)
    $hBmp = _GDIPlus_BitmapCreateFromMemory(_WinAPI_Base64Decode(_fetchIcon($icon)))    ;load ico and convert it to a GDI+ bitmap
    $hIcon = _GDIPlus_HICONCreateFromBitmap($hBmp)                    ;convert bitmap to HIcon
    _WinAPI_TraySetHIcon($hIcon)
EndFunc

Func _WinAPI_TraySetHIcon($hIcon) ;function by Mat
    Local Const $tagNOTIFYICONDATA = _
                    "dword Size;" & _
                    "hwnd Wnd;" & _
                    "uint ID;" & _
                    "uint Flags;" & _
                    "uint CallbackMessage;" & _
                    "ptr Icon;" & _
                    "wchar Tip[128];" & _
                    "dword State;" & _
                    "dword StateMask;" & _
                    "wchar Info[256];" & _
                    "uint Timeout;" & _
                    "wchar InfoTitle[64];" & _
                    "dword InfoFlags;" & _
                    "dword Data1;word Data2;word Data3;byte Data4[8];" & _
                    "ptr BalloonIcon"
    Local Const $TRAY_ICON_GUI = WinGetHandle(AutoItWinGetTitle()), $NIM_ADD = 0, $NIM_MODIFY = 1, $NIF_MESSAGE = 1, $NIF_ICON = 2, $AUT_WM_NOTIFYICON = $WM_USER + 1, $AUT_NOTIFY_ICON_ID = 1
    Local $tNOTIFY = DllStructCreate($tagNOTIFYICONDATA)
    DllStructSetData($tNOTIFY, "Size", DllStructGetSize($tNOTIFY))
    DllStructSetData($tNOTIFY, "Wnd", $TRAY_ICON_GUI)
    DllStructSetData($tNOTIFY, "ID", $AUT_NOTIFY_ICON_ID)
    DllStructSetData($tNOTIFY, "Icon", $hIcon)
    DllStructSetData($tNOTIFY, "Flags", BitOR($NIF_ICON, $NIF_MESSAGE))
    DllStructSetData($tNOTIFY, "CallbackMessage", $AUT_WM_NOTIFYICON)
    Local $aRet = DllCall("shell32.dll", "int", "Shell_NotifyIconW", "dword", $NIM_MODIFY, "ptr", DllStructGetPtr($tNOTIFY))
    If (@error) Then Return SetError(1, 0, 0)
    Return $aRet[0] <> 0
EndFunc   ;==>_Tray_SetHIcon

;Code below was generated by: 'File to Base64 String' Code Generator v1.20 Build 2015-01-20

Func _fetchIcon($icon)
    Local $iconBase = ObjCreate("Scripting.Dictionary")

    $iconBase("live") = 'AAABAAEAEBAAAAEACABoBQAAFgAAACgAAAAQAAAAIAAAAAEACAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAjI7EAIiKwACIirwAhIa4AICCtAB8frAAeHqoAHR2pABwcpwAbG6UAGRmkABgYogAXF6AAFhaeABQUnAATE5oAEhKZABAQlwAPD5UA8fHxAA0NkwAMDJEACwuPAAoKjQAICIwABweKAAYGiAAFBYcABASFAAMDhAACAoMAAQGCAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAADxAREhQVFhcYGRobHB0eHw4PEBESFBUWFxgZGhscHR4NDg8QERIUFRYXGBkaGxwdDA0ODxAREhQVFhcYGRobHAsMDQ4PEBETExUWFxgZGhsKCwwNDg8QExMUFRYXGBkaCQoLDA0ODxMTEhQVFhcYGQgJCgsTExMTExMTExUWFxgHCAkKExMTExMTExMUFRYXBgcICQoLDBMTDxAREhQVFgUGBwgJCgsTEw4PEBESFBUEBQYHCAkKExMNDg8QERIUAwQFBgcICQoLDA0ODxAREgIDBAUGBwgJCgsMDQ4PEBEBAgMEBQYHCAkKCwwNDg8QAAECAwQFBgcICQoLDA0ODwAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA='
    $iconBase("lock") = 'AAABAAEAEBAAAAEACABoBQAAFgAAACgAAAAQAAAAIAAAAAEACAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAjI7EAIiKwACIirwAhIa4AICCtAB8frAAeHqoAHR2pABwcpwAbG6UAGRmkABgYogAXF6AAFhaeABQUnAATE5oAEhKZABAQlwAPD5UA8fHxAA0NkwAMDJEACwuPAAoKjQAICIwABweKAAYGiAAFBYcABASFAAMDhAACAoMAAQGCAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAADxAREhQVFhcYGRobHB0eHw4PEBESFBUWFxgZGhscHR4NDg8QERIUFRYXGBkaGxwdDA0ODxAREhQVFhcYGRobHAsMDQ4PEBETExUWFxgZGhsKCwwNDg8QExMUFRYXGBkaCQoLDA0ODxMTEhQVFhcYGQgJCgsMDQ4TExESFBUWFxgHCAkKCwwNExMQERIUFRYXBgcICQoLDBMTDxAREhQVFgUGBwgJCgsTEw4PEBESFBUEBQYHCAkKExMNDg8QERIUAwQFBgcICQoLDA0ODxAREgIDBAUGBwgJCgsMDQ4PEBEBAgMEBQYHCAkKCwwNDg8QAAECAwQFBgcICQoLDA0ODwAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA='

    Return $iconBase($icon)
EndFunc

Func _WinAPI_Base64Decode($sB64String)
    Local $aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "ptr", 0, "dword*", 0, "ptr", 0, "ptr", 0)
    If @error Or Not $aCrypt[0] Then Return SetError(1, 0, "")
    Local $bBuffer = DllStructCreate("byte[" & $aCrypt[5] & "]")
    $aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "struct*", $bBuffer, "dword*", $aCrypt[5], "ptr", 0, "ptr", 0)
    If @error Or Not $aCrypt[0] Then Return SetError(2, 0, "")
    Return Binary(DllStructGetData($bBuffer, 1))
EndFunc   ;==>_WinAPI_Base64Decode

Alles anzeigen

**Oscar**

Du machst einen gravierenden Fehler!

Mit _GDIPlus_BitmapCreateFromMemory erstellst Du bei jedem Aufruf eine neue Bitmap. Diese werden aber beim verlassen der Funktion nicht wieder freigegeben. Das führt zu einem Speicherleck.

Besser einmal (global) die Icons erstellen und dann diese nutzen und bei Programmende wieder freigeben.

Das behebt nicht nur das Speicherleck, sondern ist auch schneller.

**autoiter**

Oscar

Das hab ich verbrochen. Das ist das Beispiel aus dem File to Base64 String Code Generator-Thread im engl. Forum.

Slevin

Pack _GDIPlus_BitmapDispose und _WinAPI_DestroyIcon mit in die _SetTrayIcon-Funktion.

So wie du die Funktion _fetchIcon() nutzt, wird tatsächlich jedes Mal von neuem jedes Icon in eine Variable gespeichert und und im Anschluss nur das einzige erfragte Icon zurückgegeben. Das ist wirklich nicht so toll.

Wenn du es unbedingt so machen willst, wäre es tatsächlich besser, du würdest gar keine Funktion aufrufen sondern dein Dictionary mit allen Icons global deklarieren. Am besten in einer eigenen au3, die du dann nur in dein Skript inkludierst. So verbraucht dein Skript zwar mehr Speicher (eben den für alle Icons, die du vielleicht in der Laufzeit mal aufrufst), aber es geht. Und so viel Speicher werden die Icons auch nicht belegen, oder reden wir wirklich von irre vielen Icons?

Ansonsten hätte ich auf das Dictionary verzichtet und die Icons in Funktionen gepackt, die lock oder live heißen. Ist aber vllt. Geschmackssache.

**Oscar**

Statt des Dictionarys könnte man auch Arrays nehmen und die Indizes mit Variablen (Enum) benennen:

AutoIt

Global $aIcons[3] = [_Icon1(), _Icon2(), _Icon3()]
Global Enum $live, $lock, $program
ConsoleWrite($aIcons[$live] & @CR)
ConsoleWrite($aIcons[$lock] & @CR)
ConsoleWrite($aIcons[$program] & @CR)

Func _Icon1()
    Local $icon = 'AAABAA...'
    Return $icon
EndFunc

Func _Icon2()
    Local $icon = 'FFCCAB...'
    Return $icon
EndFunc

Func _Icon3()
    Local $icon = 'DDCCBB...'
    Return $icon
EndFunc

Alles anzeigen

**alpines**

Zitat von Oscar

Statt des Dictionarys könnte man auch Arrays nehmen und die Indizes mit Variablen (Enum) benennen:

Map Deklaration throws error

**autoiter**

Es ginge doch auch so

Code

_ConsoleWrite(_live)
_ConsoleWrite(_lock)
_ConsoleWrite(_program)

Func _ConsoleWrite($var)
    ConsoleWrite($var() & @CR)
EndFunc

Func _live()
    Local $icon = 'AAABAA...'
    Return $icon
EndFunc
Func _lock()
    Local $icon = 'FFCCAB...'
    Return $icon
EndFunc
Func _program()
    Local $icon = 'DDCCBB...'
    Return $icon
EndFunc

Alles anzeigen

Slevin

Zitat von Oscar

Du machst einen gravierenden Fehler!

Mit _GDIPlus_BitmapCreateFromMemory erstellst Du bei jedem Aufruf eine neue Bitmap. Diese werden aber beim verlassen der Funktion nicht wieder freigegeben. Das führt zu einem Speicherleck.

Besser einmal (global) die Icons erstellen und dann diese nutzen und bei Programmende wieder freigeben.

Das behebt nicht nur das Speicherleck, sondern ist auch schneller.

Also entweder wie autoiter meinte, die _setTrayIcon() UDF so gestalten:

AutoIt

Func _setTrayIcon($icon)
    $hBmp = _GDIPlus_BitmapCreateFromMemory(_WinAPI_Base64Decode(_fetchIcon($icon)))    ;load ico and convert it to a GDI+ bitmap
    $hIcon = _GDIPlus_HICONCreateFromBitmap($hBmp)                    ;convert bitmap to HIcon
    _WinAPI_TraySetHIcon($hIcon)
    _GDIPlus_BitmapDispose($hBmp)
    _WinAPI_DestroyIcon($hIcon)
EndFunc

Oder aber jedes Icon global fertig deklarieren, das würde dann jeweils in etwa so aussehen:

AutoIt

Local $iconBaselock = 'AAABAAEAEBAAAAEACABoBQAAFgAAACgAAAAQAAAAIAAAAAEACAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAjI7EAIiKwACIirwAhIa4AICCtAB8frAAeHqoAHR2pABwcpwAbG6UAGRmkABgYogAXF6AAFhaeABQUnAATE5oAEhKZABAQlwAPD5UA8fHxAA0NkwAMDJEACwuPAAoKjQAICIwABweKAAYGiAAFBYcABASFAAMDhAACAoMAAQGCAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAADxAREhQVFhcYGRobHB0eHw4PEBESFBUWFxgZGhscHR4NDg8QERIUFRYXGBkaGxwdDA0ODxAREhQVFhcYGRobHAsMDQ4PEBETExUWFxgZGhsKCwwNDg8QExMUFRYXGBkaCQoLDA0ODxMTEhQVFhcYGQgJCgsMDQ4TExESFBUWFxgHCAkKCwwNExMQERIUFRYXBgcICQoLDBMTDxAREhQVFgUGBwgJCgsTEw4PEBESFBUEBQYHCAkKExMNDg8QERIUAwQFBgcICQoLDA0ODxAREgIDBAUGBwgJCgsMDQ4PEBEBAgMEBQYHCAkKCwwNDg8QAAECAwQFBgcICQoLDA0ODwAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA='

Global $iconBase = ObjCreate("Scripting.Dictionary")
$iconBase("lock") = GDIPlus_HICONCreateFromBitmap(_GDIPlus_BitmapCreateFromMemory(_WinAPI_Base64Decode($iconBaselock)))

Func _setTrayIcon($icon)
    _WinAPI_TraySetHIcon($icon)
EndFunc

_setTrayIcon("lock")

Wenn ich das jetzt richtig verstanden habe, dann wird bei der ersten Variante jedes Mal das Icon aufs neue kreiert, aber der für das Erstellen des Icons benötigte Bitmap-Speicher wieder freigegeben.

Bei der zweiten Variante werden alle Icons fertig kreiert und bleiben im Speicher, sind daher schneller ansprechbar, und es gibt auch kein Speicherleck - was insgesamt wahrscheinlich die intelligentere Variante ist, sofern sich das ganze in Grenzen hält (wie gesagt, so um die 20 Icons im aktuellen Fall)

Das mit dem Speicherleck wäre natürlich gar nicht gut gewesen - DANKE für die Warnung

**Bitnugger**

Ich habe hier mal was gebastelt...

AutoIt

;-- TIME_STAMP   2018-05-31 09:43:20   v 0.1

#Region    ;************ Includes ************
#Include <GDIPlus.au3>
#include <WindowsConstants.au3>
#EndRegion ;************ Includes ************

Opt('MustdeclareVars', 1)

Global $g_hGUI, $g_idButton_Ico1, $g_idButton_Ico2
Global $g_hDll = DllOpen("shell32.dll"), $g_oIconBase = ObjCreate("Scripting.Dictionary"), $g_hBmp, $g_hIcon

_Main()

Func _Main()
    _GDIPlus_Startup()

    $g_hGUI = GUICreate("Display embedded ico file in tray", 370, 100)
    GUISetBkColor(0x2F4F4F, $g_hGUI)
    $g_idButton_Ico1 = GUICtrlCreateButton("live", 10, 20, 170, 60)
    GUICtrlSetBkColor(-1, 0x778899)
    GUICtrlSetFont(-1, 14, 800)
    $g_idButton_Ico2 = GUICtrlCreateButton("lock", 190, 20, 170, 60)
    GUICtrlSetBkColor(-1, 0x778899)
    GUICtrlSetFont(-1, 14, 800)
    GUISetState()

    _ReadIcons()

    Local $iMsg, $iRet
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case -3
                ExitLoop
            Case $g_idButton_Ico1
                $iRet = _WinAPI_TraySetHIcon($g_oIconBase("live"))
                If @error Then Exit ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iRet --> " & $iRet & @CRLF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
                GUICtrlSetBkColor($g_idButton_Ico1, 0x228B22)
                GUICtrlSetBkColor($g_idButton_Ico2, 0x778899)
            Case $g_idButton_Ico2
                $iRet = _WinAPI_TraySetHIcon($g_oIconBase("lock"))
                If @error Then Exit ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iRet --> " & $iRet & @CRLF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
                GUICtrlSetBkColor($g_idButton_Ico1, 0x778899)
                GUICtrlSetBkColor($g_idButton_Ico2, 0x228B22)
        EndSwitch
    WEnd
    ; Clean up
    For $hIcon In $g_oIconBase
        $iRet = _WinAPI_DestroyIcon($hIcon)
        If @error Then ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iRet --> " & $iRet & @CRLF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
    Next
    _GDIPlus_Shutdown()
    DllClose($g_hDll)
EndFunc  ;==>_Main

Func _WinAPI_TraySetHIcon($hIcon) ;function by Mat
    Local Const $tagNOTIFYICONDATA = _
                    "dword Size;" & _
                    "hwnd Wnd;" & _
                    "uint ID;" & _
                    "uint Flags;" & _
                    "uint CallbackMessage;" & _
                    "ptr Icon;" & _
                    "wchar Tip[128];" & _
                    "dword State;" & _
                    "dword StateMask;" & _
                    "wchar Info[256];" & _
                    "uint Timeout;" & _
                    "wchar InfoTitle[64];" & _
                    "dword InfoFlags;" & _
                    "dword Data1;word Data2;word Data3;byte Data4[8];" & _
                    "ptr BalloonIcon"
    Local Const $TRAY_ICON_GUI = WinGetHandle(AutoItWinGetTitle()), $NIM_ADD = 0, $NIM_MODIFY = 1, $NIF_MESSAGE = 1, $NIF_ICON = 2, $AUT_WM_NOTIFYICON = $WM_USER + 1, $AUT_NOTIFY_ICON_ID = 1
    Local $tNOTIFY = DllStructCreate($tagNOTIFYICONDATA)
    DllStructSetData($tNOTIFY, "Size", DllStructGetSize($tNOTIFY))
    DllStructSetData($tNOTIFY, "Wnd", $TRAY_ICON_GUI)
    DllStructSetData($tNOTIFY, "ID", $AUT_NOTIFY_ICON_ID)
    DllStructSetData($tNOTIFY, "Icon", $hIcon)
    DllStructSetData($tNOTIFY, "Flags", BitOR($NIF_ICON, $NIF_MESSAGE))
    DllStructSetData($tNOTIFY, "CallbackMessage", $AUT_WM_NOTIFYICON)
    Local $aRet = DllCall($g_hDll, "int", "Shell_NotifyIconW", "dword", $NIM_MODIFY, "ptr", DllStructGetPtr($tNOTIFY))
    If (@error) Then Return SetError(1, 0, False)
    Return $aRet[0] <> 0
EndFunc  ;==>_WinAPI_TraySetHIcon

;Code below was generated by: 'File to Base64 String' Code Generator v1.20 Build 2015-01-20

Func _CreateIcon($sName, $dIcon)
    Local $hBmp = _GDIPlus_BitmapCreateFromMemory(_WinAPI_Base64Decode($dIcon))
    If @error Then Exit ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $dIcon --> " & $dIcon & @CRLF  & "   var: $hBmp --> " & $hBmp & @CRLF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)

    $g_oIconBase($sName) = _GDIPlus_HICONCreateFromBitmap($hBmp)
    _GDIPlus_BitmapDispose($hBmp)
EndFunc

Func _ReadIcons()
    Local $dIcon = 'AAABAAEAEBAAAAEACABoBQAAFgAAACgAAAAQAAAAIAAAAAEACAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAjI7EAIiKwACIirwAhIa4AICCtAB8frAAeHqoAHR2pABwcpwAbG6UAGRmkABgYogAXF6AAFhaeABQUnAATE5oAEhKZABAQlwAPD5UA8fHxAA0NkwAMDJEACwuPAAoKjQAICIwABweKAAYGiAAFBYcABASFAAMDhAACAoMAAQGCAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAADxAREhQVFhcYGRobHB0eHw4PEBESFBUWFxgZGhscHR4NDg8QERIUFRYXGBkaGxwdDA0ODxAREhQVFhcYGRobHAsMDQ4PEBETExUWFxgZGhsKCwwNDg8QExMUFRYXGBkaCQoLDA0ODxMTEhQVFhcYGQgJCgsTExMTExMTExUWFxgHCAkKExMTExMTExMUFRYXBgcICQoLDBMTDxAREhQVFgUGBwgJCgsTEw4PEBESFBUEBQYHCAkKExMNDg8QERIUAwQFBgcICQoLDA0ODxAREgIDBAUGBwgJCgsMDQ4PEBEBAgMEBQYHCAkKCwwNDg8QAAECAwQFBgcICQoLDA0ODwAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA='
    _CreateIcon("live", $dIcon)

    $dIcon = 'AAABAAEAEBAAAAEACABoBQAAFgAAACgAAAAQAAAAIAAAAAEACAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAjI7EAIiKwACIirwAhIa4AICCtAB8frAAeHqoAHR2pABwcpwAbG6UAGRmkABgYogAXF6AAFhaeABQUnAATE5oAEhKZABAQlwAPD5UA8fHxAA0NkwAMDJEACwuPAAoKjQAICIwABweKAAYGiAAFBYcABASFAAMDhAACAoMAAQGCAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAADxAREhQVFhcYGRobHB0eHw4PEBESFBUWFxgZGhscHR4NDg8QERIUFRYXGBkaGxwdDA0ODxAREhQVFhcYGRobHAsMDQ4PEBETExUWFxgZGhsKCwwNDg8QExMUFRYXGBkaCQoLDA0ODxMTEhQVFhcYGQgJCgsMDQ4TExESFBUWFxgHCAkKCwwNExMQERIUFRYXBgcICQoLDBMTDxAREhQVFgUGBwgJCgsTEw4PEBESFBUEBQYHCAkKExMNDg8QERIUAwQFBgcICQoLDA0ODxAREgIDBAUGBwgJCgsMDQ4PEBEBAgMEBQYHCAkKCwwNDg8QAAECAwQFBgcICQoLDA0ODwAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA='
    _CreateIcon("lock", $dIcon)
EndFunc  ;==>_ReadIcons

Func _WinAPI_Base64Decode($sB64String)
    Local $aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "ptr", 0, "dword*", 0, "ptr", 0, "ptr", 0)
    If @error Or Not $aCrypt[0] Then Return SetError(1, 0, "")
    Local $bBuffer = DllStructCreate("byte[" & $aCrypt[5] & "]")
    $aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "struct*", $bBuffer, "dword*", $aCrypt[5], "ptr", 0, "ptr", 0)
    If @error Or Not $aCrypt[0] Then Return SetError(2, 0, "")
    Return Binary(DllStructGetData($bBuffer, 1))
EndFunc  ;==>_WinAPI_Base64Decode

Alles anzeigen

**autoiter**

Bitnugger Cool. Das ist, denke ich, schön effizient.

Slevin

Bitnugger, das ist wirklich gut, danke

Drei Fragen hätte ich da noch zu deiner Version:

1. Hat das separate Deklarieren und Schließen von Global $g_hDll = DllOpen("shell32.dll") einen Vorteil?

2. Wieso hast du beim Setzen des Tray-Icons ein Error-Handling angefügt, würden eventuelle Fehlermöglichkeiten nicht schon vorab ausgeschlossen werden?

3. Kann man einem Errorhandling auch eine UDF zuweisen, in etwa so: If @error Then _exitFunction() ConsoleWrite("@@ Debug line" & ...

**Bitnugger**

1.) Globale Variablen sollten nicht innerhalb von Funktionen deklariert werden. Genauso schlimm, finde ich, wenn sich globale Variablen nicht von lokalen unterscheiden lassen, deshalb beginnen meine globalen immer mit $g_. Ich achte aber sehr darauf, dass ich möglichst mit lokalen Variablen arbeite, zumal das bei sehr großen Scripten die Fehlerträchtigkeit deutlich minimiert. Das DllOpen ergibt jetzt bei deinen 20-30 Icons nicht wirklich einen Mehrwert, aber wirklich wichtig wird es, wenn die DLL während der Laufzeit immer wieder angesprochen wird, z. B. mit der Funktion _IsPressed. Doch es kostet ja nichts.

2.) Die habe ich drin gelassen, damit man sehen kann, wie ich die Sachen in der Debug-Phase angehe. Später würde ich dann einfach ein Return SetError(1, 0, False) zurückgeben oder kurz eine Message einblenden.

3.) So ähnlich... wie genau man das angeht, ist aber wohl eine Sache des persöhnlichen Geschmacks, wobei ich dann sehr darauf achte, dass die Stelle des Fehlers mithilfe des Errors leicht auffindbar ist... also nicht immer SetError( 1, 0... oder du machstes mit _Assert.

_Assert ( $sCondition [, $bExit = True [, $iCode = 0x7FFFFFFF [, $sLine = @ScriptLineNumber]]] )

AutoIt

; ...
If @error Then _ErrorExit(77749, 2, '_WinAPI_DestroyIcon($hIcon)')
; ...

Func _ErrorExit($iError, $iExtended, $sErrMsg, $iLineNumer = @ScriptLineNumber)
    If $iError Then ConsoleWrite(StringFormat('Debug line (%5i)  #Error: %i \t Extended: %i \t #ErrMsg: %s\n', $iLineNumer, $iError, $iExtended, $sErrMsg))
    Exit $iError
EndFunc

PS: In deinem zweiten Script Teil 2, was passiert denn da mit den Bitmaps? Das ist nämlich auch wieder ein Speicherleck!

Slevin

Zitat von Bitnugger

PS: In deinem zweiten Script Teil 2, was passiert denn da mit den Bitmaps? Das ist nämlich auch wieder ein Speicherleck!

Stimmt, aber nur ein bedingtes, weil es nur maximal einmal mit allen Icons befüllt wird (wenn ich das jetzt halbwegs korrekt verstanden habe)

**Bitnugger**

Richtig... doch Fakt ist, du hast es nicht gesehen... und das sind dann nachher in größeren Sripten genau die Fehler, die ich keinem wünsche.

Slevin

Ja leider, ich muss mich da einfach noch mehr in die Materie einlesen, von daher bin auch dankbar für jeden Hinweis und all die Hilfe, die ich hier erhalte.

Ich bastel für gewöhnlich einfach so vor mich hin, meist Sachen in VBS. Aber memory-management hatte ich nie nötig zu beachten, da fehlts mir also einfach an Wissen.

Aber du hast recht, ich werde das Script in Zukunft sicher auch für andere Zwecke umbauen, und dann wäre sowas nicht gerade smooth...