[GDI+] Casteljau Beispiel & Bezier Beispiel

**Mars**

Moin,

Es ist eigentlich nichts großes, aber ich habe genau so ein Beispiel letztens gesucht und falls irgendwer sonst mal auf die Idee kommt den Casteljau3 (mit q = 3) Algorithmus (er ist wirklich trivial) zu basteln hat er hier eine kleine Vorlage (außerdem endet Casteljau3 auf "au3". Allein deshalb muss das hier ins Forum).

Mit den Variablen $bDrawXYZ (zeile 17 & 18) kann man auswählen in welchen Iterationsstufen man das Zwischenergebnis anzeigen lassen will.

Edit: Habe noch ein Beispiel für BezierN gebastelt.

AutoIt

#include <GDIPlus.au3>

Opt('GUIOnEventMode', 1)

Global Const $sTitle = 'Casteljau3'
Global Const $iW = 512
Global Const $iH = 512

Global Const $COL_HELLBLAU = 0xFF8EDFFF
Global Const $COL_ORANGE = 0xFFFDB961
Global Const $COL_GRUEN = 0xFF45ED67
Global Const $COL_VIOLETT = 0xFFD980E1
Global Const $COL_RED = 0xFFE28576
Global Const $COL_TUERKIS = 0xFF76E2B4

Global Const $aCol = [$COL_HELLBLAU, $COL_ORANGE, $COL_GRUEN, $COL_VIOLETT, $COL_RED, $COL_TUERKIS]
Global Const $bDrawLines  = [True, False, False, False, False, True]
Global Const $bDrawPoints = [True, False, False, False, False, False]
Global Const $MaxIter = UBound($bDrawLines) - 1

Global $aInput = [[0.15, 0.85], [0.5, 0.1], [0.8, 0.3], [0.7, 0.8]]

Global $bExit = False

_GDIPlus_Startup()
Global $hGUI = GUICreate($sTitle, $iW, $iH)
Global $hGFX = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global $hBMP = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGFX)
Global $hBUF = _GDIPlus_ImageGetGraphicsContext($hBMP)
Global $hPEN = _GDIPlus_PenCreate()

_GDIPlus_PenSetStartCap($hPEN, 2)
_GDIPlus_PenSetEndCap($hPEN, 2)

_GDIPlus_GraphicsSetSmoothingMode($hBUF, 2)

GUISetOnEvent(-3, 'EVENT', $hGUI)
OnAutoItExitRegister('Xit')
GUISetState(@SW_SHOW, $hGUI)

Local $Timer = TimerInit(), $t = 0

While Not $bExit And Sleep(10)
    $t = TimerDiff($Timer)/1000
    _GDIPlus_GraphicsClear($hBUF)
    Casteljau3($aInput)
    $aInput[0][0] = 0.15 + Cos($t)/15
    $aInput[0][1] = 0.85 + Sin($t)/15
    $aInput[1][0] = 0.5 + Cos($t/2)/15
    $aInput[1][1] = 0.1 + Sin($t/2)/15
    $aInput[2][0] = 0.8 + Cos($t/3)/15
    $aInput[2][1] = 0.3 + Sin($t/3)/15
    $aInput[3][0] = 0.7 + Cos($t/5)/15
    $aInput[3][1] = 0.8 + Sin($t/5)/15
    _GDIPlus_GraphicsDrawImageRect($hGFX, $hBMP, 0, 0, $iW, $iH)
WEnd

