Selektierten Text in SynEdit finden

Professor Bernd

Hallo Leute.

Wie kann man den markierten Text aus einem SynEdit-Control ("TPSSynEdit") bekommen?

Ich sitze nun schon seit Tagen erfolglos daran, ein markiertes Wort aus dem SynEdit von PSPad (Haupt-Editor-Komponente) zu bekommen. Unzählige Hilfe- und Web-Seiten habe ich gelesen, viele, viele Test durchgeführt, doch ich finde es alleine nicht raus. Kann mir jemand helfen?

Hier ein Ausschnitt aus meinen Versuchen, SynEdit oder dem Parent ("TfChildEdit") etwas zu entlocken.

AutoIt

Dies ist kein lauffähiges Script, sondern stellt nur einen Ausschnitt meiner Tests dar!

;~ hWnd_ActvEdt hWnd_SynEdt ID_ActvEdt ID_SynEdt

    $tActiveEdit = PSPad_GetActiveEditor($hPSPad)

    Local $hwnd_ActvEd = $tActiveEdit.hWnd_ActvEdt
    Local $hwnd_SynEdt = $tActiveEdit.hWnd_SynEdt
    Local $iID_ActvEd = $tActiveEdit.ID_ActvEdt
    Local $iID_SynEdt = $tActiveEdit.ID_SynEdt


    $sClassNameChildEd = _WinAPI_GetClassName($hwnd_ActvEd)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sClassNameChildEd = ' & $sClassNameChildEd & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

    $sClassNameSynEd = _WinAPI_GetClassName($hwnd_SynEdt)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sClassNameSynEd = ' & $sClassNameSynEd & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hwnd_ActvEd = ' & $hwnd_ActvEd & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hwnd_SynEdt = ' & $hwnd_SynEdt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iID_ActvEd = ' & $iID_ActvEd & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iID_SynEdt = ' & $iID_SynEdt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


    $sSelTxt = ""

    $sSelTxt = ControlGetText($hPSPad, '', $hwnd_ActvEd)
    $sSelTxt = $sSelTxt & ' ' & ControlGetText($hPSPad, '', $hwnd_SynEdt)
    $sSelTxt = $sSelTxt & ' ' & ControlGetText($hPSPad, '', $iID_ActvEd)
    $sSelTxt = $sSelTxt & ' ' & ControlGetText($hPSPad, '', $iID_SynEdt)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sSelTxt = ' & $sSelTxt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


    $aCtrlRecvMsg = GUICtrlRecvMsg($hwnd_ActvEd, $EM_GETSEL)
    $aCtrlRecvMsg = $aCtrlRecvMsg & ' ' & GUICtrlRecvMsg($hwnd_SynEdt, $EM_GETSEL)
    $aCtrlRecvMsg = $aCtrlRecvMsg & ' ' & GUICtrlRecvMsg($iID_ActvEd, $EM_GETSEL)
    $aCtrlRecvMsg = $aCtrlRecvMsg & ' ' & GUICtrlRecvMsg($iID_SynEdt, $EM_GETSEL)

    ; Falls GUICtrlRecvMsg 0 zurückgibt, so kommt ein Fehler. Sonst wird der Inhalt des Arrays angezeigt.
    If $aCtrlRecvMsg = 0 Then
      ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $aCtrlRecvMsg - Ein Fehler ist aufgetreten. Der zurückgegebene Wert lautet: ' & $aCtrlRecvMsg & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    Else
      ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $aCtrlRecvMsg - Start: " & $aCtrlRecvMsg[0] & " Ende: ' & $aCtrlRecvMsg[1] & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    EndIf


    $sSelTxt = ""

;~     $range = _GUICtrlEdit_GetSel($hwnd_ActvEd)       ;  5537639  17366664
;~     $range = _GUICtrlEdit_GetSel($hwnd_SynEdt)
;~     $range = _GUICtrlEdit_GetSel($iID_ActvEd)
;~     $range = _GUICtrlEdit_GetSel($iID_SynEdt)

;~     $range = _GUICtrlRichEdit_GetSel($hwnd_ActvEd)
;~     $range = _GUICtrlRichEdit_GetSel($hwnd_SynEdt)
;~     $range = _GUICtrlRichEdit_GetSel($iID_ActvEd)
    $range = _GUICtrlRichEdit_GetSel($iID_SynEdt)

