Hi,
ich lese die Ordner eines Pfades aus um sie in einem Tree darzustellen. Schaue ich mir den Ordner im Explorer an, werden auch Zahlen in Strings nach den Zahlen sortiert:
Wenn ich mit _FileListToArrayRec($sPath, "*", $FLTAR_FOLDERS, $FLTAR_NORECUR, $FLTAR_SORT) einlese ist es String-sortiert:
Das gleich ist in der Konsole mit TREE der Fall:
tree_cmd.png
Wie kann ich die Sortierung, wie im Explorer erreichen?
Meines Wissens nach bleibt dir nichts übrig, als es selbst zu implementieren...
So als Idee könnte man ja mit RegEx Zahlen finden, nach Zahlen splitten, und dann das vor den zahlen sortieren, dann die Zahlen sortieren, dann das nach den Zahlen (wo natürlich wieder Zahlen vorkommen können).
Müsste man genauer drüber nachdenken...
Du kannst erstmal nach dem Format checken und dann nach einem bestimmten Eingabeprioritätsalphabet sortieren. Du switcht das Format (Index in Klammern, Platzierung, ...) das du hast und sortierst es dann.
Hier wird beschrieben, was Windows genau macht:
http://www.alliancegroup.co.uk/windows7-explorer-sort-order.htm
Das Web gibt einige Hinweise, wie das gehen könnte.
Z.B.
http://stackoverflow.com/questions/4165…rer-without-usi
https://www.google.de/?gws_rd=ssl#q=visual+basic+sort+like+windows+explorer
Es gibt bereits eine UDF (Anhang / nicht von mir), die das Array "richtig" sortieren kann. Die hatte ich mir vor langer Zeit mal abgespeichert, weil ich so eine Funktion selbst mal brauchte.
Du brauchst dann nur noch die Funktion aufrufen und das Array ist korrekt sortiert:
#include <Array.au3>
#include <File.au3>
#include "_ArrayNaturalSort.au3"
$sPath = "" ; <- anpassen
$aFileList = _FileListToArrayRec($sPath, "*", $FLTAR_FOLDERS, $FLTAR_NORECUR, $FLTAR_SORT)
_ArrayDelete($aFileList, 0)
_ArrayNaturalSort($aFileList)
_ArrayDisplay($aFileList)Vielleicht hilft dir das hier weiter: https://www.autoitscript.com/forum/topic/10…ee-in-treeview/
DllCall('user32.dll','int','SendMessage','hwnd',$hWnd,'uint',$TVM_SORTCHILDREN,'wparam',true,'lparam',$hItem)_ArraySortLikeExplorer() wird mit einem 1D-Array gefüttert und gibt ein 2D-Array zurück...
und gibt ein 2D-Array zurück...
Oops 
- da war ich einen Moment verpeilt. Auch wenn ArrayDisplay ein $a[n][1] ebenso darstellt wie ein $a[n] ist es halt doch nicht dasselbe.
Habe es im Code korrigiert.
Für exakt solche Fälle wo man mal individuell sortieren muss hab ich in meiner DynArray-UDF eine Sortierfunktion geschrieben bei der man ganz leicht die Größenvergleichsfunktion austauschen kann.
So kann man ganz schnell und einfach individuelle Sortierungen umsetzen:
#include <DynArray.au3>
Global $a_Array[] = ['(1) Bla', '(10) Blub', '(11) Ccc', '(12) Ddd', '(2) Haa', '(3) Hoo', '(4) Muh', '(5) Wuff', '(6) Brr', '(7) Klirr', '(8) Knarr', '(9) Uff', 'Hallo', 'Welt', 'AutoIt']
_ArraySortFlexible($a_Array, MyCompare)
_ArrayDisplay($a_Array)
; eigene Vergleichsfunktion um individuelle Sortierregeln umzusetzen
Func MyCompare($A, $B)
Local $pat_A = "^\((\d+)\)"
; Falls Zahlen in Klammer am Anfang:
If StringRegExp($A, $pat_A) And StringRegExp($B, $pat_A) Then
Local $dA = Number(StringRegExp($A, $pat_A, 1)[0]), $dB = Number(StringRegExp($B, $pat_A, 1)[0])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
; ganz normale Sortierung
Return $A > $B ? 1 : $A < $B ? -1 : 0
EndFunc ;==>MyCompareIch habe hier mal alle Ergebnisse in einem Array zusammengefaßt, damit man besser vergleichen kann, welche Funktion wie sortiert.
Keine macht es zu 100% so, wie der Explorer.
#include <Array.au3>
#include <_ArrayNaturalSort.au3>
#include <_ArraySortLikeExplorer.au3>
#include <DynArray.au3>
;-- TIME_STAMP 2016-06-27 22:06:02
Local $aArray[] = ['{2} Bla','{1} Bla','[2] Bla','[1] Bla','(1) Bla','(10) Blub','(11) Ccc','(12) Ddd','(2) Haa','(3) Hoo','(4) Muh','(5) Wuff','(6) Brr','(7) Klirr','(8) Knarr','(9) Uff','Hallo','Welt','AutoIt', 'Bla 10', 'Bla 9','1 Bla','10 Blub','11 Ccc','12 Ddd','2 Haa','3 Hoo','4 Muh','5 Wuff','6 Brr','7 Klirr','8 Knarr','9 Uff',' Space']
Local $aExplorer = [' Space','(1) Bla','(2) Haa','(3) Hoo','(4) Muh','(5) Wuff','(6) Brr','(7) Klirr','(8) Knarr','(9) Uff','(10) Blub','(11) Ccc','(12) Ddd','[1] Bla','[2] Bla','{1} Bla','{2} Bla','1 Bla','2 Haa','3 Hoo','4 Muh','5 Wuff','6 Brr','7 Klirr','8 Knarr','9 Uff','10 Blub','11 Ccc','12 Ddd','AutoIt','Bla 9','Bla 10','Hallo','Welt']
Local $aShowAll[UBound($aArray)+1][6], $sSpacer = '~~~~~~~~~~~~~~~~'
_ArrayShuffle($aArray)
_Add1DTo2D($aArray, $aShowAll, 0)
_ArraySort($aArray)
_Add1DTo2D($aArray, $aShowAll, 1)
_ArraySortLikeExplorer($aArray)
_Add1DTo2D($aArray, $aShowAll, 2)
_ArrayNaturalSort($aArray)
_Add1DTo2D($aArray, $aShowAll, 3)
_ArraySortFlexible($aArray, MyCompare)
_Add1DTo2D($aArray, $aShowAll, 4)
_Add1DTo2D($aExplorer, $aShowAll, 5)
_ArrayDisplay($aShowAll, 'AllSort', '', 0, Default, 'Shuffled|_ArraySort|_ArraySortLikeExplorer|_ArrayNaturalSort|_ArraySortFlexible|Explorer')
Func _Add1DTo2D(ByRef $aArray1D, ByRef $aArray2d, $iColumn)
For $i = 0 To UBound($aArray1d) -1
$aArray2d[$i][$iColumn] = $aArray1D[$i]
Next
$aArray2d[$i][$iColumn] = $sSpacer
EndFunc
; eigene Vergleichsfunktion um individuelle Sortierregeln umzusetzen
Func MyCompare($A, $B)
Local $pat_A = "^\((\d+)\)"
; Falls Zahlen in Klammer am Anfang:
If StringRegExp($A, $pat_A) And StringRegExp($B, $pat_A) Then
Local $dA = Number(StringRegExp($A, $pat_A, 1)[0]), $dB = Number(StringRegExp($B, $pat_A, 1)[0])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
; ganz normale Sortierung
Return $A > $B ? 1 : $A < $B ? -1 : 0
EndFunc ;==>MyCompareKeine macht es zu 100% so, wie der Explorer.
Das war doch lediglich ein Beispiel um zu zeigen wie man sich relativ einfach die Sortiervorschrift entsprechend anpassen kann.
Etwas erweitert könnte man die Vergleichsfunktion z.B. so implementieren:
Func MyCompare($A, $B)
Local $pat_A = "^([\(\{\[])(\d+)[\)\}\]]", $pat_B = "^\s*(\d+)"
; Falls Zahlen in Klammer am Anfang:
If StringRegExp($A, $pat_A) And StringRegExp($B, $pat_A) Then
Local $a_A = StringRegExp($A, $pat_A, 1), $a_B = StringRegExp($B, $pat_A, 1)
If $a_A[0] = $a_B[0] Then
Local $dA = Number($a_A[1]), $dB = Number($a_B[1])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
ElseIf StringRegExp($A, $pat_B) And StringRegExp($B, $pat_B) Then
Local $a_A = StringRegExp($A, $pat_B, 1), $a_B = StringRegExp($B, $pat_B, 1)
Local $dA = Number($a_A[0]), $dB = Number($a_B[0])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
; ganz normale Sortierung
Return $A > $B ? 1 : $A < $B ? -1 : 0
EndFunc ;==>MyCompareDen letzten verbleibenden Fall mit Bla 9 und Bla 10 überlasse ich demjenigen der es braucht.
Ich verstehe deinen Einwand!
Meine Aussage bezieht sich allerdings nur auf die Ergebnisse der hier vorgestellten Funktionen, ohne deren Status zu analysieren.
Bezieht man den Status mit ein, dürfte deine Funktion natürlich nicht (ohne erklärenden Kommentar) in dieser Liste aufgeführt werden.
Wie hätte ich es denn besser formulieren sollen?
Dein erweitertes Beispiel liefert übrigens dasselbe Ergebnis, wie die einfache Funktion.
Wie hätte ich es denn besser formulieren sollen?
War schon ok. Wollte bloß den Eindruck vermeiden, dass mein Vorschlag bereits eine fertige Lösung für das Problem der Explorer-ähnlichen Sortierung darstellt.
Die kommt stattdessen jetzt 
:
#include <DynArray.au3>
Global $a_Array[] = ['{2} Bla', '{1} Bla', '[2] Bla', '[1] Bla', '(1) Bla', '(10) Blub', "Test 8 Test", "Test 10 Test", "Test 9 Test", "Test 10 Test 9 Test", "Test 10 Test 10 Test", "Test 10 Test 8 Test", '(11) Ccc', '(12) Ddd', '(2) Haa', '(3) Hoo', '(4) Muh', '(5) Wuff', '(6) Brr', '(7) Klirr', '(8) Knarr', '(9) Uff', 'Hallo', 'Welt', 'AutoIt', 'Bla 10', 'Bla 9', '1 Bla', '10 Blub', '11 Ccc', '12 Ddd', '2 Haa', '3 Hoo', '4 Muh', '5 Wuff', '6 Brr', '7 Klirr', '8 Knarr', '9 Uff', ' Space']
_ArraySortFlexible($a_Array, MyCompare)
_ArrayDisplay($a_Array)
Func MyCompare(Const ByRef $A, Const ByRef $B)
Local $pat_A = "^(?m)^(?|(\()(\d+)\)|(\[)(\d+)\]|(\{)(\d+)\}|(.{0})(\d+))", $pat_B = "^(.+?)(?|(\()(\d+)\)|(\[)(\d+)\]|(\{)(\d+)\}|(.{0})(\d+))$", $pat_C = "^(.+?)(\d+)(.+)$"
If IsString($A) And IsString($B) Then
If StringRegExp($A, $pat_A) And StringRegExp($B, $pat_A) Then ; Zahlen am Anfang
Local $a_A = StringRegExp($A, $pat_A, 1), $a_B = StringRegExp($B, $pat_A, 1)
If $a_A[0] = $a_B[0] Then
Local $dA = Number($a_A[1]), $dB = Number($a_B[1])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
EndIf
If StringRegExp($A, $pat_B) And StringRegExp($B, $pat_B) Then ; Zahlen am Ende
Local $a_A = StringRegExp($A, $pat_B, 1), $a_B = StringRegExp($B, $pat_B, 1)
If $a_A[0] = $a_B[0] And $a_A[1] = $a_B[1] Then
Local $dA = Number($a_A[2]), $dB = Number($a_B[2])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
EndIf
If StringRegExp($A, $pat_C) And StringRegExp($B, $pat_C) Then ; Zahlen in der Mitte
Local $s_X = $A, $s_Y = $B
Do ; rekursiv bis zum Ende durchgehen
Local $a_A = StringRegExp($s_X, $pat_C, 1), $a_B = StringRegExp($s_Y, $pat_C, 1)
If $a_A[0] = $a_B[0] Then
Local $dA = Number($a_A[1]), $dB = Number($a_B[1])
If $dA > $dB Then
Return 1
ElseIf $dA < $dB Then
Return -1
EndIf
EndIf
Local $s_X = $a_A[2], $s_Y = $a_B[2]
If Not (StringRegExp($s_X, $pat_C) And StringRegExp($s_Y, $pat_C, 0)) Then ExitLoop
Until 0
EndIf
EndIf
; normale Sortierung
If IsString($A) Or IsString($B) Then
Return StringCompare($A, $B)
Else
Return $A > $B ? 1 : $A < $B ? -1 : 0
EndIf
EndFuncEdit: Das eben gezeigte ist die reine AutoIt-Lösung.
Um ganz sicher zu gehen, dass exakt so wie beim Explorer sortiert wird, sollte man stattdessen eher direkt dessen interne Vergleichsfunktion anzapfen:
#include <DynArray.au3>
Global $a_Array[] = ['{2} Bla', '{1} Bla', '[2] Bla', '[1] Bla', '(1) Bla', '(10) Blub', "Test 8 Test", "Test 10 Test", "Test 9 Test", "Test 10 Test 9 Test", "Test 10 Test 10 Test", "Test 10 Test 8 Test", '(11) Ccc', '(12) Ddd', '(2) Haa', '(3) Hoo', '(4) Muh', '(5) Wuff', '(6) Brr', '(7) Klirr', '(8) Knarr', '(9) Uff', 'Hallo', 'Welt', 'AutoIt', 'Bla 10', 'Bla 9', '1 Bla', '10 Blub', '11 Ccc', '12 Ddd', '2 Haa', '3 Hoo', '4 Muh', '5 Wuff', '6 Brr', '7 Klirr', '8 Knarr', '9 Uff', ' Space']
_ArraySortFlexible($a_Array, MyCompare)
_ArrayDisplay($a_Array)
Func MyCompare(Const $A, Const $B)
Local Static $h_DLL_Shlwapi = DllOpen("Shlwapi.dll")
If IsString($A) Or IsString($B) Then
Local $a_Ret = DllCall($h_DLL_Shlwapi, "int", "StrCmpLogicalW", "wstr", $A, "wstr", $B)
If @error Then Return SetError(1, @error, 0)
Return $a_Ret[0]
EndIf
; normale Sortierung
Return $A > $B ? 1 : $A < $B ? -1 : 0
EndFunc ;==>MyCompareWow!!!
Das ist ja jetzt mal echt mega-geil, was du hier abziehst!
Wirklich sehr schön finde ich, dass du das ursprüngliche 'Beispiel' nun doch perfektioniert hast und man somit immer eine echte Alternative zu dem DllCall() hat.
Bin echt begeistert... 
Hm, bei der Explorer-Lösung scheint mir die normale Sortierung aber überflüssig... die wird wohl nie ausgeführt.
__
Grrr, was ist das denn für ein oberschwuler Editor hier auf autoit.de? Der spinnt zeitweise aber total. Will ich mit Enter einen Zeilenumbruch generieren, nimmt der die halbe Zeile einfach mit in die neue Zeile!? Im erweiterten Modus geht es aber dann.
Boar, will mittlerweile in jedem Editor mit Strg+Shift+Up/Down die Zeilen vertauschen... und wundere mich gerade, dass es hier nicht geht. 
Hm, bei der Explorer-Lösung scheint mir die normale Sortierung aber überflüssig... die wird wohl nie ausgeführt.
In dem Fall hier nicht.
Aber wenn im Array z.B. direkte Zahlentypen stecken dann schon.
Füge mal noch die Werte [1.5, 1.45, 1.55] hinzu (nicht als String sondern als reine Zahlen) und schau dir die Sortierung einmal mit der Zeile und einmal ohne an.
Ja du hast Recht - die normale Sortierung wird demnach definitiv benötigt.
Hm... da stimmt aber noch etwas nicht mit der Sortierung... siehe Bild.
Nachtrag: Und jetzt wo ich die Zahlen eingebaut habe, bekomme ich bei jedem 3-5 Aufruf einen Fehler... siehe Bild (WEnd.png).
Hast du einen Code oder ein Beispielarray dazu?
Mit beiden Funktionen wird das Array bei mir korrekt sortiert.
Was ist MyCompare und was ist MyExplorer?
Habe das Script im Angang hinzugefügt...
ok kann es nachvollziehen.Liegt an einem Problem beim Quicksort mit zwei Pivotelementen.Hab die DynArray.au3 mal entsprechend angepasst.Nochmal runterladen und die alte ersetzen dann sollte es klappen.
Genau genommen ist der Grund die Durchmischung mit verschiedenen Dateitypen.
Wenn man die Floatzahlen (1.45, 1.55, 1.5) rausnimmt und nur noch Strings vorhanden sind ist das Problem behoben.
Im Grunde werden dabei zwei Vergleichsmethoden angewendet welche untereinander inkonsistent sind und somit eine Art Barriere während der Sortierung geschaffen.
Ist schon ein ziemlicher Sonderfall - wenn auch ein sehr interessanter.
Ich schau mal ob ich den so mit abfangen kann.
Edit: So ist kein Fehler in der Dynarray.au3.
Es ist wie gesagt der Sonderfall bei der Durchmischung der Datentypen.
Es reicht im Prinzip in der Vergleichsfunktion aus dem And ein Or zu machen.
Also so:
#include <DynArray.au3>
Global $a_Array[] = [" Space", "(2) Haa", "(1) Bla", "(3) Hoo", "(4) Muh", "(5) Wuff", "(6) Brr", "(7) Klirr", "(8) Knarr", "(9) Uff", "(10) Blub", "(11) Ccc", "(12) Ddd", "[9] Bla", "[10] Bla", "{9} Bla", "{10} Bla", "1 Bla", 1.45, 1.55, "2 Haa", "4 Muh", "5 Wuff", "6 Brr", "8 Knarr", "9 Uff", "11 Ccc", "12 Ddd", "Bla 9", "Bla 10", "Fss10x", 1.5, "3 Hoo", "7 Klirr", "10 Blub", "Autolt", "Fss9x", "Hallo", "Welt"]
_ArraySortFlexible($a_Array, MyCompare)
_ArrayDisplay($a_Array)
Func MyCompare(Const $A, Const $B)
Local Static $h_DLL_Shlwapi = DllOpen("Shlwapi.dll")
If IsString($A) Or IsString($B) Then
Local $a_Ret = DllCall($h_DLL_Shlwapi, "int", "StrCmpLogicalW", "wstr", $A, "wstr", $B)
If @error Then Return SetError(1, @error, 0)
Return $a_Ret[0]
EndIf
; normale Sortierung
Return $A > $B ? 1 : $A < $B ? -1 : 0
EndFunc ;==>MyCompareEdit2: Hab auch die reine AutoIt-Lösung oben entsprechend angepasst so dass dieser Sonderfall mit beachtet wird.