String länger als 4095 Zeichen

was hat die max. Länge einer Codezeile mit deinem Problem zu tun?

Ich bin grad nicht auf der Höhe, daher möge man mir mein Unverständnis verzeihen. 😁

Zitat von gmmg

Jetzt nachdem ich noch das StringReplace für @LF eingefügt habe läuft das Script zuverlässig.

Heißt das gmmg dein Problem ist gelöst oder meinst du damit Text ==> Base64 läuft zuverlässig?

Ansonsten frage ich mich, wie du den AutoIt POST request abfeuerst? WinHttp.au3 (_WinHttpSimpleRequest())?
💡 Muss es wirklich AutoIt sein? Powershell per AutoIt ist auch schnell aufgerufen und fertig.

Viele Grüße
Sven

Falls ich dich richtig verstehe, dann willst du einfach den langen String in ein MultilineString umwandeln, damit du ihn dann dem POST request übergeben kannst?
Eigentlich hat das eine nix mit dem anderen zu tun (dies zeugt davon das ich nicht komplett verstehe was du brauchst und willst), doch hier mal ein Beispiel anhand du uns sagen kannst ob es das ist.

Alles Funktionen die ich rumliegen hatte, nix neues und daher ggf. auch nicht ganz so up-to-date, sollte aber funktionieren.

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

#include-once
#include <Array.au3>

_Main()

Func _Main()
    Local Const $iLineCharacters = 150
    Local Const $vImage = _BinaryToBase64('C:\Store\Media\Images\icon-appium.png')
    Local Const $aImage = _SplitStringByCountToArray($vImage, $iLineCharacters)

    _ArrayDisplay($aImage)

    ClipPut(_GenerateMultilineString($aImage))
EndFunc

Func _BinaryToBase64($sFilePath)
    Local Const $iBinaryMode = 16

    Local $hFile        = FileOpen($sFilePath, $iBinaryMode)
    Local $vFileContent = FileRead($hFile)
    FileClose($hFile)

    Local $oXml           = ObjCreate('MSXML2.DOMDocument')
    Local $oNode          = $oXml.createElement('b64')
    $oNode.dataType       = 'bin.base64'
    $oNode.nodeTypedValue = $vFileContent

    Return StringReplace($oNode.Text, @LF, '')
EndFunc

Func _SplitStringByCountToArray($sString, $iCount = 80)
    Local $iParts = Ceiling(StringLen($sString) / $iCount)
    Local $aContent[$iParts + 1], $x = 1

    For $i = 1 To $iParts Step 1
        $aContent[$i] = StringMid($sString, $x, $iCount)
        $x += $iCount
    Next

    $aContent[0] = $iParts

    Return $aContent
EndFunc

Func _GenerateMultilineString($aArray)
    Local $sResult

    For $i = 1 To $aArray[0]
        $sResult &= StringFormat("'%s' & _\n", $aArray[$i])
    Next

    Local Const $iEndCharactersToRemove = 6

    Return StringTrimRight(StringFormat('$sMultilineString = _\n%s', $sResult), $iEndCharactersToRemove)
EndFunc

Bin gespannt was du sagst 😁 . Erst siehst du den Base64 Code als Array, dann wird er dir gesplittet in die Zwischenablage kopiert. Dort kannst du ihr dir anschauen und sagen ob es das ist was du wolltest.

Viele Grüße
Sven

Hi Marcel 👋 ,

nur zur Vollständigkeit: Ich habe mir den ersten Beitrag von dir nochmal durchgelesen und denke du wolltest eigentlich nur wissen, wie du einen überlangen Text bzw. String (länger als 4096 Zeichen), in AutoIt verwenden kannst - richtig? In meinem Beispiel wird einfach ein Multiline String genutzt, mehr ist es gar nicht. Der Rest davor ist die Umwandlung von Binary in Base64.

Das Ganze hat wenig mit deinem POST Request zu tun, da du ja auch einfach ohne das Bild in base64 zu wandeln direkt beim POST Request mitgeben kannst (außer in deinem Fall gibt es da Einschränkungen?). Dann müsstest du einfach nur den Header Content-Type: multipart/form-data angeben und es sollte funktionieren.

Naja, so oder so, es klappt ja irgendwie - daher "nur zur Vollständigkeit".

Viele Grüße
Sven