;~     If $range[0] <> $range[1] Then
    If IsArray($range) Then
      $sSelTxt = StringMid(GUICtrlRead($iID_SynEdt), $range[0] + 1, $range[1] - $range[0])
      ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $range[0] = ' & $range[0] & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
      ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $range[1] = ' & $range[1] & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
      ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sSelTxt = ' & $sSelTxt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    EndIf


    $sSelTxt = ""

    $sSelTxt = _GUICtrlRichEdit_GetSelText($hwnd_ActvEd)
    $sSelTxt = $sSelTxt & ' ' & _GUICtrlRichEdit_GetSelText($hwnd_SynEdt)
    $sSelTxt = $sSelTxt & ' ' & _GUICtrlRichEdit_GetSelText($iID_ActvEd)
    $sSelTxt = $sSelTxt & ' ' & _GUICtrlRichEdit_GetSelText($iID_SynEdt)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sSelTxt = ' & $sSelTxt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


    $sSelTxt = ""

    $sSelTxt = ControlCommand("[CLASS:TfPSPad]", "", $hwnd_ActvEd, "GetSelected", "")
    $sSelTxt = $sSelTxt & ' ' & ControlCommand("[CLASS:TfPSPad]", "", $hwnd_SynEdt, "GetSelected", "")
    $sSelTxt = $sSelTxt & ' ' & ControlCommand("[CLASS:TfPSPad]", "", $iID_ActvEd, "GetSelected", "")
    $sSelTxt = $sSelTxt & ' ' & ControlCommand("[CLASS:TfPSPad]", "", $iID_SynEdt, "GetSelected", "")
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sSelTxt = ' & $sSelTxt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


    $sSelTxt = ""

    $sSelTxt = ControlCommand($hPSPad, "", $hwnd_ActvEd, "GetSelected", "")
    $sSelTxt = $sSelTxt & ' ' & ControlCommand($hPSPad, "", $hwnd_SynEdt, "GetSelected", "")
    $sSelTxt = $sSelTxt & ' ' & ControlCommand($hPSPad, "", $iID_ActvEd, "GetSelected", "")
    $sSelTxt = $sSelTxt & ' ' & ControlCommand($hPSPad, "", $iID_SynEdt, "GetSelected", "")
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sSelTxt = ' & $sSelTxt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

Alles anzeigen

Gruß,

Bernd.

**Bitnugger**

AutoIt

Local $hPsPad = WinGetHandle('[CLASS:TfPSPad]')
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hPsPad      --> " & $hPsPad & @LF)
Local $hTPSSynEdit = ControlGetHandle($hPsPad, '', '[CLASS:TPSSynEdit; INSTANCE:1]')
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hTPSSynEdit --> " & $hTPSSynEdit & @LF)
Local $sText = ControlGetText($hTPSSynEdit, '', '')
ConsoleWrite('---------------------------------------------------' & @CRLF)
ConsoleWrite($sText & @CRLF)
ConsoleWrite('---------------------------------------------------' & @CRLF)
WinActivate($hPsPad)
Sleep(2000)
ControlSetText($hTPSSynEdit, '', '', 'new text is good text', 1)

Alles anzeigen

**alpines**

Zitat von Bitnugger

...

Und das gibt dir den markierten Text zurück? Bei mir nur den gesamten Text im Editor und ersetzt nicht die markierte Stelle mit dem String den du übergibst, sondern den gesamten Controlinhalt.

**Bitnugger**

Zitat von alpines

Und das gibt dir den markierten Text zurück?

Wer lesen kann...

Professor Bernd

Komisch, bei mir gibt er nur ?????????? zurück:

+>19:39:38 AU3Check ended.rc:0
>Running:(3.3.14.5):C:\Program Files (x86)\AutoIt3\autoit3.exe "C:\Users\User1\Desktop\SynEdit - Get selected text 0 - Kopie.au3"
+>Setting Hotkeys...--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop
@@_Debug_line 28 var: $hPsPad --> 0x0003088A
@@_Debug_line 31 var: $hTPSSynEdit --> 0x001C1072
---------------------------------------------------
???????????????????????????????????????

---------------------------------------------------
+>19:39:40 AutoIt3.exe ended.rc:0
+>19:39:40 AutoIt3Wrapper Finished.
>Exit code: 0 Time: 2.54

Bitnugger Danke für den Code. Ich habe ihn in als Datei hochgeladen, damit man ihn bequem zum Testen benutzen kann.

Professor Bernd

Wieso kommt bei euch Text an? OS? Ich benutze Win 10 1809. Kann es daran liegen? Oder an den PSPad Versionen?

Meine PSPad Versionen

- 5.0.1 (312) - 2019-02-22

- 5.0.2 (b339) - 2019-10-25

Nachtrag: Das Schreiben ins SynEdit hat funktioniert (wenn vorher WinWaitActive). Schreiben habe ich aber jetzt abgeschaltet.

Professor Bernd

Hier mal der Code von Bitnugger kombiniert mit meiner Erkennung des SynEdits (HWND). Nun kommt zwar irgendwas an, aber das sieht eher nach einem abgeschnittenen Teil des Dateipfades an.

>Running:(3.3.14.5):C:\Program Files (x86)\AutoIt3\autoit3.exe "C:\Users\User1\Desktop\SynEdit - Get selected text\SynEdit - Get selected text - Version A - 2.au3"

