Verknüpfungen erstellen

HansiEdi

Hallo,

es ist schon gut 20 Jahre her, als ich mich mit AutoIT beschäftigt hatte.

Leider kann ich nichts mehr und benötige eure Hilfe.

Ich möchte Programmverknüpfungen erstellen.

Dabei müssen Ordnernamen in einem Verzeichnis ausgelesen werden. Die einzelnen Verknüpfungen tragen später die jeweiligen Ordnernamen und als zu startendes Programm wird der Ordnername als Parameteraufruf weitergegeben.

Beispiel1:
Name der Verknüpfungsdatei: ErsterName
Ziel der Verknüpfung: "C:\Program Files\Mozilla Firefox\firefox.exe" -P "ErsterName"

Beispiel2:
Name der Verknüpfungsdatei: ZweiterName
Ziel der Verknüpfung: "C:\Program Files\Mozilla Firefox\firefox.exe" -P "ZweiterName"

Hintergrund dieser Aktion:

Ich arbeite mit unzähligen portablen Versionen von Firefox.

Ich möchte nun alle portablen Firefox Kopien als jeweiliges Profil für meine installierte Firefox Instanz anlegen.

Der gesamte Ablauf unterteilt sich in drei Schritten.

1. Firefox Profilmanager - neues Profil erstellen

2. Firefox Portable Versionen bestehende Profile importieren. Da werde ich vielleicht noch herumprobieren.

3. Startverknüpfungen erstellen

Schritt 1 ist fast fertig, erste Versuche funktionieren schon, aber mit ein paar Problemen.

Schritt 2 kann ich im schlimmsten fall manuell durchführen, wird mir aber auch stunden an Zeit kosten alle Profile manuell zu kopieren.

Schritt 3 Die Programmverknüpfungen müssen automatisch erstellt werden.

Schritt3, Erstellung der Programmverknüpfungen:

AutoIt

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

;#include <WinAPIFiles.au3>
#include <File.au3>
#include <Array.au3>


; Pfad zum Firefox-Ordner
Local $sourceFolder = "E:\Portable\Browser\Firefox\"

; Pfad zum Zielverzeichnis für die Verknüpfungsdateien
Local $destinationFolder = "C:\Users\Hans\Desktop\Firefox Profile\"

; Liste der Unterordner im Quellverzeichnis
Local $folders = _FileListToArray($sourceFolder, "*", $FLTA_FOLDERS)

; Firefox-Exe-Pfad
Local $firefoxExePath = "C:\Program Files\Mozilla Firefox\firefox.exe"

; Schleife über alle Unterordner
For $i = 1 To $folders[0]
    ; Verknüpfungsdateiname
    Local $linkName = $folders[$i]

    ; Ziel-Pfad für die Verknüpfung
    Local $targetPath = $firefoxExePath & ' -P "' & $linkName & '"'

    ; Verknüpfung erstellen
    FileCreateShortcut($targetPath, $destinationFolder & $linkName & ".lnk")
Next

MsgBox($MB_ICONINFORMATION, "Fertig", "Verknüpfungen wurden erstellt und im Zielverzeichnis abgespeichert.")

Alles anzeigen

Leider funktioniert das nicht wie gewünscht, an die erstellten Verknüpfungen werden Zielpfad, Parameter und Arbeitsverzeichnis nicht weitergereicht.

Ich hoffe das Ihr mir helfen könnt.

Edit:

FileCreateShortcut($targetPath, $destinationFolder & $linkName & ".lnk", $sourceFolder)

nun wird das Arbeitsverzeichnis (ausführen in:) mit abgespeichert.

$targetPath wird nicht richtig übernommen.

Wenn ich folgendes zum Testen angebe, wird mir der Pfad mit Parameter in die Verknüpfungsdatei gespeichert, es werden jedoch die Anführungszeichen nach der Pfadangabe und vor dem Parameter nicht mitgegeben.

$firefoxExePath = "C:\Program Files\Mozilla Firefox\firefox.exe" & "'-P '" & "Onlineshop"

Resultat: "C:\Program Files\Mozilla Firefox\firefox.exe -P Onlineshop"

folgendes wäre korrekt: "C:\Program Files\Mozilla Firefox\firefox.exe" -P "Onlineshop"

Leider komme ich nicht weiter.

LG Hans

**Moombas**

