Tool zum verschieben von Dateien

kayes

Hallo Zusammen!

Folgende Konstellation:

Wir laden in ein nicht veränderbares Verzeichnis Dateien herunter. Hierbei handelt es sich um verschiedene Dateitypen.

Diese Dateien sollen über ein Tool weiter verschoben werden in ein Projektverzeichnis.

In dem weißen Feld soll eine Auflistung der Dateien aus dem Stammverzeichnis mit Checkboxen erscheinen.

Diese Dateien kann ich entweder einfach selektieren oder gesamt (Alles markieren und Auswahl umkehren). Die selektierten Dateien sollen in ein Unterverzeichnis

verschoben werden. Das Unterverzeichnis wird über die Radios DATA 1 und DATA 2 gewählt. In der Inputbox wird das Projekt eingetragen unter dem die Unterverzeichnisse liegen.

Die Buttons unten sollten sich eigentlich selbst erklären.

Ich habe versucht, aus 2 hier erstellten Scripten ein neues zusammen zu basteln. Hat aber nicht so gut funktioniert.

Vorschläge?

xSunLighTx3

Moin, bevor du sowas selbst codest, könnte ich dir folgende Software empfehlen: https://freefilesync.org/

Ist kostenlos und open source.

Benutze ich selbst, um Dateien zu synchronisieren.

kayes

Zitat

Benutze ich selbst, um Dateien zu synchronisieren.

Ich möchte aber nicht synchronisieren sondern Daten verschieben um Platz zu schaffen für die nächsten Daten.

kayes

@Zeitriss

Hallo Zeitriss, kannst du dich noch an das Script erinnern?

Kopierhilfe

Dein Script von damals soll in Teilen wiederverwendet werden.

Wie passe ich einen Teil an, das nur Dateien und nicht Ordner im Listview angezeigt wird?

**Musashi**

Zitat von kayes

Wie passe ich einen Teil an, das nur Dateien und nicht Ordner im Listview angezeigt wird?

Um die Listview zu besetzen, kannst Du die Dateien mittels _FileListToArrayRec oder _FileListToArray vorher einlesen. Falls Du nur Dateien - keine Ordner - im Array haben möchtest, dann :
$FLTAR_FILES (1) - Return files only

setzen (siehe Hilfe).

Gruß Musashi

**autoBert**

Stell doch einfach dein bisheriges Skript ein, dann ist es einfacher.

Ansonsten in der benutzten Func zum Ermitteln der Dateien (z. B.: _FileListToArrayRec) einfach den entsprechenden Schalter ($FLTAR_FileS) benutzen. Eine andere Möglichkeit, allerndings evtl langsamer, in der sicher benutzeten Schleife vor jedem Eintrag auf Datei bzw. Ordner prüfen.

mfg (auto)Bert

**Musashi**

Hi kayes

Hier ein Basisskript als Arbeitsgrundlage :

-> Dateien aus einem Verzeichnis einlesen und in Listview eintragen (mit Checkbox) ==> OK

-> Alles markieren ==> OK

-> Auswahl umkehren ==> OK

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=MyAutoIt3_Yellow.ico
#AutoIt3Wrapper_UseUpx = N
#AutoIt3Wrapper_Res_SaveSource = N
#AutoIt3Wrapper_Res_Description = Kayes FileMove-Tool
#AutoIt3Wrapper_Res_Fileversion = 1.0.0.1
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

; ===============================================================================================
; Programmentwurf zum Verschieben (FileMove) von Dateien aus Quellordner in Zielordner
; erstellt von @Musashi am 05.05.2019
; Letzte Änderung am 05.05.2019
; ===============================================================================================
; Die Pfade von Quell- und Zielordner können in der Filemove.ini-Datei angepasst werden.
; ===============================================================================================================================
#include <File.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <ButtonConstants.au3>
#include <WinAPIShPath.au3>
#include <GuiListView.au3>
#include <ListviewConstants.au3>

Opt('MustDeclareVars', 1)

Global $sSourceDir ; Quellordner
Global $sDestDir1, $sDestDir2 ; Zielordner
Global $aFileList  ; Dateiliste des Quellordners (inkl. Unterverzeichnisse)
Global $hListView

; Einlesen der Verzeichnisse aus "Filemove.ini" :
$sSourceDir    = IniRead("Filemove.ini", "Directories", "StammDir", @ScriptDir)
$sDestDir1     = IniRead("Filemove.ini", "Directories", "DATADir1", "")
$sDestDir1     = IniRead("Filemove.ini", "Directories", "DATADir2", "")


Global $iDPIMetricsApplied  ; Wert aus Registry (dezimal)
Global $fDPI_SF             ; Skalierungsfaktor (scale factor)
$iDPIMetricsApplied = RegRead("HKEY_CURRENT_USER\Control Panel\Desktop\WindowMetrics", "AppliedDPI")
If @error Then
    $iDPIMetricsApplied = 120  ; (125%)
EndIf
If ($iDPIMetricsApplied >= 96) And ($iDPIMetricsApplied <= 144) Then
    If $iDPIMetricsApplied = 120 Then
        $fDPI_SF = 1
    Else
        $fDPI_SF = Round(120 / $iDPIMetricsApplied, 2)
    EndIf
