Explorer halber Bildschirm

**Tweaky**

Hi,

ich möchte den Explorer öffnen und auf die linke Hälfte des Bildschirms schieben.

Leider wird er nicht nach ganz links oben geschoben.

Erst fängt nun bei x = 7 an.

Unter Win 7 hats es noch funktioniert.

Code

#Region    ;************ Includes ************
#Include <WinAPIShPath.au3>
#EndRegion ;************ Includes ************

$sPfad_explorer_tmp = "C:\"

Run("explorer.exe /N,/E," & $sPfad_explorer_tmp, "", @SW_MAXIMIZE)

If StringLen($sPfad_explorer_tmp) = 3 Then
    $sTitel_tmp = "(" & StringMid($sPfad_explorer_tmp, 1, 2) & ") " & DriveGetLabel($sPfad_explorer_tmp)
Else
    $sPfad_explorer_tmp = _WinAPI_PathRemoveBackslash($sPfad_explorer_tmp)
    $aSplit_explorer = StringSplit($sPfad_explorer_tmp, "\")
    $sTitel_tmp = $aSplit_explorer[UBound($aSplit_explorer) - 1]
EndIf

$sExplorer_titel_1 = "[REGEXPCLASS:^(Explore|Cabinet)WClass$" & "; TITLE:" & $sTitel_tmp & "]"

WinWait($sExplorer_titel_1)
$hExplorer_1 = WinGetHandle($sExplorer_titel_1)

WinMove($hExplorer_1, "", 0, 0, @DesktopWidth / 2, @DesktopHeight)

Alles anzeigen

Die Maus steht bei x = 7

Das Fenster soll angeblich bei x = 0 stehen.

Ist das normal?

Ist das Fenster immer um 7 verschoben?

**Musashi**

Zitat von Tweaky

Ist das normal?

Nur auf die Schnelle, bin gerade am Wein trinken .

Ob das normal ist - wer weiß. Zumindest bist Du nicht der Einzige :

windows10-window-position-is-wrong-in-autoit-window-info

Edit : Tweaky

https://www.autoitscript.com/forum/topic/16…taskbar-height/

**autoiter**

Ich meine wir hatten das schon mal irgendwann. War das etwas mit dem Windows Style, dass die Ränder nicht angezeigt werden?

C

#include <WinAPISys.au3>
#include <WindowsConstants.au3>

Local $iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
WinMove($hExplorer_1, "", 0 - $iFrame * 2, 0, @DesktopWidth / 2, @DesktopHeight)

So etwas klappt bei mir

**Musashi**

Zitat von autoiter

Ich meine wir hatten das schon mal irgendwann. War das etwas mit dem Windows Style, dass die Ränder nicht angezeigt werden?

Du meinst wahrscheinlich das hier :

AutoIt Info Tool zeigt andere Größe an, als WinGetPos()

Gruß Musashi

**alpines**

Windows 10 zeigt die Ränder nicht mehr beim normalen Style an. Ich glaube nur noch bei einem bestimmten Style oben (da bin ich mir aber nicht ganz sicher).

Deshalb ist das Fenster korrekt positioniert, denn du kannst dort es ja resizen.

**Tweaky**

Also meint ihr man sollte Local $iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME) verwenden?

Da bekomme ich 3 raus. Anhand der ausgelesenen Kordinaten wären es jedoch 7.

**alpines**

Zitat von Tweaky

Also meint ihr man sollte Local $iFrame = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME) verwenden?
Da bekomme ich 3 raus. Anhand der ausgelesenen Kordinaten wären es jedoch 7.

Ich habs in meinen Skripten immer so gelöst:

AutoIt

#cs _GUI_GetBorderSize($hGUI)

    Wieso nutzen wir nicht SystemMetrics statt WinGetPos - WinGetClientSize?
        Da verschiedene Fenster verschiedene Styles haben, und dementsprechend auch andere Ränder
        ist es viel zu kompliziert das alles abzufragen, stattdessen subtrahieren wir hier die Werte einfach.

    Achtung: Beim WinMove nach dem WM_DPICHANGED ist Titelleiste immer noch groß.
             Erst beim 2. WinMove wird die Titelleiste kleiner.