Dreh mal die Anführungszeichen um und da passt so oder so was nicht mit deiner Zeichensetzung (dein gepostetes Resultat kann da übrigens auch nicht stimmen!):

"C:\Program Files\Mozilla Firefox\firefox.exe" & "'-P '" & "Onlineshop" -> C:\Program Files\Mozilla Firefox\firefox.exe'-P 'Onlineshop

Versuchs mal so:

'"C:\Program Files\Mozilla Firefox\firefox.exe" -P "' & 'Onlineshop' & '"' -> "C:\Program Files\Mozilla Firefox\firefox.exe" -P "Onlineshop"

Nur mal als kurzer Blick ohne mir den Rest im Detail angeschaut zu haben.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi hansiii (Hans),
willkommen zurück zu AutoIt und damit hier im Forum 👋 .

Hier eine (hoffentlich) lauffähige Variante so wie du es angegeben hast (erwartest):

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

#include-once
#include <File.au3>

_Main()

Func _Main()
    Local $sFirefoxExe        = 'C:\Program Files\Mozilla Firefox\firefox.exe'
    Local $sSourceFolder      = 'E:\Portable\Browser\Firefox\'
    Local $sDestinationFolder = @DesktopDir & '\Firefox Profile\'

    If Not FileExists($sDestinationFolder) Then
        DirCreate($sDestinationFolder)
    EndIf

    ; Liste der Unterordner im Quellverzeichnis
    Local $aFolders = _FileListToArray($sSourceFolder, '*', $FLTA_FOLDERS)

    ; Schleife über alle Unterordner
    For $i = 1 To $aFolders[0]
        Local $sLinkName = $aFolders[$i] & '.lnk'
        Local $sLink     = $sDestinationFolder & $sLinkName

        ; Verknüpfung erstellen
        FileCreateShortcut($sFirefoxExe, $sLink, $sFirefoxExe, '-P "' & $sLinkName & '"')
    Next

    MsgBox(64, 'Fertig', 'Verknüpfungen wurden erstellt und im Zielverzeichnis abgespeichert.')
EndFunc

Alles anzeigen

Dein Problem war, dass du FileCreateShortcut() nicht korrekt aufgerufen hast. Schaue dir dazu einfach nochmal die Hilfe (3. und 4. Paramenter) und deren Beispiel-Code an. Falls du dann noch Fragen haben solltest, komme gern auf uns zurück 🤝 .

Moombas Danke das du dazugeschrieben hast, dass es nur ein kurzer Blick war, denn so hätte es nicht ausgereicht 😅 . Dennoch wichtiger Hinweis, finde ich.

Viele Grüße
Sven

**Moombas**

Das habe ich mir gedacht und deswegen dazu geschrieben.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von Moombas

Das habe ich mir gedacht und deswegen dazu geschrieben.