Else
    $fDPI_SF = 1
EndIf


; GUI aufrufen :
_MainGUI()

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _MainGUI
; -------------------------------------------------------------------------------------------------------------------------------
Func _MainGUI()
    Local $iGuiMsg, $hGUI
    Local $idSourceDir, $idDestDir
    Local $idBtnMove, $idBtnFinish, $idBtnCheckedRev, $idBtnCheckAll

    ; Einlesen der Dateien aus dem Quellordner :
    $aFileList = _FileListToArrayRec(_WinAPI_PathAddBackslash($sSourceDir), "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
    If @error Then
        MsgBox($MB_SYSTEMMODAL+$MB_ICONERROR, "Meldung : ", _
                "Fehler beim Einlesen der Dateien aus dem Quellordner" & @CRLF)
        Return
    EndIf

    Local $hFont = _WinAPI_CreateFont(18 * $fDPI_SF, 8 * $fDPI_SF, 0, 0, $FW_NORMAL)
    $hGUI = GUICreate(" Verschieben von Projektdateien", 1260, 980)
    GUISetFont(11 * $fDPI_SF, $FW_NORMAL, 1, "Arial")  ; Standardfont setzen

    $hListView = _GUICtrlListView_Create($hGUI, "Dateiliste : " & $sSourceDir, 20 , 100, 1200, 800)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_CHECKBOXES, $LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    _WinAPI_SetFont($hListView, $hFont, True)
    _GUICtrlListView_SetColumnWidth($hListView, 0, $LVSCW_AUTOSIZE_USEHEADER)

    ; ListViewItems erstellen :
    _GUICtrlListView_SetItemCount($hListView, 5000)
    For $i = 1 To UBound($aFileList) - 1
        _GUICtrlListView_AddItem($hListView, $aFileList[$i])
    Next

    $idBtnMove       = GUICtrlCreateButton("&Verschieben starten", 20, 950, 200, 30)
    $idBtnCheckAll   = GUICtrlCreateButton("Alles &markieren", 240, 950, 200, 30)
    $idBtnCheckedRev = GUICtrlCreateButton("Auswahl &umkehren", 460, 950, 200, 30)
    $idBtnFinish     = GUICtrlCreateButton("&Beenden", 680, 950, 200, 30, $BS_DEFPUSHBUTTON)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        $iGuiMsg = GUIGetMsg()

        Select
            Case $iGuiMsg = $GUI_EVENT_CLOSE
                ExitLoop


            Case $iGuiMsg = $idBtnFinish
                ExitLoop

            Case $iGuiMsg = $idBtnCheckedRev
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView)-1
                    If _GUICtrlListView_GetItemChecked($hListView, $i) Then
                        _GUICtrlListView_SetItemChecked($hListView, $i, False)
                    Else
                        _GUICtrlListView_SetItemChecked($hListView, $i, True)
                    EndIf
                Next


            Case $iGuiMsg = $idBtnCheckAll
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView)-1
                    If Not _GUICtrlListView_GetItemChecked($hListView, $i) Then
                        _GUICtrlListView_SetItemChecked($hListView, $i)
                    EndIf
                Next


            Case $iGuiMsg = $idBtnMove  ; Dateien verschieben :
                MsgBox($MB_SYSTEMMODAL+$MB_ICONINFORMATION, "Meldung : ", "...noch realisieren :-) " & @CRLF)


        EndSelect
    WEnd
    _WinAPI_DeleteObject($hFont)
    GUIDelete($hGUI)
EndFunc   ;_MainGUI


; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _DirectoryExists
; -------------------------------------------------------------------------------------------------------------------------------
Func _DirectoryExists($sDirPath )
    Local $bReturnValue = False
    If FileExists($sDirPath) AND StringInStr(FileGetAttrib($sDirPath), 'D') Then $bReturnValue = True
    Return $bReturnValue
EndFunc ;==>_DirectoryExists

Alles anzeigen

Ini-Datei (noch sinnvoll füllen) :

Code

; Standardverzeichnisse
[Directories]
;StammDir = ""
;DATADir1 = ""
;DATADir2 = ""

->Verschieben starten ==> noch nicht realisiert

Hier musst Du Dir nur noch die Zielpfade 'zusammenbasteln' und einbauen. Das hatten wir aber bereits alles ausführlich im Thread : Kopiertool

besprochen - solltest Du also selbst hinbekommen

Gruß Musashi

kayes

Code, so far.....