Func Casteljau3($a, $iter = 0)

    Local $iCol = $aCol[$iter]
    _GDIPlus_PenSetColor($hPEN, $iCol)
    _GDIPlus_PenSetWidth($hPEN, 0.005 * $iW * 0.9^$iter)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($a, 1) - 1 Step 1
        If $bDrawPoints[$iter] Then Circle($a[$i][0], $a[$i][1], 0.025 * 0.9^$iter)
    Next
    _GDIPlus_PenSetWidth($hPEN, ($iter = $MaxIter ? 0.0035 : 0.0025) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, $iter = $MaxIter ? 0 : 1)
    For $i = 0 To UBound($a, 1) - 2 Step 1
        If $bDrawLines[$iter] Then Line($a[$i][0], $a[$i][1], $a[$i+1][0], $a[$i+1][1])
    Next

    If $iter < $MaxIter Then
        ; Neue Eckpunkte berechnen: Es gibt 7 Punkte, der Mittlere ist doppelt.

        Local $p0 = [$a[0][0], $a[0][1]]
        Local $p1 = [($a[0][0] + $a[1][0])/2, ($a[0][1] + $a[1][1])/2]
        Local $p5 = [($a[2][0] + $a[3][0])/2, ($a[2][1] + $a[3][1])/2]
        Local $p6 = [$a[3][0], $a[3][1]]

        Local $m = [($a[1][0] + $a[2][0])/2, ($a[1][1] + $a[2][1])/2] ; Mittelpunkt

        Local $p2 = [($m[0] + $p1[0])/2, ($m[1] + $p1[1])/2]
        Local $p4 = [($m[0] + $p5[0])/2, ($m[1] + $p5[1])/2]

        Local $p3 = [($p2[0] + $p4[0])/2, ($p2[1] + $p4[1])/2]

        Local $aL = [[$p0[0], $p0[1]], [$p1[0], $p1[1]], [$p2[0], $p2[1]], [$p3[0], $p3[1]]]
        Local $aR = [[$p3[0], $p3[1]], [$p4[0], $p4[1]], [$p5[0], $p5[1]], [$p6[0], $p6[1]]]

        Casteljau3($aL, $iter + 1)
        Casteljau3($aR, $iter + 1)
    EndIf

EndFunc

Func Line($x1, $y1, $x2, $y2)
    _GDIPlus_GraphicsDrawLine($hBUF, $x1 * $iW, $y1 * $iH, $x2 * $iW, $y2 * $iH, $hPEN)
EndFunc

Func Circle($x, $y, $d)
    _GDIPlus_GraphicsDrawEllipse($hBUF, $x * $iW - $d/2 * $iW, $y * $iH - $d/2 * $iH, $d * $iW, $d * $iH, $hPEN)
EndFunc

Func EVENT()
    Switch @GUI_CtrlId
        Case -3
            $bExit = True
    EndSwitch
EndFunc

Func Xit()
    _GDIPlus_PenDispose($hPEN)
    _GDIPlus_GraphicsDispose($hBUF)
    _GDIPlus_BitmapDispose($hBMP)
    _GDIPlus_GraphicsDispose($hGFX)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

AutoIt

#include <GDIPlus.au3>
#include <Misc.au3>

Opt('GUIOnEventMode', 1)
Opt('MouseCoordMode', 2)

Global Const $sTitle = 'BezierN'
Global Const $iW = 512
Global Const $iH = 512
Global Const $nBezierPoints = 35

Global $aKontrollPunkte[0]
AddPoint($aKontrollPunkte, 0.1, 0.2)
AddPoint($aKontrollPunkte, 0.1, 0.3)
AddPoint($aKontrollPunkte, 0.3, 0.7)
AddPoint($aKontrollPunkte, 0.6, 0.8)
AddPoint($aKontrollPunkte, 0.9, 0.2)
AddPoint($aKontrollPunkte, 0.9, 0.9)
AddPoint($aKontrollPunkte, 0.5, 0.5)

Func AddPoint(ByRef $a, $x, $y)
    Local $z = [$x, $y], $u = UBound($a)
    ReDim $a[$u + 1] ; Jaaah macht man ja nur 1x am Anfang. Bitte NICHT oft nutzen, langsam.
    $a[$u] = $z
EndFunc

Global $aBezierN = BezierN($aKontrollPunkte, $nBezierPoints)