#ce
Func _GUI_GetBorderSize($hGUI)
    Local $aClientSize = WinGetClientSize($hGUI)
    Local $aSize = WinGetPos($hGUI)

    Local $aReturn[2] = [ $aSize[2] - $aClientSize[0], $aSize[3] - $aClientSize[1] ]
    Return $aReturn
EndFunc

Alles anzeigen

**Tweaky**

Hm,

da bekomme ich für die Breite: 16 und für die Höhe 9 raus.

Passt auch nicht ganz zu den Werten wenn ich den Explorer händisch links andocke.

**Greenhorn**

Moin Tweaky,

~~versuche es mal mit _WinAPI_GetWindowPlacement. Da sollten die korrekten Werte enthalten sein.~~

Edit: Sorry, meinte _WinAPI_GetWindowInfo ... WINDOWINFO structure

Gruß

Greenhorn

**Tweaky**

Hm, wenn ich es richtig sehe bringt mir das auch nichts.

Dies gibt ja nur die Position des Fensters wieder. Wenn ich das Fenster mit WinMove nach links schiebe wird x=0 angezeigt, obwohl links noch 7 Pixel frei sind

**Greenhorn**

Wenn ich Dich richtig verstanden habe, dann suchst Du nach einem Weg die Breite des Fensterrahmens zu ermitteln um die Fensterposition ggf. anzupassen.

Das Mitglied cxWindowBorders der WINDOWINFO Struktur sollte die (wirkliche) Breite des Fensterrahmens enthalten.

**Bitnugger**

Zitat von Tweaky

Leider wird er nicht nach ganz links oben geschoben.
Erst fängt nun bei x = 7 an.

Run("explorer.exe /N,/E," & $sPfad_explorer_tmp, "", @SW_MAXIMIZE)

Das Fenster wird somit maximiert angezeigt, wodurch der Rahmen nicht sichtbar ist... aber nach deinem WinMove ist es nicht mehr maximiert und auch nicht innerhalb eines Bereichs, in dem es automatisch von Windows angedockt wird, wodurch der Rahmen wieder sichtbar wird.

Versuche es mal hiermit:

AutoIt

;-- TIME_STAMP   2020-01-05 01:10:43

Global $sExplorerPath, $sRx, $hExplorer, $aPos
$sExplorerPath = "C:\"                     ; WindowTitle = "<DriveLabel> (C:)" oder "(C:) <DriveLabel>"
;~ $sExplorerPath = "C:\Windows\System32\" ; WindowTitle = "System32"

$sRx = '[REGEXPCLASS:^(Explore|Cabinet)WClass$; REGEXPTITLE:^' & _
    (StringRegExp($sExplorerPath, '(?i)(^[a-z]:\\?$)') _
    ? '\(' & StringLeft($sExplorerPath, 2) & '\) ' & DriveGetLabel($sExplorerPath) & '|' & DriveGetLabel($sExplorerPath) & ' \(' & StringLeft($sExplorerPath, 2) & '\)' _ ; "C:\"
    : StringRegExpReplace($sExplorerPath, '(?:.+\\)?(.+)\\$', '\1')) & _ ; "C:\Windows\System32\"
    '$]'
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $sRx                --> " & $sRx & @CRLF)

$hExplorer = WinGetHandle($sRx)

If Not IsHWnd($hExplorer) Then
    RunWait("explorer.exe /N,/E," & $sExplorerPath, "", @SW_MAXIMIZE)
    $hExplorer = WinWait($sRx, '', 3)
Else
    WinSetState($hExplorer, '', @SW_MAXIMIZE)
EndIf

If IsHWnd($hExplorer) Then
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $hExplorer          --> " & $hExplorer & ' "' & WinGetTitle($hExplorer) & '"' & @CRLF)

    WinActivate($hExplorer)

    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @DesktopWidth       --> " & @DesktopWidth & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @DesktopHeight      --> " & @DesktopHeight & @CRLF)

    $aPos = WinGetPos($hExplorer)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @SW_MAXIMIZE  $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))

    Send('#{LEFT}')
    Sleep(2000)
    $aPos = WinGetPos($hExplorer) ; <-- Diese Werte müssten bei WinMove angeben werden, damit es genauso wie mit Send('#{LEFT}') funktioniert!
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  Send #{LEFT}  $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))
EndIf

Alles anzeigen

**Tweaky**