C

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <FileConstants.au3>
#include <Array.au3>
#include <ColorConstants.au3>
;
; ==============================================================================
; Projekt       : Daten verschieben
; bearbeitet am : 05.05.2019
; ==============================================================================
; Danksagungen  :
; Erstellt unter Mithilfe aus dem autoit.de-Forum von :
; @Musashi, @BugFix, @autoiter, @alpines, @Code-Jack, @zeitriss  usw.
; ==============================================================================
;  Variablendeklaration
;
Global $g_sPath_Source = "F:\TESTUMGEBUNG\Ursprungsdaten"
Global $g_aLV_Folder[0][2]
#GUI Start
$Form1_1 = GUICreate("Daten verschieben (c) Kayes", 615, 438, 250, 284)
$Radio1 = GUICtrlCreateRadio("DATA 1", 16, 48, 70, 17)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", "Explorer", "wstr", 0) ; _WinAPI_SetWindowTheme($hWnd, $sName = Default, $sList = Default)
$Radio2 = GUICtrlCreateRadio("DATA 2", 104, 48, 70, 17)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", "Explorer", "wstr", 0) ; _WinAPI_SetWindowTheme($hWnd, $sName = Default, $sList = Default)
_SetRadioColor()
$projektname = GUICtrlCreateInput("19", 208, 40, 281, 32)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
Global $g_idLV_SelectFolder = GUICtrlCreateListView("Projekt", 20, 100, 575, 280, $LVS_LIST, $LVS_EX_CHECKBOXES)
$aktualisieren = GUICtrlCreateButton("Aktualisieren", 20, 392, 120, 33)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$verschieben = GUICtrlCreateButton("Verschieben", 475, 392, 120, 33)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$umkehren = GUICtrlCreateButton("Auswahl umkehren", 323, 392, 120, 33)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$amarkieren = GUICtrlCreateButton("Alles markieren", 172, 392, 120, 33)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)
#Ende GUI

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $aktualisieren
            aktualisieren()
        Case $verschieben
            MoveFiles()
        Case $radio1
            _SetRadioColor()
        Case $radio2
            _SetRechnerColor()
        Case $umkehren
             umkehren()
          Case $amarkieren
             markieren()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
Func Event_Button_SelectInv(); Invertiert die Auswahl des ListView
   Local $iState
   GUICtrlSetState($g_idLV_SelectFolder, $GUI_HIDE)
   For $i = 0 to UBound($g_aLV_Folder) -1
      $iState = GUICtrlRead($g_aLV_Folder[$i][1], 1)
      If BitAND($iState, $GUI_CHECKED) Then
         GUICtrlSetState($g_aLV_Folder[$i][1], $GUI_UNCHECKED)
      Else
         GUICtrlSetState($g_aLV_Folder[$i][1], $GUI_CHECKED)
      EndIf
   Next
   GUICtrlSetState($g_idLV_SelectFolder, $GUI_SHOW)
EndFunc
Func Event_Button_Start(); Listet die ausgewählten Projekte auf und ruft CopyProject() auf
   If Not CheckFolder() Then Return
   GUICtrlSetState($g_idButton_Start, $GUI_DISABLE)
   GUICtrlSetData($g_idButton_Start, "Arbeitet")
   Local $aFolderList[UBound($g_aLV_Folder)][2]
   Local $iCounter = 0
   For $i = 0 to UBound($g_aLV_Folder) -1
      If BitAND(GUICtrlRead($g_aLV_Folder[$i][1], 1), $GUI_CHECKED) Then
      $aFilesList[$iCounter][0] = $g_aLV_Files[$i][0]
      $aFilesList[$iCounter][1] = $g_aLV_Files[$i][1]
      $iCounter += 1
      EndIf
   Next
   ReDim  $aFilesList[$iCounter][2]
   CopyProject($aFilesList, $g_sPath_Source, $g_sPath_Dest)
   GUICtrlSetState($g_idButton_Start, $GUI_ENABLE)
   GUICtrlSetData($g_idButton_Start, "Kopieren")
EndFunc
Func Event_Button_Source(); Auswählen des Quellordners über den Benützer
   Local $sNewPath = FileSelectFolder("Bitte den Projekt-Ordner wählen", $g_sPath_Source)
   If @error Then Return
   $g_sPath_Source = $sNewPath
   GUICtrlSetData($g_idInput_Path_Source, $sNewPath)
   LoadFilesInListView($g_sPath_Source)
   GUICtrlSetState($g_idButton_Save, $GUI_ENABLE)
EndFunc
Func Event_Close()
   Exit
EndFunc
Func LoadFilesInListView($sPath); Listet die Projekte aus dem Quellordner auf, wenn sie dem Schema entsprechenden.
   For $i = 0 to UBound($g_aLV_Folder) -1
      $g_aLV_Files[$i][0] = ""
      GUICtrlDelete($g_aLV_Folder[$i][1])
   Next
   Local $aFiles = _FileListToArray($sPath, "*", $FLTA_FILES, False)
   If Not IsArray($aFiles) Then
      ReDim $g_aLV_Files[0][2]
      Return
   EndIf
   Local $iCounter = 0
   ReDim $g_aLV_Files[ $aFiles[0] ][2]
   For $i = 1 to $aFiles[0]
      If StringRegExp($aFiles[$i], "\d\d\d\d....") Then
         $g_aLV_Files[$iCounter][0] = $aFolder[$i]
         $g_aLV_Files[$iCounter][1] = GUICtrlCreateListViewItem($aFiles[$i], $g_idLV_SelectFiles)
         $iCounter += 1
      EndIf
   Next
   ReDim $g_aLV_Files[ $iCounter ][2]
EndFunc

Func movefiles()
    ;Prüfung der Radios und setzen der entsprechende Zielvariablen
    If GUICtrlRead($radio1) = $GUI_CHECKED Then $dest = "\DATA1"
    If GUICtrlRead($radio2) = $GUI_CHECKED Then $dest = "\DATA2"
        Local $source =
        Return
 EndFunc   ;==>movefiles

