Probleme beim Empfangen von Modbus-Daten

autoit_dau

Hallo,

ich bin mal wieder beim Versuch verschiedene Janitzas per Modbus auszulesen. Mein Versuch erst mal nur einen Janitza auszulesen funktioniert teilweise.

Bei manschen "Starts" bekomme ich die angefrageten Werte - bei den nächsten "Starts" ist die Antwort zu kurz und die falschen Register werden ausgelesen.

Bild "matrix_ok" zeigt einen gelungenen Versuch 64 Register (float).

Bild "matrix_falsch" zeigt einen misslungenen Versuch 64 Register (float).

Ich habe viel rumprobiert - komme aber zu keiner Lösung. Vielen Dank schon mal!

AutoIt

; Abfragen von Modbusstationen,


#include <WinAPI.au3>
#include <Misc.au3>
#include <Array.au3>
#include <File.au3>
#include <FTPEx.au3>
#include <Timers.au3>

#include <GUIConstants.au3>
#include <MsgBoxConstants.au3>
#include <TrayConstants.au3>

#Include <GuiListView.au3>

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <ListviewConstants.au3>

Global $ModbusTCP_Debug_Send = 1
Global $ModbusTCP_Debug_Recv = 1

;$anzahl_stationen      = 10                                                            ;;;;; Unbedingt noch aus inia die Anzahl ermitteln
$anzahl_janitzas     = 1
      $FC2 = "04"
     $s_uID = "02"
     $s_port = 502;


$Start_regJanitza    = 19000

Local $iTimeout = 5


             ;;;;;;;;;;;; Hier gehts los
HotKeySet("{F8}","_stopIt")            ; F8 Beendet Programm
$runner = True

 $hTimer = TimerInit() ; Begin the timer and store the handle in a variable.

;MsgBox($MB_SYSTEMMODAL, "Time Difference", $fDiff)

While $runner

               _INI_zu_ARRAY_janitza()


                   TCPStartup()



                For $s = 1 TO   UBound($listeJan)-1                ;Anzahl Janitzas


                     $s_port            = $listeJan[$s][2]
                     $s_uID                = $listeJan[$s][3]

                  Global $iSock = TCPConnect($listeJan[$s][1], $s_port)


                                     If $iSock = -1 Then
                                       ConsoleWrite("Fehler Verbindungsaufbau TCP Modbus" & $listeJan[$s][1] &  @LF)

                                       ;Exit
                                       EndIf

                                    If $iSock <> -1 Then
                                       ConsoleWrite(" TCP Modbus OK  " & $listeJan[$s][1] & @LF)

                                       ;Exit



      $aWR_meter = _ModbusTCP_ReadValues($iSock, $FC2, $Start_regJanitza,64, "float") ;


      _ArrayDisplay($aWR_meter)


   TCPCloseSocket($iSock)
    TCPShutdown()
      exit

                       EndIf  ;; Verbinugsaufbau OK




;_____________________________________________________________


               NEXT   ; Nächste Station

                TCPCloseSocket($iSock)


 sleep(Abs($timer *1000) - (_Timer_Diff($hStarttime)))

WEnd
                       TCPShutdown()
Exit


;;;____________________________________________FUNKTIONEN_________________________________________________________________________________;;;;;;;

Func _stopIt()

    $runner = False
    TCPCloseSocket($iSock)
    TCPShutdown()
    Exit
EndFunc



;;;;;;;;;;;;;;;  INI ZU ARRAY JANITZA
Func _INI_zu_ARRAY_janitza()

Global $listeJan[$anzahl_janitzas+1][14] ;zeile, spalte

FOR $i = 1 To $anzahl_janitzas