+>Setting Hotkeys...--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop

---------------------------------------------------

???????????????????????????????????????

ected text\Test-Text.txt

---------------------------------------------------

Ich habe verschiedene Kombinationen von Handles und IDs probiert, leider ohne Glück.

Weitere Vorschläge?

Professor Bernd

Vielleicht hilft die Auflistung der PSPad Controls.

Edit: Ups, falsche Datei hochgeladen.

**alpines**

Zitat von Bitnugger

Wer lesen kann...

Was immer du auch meinst, ich sehs nicht. Ich steh glaube ich aufm Schlauch.

Professor Bernd

Meine Glaskugel sagt, er könnte ControlGetText meinen (also ohne Selection). Aber viel wichtiger: Kommt bei dir denn der Text an? Siehe mein Posting #6 wg Infos zu meinem OS und PSPad Versionen.

**alpines**

Ich kann ja den Inhalt auslesen mit ControlGetText aber nicht die Selektion, deshalb wundere ich mich was er meinte mit "Wer lesen kann..."

Professor Bernd

Welches OS und welche PSPad Version hast du benutzt?

**Bitnugger**

Mit "Wer lesen kann..." meinte ich natürlich mich selbst!

**alpines**

Zitat von Bitnugger

Mit "Wer lesen kann..." meinte ich natürlich mich selbst!

Achsoooooooooo

Professor Bernd

Hat noch jemand eine Idee?

Grimli

Moin,

ich habe heute eine ganze Weile mit AutoItObject gespielt (erneut).

Folgende Option hättest du:

Du kannst mit AutoItObject ein Com-Object im ROT (Running Object Table) erstellen und auf dieses aus den JScript / VBScript Skripten zugreifen.

Auf diesem Wege könntest du dir eine kleine Brücke zwischen den beiden Welten schlagen.

Ich habe es eben nur mit einem kleinen Snipsel probiert, aufwändigere Aktionen müsste man testen.

Falls Bedarf und Interesse besteht werde ich gern ausführlicher.

Gruß

Professor Bernd

Zitat von Churanos

Du kannst mit AutoItObject ein Com-Object im ROT (Running Object Table) erstellen und auf dieses aus den JScript / VBScript Skripten zugreifen.
Auf diesem Wege könntest du dir eine kleine Brücke zwischen den beiden Welten schlagen.

Hallo Churanos, das hört sich interessant an!

Ich habe schon öfter überlegt, wie man VBScript und AutoIt miteinander kommunizieren lassen kann. Ein Brücke zwischen den beiden wäre wohl nützlich. Wenn du das weiter testen würdest, würde ich mich freuen. PSPad kannst du einfach downloaden. Der Haupt-Editorbereich ist das SynEdit. Wenn du noch etwas brauchst, sag Bescheid.

Bernd.

Grimli

Moin,

ich habe etwas gebastelt und bin, nach vielen vielen Versuchen, endlich an den Text und auch alles andere ran gekommen.

Leider ist der Weg dahin nicht ganz einfach, aber machbar.

Du brauchst folgendes (im Anhang):

AutoItObject.au3
PsPadExt.au3
AutoItScriptExtension.vbs (umbenennen)

Um das ganze zu testen musst du zuerst das VBScript zu PsPad hinzufügen.
Dann startest du das AutoIt Skript "PsPadExt.au3".
Jetzt PsPad starten und Datei bearbeiten, test markieren
In der AutoIt Gui auf den Button klicken
freuen

Hier nochmal die Skripte als Text:

AutoIt: PsPadExt.au3

;*****************************************
;PsPadExt.au3 by Churanos
;Created with ISN AutoIt Studio v. 1.10
;*****************************************
#NoTrayIcon

#include <AutoItObject.au3>
#include <GUIConstantsEx.au3>


AutoItSetOption("GUIOnEventMode", 1)
OnAutoItExitRegister("_Exit")
_AutoItObject_Startup()



#Region COM Error Function
Func _ErrFunc()
    ConsoleWrite("COM Error, ScriptLine(" & $oError.scriptline & ") : Number 0x" & Hex($oError.number, 8) & " - " & $oError.windescription & @CRLF)
EndFunc    ;==>_ErrFunc
Global $oError = ObjEvent("AutoIt.Error", "_ErrFunc")
#EndRegion COM Error Function



#Region Define variables
Global Const $sExtName    = "PsPadExt"
Global Const $sExtVersion = "0.0.1"
Global Const $sExtAuthor  = "Churanos <kleist.steven@gmail.com>"

Global Const $sClsId      = "PsPadExt.Bridge"

Global $oPlugin           = Null
Global $hROTHandle        = Null

Global $bShouldQuit       = False
Global $bInit             = False
#EndRegion Define variables