Beim Skript von Greenhorn bekomme ich x=8 und y=8 als Rand

C

#Region    ;************ Includes ************
#include <WinAPISysWin.au3>
#include <WinAPIShPath.au3>
#EndRegion ;************ Includes ************

$sPfad_explorer_tmp = "C:\"

Run("explorer.exe /N,/E," & $sPfad_explorer_tmp, "", @SW_MAXIMIZE)

If StringLen($sPfad_explorer_tmp) = 3 Then
    $sTitel_tmp = "(" & StringMid($sPfad_explorer_tmp, 1, 2) & ") " & DriveGetLabel($sPfad_explorer_tmp)
Else
    $sPfad_explorer_tmp = _WinAPI_PathRemoveBackslash($sPfad_explorer_tmp)
    $aSplit_explorer = StringSplit($sPfad_explorer_tmp, "\")
    $sTitel_tmp = $aSplit_explorer[UBound($aSplit_explorer) - 1]
EndIf

$sExplorer_titel_1 = "[REGEXPCLASS:^(Explore|Cabinet)WClass$" & "; TITLE:" & $sTitel_tmp & "]"

WinWait($sExplorer_titel_1)
$hExplorer_1 = WinGetHandle($sExplorer_titel_1)

$tWINDOWINFO = _WinAPI_GetWindowInfo($hExplorer_1)

ConsoleWrite('x: ' & DllStructGetData($tWINDOWINFO, 'cxWindowBorders') & @CRLF)
ConsoleWrite('y: ' & DllStructGetData($tWINDOWINFO, 'cxWindowBorders') & @CRLF)

Alles anzeigen

Beim Skript von Bitnugger sitzt der Explorer zu weit oben

Ändere ich das Skript und werfe es manuell nach links passt der Explorer

Code

;-- TIME_STAMP   2020-01-05 01:10:43

Global $sExplorerPath, $sRx, $hExplorer, $aPos
$sExplorerPath = "C:\"                     ; WindowTitle = "<DriveLabel> (C:)" oder "(C:) <DriveLabel>"
;~ $sExplorerPath = "C:\Windows\System32\" ; WindowTitle = "System32"

$sRx = '[REGEXPCLASS:^(Explore|Cabinet)WClass$; REGEXPTITLE:^' & _
    (StringRegExp($sExplorerPath, '(?i)(^[a-z]:\\?$)') _
    ? '\(' & StringLeft($sExplorerPath, 2) & '\) ' & DriveGetLabel($sExplorerPath) & '|' & DriveGetLabel($sExplorerPath) & ' \(' & StringLeft($sExplorerPath, 2) & '\)' _ ; "C:\"
    : StringRegExpReplace($sExplorerPath, '(?:.+\\)?(.+)\\$', '\1')) & _ ; "C:\Windows\System32\"
    '$]'
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $sRx                --> " & $sRx & @CRLF)

$hExplorer = WinGetHandle($sRx)

If Not IsHWnd($hExplorer) Then
    RunWait("explorer.exe /N,/E," & $sExplorerPath, "", @SW_MAXIMIZE)
    $hExplorer = WinWait($sRx, '', 3)
Else
    WinSetState($hExplorer, '', @SW_MAXIMIZE)
EndIf

If IsHWnd($hExplorer) Then
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $hExplorer          --> " & $hExplorer & ' "' & WinGetTitle($hExplorer) & '"' & @CRLF)

    WinActivate($hExplorer)

    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @DesktopWidth       --> " & @DesktopWidth & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @DesktopHeight      --> " & @DesktopHeight & @CRLF)

    $aPos = WinGetPos($hExplorer)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @SW_MAXIMIZE  $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))

;~     Send('#{LEFT}') ;>>> Fenster manuell nach links werfen
    Sleep(5000)
    $aPos = WinGetPos($hExplorer) ; <-- Diese Werte müssten bei WinMove angeben werden, damit es genauso wie mit Send('#{LEFT}') funktioniert!
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  Send #{LEFT}  $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))
EndIf

Alles anzeigen

Dann bekomme ich als Rand x=7 und y=0 raus, was wieder stimmen würde.

Aber im Vorfeld komme ich wohl nicht an die Daten.

**Bitnugger**

Teste dieses mal:

AutoIt

;-- TIME_STAMP   2020-01-05 18:46:46

