GDI+ Transparenz Problem bei Bildüberlappung

Sven-Seyfert

Hallo Community,

ich habe ein Problem wenn ich ein mit GDI+ geladenes Bild (*.png), auf der GUI, auf eine andere Position ziehe (drag). Wenn ich das nächste Bild (von insgesamt drei) in die unmittelbare Nähe des ersten gezogenen Bildes ziehe, habe ich einen Überlappungseffekt, der nicht transparent ist, wie ich ihn gern hätte.

Das animierte GIF sollte hoffentlich mein Problem weiter erklären (wie auf GitHub).

Warum sind die GDI+ PNG Bilder nicht transparent auf der GUI?

Ich möchte nicht unbedingt ein Buffer System zur Darstellung einsetzen oder muss ich dies?

Danke für Vorschläge, Tipps und Hilfe - ich bin dankbar!
Sven

Vorher:

[Blockierte Grafik: https://www.autoitscript.com/forum/uploads/monthly_2017_10/ImageOverlappingWithoutTransparence.gif.295382858e74cbeb6bc99b0bb6bb9646.gif]

[Solved] Finale Lösung:

Danke der Community und besonders UEZ und @argumentum (EN Forum).

Code:

Code

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
        #AutoIt3Wrapper_Icon=..\Libraries\icon.ico
        #AutoIt3Wrapper_UseUpx=n
        #AutoIt3Wrapper_UseX64=y
        #AutoIt3Wrapper_Res_Fileversion=0.5
        #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
        ; ------------------------------------------------------------------------------
        ; GDIPlusGame_MapEditor (2017-11-13)
        ; ------------------------------------------------------------------------------
        ; includes ---------------------------------------------------------------------
        #include-once
        #include <GDIPlus.au3>
        #include <GuiConstantsEx.au3>
        #include <String.au3>
        #include <WindowsConstants.au3>
        ; opt and just singleton -------------------------------------------------------
        Opt( 'MustDeclareVars', 1 )
        Local $aInst = ProcessList( 'GDIPlusGame_MapEditor.exe' )
        If $aInst[0][0] > 1 Then Exit
        ; declaration ------------------------------------------------------------------
        Local Const $sPathImg         = '.\tiles\'
        Local Const $sExtImg          = '.png'
        Local Const $iGuiWidth        = 1000
        Local Const $iGuiHeight       = 690
        Local Const $iGuiLeft         = 10
        Local Const $iGuiTop          = 10
        Local Const $iGuiTrans        = 255
        Local Const $vTransColor1     = 0xABCDEF
        Local Const $vTransColor2     = 0xFFABCDEF
        Local $aImgInformations[4][7] = [['Object', 'Width', 'Height', 'X', 'Y', 'Id', 'Name']]
        ; init -------------------------------------------------------------------------
        _GDIPlus_Startup()
        Local $aImgWidths[4][1]
        Local $iMaxImgWidth
        Func _getImageObjectsForGettingWidth( $aArray, $sImgName )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                If StringLen( $i ) == 1 Then $aArray[$i][0] = _GDIPlus_ImageLoadFromFile( $sPathImg & $sImgName & '0' & $i & '_01' & $sExtImg )
                If StringLen( $i ) <> 1 Then $aArray[$i][0] = _GDIPlus_ImageLoadFromFile( $sPathImg & $sImgName & $i & '_01' & $sExtImg )
            Next
            Return $aArray
        EndFunc
        Func _setMaxImgWidth( $aArray )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                Local $iWidthSave = _GDIPlus_ImageGetWidth( $aArray[$i][0] )
                If $iWidthSave > $iMaxImgWidth Then $iMaxImgWidth = $iWidthSave
            Next
            Return $iMaxImgWidth
        EndFunc
        $aImgWidths   = _getImageObjectsForGettingWidth( $aImgWidths, 'tree' )
        $iMaxImgWidth = _setMaxImgWidth( $aImgWidths )
        ; gui --------------------------------------------------------------------------
        Local $hMainGui = GUICreate( 'GDIPlusGame_MapEditor', $iGuiWidth + $iMaxImgWidth, $iGuiHeight, $iGuiLeft, $iGuiTop, -1, $WS_EX_LAYERED )
        GUISetBkColor( $vTransColor1, $hMainGui )
        _WinAPI_SetLayeredWindowAttributes( $hMainGui, $vTransColor1, $iGuiTrans )
        GUISetState( @SW_SHOW, $hMainGui )
        ; functions --------------------------------------------------------------------
        Func _createGraphicsBufferSystem()
            Global $hDC       = _WinAPI_GetDC( $hMainGui )
            Global $hDCBitmap = _WinAPI_CreateCompatibleBitmap( $hDC, $iGuiWidth + $iMaxImgWidth, $iGuiHeight )
            Global $hDCBuffer = _WinAPI_CreateCompatibleDC( $hDC )
            Global $hDCObject = _WinAPI_SelectObject( $hDCBuffer, $hDCBitmap )
            Global $hGraphics = _GDIPlus_GraphicsCreateFromHDC( $hDCBuffer )
        EndFunc
        Func _loadImageObjects( $aArray, $sImgName )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                If StringLen( $i ) == 1 Then $aArray[$i][0] = _GDIPlus_ImageLoadFromFile( $sPathImg & $sImgName & '0' & $i & '_01' & $sExtImg )
                If StringLen( $i ) <> 1 Then $aArray[$i][0] = _GDIPlus_ImageLoadFromFile( $sPathImg & $sImgName & $i & '_01' & $sExtImg )
            Next
            Return $aArray
        EndFunc
        Func _getImgObjectsSize( $aArray )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                Local $hImg = $aArray[$i][0]
                $aArray[$i][1] = _GDIPlus_ImageGetWidth( $hImg )
                $aArray[$i][2] = _GDIPlus_ImageGetHeight( $hImg )
            Next
            Return $aArray
        EndFunc
        Func _setImgObjectsPosition( $aArray )
            Local $iTopPosOfFirstImg = 0
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                Local $iImgHeight = $aArray[$i][2]
                $aArray[$i][3] = $iGuiWidth
                $aArray[$i][4] = $iTopPosOfFirstImg
                $iTopPosOfFirstImg += $iImgHeight
            Next
            Return $aArray
        EndFunc
        Func _setHelpLabelsForImgObjects( $aArray )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                $aArray[$i][5] = GUICtrlCreateLabel( '', $aArray[$i][3], $aArray[$i][4], $aArray[$i][1], $aArray[$i][2] )
            Next
            Return $aArray
        EndFunc
        Func _setImgNameForImgObjects( $aArray, $sImgName )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                If StringLen( $i ) == 1 Then $aArray[$i][6] = $sImgName & '0' & $i & '_01'
                If StringLen( $i ) <> 1 Then $aArray[$i][6] = $sImgName & $i & '_01'
            Next
            Return $aArray
        EndFunc
        Func _setGraphicsMode()
            _GDIPlus_GraphicsSetSmoothingMode( $hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY )
            _GDIPlus_GraphicsSetPixelOffsetMode( $hGraphics, $GDIP_PIXELOFFSETMODE_HIGHQUALITY )
            Global $hBrush = _GDIPlus_BrushCreateSolid( $vTransColor2 )
        EndFunc
        Func _imgControlMoveLoop( $aImgs )
            ; 0 to 6 => 'Object', 'Width', 'Height', 'X', 'Y', 'Id', 'Name'
            Do
                _callGdipFillRectangle()
                _getMouseInfos( $hMainGui )
                If $iMouseLeftDown And $cHoveredCtrl Then
                    Local $iCtrl = _findImgCtrl( $cHoveredCtrl, $aImgs )
                    Local $iDX   = Abs( MouseGetPos( 0 ) - $aImgs[$iCtrl][3] )
                    Local $iDY   = Abs( MouseGetPos( 1 ) - $aImgs[$iCtrl][4] )
                    Do
                        _callGdipFillRectangle()
                        _getMouseInfos( $hMainGui )
                        $aImgs[$iCtrl][3] = MouseGetPos( 0 ) - $iDX
                        $aImgs[$iCtrl][4] = MouseGetPos( 1 ) - $iDY
                        _drawImages( $aImgs )
                        _performBitBlockTranfer()
                    Until Not $iMouseLeftDown
                    _writeImgInfosToConsole( $aImgs )
                    ControlMove( $hMainGui, '', $aImgs[$iCtrl][5], $aImgs[$iCtrl][3], $aImgs[$iCtrl][4] )
                Else
                    _drawImages( $aImgs )
                EndIf
                _performBitBlockTranfer()
            Until Not Sleep( 10 )
        EndFunc
        Func _callGdipFillRectangle()
            DllCall( $__g_hGDIPDll, 'int', 'GdipFillRectangle', 'handle', $hGraphics, 'handle', $hBrush, 'float', 0, 'float', 0, 'float', $iGuiWidth + $iMaxImgWidth, 'float', $iGuiHeight )
        EndFunc
        Func _getMouseInfos( $hWin )
            Global $aMouseInfos    = GUIGetCursorInfo( $hWin )
            Global $iMouseLeftDown = $aMouseInfos[2]
            Global $cHoveredCtrl   = $aMouseInfos[4]
        EndFunc
        Func _findImgCtrl( $iCtrl, $aArray )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                Local $iHelpLabelCtrlForImage = $aArray[$i][5]
                If $iHelpLabelCtrlForImage    = $iCtrl Then Return $i
            Next
        EndFunc
        Func _drawImages( $aArray )
            For $i = 1 To UBound( $aArray ) - 1 Step 1
                _GDIPlus_GraphicsDrawImageRect( $hGraphics, $aArray[$i][0], $aArray[$i][3], $aArray[$i][4], $aArray[$i][1], $aArray[$i][2] )
            Next
        EndFunc
        Func _performBitBlockTranfer()
            _WinAPI_BitBlt( $hDC, 0, 0, $iGuiWidth + $iMaxImgWidth, $iGuiHeight, $hDCBuffer, 0, 0, $SRCCOPY )
        EndFunc
        Func _writeImgInfosToConsole( $aArray )
            ConsoleWrite( _StringRepeat( '-', 81 ) & @CRLF )
            For $i = 0 To UBound( $aArray ) - 1 Step 1
                ConsoleWrite( $aArray[$i][0] & ', ' & $aArray[$i][1] & ', ' & $aArray[$i][2] & ', ' & _
                              $aArray[$i][3] & ', ' & $aArray[$i][4] & ', ' & $aArray[$i][5] & ', ' & _
                              $aArray[$i][6] & @CRLF )
            Next
        EndFunc
        Func _disposeAndExit()
            For $i = 1 To UBound( $aImgInformations ) - 1
                _GDIPlus_ImageDispose( $aImgInformations[$i][0] )
            Next
            _GDIPlus_BrushDispose( $hBrush )
            _GDIPlus_GraphicsDispose( $hGraphics )
            _WinAPI_SelectObject( $hDCBuffer, $hDCObject )
            _WinAPI_DeleteDC( $hDCBuffer )
            _WinAPI_DeleteObject( $hDCBitmap )
            _WinAPI_ReleaseDC( $hMainGui, $hDC )
            GUIDelete( $hMainGui )
            _GDIPlus_Shutdown()
            Exit
        EndFunc
        ; processing -------------------------------------------------------------------
        AutoItSetOption( 'GUIOnEventMode', 1 )
        GUISetOnEvent( $GUI_EVENT_CLOSE, '_disposeAndExit' )
        _createGraphicsBufferSystem()
        Local $aImgInfos = _loadImageObjects( $aImgInformations, 'tree' )
              $aImgInfos = _getImgObjectsSize( $aImgInfos )
              $aImgInfos = _setImgObjectsPosition( $aImgInfos )
              $aImgInfos = _setHelpLabelsForImgObjects( $aImgInfos )
              $aImgInfos = _setImgNameForImgObjects( $aImgInfos, 'tree' )
        _setGraphicsMode()
        _imgControlMoveLoop( $aImgInfos )
        AutoItSetOption( 'GUIOnEventMode', 0 )

Alles anzeigen

Nachher:

[Blockierte Grafik: https://www.autoitscript.com/forum/uploads/monthly_2017_11/ImageOverlappingTransparenceSolution.gif.47c5fcfe6349de8878c691d0208c7c2b.gif]

Zeitriss

Hi,

Aus der AutoIt-Hilfe:

Zitat von https://www.autoitscript.com/autoit3/docs/functions/GUICtrlCreatePic.htm

To have a transparent picture create the GUI with the WS_EX_LAYERED extended style. The left-top pixel will be used as the transparency color. If several pictures are created the last picture defines the transparent color. See example 2.

Zitat von UserIsGrateful

Ich möchte nicht unbedingt ein Buffer System zur Darstellung einsetzen oder muss ich dies?

Was spricht dagegen? Ich denke GDIPlus + Buffer sind hier eine gute Lösung.

Dein Script enthält übrigens viele Stellen die mit Arrays viel einfacher und übersichtlicher laufen würden.

Sieh dir hierzu mal das Tutorial von Bugfix an.

mfg

Zeitriss

Sven-Seyfert

Hallo Zeitriss,

vielen Dank für deine Hinweise. Leider schade, dass du offensichtlich es nicht versucht/getestet hast. Wenn ich die GUI mit dem Style erstelle, habe ich noch immer das gleiche Verhalten (keine Besserung). Habe den Code und die Images extra zu Verfügung gestellt, damit man direkt damit probieren kann. Aber dennoch Danke.

Was das Buffer System angeht, wollte ich dies nicht extra für den kleinen MapEditor, den ich da baue, einführen. Wenn es aber nicht anders geht, muss ich wohl. Zu deiner Anmerkung mit den Stellen, die besser Arrays sein könnten danke ich dir. Ich habe das Skript noch nicht refactored, aber werde es dann dabei berücksichtigen.

Leider wiedersprechen Arrays ein Stück weit verschiedener Clean Code Empfehlungen, welche ich umzusetzen bemüht bin.

Danke für weitere Vorschläge, Tipps und Hilfe - ich bin dankbar!

Sven

**AspirinJunkie**

Zitat von UserIsGrateful

Leider wiedersprechen Arrays ein Stück weit verschiedener Clean Code Empfehlungen, welche ich umzusetzen bemüht bin.

Darf man fragen was das für Empfehlungen sind und wo man diese nachlesen kann?

**alpines**

Zitat von AspirinJunkie

Darf man fragen was das für Empfehlungen sind und wo man diese nachlesen kann?

Ich glaube er hat sich einfach nur unglücklich ausgedrückt. Nur weil man an einigen Stellen Arrays verwenden kann um paar Zeilen zu sparen, sollte man ab und zu darauf verzichten um die Lesbarkeit des Codes zu gewährleisten oder die dahinterliegende Semantik schneller nachvollziehen zu können.

@UserIsGrateful du solltest noch eine Abfrage einbauen, ob der Mausklick im Fenster liegt oder nicht. Wenn du außerhalb des Fensters klickst, crasht dein Script.

Sven-Seyfert

Zitat von AspirinJunkie

Darf man fragen was das für Empfehlungen sind und wo man diese nachlesen kann?

Natürlich darf man fragen: Bspw. in Clean Code by Robert C. Martin, näher im Zusammenhang mit readability und structured handover in a team. Nicht falsch verstehen, geht nicht im speziellen um Arrays. Für Skriptsprachen sind viele Empfehlungen auch gar nicht vollends umsetzbar. Ich möchte aber keine Grundsatzdiskussion führen müssen oder diese anleiern oder so.

Mir ging es in erster Linie nur um die Transparenz der PNG Bilder auf der GUI, welche nicht wirklich transparent sind - warum nicht?

Danke für weitere Vorschläge, Tipps und Hilfe.

Sven

Sven-Seyfert

Zitat von alpines

Nur weil man an einigen Stellen Arrays verwenden kann um paar Zeilen zu sparen, sollte man ab und zu darauf verzichten um die Lesbarkeit des Codes zu gewährleisten oder die dahinterliegende Semantik schneller nachvollziehen zu können.

@UserIsGrateful du solltest noch eine Abfrage einbauen, ob der Mausklick im Fenster liegt oder nicht. Wenn du außerhalb des Fensters klickst, crasht dein Script.

Hallo Alpines,

ja ganz genau, dies ist einer der Punkte um den es mir beim Refaktorisieren, Richtung Clean Code bspw. geht. Danke für die Erläuterung in anderer Ausdrucksweise .

Was den Fenster-Crash angeht, habe ich dies bereits gefixed, ist mir auch aufgefallen - merci!

Sven-Seyfert

Hallo nochmal Zeitriss,

entschuldige, ich habe dir Unrecht getan. Generell müsste es mit WS_EX_LAYERED funktionieren, ja. Habe diverse andere Skripte mal versucht und da geht es mit der GUI Transparenz. Nur eben bei diesem Skript irgendwie gerade nicht. Wenn ich nach GUISetState() ein Sleep( 5000 ) bspw. einbaue, sieht man, dass es mit der Transparenz funktioniert.

Nach der Zeit wird diese Eigenschaft durch irgendeinen Aspekt wieder überschrieben und ich habe wieder ein GUI Hintergrund. Na mal sehen, dass bekomme ich schon raus.

Melde mich sicherlich nochmals hier, um möglichen Interessenten etwas für die Nachwelt zu hinterlassen .

Sven-Seyfert

Okay, gelöst.

Danke allen Helfenden. Der transparente GUI Hintergrund ist nun vorhanden. Das die PNGs sich noch überlappen löse ich dann mit einem GDI+ Buffer System.

Problem war:

_WinAPI_SetLayeredWindowAttributes( $oMain, $vGuiBkColor, 255 )
muss nach

_GDIPlus_BitmapCreateHBITMAPFromBitmap( $hImage )

aufgerufen werden, damit der GUI Hintergrund transparent wird. Denn die GDI+ Funktion setzt erneut den Background der GUI.

Im Post #1 füge ich den korrekten Code nochmals ein, damit bei Interesse man dies nachvollziehen kann. Danach schließe ich den Thread.

Danke,
Sven

**Mars**

Falls du nicht in die SB schaust: Großes Lob an Dich. Das hier ist ein Vorbildlicher H&U Thread in welchem das Problem sauber beschrieben, mit Beispielskript und Bildchen versehen und anschließend eine Lösung für jeden zugänglich gemacht wurde. So sollte ein guter H&U Thread aussehen

lg

Mars & Musashi

**UEZ**

Hier ein Lösungsansatz:

AutoIt

;coded by UEZ

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()
Global $hGUI, $bExit
Global Const $iW = @DesktopWidth * 0.95, $iH = @DesktopHeight * 0.90, $iWh = $iW / 2, $iHh = $iH / 2, $sTitle = "GDI+ Test"

AutoItSetOption("GUIOnEventMode", 1)

GDIPlus_Test()

AutoItSetOption("GUIOnEventMode", 0)
_GDIPlus_Shutdown()


Func GDIPlus_Test()
    $bExit = False
    $hGUI = GUICreate($sTitle, $iW, $iH)
    GUISetState(@SW_SHOW, $hGUI)

    Local Const $hDC = _WinAPI_GetDC($hGUI)
    Local Const $hHBitmap = _WinAPI_CreateCompatibleBitmap($hDC, $iW, $iH)
    Local Const $hDC_backbuffer = _WinAPI_CreateCompatibleDC($hDC)
    Local Const $DC_obj = _WinAPI_SelectObject($hDC_backbuffer, $hHBitmap)
    Local Const $hCanvas = _GDIPlus_GraphicsCreateFromHDC($hDC_backbuffer)
    _GDIPlus_GraphicsSetSmoothingMode($hCanvas, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetPixelOffsetMode($hCanvas, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)

    Local $aSprites[3][6], $i, $iDX, $iDY, $iControl, $aInfo, $aCtrlPos
    For $i = 0 To UBound($aSprites) - 1
        $aSprites[$i][0] = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\tree0" & $i + 1 & "_01.png")
        $aSprites[$i][1] = _GDIPlus_ImageGetWidth($aSprites[$i][0])
        $aSprites[$i][2] = _GDIPlus_ImageGetHeight($aSprites[$i][0])
        $aSprites[$i][3] = Random(0, $iW - $aSprites[$i][1], 1)
        $aSprites[$i][4] = Random(0, $iH - $aSprites[$i][2], 1)
        $aSprites[$i][5] = GUICtrlCreateLabel("", $aSprites[$i][3], $aSprites[$i][4], $aSprites[$i][1], $aSprites[$i][2])
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        _GDIPlus_GraphicsDrawImageRect($hCanvas, $aSprites[$i][0], $aSprites[$i][3], $aSprites[$i][4], $aSprites[$i][1], $aSprites[$i][2])
    Next

    Local Const $hBrush_Clr = _GDIPlus_BrushCreateSolid(0xFFA0A0A0), _
                $hBrush_FPS = _GDIPlus_BrushCreateSolid(0xF0101010)

    $iFPS = 0
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit_About")

    Do
        DllCall($__g_hGDIPDll, "int", "GdipFillRectangle", "handle", $hCanvas, "handle", $hBrush_Clr, "float", 0, "float", 0, "float", $iW, "float", $iH)
        $aInfo = GUIGetCursorInfo($hGUI)
        If $aInfo[2] And $aInfo[4] Then
            $iControl = FindCtrl($aInfo[4], $aSprites)
            If Not @error Then
                $iDX = Abs(MouseGetPos(0) - $aSprites[$iControl][3])
                $iDY = Abs(MouseGetPos(1) - $aSprites[$iControl][4])
                Do
                    DllCall($__g_hGDIPDll, "int", "GdipFillRectangle", "handle", $hCanvas, "handle", $hBrush_Clr, "float", 0, "float", 0, "float", $iW, "float", $iH)
                    $aInfo = GUIGetCursorInfo($hGUI)
                    $aCtrlPos = ControlGetPos($hGUI, "", $aSprites[$iControl][5])
                    $aSprites[$iControl][3] = MouseGetPos(0) - $iDX
                    $aSprites[$iControl][4] = MouseGetPos(1) - $iDY
                    For $i = 0 To UBound($aSprites) - 1
                        _GDIPlus_GraphicsDrawImageRect($hCanvas, $aSprites[$i][0], $aSprites[$i][3], $aSprites[$i][4], $aSprites[$i][1], $aSprites[$i][2])
                    Next
                    _WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hDC_backbuffer, 0, 0, $SRCCOPY)
                Until Not $aInfo[2]
                ControlMove($hGUI, "", $aSprites[$iControl][5], $aSprites[$iControl][3], $aSprites[$iControl][4])
            EndIf
        Else
            For $i = 0 To UBound($aSprites) - 1
                _GDIPlus_GraphicsDrawImageRect($hCanvas, $aSprites[$i][0], $aSprites[$i][3], $aSprites[$i][4], $aSprites[$i][1], $aSprites[$i][2])
            Next
        EndIf

        _WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hDC_backbuffer, 0, 0, $SRCCOPY)
        If $bExit Then ExitLoop
    Until Not Sleep(10)

    For $i = 0 To UBound($aSprites) - 1
        _GDIPlus_ImageDispose($aSprites[$i][0])
    Next
    _GDIPlus_BrushDispose($hBrush_Clr)
    _GDIPlus_BrushDispose($hBrush_FPS)
    _GDIPlus_GraphicsDispose($hCanvas)
    _WinAPI_SelectObject($hDC_backbuffer, $DC_obj)
    _WinAPI_DeleteDC($hDC_backbuffer)
    _WinAPI_DeleteObject($hHBitmap)
    _WinAPI_ReleaseDC($hGUI, $hDC)
    GUIDelete($hGUI)
EndFunc   ;==>GDIPlus_Test

Func FindCtrl($iCtrl, $aArray)
    Local $i
    For $i = 0 To UBound($aArray) - 1
        If $aArray[$i][5] = $iCtrl Then Return $i
    Next
    Return SetError(0, 0, -1)
EndFunc

Func _Exit_About()
    $bExit = True
EndFunc   ;==>_Exit_About

Alles anzeigen

Sven-Seyfert

Zitat von Mars

Falls du nicht in die SB schaust: Großes Lob an Dich. Das hier ist ein Vorbildlicher H&U Thread in welchem das Problem sauber beschrieben, mit Beispielskript und Bildchen versehen und anschließend eine Lösung für jeden zugänglich gemacht wurde. So sollte ein guter H&U Thread aussehen

lg

Mars & Musashi

Hallo Mars, hallo Musashi,

habe nun extra ins SB Archiv geschaut - Dankeschön! Solch ein Lob freut mich natürlich.
Aus meiner Sicht gab es auch keinen einfacheren/deutlicheren Weg Mißverständnisse zu minimieren.

Nun zu dir UEZ
Ebenfalls vielen Dank! Super Lösungsvorschlag!
Das du dich im EN Forum gewundert hast (... and I'm wondering why the solution #2 works properly for him!?!?.), warum dies für mich bereits reicht, bitte ich zu entschuldigen.

Hatte im Post #9 (DE) geschrieben:

Danke allen Helfenden. Der transparente GUI Hintergrund ist nun vorhanden. Das die PNGs sich noch überlappen löse ich dann mit einem GDI+ Buffer System.

Jedoch hilft mir dein Ansatz/Lösungsvorschlag viel mehr .

Bis zur nächsten Frage dann, klasse Community!

Sven