#Region GUI Part
Global $frm_Main = GUICreate($sExtName, 320, 360)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Global $btn_GetText = GUICtrlCreateButton("Get Text", 10, 10, 80, 25)
GUICtrlSetOnEvent(-1, "_GetTextFromEditor")
Global $txt_Text = GUICtrlCreateEdit("", 10, 50, 300, 300)
#EndRegion GUI Part



#Region Main Loop
_Init()
While 1
    ; Do stuff
    If $bShouldQuit Then _Exit()
    Sleep(10)
Wend
#EndRegion Main Loop


#Region Functions
;##############################################################################
;### Init function
;##############################################################################
Func _Init()
    $oPlugin = _PSPadExt()
    If @error Then
        MsgBox(16, "Error", "Error while creating object from Func: _PsPadExt()!")
        _Exit()
    EndIf
    $hROTHandle = _AutoItObject_RegisterObject($oPlugin, $sClsId)
    GUISetState(@SW_SHOW, $frm_Main)
EndFunc
;##############################################################################


;##############################################################################
;### Exit function
;##############################################################################
Func _Exit()
    _AutoItObject_UnregisterObject($hROTHandle)
    $oPlugin = 0
    _AutoItObject_Shutdown()
    Exit
EndFunc
;##############################################################################


Func _GetTextFromEditor()
    GUICtrlSetData($txt_Text, $oPlugin.PsPadSelectedText())
EndFunc
#EndRegion Functions


#Region Object Functions
Func _PSPadExt()
    
    local $class = _AutoItObject_Class()
    With $class
        .AddProperty("Name", $ELSCOPE_READONLY, $sExtName)
        .AddProperty("Version", $ELSCOPE_READONLY, $sExtVersion)
        .AddProperty("PsPad", $ELSCOPE_PUBLIC, Null)
        
        .AddMethod("PsPadSelectedText", "_PsPadExt_PsPadSelectedText")
        .AddMethod("Quit", "_PsPadExt_Quit")
    EndWith

    Return $class.Object
EndFunc

Func _PsPadExt_PsPadSelectedText($this)
    $this.PsPad.Item("Editor").assignActiveEditor()
    ConsoleWrite(StringFormat("Editor.selText(): %s", $this.PsPad.Item("Editor").selText()) & @CRLF)
    Return $this.PsPad.Item("Editor").selText()
EndFunc


Func _PSPadExt_Quit($this)
    $bShouldQuit = True
EndFunc
#EndRegion Object Functions

Alles anzeigen

Code: AutoItScriptExtension.vbs

' it will print all open files to printer
const module_name  = "AutoItScriptExtension"         'this name must be unique !!!
const module_ver   = "0.0.1"            'version

Dim PsPadExt
Set PsPadExt = GetObject("PsPadExt.Bridge")


Sub About_Dialog
    echo "Hello from " & module_name & "."
    
    ' PsPadExt.PsPadEditor()
    
    ' Editor.assignActiveEditor()
    ' Editor.appendText("Hello from vbs.")
    PsPadExt.Quit()
End Sub

' name "Init" is required, its called automatically during initialization to create menu items
sub Init
    addMenuItem "Exit", "AutoItScriptExtension", "About_Dialog"
    
    PsPadExt.PsPad = CreateObject("Scripting.Dictionary")
    PsPadExt.PsPad.Add "Editor", NewEditor()

end sub

Alles anzeigen

Ich hoffe das hilft dir weiter, mein Gehirn braucht erstmal eine kleine Pause

Gruß

Professor Bernd

Zitat von Churanos

Ich hoffe das hilft dir weiter, mein Gehirn braucht erstmal eine kleine Pause

Hi hi, das kenne ich! Ich werde mir deine Scripts ansehen, hört sich ja recht vielversprechend an.

Professor Bernd

Angesehen und für gut befunden!

Ich habe mir den Code angesehen (und die Lizenz überflogen) und freue mich, dass du das möglichst einfach gehalten hast. (Kompliziert kann jeder, ist also als Lob gedacht.) Getestet habe ich gerade eben. Ein markierter Text wird erkannt, sogar wenn er über mehrere Zeilen geht oder im Spaltenmodus markiert wurde ("Alt"+markieren).

Da Funktionen des Improvement Kits aus PSPad heraus aufgerufen werden, bräuchte es noch eine Möglichkeit, um die Erkennung einzuleiten, wenn PsPadExt von PSPad gestartet wird. Anders ausgedrückt: PSPad wird gestartet und dann wird PsPadExt gestartet.

...

Hmm, jetzt wo ich das hier schreibe, kommt mir gerade der Gedanke, dass das ja einfach im Modul "AutoItScriptExtension.vbs" erledigt werden kann. ... zurück zum Testen. ...

Professor Bernd 8. November 2019 um 20:59