; Farbe für aktiven Radiobutton setzen :
Func _SetRadioColor()
    If GUICtrlRead($radio1) = $GUI_CHECKED Then
        GUICtrlSetColor($rradio1, $COLOR_RED)
    Else
        GUICtrlSetColor($radio1, $COLOR_BLACK)
    EndIf
    If GUICtrlRead($radio2) = $GUI_CHECKED Then
        GUICtrlSetColor($radio2, $COLOR_RED)
    Else
        GUICtrlSetColor($radio2, $COLOR_BLACK)
    EndIf
  EndFunc   ;==>_SetRadioColor

Alles anzeigen

xSunLighTx3

Zitat von kayes

Ich möchte aber nicht synchronisieren sondern Daten verschieben um Platz zu schaffen für die nächsten Daten.

Und das ist natürlich auch möglich, wenn du mal einen Blick drauf geworfen hättest.

Ist aber auch egal, wollte es nur nochmal ergänzen.

kayes

So, Musashi ,

ich habe dein Script bearbeitet und getestet.

Es funktioniert. Was mir noch fehlen würde wäre ein Aktualisieren (also neu einlesen des Pfades)

Edit: Beim Programmstart sind noch keine Dateien vorhanden. Das Script gibt eine Fehlermeldung aus. Es soll aber eine leere Filelist anzeigen und nachdem Dateien im Ursprungspfad vorhanden sind über den Aktualisieren Button erscheinen.

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=MyAutoIt3_Yellow.ico
#AutoIt3Wrapper_UseUpx = N
#AutoIt3Wrapper_Res_SaveSource = N
#AutoIt3Wrapper_Res_Description = Kayes FileMove-Tool
#AutoIt3Wrapper_Res_Fileversion = 1.0.0.1
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
; ===============================================================================================
; Programmentwurf zum Verschieben (FileMove) von Dateien aus Quellordner in Zielordner
; erstellt von @Musashi am 05.05.2019
; ergänzt und bearbeitet von @kayes am 05.05.2019
; Letzte Änderung am 05.05.2019
; ===============================================================================================
; Die Pfade von Quell- und Zielordner können in der Filemove.ini-Datei angepasst werden.
; ===============================================================================================================================
#include <File.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <ButtonConstants.au3>
#include <WinAPIShPath.au3>
#include <GuiListView.au3>
#include <ListviewConstants.au3>
Opt('MustDeclareVars', 1)
Global $sSourceDir ; Quellordner
Global $sDestDir ; partieller Zielordner
Global $projektname
Global $dest
Global $idEditProjekt
Global $MoveSuccess
Global $sDestDir1, $sDestDir2 ; Zielordner
Global $aFileList  ; Dateiliste des Quellordners (inkl. Unterverzeichnisse)
Global $hListView
; Einlesen der Verzeichnisse aus "Filemove.ini" :
$sSourceDir    = "F:\TESTUMGEBUNG\Ursprungsdaten"
$sDestDir     = "F:\TESTUMGEBUNG\DATEN"
Global $iDPIMetricsApplied  ; Wert aus Registry (dezimal)
Global $fDPI_SF             ; Skalierungsfaktor (scale factor)
$iDPIMetricsApplied = RegRead("HKEY_CURRENT_USER\Control Panel\Desktop\WindowMetrics", "AppliedDPI")
If @error Then
    $iDPIMetricsApplied = 120  ; (125%)
EndIf
If ($iDPIMetricsApplied >= 96) And ($iDPIMetricsApplied <= 144) Then
    If $iDPIMetricsApplied = 120 Then
        $fDPI_SF = 1
    Else
        $fDPI_SF = Round(120 / $iDPIMetricsApplied, 2)
    EndIf
Else
    $fDPI_SF = 1