; Input : Array[i] = Array[2] = [x, y] für beliebige Punktmengen
; Output: Array[i] = Array[2] = [x, y] mit $n Einträgen
Func BezierN(ByRef $aPoints, $n = 25)
    Local $u = UBound($aPoints), $aBuf[$u][2], $aRet[$n], $r = 0, $t = 0, $a[2], $b[2], $c[2], $m = 0
    For $tt = 0 To $n - 1 Step 1
        $t = $tt / ($n - 1)
        For $i = 0 To $u - 1 Step 1
            $aBuf[$i][0] = $aPoints[$i]
        Next
        For $sub = 2 To $u Step 1
            $m = IsInt($sub/2)
            For $i = 0 To $u - $sub Step 1
                $a = $aBuf[$i][1-$m]
                $b = $aBuf[$i+1][1-$m]
                $c[0] = $a[0] + $t * ($b[0] - $a[0])
                $c[1] = $a[1] + $t * ($b[1] - $a[1])
                $aBuf[$i][$m] = $c
                If $sub = $u Then
                    $aRet[$r] = $aBuf[$i][$m]
                    $r += 1
                EndIf
            Next
        Next
    Next
    Return $aRet
EndFunc

Global $bExit = False

_GDIPlus_Startup()
Global $hGUI = GUICreate($sTitle, $iW, $iH)
Global $hGFX = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global $hBMP = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGFX)
Global $hBUF = _GDIPlus_ImageGetGraphicsContext($hBMP)
Global $hPEN = _GDIPlus_PenCreate()

_GDIPlus_PenSetStartCap($hPEN, 2)
_GDIPlus_PenSetEndCap($hPEN, 2)
_GDIPlus_GraphicsSetSmoothingMode($hBUF, 2)

GUISetOnEvent(-3, 'EVENT', $hGUI)
OnAutoItExitRegister('Xit')
GUISetState(@SW_SHOW, $hGUI)

While Not $bExit And Sleep(10)
    _GDIPlus_GraphicsClear($hBUF)
    $aBezierN = BezierN($aKontrollPunkte, $nBezierPoints)
    Print($aBezierN, 0.015, 0xFFFF6050)
    Print($aKontrollPunkte, 0.025, 0xFF808080)
    Mouse($aKontrollPunkte)
    _GDIPlus_GraphicsDrawImageRect($hGFX, $hBMP, 0, 0, $iW, $iH)
WEnd