$spalte1 = IniRead(@ScriptDir & "\janitza.ini", $i, "Janiza", "xxx")         ;IP Adresse
$spalte2 = IniRead(@ScriptDir & "\janitza.ini", $i, "PORT", "xxx")             ;Modbus Port
$spalte3 = IniRead(@ScriptDir & "\janitza.ini", $i, "MODBUS_ID", "xxx")     ;Modbus uID
$spalte4 = IniRead(@ScriptDir & "\janitza.ini", $i, "KOPF", "xxx")             ;Kopf
$spalte5 = IniRead(@ScriptDir & "\janitza.ini", $i, "ID", "xxx")             ;ID
$spalte6 = IniRead(@ScriptDir & "\janitza.ini", $i, "MANUFAKTUR", "xxx")     ;Hersteller
$spalte7 = IniRead(@ScriptDir & "\janitza.ini", $i, "MODEL", "xxx")         ;Model
$spalte8 = IniRead(@ScriptDir & "\janitza.ini", $i, "SERIAL", "xxx")         ;Sereiennummer
$spalte9 = IniRead(@ScriptDir & "\janitza.ini", $i, "NIX", "xxx")             ;Sereiennummer

$spalte10 = IniRead(@ScriptDir & "\janitza.ini", $i, "FTP_HOST", "xxx")     ;FTP host
$spalte11 = IniRead(@ScriptDir & "\janitza.ini", $i, "FTP_USER", "xxx")     ;FTuser
$spalte12 = IniRead(@ScriptDir & "\janitza.ini", $i, "PTP_PAS", "xxx")         ;FTPpa
$spalte13 = IniRead(@ScriptDir & "\janitza.ini", $i, "FTP_PFAD", "xxx")     ;FT Pfad

$listeJan[$i][1] =    $spalte1                                                 ;zeile, spalte
$listeJan[$i][2] =    $spalte2
$listeJan[$i][3] =    $spalte3
$listeJan[$i][4] =    $spalte4
$listeJan[$i][5] =    $spalte5
$listeJan[$i][6] =    $spalte6
$listeJan[$i][7] =    $spalte7
$listeJan[$i][8] =    $spalte8
$listeJan[$i][9] =    $spalte9
$listeJan[$i][10] =    $spalte10
$listeJan[$i][11] =    $spalte11
$listeJan[$i][12] =    $spalte12
$listeJan[$i][13] =    $spalte13


NEXT


EndFunc
;;;;;;;;;;;;;;; ENDE INI ZU ARRAY Janitza


 ;;;;;;;;;;;;;FUNC MODBUS;;;;;;;;;;;;;;;;;;;;;;


Func _ModbusTCP_ReadValues($mainsocket, $FC2, $iStart, $iNum, $sType)
Local Static $TI = 0
$TI += 1


Local $iBytesToSend = 6

_ModbusTCP_Send($mainsocket, "0x" & Hex($TI, 4) & "0000" & Hex($iBytesToSend, 5)  & $s_uID & Hex($FC2, 2) & Hex($iStart, 4) & Hex($iNum, 4)) ;; komisch Hex($iBytesToSend, 4) ist sonst OK
;_ModbusTCP_Send($mainsocket, "0x" & Hex($__TID, 4) & "0000" & Hex($iBytesToSend, 4)  & $ID & Hex($FC, 2) & Hex($iStart, 4) & Hex($iNum, 4))

      MsgBox(0, "", "$iSock:  "& $iSock & ' IP: ' &$listeJan[$s][1] &' uID: '& $s_uID  &' Port: '& $s_port &' FC: '& $FC2 &' Reg: '& $Start_regJanitza &' iNum: '& $iNum)
If @error Then Return SetError(1, 0, 0)


Local $sRecv


Do
$sRecv = _ModbusTCP_Recv($mainsocket, 512)
;MsgBox(0, "", "FEHLER:  "& "**" & 'local : ' & $sRecv  & ' FC : '& $FC2)
Until @error Or $sRecv <> ""
If @error Then Return SetError(2, 0, 0)


If Int(String(BinaryMid($sRecv, 1, 2))) <> $TI Then Return SetError(3, 0, 0)


Local $iSize = 4 ; default


Switch $sType
Case "word"
$iSize = 2
Case "float"
$iSize = 4
Case "double"
$iSize = 8
EndSwitch


Local $aRet[$iNum / ($iSize / 2)], $iTemp        ;$iSize