EndIf
; GUI aufrufen :
_MainGUI()
; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _MainGUI
; -------------------------------------------------------------------------------------------------------------------------------
Func _MainGUI()
    Local $iGuiMsg, $hGUI
    Local $idSourceDir, $idDestDir
    Local $idBtnMove, $idBtnFinish, $idBtnCheckedRev, $idBtnCheckAll
    ; Einlesen der Dateien aus dem Quellordner :
    $aFileList = _FileListToArrayRec(_WinAPI_PathAddBackslash($sSourceDir), "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
    If @error Then
        MsgBox($MB_SYSTEMMODAL+$MB_ICONERROR, "Meldung : ", _
                "Fehler beim Einlesen der Dateien aus dem Quellordner" & @CRLF)
        Return
    EndIf
    Local $hFont = _WinAPI_CreateFont(18 * $fDPI_SF, 8 * $fDPI_SF, 0, 0, $FW_NORMAL)
    $hGUI = GUICreate(" Verschieben von Projektdateien", 950, 910)
    Global $Radio1 = GUICtrlCreateRadio("DATA 1", 16, 48, 70, 17)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", "Explorer", "wstr", 0) ; _WinAPI_SetWindowTheme($hWnd, $sName = Default, $sList = Default)
    Global $Radio2 = GUICtrlCreateRadio("DATA 2", 104, 48, 70, 17)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", "Explorer", "wstr", 0) ; _WinAPI_SetWindowTheme($hWnd, $sName = Default, $sList = Default)
    Global $Projekt
    Global $idEditProjekt = GUICtrlCreateEdit("", 352, 28, 180, 40, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_WANTRETURN))
    GUICtrlSetData($idEditProjekt, StringRight(@YEAR, 2))
    GUICtrlSetFont($idEditProjekt, 18, 400, 0, "MS Sans Serif")
    GUICtrlSetState($idEditProjekt, $GUI_FOCUS)
    GUISetFont(11 * $fDPI_SF, $FW_NORMAL, 1, "Arial")  ; Standardfont setzen
    $hListView = _GUICtrlListView_Create($hGUI, "Dateiliste : " & $sSourceDir, 20 , 100, 900, 700)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_CHECKBOXES, $LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    _WinAPI_SetFont($hListView, $hFont, True)
    _GUICtrlListView_SetColumnWidth($hListView, 0, $LVSCW_AUTOSIZE_USEHEADER)
    ; ListViewItems erstellen :
    _GUICtrlListView_SetItemCount($hListView, 5000)
    For $i = 1 To UBound($aFileList) - 1
        _GUICtrlListView_AddItem($hListView, $aFileList[$i])
    Next
    $idBtnMove       = GUICtrlCreateButton("&Verschieben starten", 20, 850, 200, 30)
    $idBtnCheckAll   = GUICtrlCreateButton("Alles &markieren", 240, 850, 200, 30)
    $idBtnCheckedRev = GUICtrlCreateButton("Auswahl &umkehren", 460, 850, 200, 30)
    $idBtnFinish     = GUICtrlCreateButton("&Beenden", 680, 850, 200, 30, $BS_DEFPUSHBUTTON)
    GUISetState(@SW_SHOW, $hGUI)
    While 1
        $iGuiMsg = GUIGetMsg()
        Select
            Case $iGuiMsg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $iGuiMsg = $idBtnFinish
                ExitLoop
            Case $iGuiMsg = $idBtnCheckedRev
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView)-1
                    If _GUICtrlListView_GetItemChecked($hListView, $i) Then
                        _GUICtrlListView_SetItemChecked($hListView, $i, False)
                    Else
                        _GUICtrlListView_SetItemChecked($hListView, $i, True)
                    EndIf
                Next
            Case $iGuiMsg = $idBtnCheckAll
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView)-1
                    If Not _GUICtrlListView_GetItemChecked($hListView, $i) Then
                        _GUICtrlListView_SetItemChecked($hListView, $i)
                    EndIf
                Next
            Case $iGuiMsg = $idBtnMove  ; Dateien verschieben :
                ;MsgBox($MB_SYSTEMMODAL+$MB_ICONINFORMATION, "Meldung : ", "...noch realisieren :-) " & @CRLF)
                _filemove()
        EndSelect
    WEnd
    _WinAPI_DeleteObject($hFont)
    GUIDelete($hGUI)