#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPISys.au3>

Global $sExplorerPath, $hExplorer, $aPos, $hMonitor, $aMonitorInfo, $aMonitorRectangle, $aMonitorPos, $iCXFrame, $iCYFrame
;~ $sExplorerPath = "C:\"                     ; WindowTitle = "<DriveLabel> (C:)" oder "(C:) <DriveLabel>"
$sExplorerPath = "C:\Windows\System32\" ; WindowTitle = "System32"
Global $sRx, $aRx = [StringLeft($sExplorerPath, 2), DriveGetLabel($sExplorerPath)]

$sRx = '[REGEXPCLASS:^(Explore|Cabinet)WClass$; REGEXPTITLE:^' & _
    (StringRegExp($sExplorerPath, '(?i)(^[a-z]:\\?$)') _
    ? '\(' & $aRx[0] & '\) ' & $aRx[1] & '|' & $aRx[1] & ' \(' & $aRx[0] & '\)' _ ; "C:\"
    : StringRegExpReplace($sExplorerPath, '(?:.+\\)?(.+)\\$', '\1')) & _ ; "C:\Windows\System32\"
    '$]'
ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $sRx                --> " & $sRx & @CRLF)

$hExplorer = WinGetHandle($sRx)

If Not IsHWnd($hExplorer) Then
;~     RunWait("explorer.exe /N,/E," & $sExplorerPath, "", @SW_MAXIMIZE)
    RunWait("explorer.exe /N,/E," & $sExplorerPath, "", @SW_RESTORE)
    $hExplorer = WinWait($sRx, '', 3)
Else
;~     WinSetState($hExplorer, '', @SW_MAXIMIZE)
    WinSetState($hExplorer, '', @SW_RESTORE)
EndIf

If IsHWnd($hExplorer) Then
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $hExplorer          --> " & $hExplorer & ' "' & WinGetTitle($hExplorer) & '"' & @CRLF)

    WinActivate($hExplorer)

    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @DesktopWidth       --> " & @DesktopWidth & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @DesktopHeight      --> " & @DesktopHeight & @CRLF)

    $aPos = WinGetPos($hExplorer)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  @SW_MAXIMIZE  $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))

    $hMonitor = _WinAPI_MonitorFromWindow($hExplorer)
    $aMonitorInfo = _WinAPI_GetMonitorInfo($hMonitor)
    $aMonitorRectangle = $aMonitorInfo[0]
    $aMonitorPos = _WinAPI_GetPosFromRect($aMonitorRectangle)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  $aMonitorPos        --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aMonitorPos[0], $aMonitorPos[1], $aMonitorPos[2], $aMonitorPos[3]))
    $iCXFrame = _WinAPI_GetSystemMetrics($SM_CXSIZEFRAME)
    $iCYFrame = _WinAPI_GetSystemMetrics($SM_CYSIZEFRAME)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $iCXFrame --> " & $iCXFrame & @LF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $iCYFrame --> " & $iCYFrame & @LF)

;~     Send('#{LEFT}')
    WinMove($hExplorer, '', $aMonitorPos[0] - ($iCXFrame -1), $aMonitorPos[1], $aMonitorPos[2] / 2, $aMonitorPos[3] + $iCYFrame -1)
    Sleep(2000)

    $aPos = WinGetPos($hExplorer)
;~     ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  Send #{LEFT}  $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "  WinMove       $aPos --> " & StringFormat('%5i, %5i, %5i, %5i\r\n', $aPos[0], $aPos[1], $aPos[2], $aPos[3]))
EndIf

Alles anzeigen

**Tweaky**

OK, als Rahmenbreite kommt x=8 und y=8 raus.

Bei WinMove ziehst du noch 1 ab, so dass du auf 7 kommst. Hast das gemacht, weil ich geschrieben habe, dass 7 richtig ist?

**Bitnugger**

Zitat von Tweaky

Bei WinMove ziehst du noch 1 ab, so dass du auf 7 kommst. Hast das gemacht, weil ich geschrieben habe, dass 7 richtig ist?

Nein, sondern weil die Automatik in Windows es so macht. 8 Pixel, wenn das Fenster vor dem Andocken maximiert war, anderfalls 7.

**Tweaky**

OK, danke dann werde ich dies so verwenden