For $i = 0 To UBound($aRet) - 1
$iTemp = BinaryMid($sRecv, 10 + $i * $iSize, $iSize)
Switch $sType
Case "word"
$aRet[$i] = Int(String($iTemp))
Case "float"
$aRet[$i] = _WinAPI_IntToFloat(Int(String($iTemp)))
Case "double"
$aRet[$i] = _WinAPI_Int64ToDouble(Int(String($iTemp)))
EndSwitch
Next
Return $aRet
EndFunc ;==>_ModbusTCP_ReadValues


Func _ModbusTCP_Send($mainsocket, $data)
If $ModbusTCP_Debug_Send Then ConsoleWrite("_ModbusTCP_Send(" & $mainsocket & ", """ & $data & """)" & @CRLF)
;$TextZeile_log = $TextZeile_log & "_ModbusTCP_Send(" & $mainsocket & ", """ & $data & """)" & @CRLF
Local $Send = TCPSend($mainsocket, $data)
Return SetError(@error, 0, $Send)
EndFunc ;==>_ModbusTCP_Send


Func _ModbusTCP_Recv($mainsocket, $maxlen = 256, $flag = 0)
Local $sRecv = TCPRecv($mainsocket, $maxlen, $flag)
Local $error = @error
If $sRecv <> "" And $ModbusTCP_Debug_Recv Then ConsoleWrite("_ModbusTCP_Recv: " & $sRecv & @CRLF)
;$TextZeile_log = $TextZeile_log & "_ModbusTCP_Recv: " & $sRecv & @CRLF
Return SetError($error, 0, $sRecv)
EndFunc ;==>_ModbusTCP_Recv


; #FUNCTION# ====================================================================================================================
; Name...........: _WinAPI_Int64ToDouble
; Description ...: Returns a 8 byte integer as a double value
; Syntax.........: _WinAPI_IntToFloat($iInt64)
; Parameters ....: $iInt64 - 8 byte Integer value (64 bit)
; Return values .: Success - 8 byte integer value as a double
; Author ........: funkey
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _WinAPI_Int64ToDouble($iInt64)
Local $tInt64 = DllStructCreate("INT64")
Local $tDouble = DllStructCreate("double", DllStructGetPtr($tInt64))
DllStructSetData($tInt64, 1, $iInt64)
Return DllStructGetData($tDouble, 1)
EndFunc ;==>_WinAPI_Int64ToDouble



; #FUNCTION# ====================================================================================================================
; Name...........: UAS  E`WEB https://www.autoitscript.com/forum/topic/49435-lparam-array/?tab=comments#comment-373039
; Description ...:   WORD zu Dword
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; E
$iWord = MakeWord(0x34,0x12)
ConsoleWrite("0x" & Hex($iWord) & @CRLF)
ConsoleWrite("0x" & Hex(LoByte($iWord)) & @CRLF);These output original values passed to MakeWord()
ConsoleWrite("0x" & Hex(HiByte($iWord)) & @CRLF)
;$TextZeile_log = $TextZeile_log & "0x" & Hex($iWord) & @CRLF

Func LoByte($iWord)
    Return BitAND($iWord, 0xFF)
EndFunc   ;==>LoByte

Func HiByte($iWord)
    Return BitAND($iWord, 0xFF00) / 0x100
EndFunc   ;==>HiByte

Func MakeWord($iLoByte, $iHiByte)
    If $iHiByte < 0x80 Then
        Return BitOR($iHiByte * 0x100, $iLoByte)
    Else
        Return BitOR($iHiByte, 0xFF00) * BitOR(0x100, $iLoByte)
     EndIf

EndFunc   ;==>MakeWord

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi autoit_dau,

das Review deines Skripts dauert ein wenig, aber vielleicht kannst du mir und den Anderen hier noch etwas helfen, indem du die INI-Datei (@ScriptDir & "\janitza.ini") oder eine Test-Ini bereit stellst, welche wir zur Fehlersuche verwenden können 😀 ?!

Ansonten gilt ganz allgemein Global nur außerhalb von Funktionen zu verwenden, da andernfalls der "Au3Check" Warnungen schmeißt.
Des Weiteren fehlt die Deklaration von $timer und $hStarttime.
- Oder sollte $timer eher $hTimer aus Zeile 41 sein?!
Ist das Skript nur ein Auszug aus einem größeren oder warum sind so viele Includes (Libraries) eingebunden/vorhanden?
- Nötig sind anscheinend nur:

AutoIt

#include-once
#include <Array.au3>
#include <Timers.au3>
#include <WinAPI.au3>

💡 Und noch etwas: Der untere Bereich ab Zeile 271 deines Skriptes wird nie erreicht. Denn nach deiner While Schleife gehst du ins Exit.

Viele Grüße
Sven

autoit_dau

Hallo Sven,

ich habe auf dem Weg der Fehlersuche alles entfernt was nicht gebraucht wird. Deshalb auch kein Ende der While-Schleife. Das Original hat genauso nicht funktioniert und ist mittlerweile zerstört.

FTP, Listview usw. sind dann noch (wieder) vorgesehen.

Die ini lade ich mal als txt hoch.

Danke schon mal!!

Velted

Moin,

wie erzeugt man eine so unüberscichtliche Codestruktur?

Mein Wissen über den Modbus beschränkt sich auf das Ergebnis von 30 Minuten Google-Studium, aber

AutoIt

    _ModbusTCP_Send($mainsocket, "0x" & Hex($TI, 4) & "0000" & Hex($iBytesToSend, 5)  & $s_uID & Hex($FC2, 2) & Hex($iStart, 4) & Hex($iNum, 4)) ;; komisch Hex($iBytesToSend, 4) ist sonst OK

4 ist nicht 'sonst' OK, 4 ist 'einzig und allein' OK. Bei 5 sind alle folgenden Bytes um 1 verschoben. Es würde mich sehr wundern, wenn dabei etwas vernünftiges zurückgegeben wird.

autoit_dau

Danke,

genau hier lag auch der Fehler. Ich musste in der ini die Stationsnummer ($s_uID) in Anführungszeichen setzen z.B. "02" und nicht 02

Ich hatte die gesendeten Daten verglichen. Als die Kommunikation funktioniert hatte war eine "0" mehr im Sendeprotokoll. Dann hab ich geschraubt.....

Danke erst mal, ich versuche weiter zu kommen...

Grüße!

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von autoit_dau

Danke erst mal, ich versuche weiter zu kommen...

Ja viel Erfolg dabei autoit_dau. Falls du weitere Fragen hast schlage ich vor, dass wir hier, gemeinsam mit dir Stück für Stück an einzelnen Funktionalitäten arbeiten und so nach und nach ein Skript erstellen, denn wie Velted es so treffend ausgedrückt hat 😅 , gibt es bei der Struktur deines Skriptes Verbesserungspotenzial. Dies machte es mir zumindest auch nicht so einfach, dein Code zu sichten (ein Review durchzuführen). Nur als Möglichkeit => "it's up to you".

Viele Grüße
Sven

**Moombas**

Es ist ja nicht nur die Strucktur, sondern leider auch GLobale Variablen, die Lokal in einer funktion deklariert werden usw. (macht man nicht).

Wobei ich auch, sowohl weil ich von der ModBus-Ansteuerung zu wenig Kenntnis habe, als auch bei diesem Horror von Strucktur/Formatierung das Thema auch gleich mal verworfen habe.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von Moombas

[...] sondern leider auch GLobale Variablen, die Lokal in einer funktion deklariert werden usw. (macht man nicht) [...]

Siehe meinen #2 Beitrag 😅 . Ich glaube umso dankbarer wird autoit_dau sein, wenn wir ihn helfen 😇 .

Viele Grüße
Sven

**Moombas**

Ja, hab ich gesehen.

Helfe auch gerne was die Strucktur angeht ( autoit_dau ), die finale Strucktur ist ja so oder so Benutzerspezifisch leicht variabel, sollte aber lesbar sein.

Ich denke einige Zeilenumbrüche kommen ggf. auch beim kopieren aus dem Editor hier auf die Webseite. Aber auch da sollte man vor dem Posten nochmal nachsteuern damit man damit was anfangen kann ohne den kompletten Code erstmal formatieren zu müssen wenn man helfen möchte.

Velted

Moin,

ich habe noch ein paar Minuten Google nachgelegt. Wenn Du diesen Artikel noch nicht kennst, könnte er Dir helfen.

Zitat von autoit_dau

Ich musste in der ini die Stationsnummer ($s_uID) in Anführungszeichen setzen z.B. "02" und nicht 02

Das stimmt so nicht. In der Nachricht belegen die Geräteadresse (ID) und der 'funktionale Code' (FC) jeweils ein Byte und beide sind numerisch.

In der Hex-Darstellung brauchst Du für ein Byte zwei Zeichen. Aus dem numerischen Wert 2 wird dabei 02. Wenn Du den Wert als Text/String mit zwei Zeichen übergibst, klappt das nur bis zur Zahl 9, weil der Text"09" den zwei Halbbytes für den Wert entspricht. Ab "10" wird das aber falsch. Die hexadezimale Darstellung für die Zahl 10 ist 0A. Wenn Du stattdessen "10" übergibst, entspricht das dem Wert 16. Deshalb:

AutoIt

_ModbusTCP_Send($mainsocket, "0x" & Hex($TI, 4) & "0000" & Hex($iBytesToSend, 4) & Hex($s_uID, 2) & Hex($FC2, 2) & Hex($iStart, 4) & Hex($iNum, 4))

Du kannst auch für die unterschiedlichen Abfragen/funktionalen Codes Formatspezifikationen für StringFormat erstellen. Ich finde das übersichtlicher. Für FC 0x04 könnte das dann so aussehen:

AutoIt

$iStart_regJanitza = 19000
$iTI = 1
$iUID = 2
$iStart = $iStart_regJanitza
$iNum = 64
; StringFormat 'format control' für FC 0x04 - Nachrichtenlänge = 6
; XXXX    Transaktions-Bezeichner $iTI
; 0000    Protokoll-Bezeichner (immer 0000)
; 0006    Nachrichtenlänge (für FC 0x04 immer 0006)
; XX    Geräteadresse $iUID
; 04    Funktionaler Code (hier immer 04)
; XXXX    Adresse des ersten Registers $iStart
; XXXX    Anzahl der Register $iNum
$sFC04 = "0x%04X00000006%02X04%04X%04X"
$sSend = StringFormat($sFC04, $iTI, $iUID, $iStart, $iNum)
MsgBox(0, "Ergebnis", $sSend)
#cs
---------------------------
Ergebnis
---------------------------
0x00010000000602044A380040
---------------------------
OK
---------------------------
#ce

Alles anzeigen

autoit_dau

Vielen Tausend Dank,

..ihr seid Helden!

ja die Struktur ist vorab schon schlecht und geht bei der Fehlersuche immer komplett in den Eimer. Die global/local Variablen werde ich noch richten.

So langsam funktioniert das Auslesen. Zum Glück hatte ich "Fehler Verbindungsaufbau" daraufhin habe ich die Funktion dahin geändert, dass sie sich selber aufruft, an Stelle von exit. Fuktioniert - nur leider habe ich ein schlechtes Gefühl dabei. Kann man das so machen?

...nochmals vielen Dank!

AutoIt

Func _example_nativ()
    ;MsgBox(0, "_example_native()", "Example modbusTCP only via Autoit")
    TCPStartup()

    $_native_ModbusTCP_Debug_Send = 1
    $_native_ModbusTCP_Debug_Recv = 1

    Global $iSock = TCPConnect($S_IP, $s_port   )

    If $iSock = -1 Then
        ConsoleWrite("Fehler Verbindungsaufbau" & @LF)
        ConsoleWrite("Conn = IP: " & $S_IP &" Port:  " & $s_port & " uId: " & $s_uID & " FC: " & $FC &  " RegStart: " & $Start_regJanitza & " RegAnz: " & $RegAnzahl &  @CRLF)
        sleep(10000)
        _example_nativ()
        ;Exit
    EndIf


        $aJani = _native_ModbusTCP_ReadImputRegister($iSock, $Start_regJanitza, $RegAnzahl, "float") ;Functioncode 4, Register 1, Länge 4 Resiter lesen, als float zurückgeben
        ConsoleWrite("Conn = IP: " & $S_IP &" Port:  " & $s_port & " uId: " & $s_uID & " FC: " & $FC &  " RegStart: " & $Start_regJanitza & " RegAnz: " & $RegAnzahl &  @CRLF)
        ConsoleWrite("$iSock = " & $iSock & @CRLF)
        ;ConsoleWrite("float = " & $aJani[0] & @CRLF)

        ;_ArrayDisplay($aJani)


    TCPShutdown()

EndFunc   ;==>_example_nativ

Alles anzeigen

**Moombas**

Ich rate davon ab, aus mehreren Gründen:

1. Schaffst du somit im worst case eine riesige Kaskade

2. Sobald der 2. bzw. Xte Aufruf der Funktion abgefrühstückt ist, springt er wieder an den Punkt wo sie aufgerufen wurde. Bedeutet, das alles was danach kommt Xmal ausgeführt wird.

Versuch den Verbindungsaufbau zu machen, pack das aber mit einem Timer sleep(X) (den hast du ja bereits) und in eine Schleife mit einem maximum von z.B. 10 Versuchen. Wenn die 10 Versuche fehlschlagen, Abbruch per z.B. Return 'keine Verbindung'.

Wenn die Verbindung erfolgreich ist mit ExitLoop raus aus der Funktion und dann kommt dein Code den du ausführen willst.

Edit: Hier mal, wie ich das quick & dirty Umsetzen würde in deinem Code. Ich habe dabei auch gleich die falschen/fehlenden Deklarationen korrigiert und erwarte (das würde ich wirklich empfehlen), das du die Werte, die in der () der Funktion stehen, der Funktion übergibst und nicht alle Global definierst. Letzteres wird dir sonst irgendwann auf die Füße fallen.

AutoIt

Func _example_nativ($S_IP, $s_port, $s_uID, $FC, $Start_regJanitza, $RegAnzahl)
Local $iSock, $iTry = 10
Local Const $_native_ModbusTCP_Debug_Send = 1
Local Const $_native_ModbusTCP_Debug_Recv = 1

    ;MsgBox(0, "_example_native()", "Example modbusTCP only via Autoit")
    
    TCPStartup()
    
    For $Connect = 1 to $iTry
        $iSock = TCPConnect($S_IP, $s_port)
        sleep(1000)
        
        If $iSock = -1 Then
            ConsoleWrite("Fehler Verbindungsaufbau" & @LF)
            ConsoleWrite("Conn = IP: " & $S_IP &" Port:  " & $s_port & " uId: " & $s_uID & " FC: " & $FC &  " RegStart: " & $Start_regJanitza & " RegAnz: " & $RegAnzahl &  @CRLF)
            If $Connect = $iTry Then
                Return 'Fehler: Kein Verbindungsaufbau möglich.'
            Else
                Consolewrite('Verbindungsaufbau (' & $Connect & ') fehlgeschlagen. Erneuter Versuch.' & @CRLF)
            EndIf
        Else
            ExitLoop
        EndIf
    Next

    $aJani = _native_ModbusTCP_ReadImputRegister($iSock, $Start_regJanitza, $RegAnzahl, "float") ;Functioncode 4, Register 1, Länge 4 Resiter lesen, als float zurückgeben
    ConsoleWrite("Conn = IP: " & $S_IP &" Port:  " & $s_port & " uId: " & $s_uID & " FC: " & $FC &  " RegStart: " & $Start_regJanitza & " RegAnz: " & $RegAnzahl &  @CRLF)
    ConsoleWrite("$iSock = " & $iSock & @CRLF)
    ;ConsoleWrite("float = " & $aJani[0] & @CRLF)

    ;_ArrayDisplay($aJani)

    TCPShutdown()
EndFunc   ;==>_example_nativ

Alles anzeigen

autoit_dau

Hallo Moombas,

danke für die Hilfe. Allerdings läuft das skript "unbeaufsichtigt", d.h. Es soll solange "schleifen" bis wieder einer den Stecker steckt - und weiter gehts.

Jetzt haab ich ein großes FTP Problem. Da mach im mal ein neues Thema.

Danke!

**Moombas**

Zitat von autoit_dau

Hallo Moombas,
danke für die Hilfe. Allerdings läuft das skript "unbeaufsichtigt", d.h. Es soll solange "schleifen" bis wieder einer den Stecker steckt - und weiter gehts.
Danke!

Dann würde ich das dennoch trennen:

1. Prüfen ob eine Verbindung aufgebaut werden kann (Endlosschleife mit Ping), dennoch Empfehlung einen Shortcut zum Abbruch einbauen

2. Wenn erfolgreich: Code ausführen (der obige Code).

3. Prüfen ob die Verbindung (Endlosschleife mit Ping) wieder getrennt wurde und erst dann wieder bei "1." einsetzen um eine Mehrfachausführung zu vermeiden.

Q&D:

AutoIt

Global $bTerminate = False
HotKeySet("{ESC}", "Terminate")


Func WaitForDevice($S_IP, $s_port, $s_uID, $FC, $Start_regJanitza, $RegAnzahl) ; Auch hier müssen die POarameter rein, da du diese ja an die "finale Funktion" weiter geben musst.
    While 1
        If $bTerminate then 
            $bTerminate = False
            Exitloop
        Endif
        If Ping($S_IP, 1000) > 0 Then ;Warten bis das Gerät sich an der IP meldet, Timeout bitte ggf. anpassen
            If _example_nativ($S_IP, $s_port, $s_uID, $FC, $Start_regJanitza, $RegAnzahl) Then ;Code ausführen, falls erfolgreich warten bis die Verbindung getrennt wurde
                While Ping($S_IP, 1000) ;Warten bis das Gerät sich an der IP nicht mehr meldet, Timeout bitte ggf. anpassen
                    sleep(100)
                    If $bTerminate then 
                        $bTerminate = False
                        Exitloop
                    Endif
                WEnd
            EndIf
        EndIf
    WEnd
EndFunc

Func _example_nativ($S_IP, $s_port, $s_uID, $FC, $Start_regJanitza, $RegAnzahl)
Local $iSock, $aJani, $iTry = 10
Local Const $_native_ModbusTCP_Debug_Send = 1
Local Const $_native_ModbusTCP_Debug_Recv = 1

    ;MsgBox(0, "_example_native()", "Example modbusTCP only via Autoit")
    TCPStartup()

    For $Connect = 1 to $iTry
        $iSock = TCPConnect($S_IP, $s_port)
        sleep(1000)

        If $iSock = -1 Then
            ConsoleWrite("Fehler Verbindungsaufbau" & @LF)
            ConsoleWrite("Conn = IP: " & $S_IP &" Port:  " & $s_port & " uId: " & $s_uID & " FC: " & $FC &  " RegStart: " & $Start_regJanitza & " RegAnz: " & $RegAnzahl &  @CRLF)
            If $Connect = $iTry Then
                Consolewrite('Fehler: Kein Verbindungsaufbau möglich.')
                Return False
            Else
                Consolewrite('Verbindungsaufbau (' & $Connect & ') fehlgeschlagen. Erneuter Versuch.' & @CRLF)
            EndIf
        Else
            ExitLoop
        EndIf
    Next

    $aJani = _native_ModbusTCP_ReadImputRegister($iSock, $Start_regJanitza, $RegAnzahl, "float") ;Functioncode 4, Register 1, Länge 4 Resiter lesen, als float zurückgeben
    ConsoleWrite("Conn = IP: " & $S_IP &" Port:  " & $s_port & " uId: " & $s_uID & " FC: " & $FC &  " RegStart: " & $Start_regJanitza & " RegAnz: " & $RegAnzahl &  @CRLF)
    ConsoleWrite("$iSock = " & $iSock & @CRLF)
    ;ConsoleWrite("float = " & $aJani[0] & @CRLF)

    ;_ArrayDisplay($aJani)

    TCPShutdown()

    Return True
EndFunc   ;==>_example_nativ

Func Terminate()
    $bTerminate = True
EndFunc

Alles anzeigen

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)