Jetzt fehlt mir wieder so'n Reaktionsbutton/Icon wie 👌 oder 😅 oder 💙 .
Naja, kommt Zeit, kommt Rat (#gun-food).

**Moombas**

Eine Sache würde ich noch ändern:
Eine finale Prüfung ob die Verknüpfungen wirklich erstellt wurden (das die Schleife durchläuft ist leider kein Erfolgsindikator).
Man könnte das ganz noch weiter aufdröseln und direkt Listen welche Fehlgeschlagen sind aber ich denke das wäre hier zu viel des guten.

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

#include-once
#include <File.au3>
#include <MsgBoxConstants.au3>

_Main()

Func _Main()
Local $aFolders, $sLinkName, $sLink
Local 		$iFails 			= 0
Local Const $sFirefoxExe        = 'C:\Program Files\Mozilla Firefox\firefox.exe'
Local Const $sSourceFolder      = 'E:\Portable\Browser\Firefox\'
Local Const $sDestinationFolder = @DesktopDir & '\Firefox Profile\'

    If Not FileExists($sDestinationFolder) Then
        DirCreate($sDestinationFolder)
    EndIf

    ; Liste der Unterordner im Quellverzeichnis
    $aFolders = _FileListToArray($sSourceFolder, '*', $FLTA_FOLDERS)

    ; Schleife über alle Unterordner
    For $i = 1 To $aFolders[0]
        $sLinkName = $aFolders[$i] & '.lnk'
        $sLink     = $sDestinationFolder & $sLinkName

        ; Verknüpfung erstellen
        If FileCreateShortcut($sFirefoxExe, $sLink, $sFirefoxExe, '-P "' & $sLinkName & '"') <> 1 then $iFails += 1
    Next

	If $iFails = 0 then 
		MsgBox($MB_ICONINFORMATION, 'Fertig', 'Verknüpfungen wurden erstellt und im Zielverzeichnis abgespeichert.')
	Else
		MsgBox($MB_ICONWARNING    , 'Fertig', $iFails & ' Verknüpfungen konnten nicht erstellt und im Zielverzeichnis abgespeichert werden.')
	EndIf
EndFunc

Alles anzeigen

HansiEdi

Na da schau mal einer an, ich werkel da mindestens einen Tag lang herum und komme einfach nicht weiter und Ihr bastelt mir da etwas das fast fehlerfrei ist.

Vielen lieben dank euch beiden.

Ich hatte mir die Hilfe zu FileCreateShortcut angesehen, bin da aber irgendwie auch nicht viel weiter gekommen. Ein paar andere Beispiele haben mich wenigstens so weit gebracht wie ich gekommen bin. Ich sehe mir aber wirklich noch einmal diese Parameter dazu an und hoffe das ich doch noch durchblicke.

Zwei kleine Fehler sind jetzt noch vorhanden

Beispiel:

Ziel: "C:\Program Files\Mozilla Firefox\firefox.exe" -P "3D Zeichnungen für 3D Druck" (korrekt)
Ziel: "C:\Program Files\Mozilla Firefox\firefox.exe" -P "3D Zeichnungen für 3D Druck.lnk" (falsch)

Ausführen in: "C:\Program Files\Mozilla Firefox" (korrekt)
Ausführen in: "C:\Program Files\Mozilla Firefox\firefox.exe" (falsch)

Die Überprüfung mit der Fehlermeldung finde ich schon mal gut, das gefällt mir.

Lg Hans

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von HansiEdi

Zwei kleine Fehler sind jetzt noch vorhanden

Okay, dann hier die beiden kleinen Fixe, so sollte es passen.

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

#include-once
#include <File.au3>
#include <MsgBoxConstants.au3>

_Main()

Func _Main()
    Local $aFolders, $sLinkName, $sLink
    Local $iFails = 0

    Local Const $sFirefoxPath       = 'C:\Program Files\Mozilla Firefox'
    Local Const $sFirefoxExe        = $sFirefoxPath & '\firefox.exe'
    Local Const $sSourceFolder      = 'E:\Portable\Browser\Firefox\'
    Local Const $sDestinationFolder = @DesktopDir & '\Firefox Profile\'

    If Not FileExists($sDestinationFolder) Then
        DirCreate($sDestinationFolder)
    EndIf

    ; Liste der Unterordner im Quellverzeichnis
    $aFolders = _FileListToArray($sSourceFolder, '*', $FLTA_FOLDERS)

    ; Schleife über alle Unterordner
    For $i = 1 To $aFolders[0]
        $sLinkName = $aFolders[$i]
        $sLink     = $sDestinationFolder & $sLinkName

        ; Verknüpfung erstellen
        If Not FileCreateShortcut($sFirefoxExe, $sLink, $sFirefoxPath, '-P "' & $sLinkName & '"') Then
            $iFails += 1
        EndIf
    Next

    If $iFails = 0 Then
        MsgBox($MB_ICONINFORMATION, 'Fertig', 'Verknüpfungen wurden erstellt und im Zielverzeichnis abgespeichert.')
    Else
        MsgBox($MB_ICONWARNING    , 'Fertig', $iFails & ' Verknüpfungen konnten nicht erstellt und im Zielverzeichnis abgespeichert werden.')
    EndIf
EndFunc

Alles anzeigen

Ich habe gleich das Beispiel von Moombas genommen, damit du die Fehlermeldung mit dabei hast 🤝 .

Viele Grüße
Sven

HansiEdi

Das ist richtig super von euch beiden, danke Sven das du mir die Korrektur vorgenommen hast.

Es funktioniert einwandfrei.

Zu der Hilfe von FileCreatShortcut ist mir nur folgende Hilfe bekannt, gibt es dazu noch bessere?

Function FileCreateShortcut (autoitscript.com)

Lg Hans

Verknüpfungen erstellen

Ähnliche Themen

ISN AutoIt Studio

Fehlermeldungen unterdrücken allgemein

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)