Programm mit Adminrechte (UAC) restarten

Racer

Hallo @ALL

Ich möchte ein Programm das ohne #RequireAdmin im Script im Usermode läuft. Mit einem Butten soll dann die Aufforderung kommen Username und Password einzugeben, das Programm soll sich selbst restarten und dann mit Adminrechte ausgeführt werden. Am liebsten wäre mir die UAC, aber ich weiß nicht wie man einen Programmaufruf dazu bringt die UAC auszugeben, so das das gleich Programm mit Adminrechte läuft.

Das soll optisch dann so aussehen:

Das wäre jetzt der Usermode und mit dem Klick auf "Admin" soll das Programm (mit UAC) neu gestaret werden und dann erhöhte Rechte haben.
Bis jetzt habe ich ein kleines Testprogramm das auch keinen gewünschten Erfolg brachte:

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=Icons\0472.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;Test: Restart with Adminrights


#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


#Region ### START Koda GUI section ### Form=
local $Form1 = GUICreate("Form1", 185, 130, 853, 202)
local $Button1 = GUICtrlCreateButton("Button1", 45, 25, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

local $nMsg
local $update_program
local $user
local $pw
local $pid

MsgBox ("", "", "IsAdmin: " & IsAdmin ())

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit


        Case $Button1
            if @Compiled = 0 then
                ConsoleWrite  ('$user, @LogonDomain, $pw, $RUN_LOGON_NOPROFILE, "@ScriptFullPath"' & @CRLF)
            Else
                $user = InputBox ("Adminaccount", "Username", "")
                $pw = InputBox ("Adminaccount", "Username", "", "*")
                $pid = RunAs ($user, @LogonDomain, $pw, $RUN_LOGON_NOPROFILE, @ScriptFullPath, "")
                sleep (1000)

                Exit
            EndIf

    EndSwitch
WEnd

Alles anzeigen

Mit RunAs User & Passwort wird das Programm zwar korrekt unter dem User gestartet, aber ohne Adminrechte

Ich habe auch den Betrag RE: 'Run' führt Exe NICHT aus die Adminrechte benötigt, 'ShellExecute' tut's gefunden, hilft mir aber auch nicht weiter da Shellexecute keinen Usernamen/PW zulässt.

Der kleine Trick mit set __COMPAT_LAYER=RunAsAdmin funktioniert auch nicht!

Was natülich geht ist das Programm mit "rechter Maustaste" -> als Administrator ausführen. Ist halt nicht elegant

Vielleicht hat hier wer eine Idee oder gar eine Lösung.

lg

Racer

wuff100

C

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$UAC = GUICreate("UAC", 220, 82, 192, 124)
$AN = GUICtrlCreateButton("AN", 24, 22, 73, 33)
$AUS = GUICtrlCreateButton("Aus", 121, 22, 73, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        case $AN
            RegWrite("HKLM64\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Policies\System", "ConsentPromptBehaviorAdmin", "REG_DWORD", "5")
            RegWrite("HKLM64\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Policies\System", "EnableLUA", "REG_DWORD", "1")

        case $AUS
            RegWrite("HKLM64\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Policies\System", "ConsentPromptBehaviorAdmin", "REG_DWORD", "0")
            RegWrite("HKLM64\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Policies\System", "EnableLUA", "REG_DWORD", "0")
    EndSwitch
WEnd

Alles anzeigen

Racer

Die UAC zu deaktivieren ist keine Lösung.....

Trotzdem Danke!

lg

Racer

gmmg

Racer: schau doch mal nach #RequireAdmin

Ich hatte mal folgendes Script im Einsatz, um eine msi zu installieren. vielleicht kannst du damit was anfangen.

AutoIt

;msi installer

#RequireAdmin

If Not IsAdmin() Then
    RunAs("****", @LogonDomain, "**********", 0, @ScriptFullPath, @ScriptDir, @SW_HIDE)
    Exit
EndIf


If IsAdmin() Then
     MsgBox(0, "", "Admin-Rechte erkannt.",1)
EndIf

MsgBox(0,"","Install beginnt",2)
;RunWait ('msiexec /i "C:\scripte\7z465.msi" /quiet', "" , @SW_HIDE)

MsgBox(0,"","Install fertig",2)

Alles anzeigen

Gruß gmmg

Racer

Hallo!

Danke gmmg, aber genau das kann ich nicht brauchen. Das Programm sollte grundsätzlich von einem Benutzer mit Userrechte gestartet werden könnnen und nur bei "Klick" mit Username/PW dann mit Adminrechte restarten.

Notepad++ kann so was: Wenn als User eine Datei öffnet und diese dann schreiben möchte an einen Ort wo erhöhte Rechte benötigt werden, macht das Notepad++ einen restart und fordert über die UAC dann Username/PW.... So was hätte ich gesucht

lg

Racer

gmmg

Racer:

im englischen Forum gefunden: https://www.autoitscript.com/forum/topic/19…t-requireadmin/

AutoIt

MsgBox(0, "Test", "User is " & (IsAdmin() ? "" : "not ") & "Admin.")

If Not IsAdmin() Then
    _RerunAsAdmin()
Else
    MsgBox(0, "Is Admin?", "Yes, Admin.") ;Example.
EndIf


Func _RerunAsAdmin()
    Local $sParameters = ""
    If Not @Compiled Then
        $sParameters = '"' & @ScriptFullPath & '"'
    EndIf

    ShellExecute(@AutoItExe, $sParameters, "", "runas")
    If @error Then Return MsgBox(16 + 262144, "ERROR!", "Unable to elevate to Admin due to UAC.")

EndFunc

Alles anzeigen

Beispiel GUI

AutoIt

#include <GUIConstantsEx.au3>

GUICreate("AutoIt IsAdminTest", 220, 200)
$Button_admin = GUICtrlCreateButton("admin", 10, 70, 50, 20)
GUISetState(@SW_SHOW)

MsgBox(0, "Test", "User is " & (IsAdmin() ? "" : "not ") & "Admin.")

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_admin

            _RerunAsAdmin()
            Exit

    EndSelect
WEnd

MsgBox(0, "Test", "User is " & (IsAdmin() ? "" : "not ") & "Admin.")

If Not IsAdmin() Then
    _RerunAsAdmin()

Else
    MsgBox(0, "Is Admin?", "Yes, Admin.") ;Example.
EndIf


Func _RerunAsAdmin()
    Local $sParameters = ""
    If Not @Compiled Then
        $sParameters = '"' & @ScriptFullPath & '"'
    EndIf

    ShellExecute(@AutoItExe, $sParameters, "", "runas")
    If @error Then Return MsgBox(16 + 262144, "ERROR!", "Unable to elevate to Admin due to UAC.")

EndFunc

Alles anzeigen

Gruß gmmg

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Also ich schalt auf allen Rechnern UAC immer aus - wer braucht denn sowas....

**water**

Das hilft dem OP aber nicht wirklich, oder?

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Warum nicht? Er schreibt zwar das sei keine Lösung... aber vielleicht braucht er einen User, der Ihm sagt es geht auch ohne?

Peter

**water**

Wenn er sagt, dass die UAC abzuschalten keine Lösung für ihn ist, dann ist doch jeder weitere Kommentar überflüssig!

Over and Out.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Sagt wer? Ein Oberlehrer mit drei Sternen? Wiewäre es wenn Du das dem TE selbst entscheiden lassen würdest - der ist bestimmt alt genug um für sich selbst zu sprechen... da brauchts keine Aufpasser. Ich mag diesen UMGANGSTON NICHT.... und weil meine Meinung nicht opurtun ist wirds sowieso wieder gelöscht..... das nennt man dann Demokratie

**BugFix**

Zitat von Peter S. Taler

das nennt man dann Demokratie

Wir sind hier keine Demokratie. Tut mir leid, dass dir das in all den Jahren nicht bewusst geworden ist. Die Bemerkung von water war völlig korrekt und ich möchte dich bitten beim Thema zu bleiben.

Ansonsten werde ich deinem "Wunsch" nach Löschung Rechnung tragen.

Racer

Hallo!

gmmg: Ja das sieht sehr gut aus. Starte ich das Programm mit Userrechte, wird nach dem Klick auf den Butten das Programm restartet und mit einer UAC-Abfage nach Adminrechte ausgeführt. Morgen kommt dann der Echttest in meine Programm...Hoffe das funkioniert auch so gut wie zu Hause!

vielen Dank!

Peter S. Taler: Ich bin immer der Meinung das jeder auf seinen Geräten machen soll was er für richtig hält. Aber wenn Du Dich mal mit IT-Sicherheit insesonders in Unternehmen beschäftigst wirst Du sehr schnell feststellen das die UAC doch mehr ist als nur ein lässtiges Feature von der MS.....

Auch die Apfel-Jünger behaupten nach wie vor das es keine Viren am Mac gibt....ich frage mich nur warum ich nur jede Woche einen Sicherheitsbericht von Schadsoftware für Apple bekomme...

lg

Racer

Racer

Hallo!

Ich habe das jetzt in der Arbeit bei meine Projekt eingebaut und es funktioniert top!

Das Geheimnis liegt im ShellExecute (@ScriptFullPath, "", "", "runas"), genauer gesagt an dem Verb "runas" - vielleicht kann man das in die Doku aufnehmen, könnte den einen oder anderen Interessieren.

vielen Dank

lg

Racer

gmmg

Racer: Prima das es läuft

Gruß gmmg