EndFunc   ;_MainGUI
; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _DirectoryExists
; -------------------------------------------------------------------------------------------------------------------------------
Func _DirectoryExists($sDirPath )
    Local $bReturnValue = False
    If FileExists($sDirPath) AND StringInStr(FileGetAttrib($sDirPath), 'D') Then $bReturnValue = True
    Return $bReturnValue
 EndFunc ;==>_DirectoryExists

 Func _filemove()
    ;Prüfung der Radios und setzen der entsprechende Zielvariablen
    If GUICtrlRead($radio1) = $GUI_CHECKED Then $dest = "DATA1\"
    If GUICtrlRead($radio2) = $GUI_CHECKED Then $dest = "DATA2\"
    Local $jjjj = "20" & StringLeft(GUICtrlRead($idEditProjekt), 2)
    Local $pro = GUICtrlRead($idEditProjekt)
    ; Filemove Befehl
    FileMove ( $sSourceDir, $sDestDir & "\" & $jjjj & "\" & $pro & "\" & $dest , $FC_OVERWRITE + $FC_CREATEPATH )
    Return
EndFunc   ;==>_filemove

Alles anzeigen

**Musashi**

Zitat von kayes

ich habe dein Script bearbeitet und getestet.

Es funktioniert. Was mir noch fehlen würde wäre ein Aktualisieren (also neu einlesen des Pfades)

Edit: Beim Programmstart sind noch keine Dateien vorhanden. Das Script gibt eine Fehlermeldung aus. Es soll aber eine leere Filelist anzeigen und nachdem Dateien im Ursprungspfad vorhanden sind über den Aktualisieren Button erscheinen.

Ich habe mein Basisskript mal nach Deinen Wünschen erweitert.

Neu :

-> 'Aktualisieren' - Button ==> akt. Fileliste des Quellordners wird eingelesen

-> Fehlermeldung wird beim Programmstart nur ausgegeben, falls der Quellordner nicht existiert.

-> ist der Quellordner vorhanden aber leer, dann -> 'Aktualisieren' , sobald was drin ist.

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=MyAutoIt3_Yellow.ico
#AutoIt3Wrapper_UseUpx = N
#AutoIt3Wrapper_Res_SaveSource = N
#AutoIt3Wrapper_Res_Description = Kayes FileMove-Tool
#AutoIt3Wrapper_Res_Fileversion = 1.0.0.2
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

; ===============================================================================================
; Programmentwurf zum Verschieben (FileMove) von Dateien aus Quellordner in Zielordner
; erstellt von @Musashi am 05.05.2019
; Letzte Änderung am 05.05.2019 - 23:00 Uhr
; ===============================================================================================
; Die Pfade von Quell- und Zielordner können in der Filemove.ini-Datei angepasst werden.
; ===============================================================================================================================
#include <File.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <ButtonConstants.au3>
#include <WinAPIShPath.au3>
#include <GuiListView.au3>
#include <ListviewConstants.au3>

Opt('MustDeclareVars', 1)

Global $sSourceDir ; Quellordner
Global $sDestDir1, $sDestDir2 ; Zielordner
Global $aFileList  ; Dateiliste des Quellordners (inkl. Unterverzeichnisse)
Global $hListView

; Einlesen der Verzeichnisse aus "Filemove.ini" :
$sSourceDir    = IniRead("Filemove.ini", "Directories", "StammDir", @ScriptDir)
$sDestDir1     = IniRead("Filemove.ini", "Directories", "DATADir1", "")
$sDestDir1     = IniRead("Filemove.ini", "Directories", "DATADir2", "")


Global $iDPIMetricsApplied  ; Wert aus Registry (dezimal)
Global $fDPI_SF             ; Skalierungsfaktor (scale factor)
$iDPIMetricsApplied = RegRead("HKEY_CURRENT_USER\Control Panel\Desktop\WindowMetrics", "AppliedDPI")
If @error Then
    $iDPIMetricsApplied = 120  ; (125%)
EndIf
If ($iDPIMetricsApplied >= 96) And ($iDPIMetricsApplied <= 144) Then
    If $iDPIMetricsApplied = 120 Then
        $fDPI_SF = 1
    Else
        $fDPI_SF = Round(120 / $iDPIMetricsApplied, 2)
    EndIf
Else
    $fDPI_SF = 1
EndIf


; GUI aufrufen :
_MainGUI()

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _MainGUI
; -------------------------------------------------------------------------------------------------------------------------------
Func _MainGUI()
    Local $iGuiMsg, $hGUI
    Local $idSourceDir, $idDestDir
    Local $iSourceDirReadError = False, $iExtended

    ; GUI-Elemente :
    Local $idBtnMove, $idBtnFinish, $idBtnRefresh, $idBtnCheckedRev, $idBtnCheckAll

    ; Einlesen der Dateien aus dem Quellordner :
    ; -> existiert der Pfad nicht oder ist ungültig, dann Fehlermeldung
    ; -> ist der Pfad leer, dann später über 'Aktualisieren' gehen
    $aFileList = _FileListToArrayRec(_WinAPI_PathAddBackslash($sSourceDir), "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
    $iSourceDirReadError = @error
    $iExtended           = @extended
    If $iSourceDirReadError And ($iExtended == 1) Then
        MsgBox($MB_SYSTEMMODAL+$MB_ICONWARNING, "Meldung : ", _
                "Quellordner nicht gefunden oder ungültig : " & @CRLF & @CRLF & _
                _WinAPI_PathAddBackslash($sSourceDir) & @CRLF)
        Return
    EndIf


    Local $hFont = _WinAPI_CreateFont(18 * $fDPI_SF, 8 * $fDPI_SF, 0, 0, $FW_NORMAL)
    $hGUI = GUICreate(" Verschieben von Projektdateien", 1260, 980)
    GUISetFont(11 * $fDPI_SF, $FW_NORMAL, 1, "Arial")  ; Standardfont setzen

    $hListView = _GUICtrlListView_Create($hGUI, "Dateiliste : " & $sSourceDir, 20 , 100, 1200, 800)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_CHECKBOXES, $LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    _WinAPI_SetFont($hListView, $hFont, True)
    _GUICtrlListView_SetColumnWidth($hListView, 0, $LVSCW_AUTOSIZE_USEHEADER)
    _GUICtrlListView_SetItemCount($hListView, 5000)

    ; ListViewItems befüllen, falls im SourceDir Daten vorhanden sind :
    If Not $iSourceDirReadError Then
        _GUICtrlListView_BeginUpdate($hListView)
        For $i = 1 To UBound($aFileList) - 1
            _GUICtrlListView_AddItem($hListView, $aFileList[$i])
        Next
        _GUICtrlListView_EndUpdate($hListView)
    EndIf

    $idBtnRefresh    = GUICtrlCreateButton("&Aktualisieren", 20, 950, 200, 30)
    $idBtnCheckAll   = GUICtrlCreateButton("Alles &markieren", 230, 950, 200, 30)
    $idBtnCheckedRev = GUICtrlCreateButton("Auswahl &umkehren", 440, 950, 200, 30)
    $idBtnMove       = GUICtrlCreateButton("&Verschieben starten", 650, 950, 200, 30)
    $idBtnFinish     = GUICtrlCreateButton("&Beenden", 900, 950, 200, 30, $BS_DEFPUSHBUTTON)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        $iGuiMsg = GUIGetMsg()

        Select
            Case $iGuiMsg = $GUI_EVENT_CLOSE
                ExitLoop


            Case $iGuiMsg = $idBtnFinish
                ExitLoop


            Case $iGuiMsg = $idBtnRefresh
                _GUICtrlListView_BeginUpdate($hListView)
                _GUICtrlListView_DeleteAllItems($hListView)
                _GUICtrlListView_EndUpdate($hListView)

                ; ListViewItems befüllen, falls im SourceDir Daten vorhanden sind :
                $aFileList = _FileListToArrayRec(_WinAPI_PathAddBackslash($sSourceDir), "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
                $iSourceDirReadError = @error
                If Not $iSourceDirReadError Then
                    _GUICtrlListView_BeginUpdate($hListView)
                    For $i = 1 To UBound($aFileList) - 1
                        _GUICtrlListView_AddItem($hListView, $aFileList[$i])
                    Next
                    _GUICtrlListView_EndUpdate($hListView)
                EndIf


            Case $iGuiMsg = $idBtnCheckedRev
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView)-1
                    If _GUICtrlListView_GetItemChecked($hListView, $i) Then
                        _GUICtrlListView_SetItemChecked($hListView, $i, False)
                    Else
                        _GUICtrlListView_SetItemChecked($hListView, $i, True)
                    EndIf
                Next


            Case $iGuiMsg = $idBtnCheckAll
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView)-1
                    If Not _GUICtrlListView_GetItemChecked($hListView, $i) Then
                        _GUICtrlListView_SetItemChecked($hListView, $i)
                    EndIf
                Next


            Case $iGuiMsg = $idBtnMove  ; Dateien verschieben :
                MsgBox($MB_SYSTEMMODAL+$MB_ICONINFORMATION, "Meldung : ", "...noch realisieren :-) " & @CRLF)


        EndSelect
    WEnd
    _WinAPI_DeleteObject($hFont)
    GUIDelete($hGUI)
EndFunc   ;_MainGUI


; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _DirectoryExists
; -------------------------------------------------------------------------------------------------------------------------------
Func _DirectoryExists($sDirPath )
    Local $bReturnValue = False
    If FileExists($sDirPath) AND StringInStr(FileGetAttrib($sDirPath), 'D') Then $bReturnValue = True
    Return $bReturnValue
EndFunc ;==>_DirectoryExists

Alles anzeigen

Zitat von Musashi

->Verschieben starten ==> noch nicht realisiert

Hier musst Du Dir nur noch die Zielpfade 'zusammenbasteln' und einbauen. Das hatten wir aber bereits alles ausführlich im Thread : Kopiertool

besprochen - solltest Du also selbst hinbekommen

Wie Du Dich wahrscheinlich erinnern kannst, war Dein Ausgangsskript damals bereits, nennen wir es mal freundlich, ziemlich verfrickelt . Wir haben es nur weitergeführt, da Du auf dieser Basis lernen und selbst entwickeln wolltest. Die fehlenden Elemente jetzt einfach per Copy&Paste in das neue Design zu übernehmen ist keine gute Idee. Du hast z.B. Global-Deklarationen in eine Funktion kopiert, und Deine _filemove Funktion wird so auch nicht funktionieren, da sie die Checked-Flags der FileList gar nicht berücksichtigt. Ich würde Dir raten, hier noch etwas Arbeit 'reinzustecken.

Gruß Musashi

Professor Bernd

@kayes

Auch wenn der Bereich hier Programmieranfragen ohne Gegenleistung heißt, würden sich die Helfenden bestimmt über ein kleines Dankeschön freuen. Oder habe ich was übersehen?

Bernd.

**BugFix**

Professor Bernd - Boah, seit wann gehst du denn Leichen schänden? (05/2019)

Professor Bernd

Och, mir war gerade danach. ... Nein im Ernst, sorry. Das habe ich irgendwie nicht richtig registriert. Ich hatte gesehen, dass der Threadersteller vor 3 Wochen im Forum war und nicht mehr auf das Alter des Threads geachtet.

Auf der Suche nach Lösungen für meine Programmier-Anliegen lese ich unglaublich viele Threads hier und im EN Forum, und freue mich wie Bolle, wenn ich Lösungen finde, oder selbst geholfen bekomme. Ich finde es klasse, wie viele hilfsbereite Menschen ihr Wissen teilen! Auch würde ich mich freuen, wenn weiterhin geholfen wird. Es gibt immer wieder User, die stellen eine Frage, und sobald sie Hilfe bekommen haben, sind sie weg. Das hat so manchen Helfer frustriert. Manche helfen einfach nicht mehr, andere werden verbittert und machen alles nieder. Beides ist schade. ... Aber manchmal vergisst man es einfach nur, seinen Thread abzuschließen.

Bernd.

**Musashi**

Zitat von Professor Bernd

Ich hatte gesehen, dass der Threadersteller vor 3 Wochen im Forum war

Der TE schaut immer mal wieder 'rein, wohl in der Hoffnung, dass auf wundersame Weise die perfekte Lösung vom Himmel gefallen ist .

Zitat von Professor Bernd

Es gibt immer wieder User, die stellen eine Frage, und sobald sie Hilfe bekommen haben, sind sie weg. [...]
Aber manchmal vergisst man es einfach nur, seinen Thread abzuschließen.

Dieser User ist ein echter Härtefall, der das Konzept "ohne Gegenleistung" an seine Grenzen treibt.

Wer Langeweile hat, kann sich ja mal den Thread Kopiertool (Start 2017 !!) anschauen. Dort wurde von vielen ( u.a. auch mir) über 100+ Beiträge versucht, dem TE zu helfen. Ich hatte zudem eine Konversation mit ihm, auf die ich aber, aus Gründen der Vertraulichkeit, nicht im Detail eingehen werde. Nur soviel sei gesagt :

Es gibt in der firmeninternen Software offenbar ein Modul, welches diese Kopiererei erledigen kann. Dieses Modul ist aber seit geraumer Zeit kostenpflichtig (zu einem m.M.n. erträglichen Preis). Hier wird wohl (wieder) am falschen Ende gespart .

Zitat von Professor Bernd

Das hat so manchen Helfer frustriert. Manche helfen einfach nicht mehr, andere werden verbittert und machen alles nieder. Beides ist schade.

Das möchte ich nicht ausschließen ! Glücklicherweise steht es aber jedem frei, ob, und in welchem Umfang, man helfen möchte .

Gruß Musashi

Professor Bernd

Zitat von Musashi

Dieser User ist ein echter Härtefall, der das Konzept "ohne Gegenleistung" an seine Grenzen treibt.

Du sprichst mir aus der Seele!

kayes

Tut mir leid Jungs, das ich hier wohl eine grundlegende Regel eines Forums verletzt habe.

Den Thread quasi "abzuschließen"

Nachdem ich eure letzten Kommentare hier gelesen habe ist mir überhaupt erst einmal in den Sinn gekommen, das ICH den Thread ja auch zumachen sollte nach erhaltener Hilfe.

Dafür möchte ich mich bei euch wirklich entschuldigen.

Zitat

Dieser User ist ein echter Härtefall, der das Konzept "ohne Gegenleistung" an seine Grenzen treibt.

Ja, tut mir leid, von eurem Standpunkt kann ich das durchaus verstehen.

Ich versuche jedoch erst einmal auf eigenem Weg mein Ziel zu finden. Da ich mich aber nicht ständig mit AutoIt beschäftige, scheitert es oft schon ziemlich weit am Anfang.

Dies erstellten Tools nutze ich beruflich und sind jetzt schon seit Jahren im täglichen Einsatz.

Alles was mir hilft, meine Arbeit zu optimieren ist mir willkommen und macht mir das Leben leichter.

Ja, es gibt auch Softwaremodule die wir kaufen könnten um das zumindest zum Teil zu erledigen.

Aber zum einen schießen wir mit der fertigen Software mit Kanonen auf Spatzen (was heißt das nur ein winzig kleiner Teil der Software für uns nutzbar ist, die Kosten aber den Nutzen bei WEITEM übersteigen) zum anderen

spielt noch ein weiteres Thema hier mit warum wir die Software (nicht eure) ungern bezahlen.

Der Softwarehersteller hat die Software nur als 2. Standbein. Sein 1. Standbein ist eine direkte Konkurrenz zu uns. Sprich, wir werfen einem direkten Konkurrenten auch noch unser Geld zu. Leider ist die angesprochene Software leider in unserer Branche Standard. Deswegen - so wenig wie möglich.

Desweiteren bleibt mir als Angestelltem auch nicht die Möglichkeit, meine eigene Geldbörse auf zumachen.

Alles in allem - Sollte ich hier einigen Leuten vor den Kopf gestossen haben, so tut mir dies sehr leid.

**Musashi**

Zitat von kayes

Alles in allem - Sollte ich hier einigen Leuten vor den Kopf gestossen haben, so tut mir dies sehr leid.

Na ja, sooo schlimm ist es nun auch wieder nicht - Du hast schließlich keinen Mord begangen .

Hast Du mein Skript vom 5. Mai 2019 denn mal probiert ? RE: Tool zum verschieben von Dateien

Gruß Musashi

kayes

Zitat von Musashi

Hast Du mein Skript vom 5. Mai 2019 denn mal probiert ? RE: Tool zum verschieben von Dateien

Ja, habe ich und es funktioniert auch. Es ist aber leider nicht in "Gebrauch" gegangen.

Ich bin gerade mit einem neuen Projekt beschäftigt und versuche gerade die entsprechenden Bauteile zusammenzuklauben.

Dieses Script gehört auch dazu

Alles wieder gut zusammen zu setzen wird wieder die Herausforderung sein.

Wobei ich momentan auch etwas ähhh gehemmt bin, nach Hilfe zu fragen....

**Musashi**

Zitat von kayes

Wobei ich momentan auch etwas ähhh gehemmt bin, nach Hilfe zu fragen....

Frag einfach, antworten ist ja freiwillig .

Tool zum verschieben von Dateien

Ähnliche Themen

ISN AutoIt Studio

Kopiertool

kleines Kopiertool für Fotos

Probleme bei _OL_ItemMove aus der Outlook-UDF