Func Mouse(ByRef $aPoints)
    Local $mPos = MouseGetPos(), $a[2]
    Local Static $iDrag = -1
    _GDIPlus_PenSetColor($hPEN, 0xFF80FF00)
    _GDIPlus_PenSetWidth($hPEN, (0.035 / 5.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($aPoints) - 1 Step 1
        If Sqrt(($mPos[0]/$iW - ($aPoints[$i])[0])^2 + ($mPos[1]/$iH - ($aPoints[$i])[1])^2) < 0.0325 Then
            If _IsPressed('01') Then
                $iDrag = $i
            Else
                $iDrag = -1
            EndIf
            Circle($aPoints[$i], 0.035)
        EndIf
    Next
    If $iDrag <> -1 Then
        $a[0] = $mPos[0] / $iW
        $a[1] = $mPos[1] / $iH
        $aPoints[$iDrag] = $a
    EndIf
EndFunc

Func Print(ByRef $aPoints, $d = 0.025, $iCol = 0xFFFFFFFF)
    _GDIPlus_PenSetColor($hPEN, $iCol)
    _GDIPlus_PenSetWidth($hPEN, ($d / 5.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($aPoints) - 1 Step 1
        Circle($aPoints[$i], $d)
    Next
    _GDIPlus_PenSetWidth($hPEN, ($d / 8.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 1)
    For $i = 0 To UBound($aPoints) - 2 Step 1
        Line($aPoints[$i], $aPoints[$i+1])
    Next
EndFunc

Func Line($p1, $p2)
    _GDIPlus_GraphicsDrawLine($hBUF, $p1[0] * $iW, $p1[1] * $iH, $p2[0] * $iW, $p2[1] * $iH, $hPEN)
EndFunc

Func Circle($p, $d)
    _GDIPlus_GraphicsDrawEllipse($hBUF, $p[0] * $iW - $d/2 * $iW, $p[1] * $iH - $d/2 * $iH, $d * $iW, $d * $iH, $hPEN)
EndFunc

Func EVENT()
    Switch @GUI_CtrlId
        Case -3
            $bExit = True
    EndSwitch
EndFunc

Func Xit()
    _GDIPlus_PenDispose($hPEN)
    _GDIPlus_GraphicsDispose($hBUF)
    _GDIPlus_BitmapDispose($hBMP)
    _GDIPlus_GraphicsDispose($hGFX)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

lg

M

**UEZ**

Coole Sache

Ich hatte mit dem Titel erst Probleme, hatte an Kabeljau gedacht. Aber nach dem Googlen habe ich mehr erfahren über De-Casteljau...

Könnte ich für FB gut gebrauchen.

**Andy**

Sehr schick!

Wenn man die Zeile 55

_GDIPlus_GraphicsDrawImageRect($hGFX, $hBMP, 0, 0, $iW, $iH)

(ggf sleep(100) anfügen)

vor die Zeile 73

If $iter < $MaxIter Then

kopiert, dann sieht man auch, dass das Script "funktioniert" :o)

aka die Punkte auf den Bezierkurven aus den Geraden berechnet werden.

**Mars**

Schön, dass es euch gefällt. Ja im Prinzip ist Casteljau eine coole Sache, aber (in dieser Form) nicht der Way to go (Beschränktheit auf durch 4 teilbare Punktmengen (bzw wenn man garnichts ändert nur auf 4 Punkte^^), diskrete Punktmenge als Ergebnis (ich kann nicht einfach sagen, dass ich z.B. 50 Punkte für die neue Kurve will, ich bekomme je nach Iterationsschritt eben so viele wie ich bekomme), usw usw.

Da ich sowieso noch ein weiteres Beispiel gebraucht habe hab ich noch ein bisschen mehr Spielzeug für UEZ

PS: Die Methode geht in einer pointerbasierten Programmiersprache bestimmt richtig steil, in AutoIt hat man hier ziemlich viel overhead.

AutoIt

#include <GDIPlus.au3>
#include <Misc.au3>

Opt('GUIOnEventMode', 1)
Opt('MouseCoordMode', 2)

Global Const $sTitle = 'BezierN'
Global Const $iW = 768
Global Const $iH = 768
Global Const $nBezierPoints = 35

Global $aKontrollPunkte[0]
AddPoint($aKontrollPunkte, 0.1, 0.2)
AddPoint($aKontrollPunkte, 0.1, 0.3)
AddPoint($aKontrollPunkte, 0.3, 0.7)
AddPoint($aKontrollPunkte, 0.6, 0.8)
AddPoint($aKontrollPunkte, 0.9, 0.2)
AddPoint($aKontrollPunkte, 0.9, 0.9)
AddPoint($aKontrollPunkte, 0.5, 0.5)

Func AddPoint(ByRef $a, $x, $y)
    Local $z = [$x, $y], $u = UBound($a)
    ReDim $a[$u + 1] ; Jaaah macht man ja nur 1x am Anfang. Bitte NICHT oft nutzen, langsam.
    $a[$u] = $z
EndFunc

Global $aBezierN = BezierN($aKontrollPunkte, $nBezierPoints)

; Input : Array[i] = Array[2] = [x, y] für beliebige Punktmengen
; Output: Array[i] = Array[2] = [x, y] mit $n Einträgen
Func BezierN(ByRef $aPoints, $n = 25)
    Local $u = UBound($aPoints), $aBuf[$u][2], $aRet[$n], $r = 0, $t = 0, $a[2], $b[2], $c[2], $m = 0
    For $tt = 0 To $n - 1 Step 1
        $t = $tt / ($n - 1)
        For $i = 0 To $u - 1 Step 1
            $aBuf[$i][0] = $aPoints[$i]
        Next
        For $sub = 2 To $u Step 1
            $m = IsInt($sub/2)
            For $i = 0 To $u - $sub Step 1
                $a = $aBuf[$i][1-$m]
                $b = $aBuf[$i+1][1-$m]
                $c[0] = $a[0] + $t * ($b[0] - $a[0])
                $c[1] = $a[1] + $t * ($b[1] - $a[1])
                $aBuf[$i][$m] = $c
                If $sub = $u Then
                    $aRet[$r] = $aBuf[$i][$m]
                    $r += 1
                EndIf
            Next
        Next
    Next
    Return $aRet
EndFunc

Global $bExit = False

_GDIPlus_Startup()
Global $hGUI = GUICreate($sTitle, $iW, $iH)
Global $hGFX = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global $hBMP = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGFX)
Global $hBUF = _GDIPlus_ImageGetGraphicsContext($hBMP)
Global $hPEN = _GDIPlus_PenCreate()

_GDIPlus_PenSetStartCap($hPEN, 2)
_GDIPlus_PenSetEndCap($hPEN, 2)
_GDIPlus_GraphicsSetSmoothingMode($hBUF, 2)

GUISetOnEvent(-3, 'EVENT', $hGUI)
OnAutoItExitRegister('Xit')
GUISetState(@SW_SHOW, $hGUI)

While Not $bExit And Sleep(10)
    _GDIPlus_GraphicsClear($hBUF)
    $aBezierN = BezierN($aKontrollPunkte, $nBezierPoints)
    Print($aBezierN, 0.015, 0xFFFF6050)
    Print($aKontrollPunkte, 0.025, 0xFF808080)
    Mouse($aKontrollPunkte)
    _GDIPlus_GraphicsDrawImageRect($hGFX, $hBMP, 0, 0, $iW, $iH)
WEnd

Func Mouse(ByRef $aPoints)
    Local $mPos = MouseGetPos(), $a[2]
    Local Static $iDrag = -1
    _GDIPlus_PenSetColor($hPEN, 0xFF80FF00)
    _GDIPlus_PenSetWidth($hPEN, (0.035 / 5.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($aPoints) - 1 Step 1
        If Sqrt(($mPos[0]/$iW - ($aPoints[$i])[0])^2 + ($mPos[1]/$iH - ($aPoints[$i])[1])^2) < 0.0325 Then
            If _IsPressed('01') Then
                $iDrag = $i
            Else
                $iDrag = -1
            EndIf
            Circle($aPoints[$i], 0.035)
        EndIf
    Next
    If $iDrag <> -1 Then
        $a[0] = $mPos[0] / $iW
        $a[1] = $mPos[1] / $iH
        $aPoints[$iDrag] = $a
    EndIf
EndFunc

Func Print(ByRef $aPoints, $d = 0.025, $iCol = 0xFFFFFFFF)
    _GDIPlus_PenSetColor($hPEN, $iCol)
    _GDIPlus_PenSetWidth($hPEN, ($d / 5.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($aPoints) - 1 Step 1
        Circle($aPoints[$i], $d)
    Next
    _GDIPlus_PenSetWidth($hPEN, ($d / 8.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 1)
    For $i = 0 To UBound($aPoints) - 2 Step 1
        Line($aPoints[$i], $aPoints[$i+1])
    Next
EndFunc

Func Line($p1, $p2)
    _GDIPlus_GraphicsDrawLine($hBUF, $p1[0] * $iW, $p1[1] * $iH, $p2[0] * $iW, $p2[1] * $iH, $hPEN)
EndFunc

Func Circle($p, $d)
    _GDIPlus_GraphicsDrawEllipse($hBUF, $p[0] * $iW - $d/2 * $iW, $p[1] * $iH - $d/2 * $iH, $d * $iW, $d * $iH, $hPEN)
EndFunc

Func EVENT()
    Switch @GUI_CtrlId
        Case -3
            $bExit = True
    EndSwitch
EndFunc

Func Xit()
    _GDIPlus_PenDispose($hPEN)
    _GDIPlus_GraphicsDispose($hBUF)
    _GDIPlus_BitmapDispose($hBMP)
    _GDIPlus_GraphicsDispose($hGFX)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

Der Algorithmus ist für beliebige Punktmengen nutzbar, hat aber n² Komplexität (in Bezug auf die Menge der Eingabepunkte) und lineare Komplexität in Bezug zum Output (also wenn man z.B. 100 Punkte statt 50 haben will). Er hat noch tonnenweise weitere Nachteile (z.B. ist "alles" verknüpft, selbst bei 10 Eingabepunkten bewirkt eine Bewegung eines Randpunktes veränderungen an der ganzen Kurve, auch wenn die Veränderungen klein sind), aber das ist schon so geplant

Wenn jemand Lust hat kann er ja ein Beispiel für B-Splines (via BezierN frei wählbarer Grad) basteln, dann hat man bessere lokale Eigenschaften und bessere Komplexität

Edit: Und noch eine Version mit Pseudo Äquidistanten Punkten (auch O(n²)):

AutoIt

#include <GDIPlus.au3>
#include <Misc.au3>
#include <Array.au3>

Opt('GUIOnEventMode', 1)
Opt('MouseCoordMode', 2)

Global Const $sTitle = 'BezierN_PseudoEquidistant'
Global Const $iW = 512
Global Const $iH = 512
Global Const $nBezierPoints = 50

Global $aKontrollPunkte[0]
AddPoint($aKontrollPunkte, 0.1, 0.2)
AddPoint($aKontrollPunkte, 0.1, 0.3)
AddPoint($aKontrollPunkte, 0.3, 0.7)
AddPoint($aKontrollPunkte, 0.6, 0.8)
AddPoint($aKontrollPunkte, 0.9, 0.2)
AddPoint($aKontrollPunkte, 0.9, 0.9)
AddPoint($aKontrollPunkte, 0.5, 0.5)

Func AddPoint(ByRef $a, $x, $y)
    Local $z = [$x, $y], $u = UBound($a)
    ReDim $a[$u + 1] ; Jaaah macht man ja nur 1x am Anfang. Bitte NICHT oft nutzen, langsam.
    $a[$u] = $z
EndFunc

Global $aBezierN = BezierN($aKontrollPunkte, $nBezierPoints)

; Input : Array[i] = Array[2] = [x, y] für beliebige Punktmengen
; Output: Array[i] = Array[2] = [x, y] mit $n Einträgen
Func BezierN(ByRef $aPoints, $n = 25)
    Local $u = UBound($aPoints), $aBuf[$u][2], $aRet[$n], $r = 0, $t = 0, $a[2], $b[2], $c[2], $m = 0
    For $tt = 0 To $n - 1 Step 1
        $t = $tt / ($n - 1)
        For $i = 0 To $u - 1 Step 1
            $aBuf[$i][0] = $aPoints[$i]
        Next
        For $sub = 2 To $u Step 1
            $m = IsInt($sub/2)
            For $i = 0 To $u - $sub Step 1
                $a = $aBuf[$i][1-$m]
                $b = $aBuf[$i+1][1-$m]
                $c[0] = $a[0] + $t * ($b[0] - $a[0])
                $c[1] = $a[1] + $t * ($b[1] - $a[1])
                $aBuf[$i][$m] = $c
                If $sub = $u Then
                    $aRet[$r] = $aBuf[$i][$m]
                    $r += 1
                EndIf
            Next
        Next
    Next
    Return $aRet
EndFunc

Func BezierN_PseudoEquidistant(ByRef $aPoints, $n = 25)
    Local $BN = BezierN($aPoints, $n), $l = 0, $at[$n][2], $eps = 1e-6
    For $i = 0 To $n - 2 Step 1
        $l += Sqrt((($BN[$i])[0] - ($BN[$i+1])[0])^2 + (($BN[$i])[1] - ($BN[$i+1])[1])^2)
        $at[$i+1][0] = ($i + 1) /($n - 1)
        $at[$i+1][1] = $l
    Next
    Local $ls = $l / ($n - 1), $newT[$n] = [0], $ii = 0, $minI = 0
    For $i = 0 To $n - 2 Step 1
        For $o = $ii To $n - 2 Step 1 ; hier bin ich nicht sicher ob ein invalides $ii auftreten kann...
            If $ls * ($i + 1) >= ($at[$o][1] - $eps) And $ls * ($i + 1) <= ($at[$o+1][1] + $eps) Then
                $ii = $o
                ExitLoop
            EndIf
        Next
        $newT[$i + 1] = $at[$ii][0] + ($ls * ($i + 1) - $at[$ii][1]) / ($at[$ii+1][1] - $at[$ii][1]) * ($at[$ii+1][0] - $at[$ii][0])
    Next
    Local $u = UBound($aPoints), $aBuf[$u][2], $aRet[$n], $r = 0, $t = 0, $a[2], $b[2], $c[2], $m = 0
    For $tt = 0 To $n - 1 Step 1
        $t = $newT[$tt]
        For $i = 0 To $u - 1 Step 1
            $aBuf[$i][0] = $aPoints[$i]
        Next
        For $sub = 2 To $u Step 1
            $m = IsInt($sub/2)
            For $i = 0 To $u - $sub Step 1
                $a = $aBuf[$i][1-$m]
                $b = $aBuf[$i+1][1-$m]
                $c[0] = $a[0] + $t * ($b[0] - $a[0])
                $c[1] = $a[1] + $t * ($b[1] - $a[1])
                $aBuf[$i][$m] = $c
                If $sub = $u Then
                    $aRet[$r] = $aBuf[$i][$m]
                    $r += 1
                EndIf
            Next
        Next
    Next
    Return $aRet
EndFunc

Global $bExit = False

_GDIPlus_Startup()
Global $hGUI = GUICreate($sTitle, $iW, $iH)
Global $hGFX = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global $hBMP = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGFX)
Global $hBUF = _GDIPlus_ImageGetGraphicsContext($hBMP)
Global $hPEN = _GDIPlus_PenCreate()

_GDIPlus_PenSetStartCap($hPEN, 2)
_GDIPlus_PenSetEndCap($hPEN, 2)
_GDIPlus_GraphicsSetSmoothingMode($hBUF, 2)

GUISetOnEvent(-3, 'EVENT', $hGUI)
OnAutoItExitRegister('Xit')
GUISetState(@SW_SHOW, $hGUI)

While Not $bExit And Sleep(10)
    _GDIPlus_GraphicsClear($hBUF)
    $aBezierN = BezierN_PseudoEquidistant($aKontrollPunkte, $nBezierPoints)
    Print($aBezierN, 0.015, 0xFFFF6050)
    Print($aKontrollPunkte, 0.025, 0xFF808080)
    Mouse($aKontrollPunkte)
    _GDIPlus_GraphicsDrawImageRect($hGFX, $hBMP, 0, 0, $iW, $iH)
WEnd

Func Mouse(ByRef $aPoints)
    Local $mPos = MouseGetPos(), $a[2]
    Local Static $iDrag = -1
    _GDIPlus_PenSetColor($hPEN, 0xFF80FF00)
    _GDIPlus_PenSetWidth($hPEN, (0.035 / 5.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($aPoints) - 1 Step 1
        If Sqrt(($mPos[0]/$iW - ($aPoints[$i])[0])^2 + ($mPos[1]/$iH - ($aPoints[$i])[1])^2) < 0.0325 Then
            If _IsPressed('01') Then
                $iDrag = $i
            Else
                $iDrag = -1
            EndIf
            Circle($aPoints[$i], 0.035)
        EndIf
    Next
    If $iDrag <> -1 Then
        $a[0] = $mPos[0] / $iW
        $a[1] = $mPos[1] / $iH
        _GDIPlus_PenSetColor($hPEN, 0xFF80FFFF)
        Circle($aPoints[$iDrag], 0.035)
        $aPoints[$iDrag] = $a
    EndIf
EndFunc

Func Print(ByRef $aPoints, $d = 0.025, $iCol = 0xFFFFFFFF)
    _GDIPlus_PenSetColor($hPEN, $iCol)
    _GDIPlus_PenSetWidth($hPEN, ($d / 5.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 0)
    For $i = 0 To UBound($aPoints) - 1 Step 1
        Circle($aPoints[$i], $d)
    Next
    _GDIPlus_PenSetWidth($hPEN, ($d / 8.0) * $iW)
    _GDIPlus_PenSetDashStyle($hPEN, 1)
    For $i = 0 To UBound($aPoints) - 2 Step 1
        Line($aPoints[$i], $aPoints[$i+1])
    Next
EndFunc

Func Line($p1, $p2)
    _GDIPlus_GraphicsDrawLine($hBUF, $p1[0] * $iW, $p1[1] * $iH, $p2[0] * $iW, $p2[1] * $iH, $hPEN)
EndFunc

Func Circle($p, $d)
    _GDIPlus_GraphicsDrawEllipse($hBUF, $p[0] * $iW - $d/2 * $iW, $p[1] * $iH - $d/2 * $iH, $d * $iW, $d * $iH, $hPEN)
EndFunc

Func EVENT()
    Switch @GUI_CtrlId
        Case -3
            $bExit = True
    EndSwitch
EndFunc

Func Xit()
    _GDIPlus_PenDispose($hPEN)
    _GDIPlus_GraphicsDispose($hBUF)
    _GDIPlus_BitmapDispose($hBMP)
    _GDIPlus_GraphicsDispose($hGFX)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

Die Methodik hier ist:

1. Berechne die "normalen" Bezier Punkte
2. Man kennt jetzt zu jedem Punkt den Abstand zum Nachfolger UND das $t welches in der originalen Version äquidistant verteilt wurde
3. Jetzt berechnet man pi mal Daumen die Gesamtlänge der Kurve (ist natürlich nicht exakt weil man endliche Samples hat)

4. Man kennt jetzt den Mittleren Abstand und findet ein modifiziertes $t, sodass der Abstand bei jedem Punkt zu seinem Vorgänger gleich ist.

Da das ganze unter der Annahme ist, dass man die Gesamtlänge der Kurve kennt (die man nicht kennt), sowie das die Kurve lokal eine kleine Änderungsrate hat (was oft nicht stimmt, wir sagen hier immerhin, dass das Integral entlang der Kurve GLEICH dem Abstand 2er Punkte ist. Nur ein Narr glaubt dass das immer geht) funktioniert die Methode nur wenn man hinreichend viele Punkte hat. Im Beispiel kann man z.B. mal eine 5 eintragen und sehen dass die Punkte KEINE gleichmäßige Abstände haben. Verwendbar wenn man genügend Punkte, und eine Kurve ohne zu stark knickende Stellen hat. Verwendungszweck: Wenn man aus irgendwelchen Gründen (z.B. Simulationen) halbwegs gleiche Abstände braucht, in 99% aller anderen Fälle ist der normale Bezier besser.

lg

M

**UEZ**

Danke.

Mars 16. August 2020 um 15:12