Mahlzeit,
Grrr - es ist nicht mein Tag. Das kommt davon wenn man ein Jahr keine Zeile Code geschrieben hatt:
In einem beliebigen String, die beliebig oft vorkommenden Umlaute gegen etwas anderes z.B. ä=1, Ä=2 usw. ersetzen.
Das folgende ist nat. falsch.
$ohne = StringRegExpReplace ("ä_ber_ü_keiner", "[äÄüÖß]", "12345") --> Falsch!
Ich bekomme es leider auf die Eile auch nicht richtig.
Danke für die Hilfe.
Peter
Ps.: Und Danke, dass Ihr mir den Spott erspart 
Also ich vermute, dir schwebt eine Aktion: "Alles auf einmal Ersetzen" vor. Das geht jedoch nicht, bzw. ist es nicht unbedingt sinnvoll Konstrukte zu erstellen, die das hinbiegen. Das Ersetzen in einer Schleife ist hierfür sicher noch die schnellste Variante, ein Wert nach dem anderen. Und dann kannst du auch auf StringReplace zurückgreifen und benötigst kein RegEx.
Oder du nimmst _StringRegExpReplace_Callback von Taz77 , das ist sauschnell:
$s = "ä_ber_ü_keiner"
_StringRegExpReplace_Callback($s, '([äöüÄÖÜß])', '_MyCallbackReplace("$1")')
ConsoleWrite('Ergebnis' & @CRLF & $s & @CRLF)
Func _MyCallbackReplace($_sMatch)
Local Static $sReplace = 'äöüÄÖÜß' ; durchsuchen mit StringInStr -- Pos ist Index für Replace Array
Local Static $aReplace[] = ['bleibt-leer', 1, 2, 3, 4, 5, 6, 7] ; Ersetzungen
Local $iPos = StringInStr($sReplace, $_sMatch)
If $iPos = 0 Then ; kann eigentlich nicht passieren
Return $_sMatch
Else
Return $aReplace[$iPos]
EndIf
EndFunc
; #FUNCTION# ====================================================================================================================
; Name ..........: _StringRegExpReplace_Callback
; Description ...: Replaces ByRef all matches in a string by manipulation of the matches in a callback function
; Parameters ....: $sString String to manipulate
; ...............: $sPattern RegExp pattern for the match
; ...............: $sCallback Callback function as string, i.e. "MyCallback('$1')" -- '$1' represents the match
; .....optional..: $sBefore String to insert before the manipulated match
; .....optional..: $sAfter String to insert after the manipulated match
; Return values .: Success 1
; ...............: Failure 0 set error = 1
; Author ........: Taz77
; ===============================================================================================================================
Func _StringRegExpReplace_Callback(ByRef $sString, $sPattern, $sCallback, $sBefore = '', $sAfter = '')
$sString = Execute("'" & StringRegExpReplace(StringReplace($sString, "'", Chr(26), 0, 2), $sPattern, $sBefore & "'&" & $sCallback & "&'" & $sAfter) & "'")
If @error Then
ConsoleWrite('_StringRegExpReplace_Callback error! Pattern: "' & $sPattern & '", Callback: "' & $sCallback & '"' & @LF)
Return SetError(1,0,0)
EndIf
$sString = StringReplace($sString, Chr(26), "'", 0, 2)
Return 1
EndFunc ;==>_StringRegExpReplace_CallbackOder du nimmst _StringRegExpReplace_Callback von Taz77 , das ist sauschnell:
Schöne Funktion 
Peter S. Taler : Hier eine eher rustikale Variante 
; Ersetzt werden : Ä Ö Ü ä ö ü ß mit 1 2 3 4 5 6 7
Global $aReplaceChars[8][2] = [[7],['Ä','1'],['Ö','2'],['Ü','3'],['ä','4'],['ö','5'],['ü','6'],['ß','7']]
Global $sString = 'Satz mit Ä Ö Ü ä ö ü ß zum Ersetzen von Ä Ö Ü ä ö ü ß '
For $i = 1 To $aReplaceChars[0][0]
$sString = StringReplace($sString, $aReplaceChars[$i][0], $aReplaceChars[$i][1], 0, 1)
Next
ConsoleWrite('@@ Neuer String = ' & $sString & @CRLF)Gruß Musashi
Ich kenne mittlerweile auch eine extrem rustikale Variante Marke Eigenbau (Grins oder Schäm - >nicht ganz sicher)
$klammeraffe = _HexToString ("1B5200401B5202") ; so hier wird es nun wirklich von hinten durch die Brust. Da es den
; Klammeraffen im Deutschen Zeichensatz nicht gibt: USA Zeichensatz
; ein 1B 52 00 Klammeraffe 40 deutschen Zeichensatz ein 1B 52 02
$rr = StringRegExpReplace ($rr, "[ä]", "{")
$rr = StringRegExpReplace ($rr, "[Ä]", "[")
$rr = StringRegExpReplace ($rr, "[ö]", "|")
$rr = StringRegExpReplace ($rr, "[Ö]", "\")
$rr = StringRegExpReplace ($rr, "[ü]", "}")
$rr = StringRegExpReplace ($rr, "[Ü]", "]")
$rr = StringRegExpReplace ($rr, "[ß]", "á")
$rr = StringRegExpReplace ($rr, "[@]", $klammeraffe)
Danke an alle... Die Lösung von Bugfix schaue ich mir an - ist schlank so wollte ich es eigentlich - aber Bugfixes erster Post hat mich dann doch verunsichert....
Gruß
Peter
Closed.....
Alles anzeigen$rr = StringRegExpReplace ($rr, "[ä]", "{")
$rr = StringRegExpReplace ($rr, "[Ä]", "[")
$rr = StringRegExpReplace ($rr, "[ö]", "|")
$rr = StringRegExpReplace ($rr, "[Ö]", "\")
$rr = StringRegExpReplace ($rr, "[ü]", "}")
$rr = StringRegExpReplace ($rr, "[Ü]", "]")
$rr = StringRegExpReplace ($rr, "[ß]", "á")
$rr = StringRegExpReplace ($rr, "[@]", $klammeraffe)
Ne ne ne ne ne, das wollen wir SO nicht stehen lassen!
Erstelle ein 2D-Array in dem du die Kombinationen abspeicherst und laufe sie mit einer For-Schleife durch, aber nicht so!
aber Bugfixes erster Post hat mich dann doch verunsichert....
Das war gar nicht meine Absicht. Aber keine der Lösungen kann alles auf einmal ersetzen. Die Callbackfunktion ist am Elegantesten, weil der String für die Suche nur einmal durchgegangen wird, von Match zu Match und dann entsprechend die Treffer ersetzt werden. Wenn du große Texte hast ist der Speed spürbar.
Wieso? geht fix mit Copy und Paste und tut was es soll ? Und an der Stelle hat das Programm viel Zeit....
Aber ich gebe zu - nicht elegant, nicht schön - also schämmmmmm - sorry - Ich schreibs aber nicht mehr um. Und wenn dann nur auf BugFix....
Peter
Erstelle ein 2D-Array in dem du die Kombinationen abspeicherst und laufe sie mit einer For-Schleife durch, aber nicht so!
Äh, inwiefern unterscheidet sich das von meiner Variante in Beitrag #5 ? 
Gruß Musashi
Mein rustikales Copy & Paste hat Ihn so aufgebracht --> Doppelpost 
Äh, inwiefern unterscheidet sich das von meiner Variante in Beitrag #5 ?
Den habe ich nicht gelesen, der Browser scrollt automatisch zum letzten Beitrag und da wollte ich ihm direkt auf die Finger hauen.
Ist ja noch schlimmer, dass er sowas postet obwohl du schon was vernünftiges geliefert hast.
Oder du nimmst _StringRegExpReplace_Callback von Taz77 , das ist sauschnell:
Hihi... wohl eher "schneckenlahm"... denn die Version von Musashi ist ca. 4x schneller! 
Hihi... wohl eher "schneckenlahm"... denn die Version von Musashi ist ca. 4x schneller!
Bei 2 möglichen Treffern brauchst du gar nicht erst vergleichen, die gemessene Zeit reflektiert dann eher deine Raumtemperatur oder die Lautstärke der vorbeifahrenden Straßenbahn als die tatsächlich benötigte Zeit. Wir hatten mal in einem Thread zu Ersetzungen, diese Funktion als die um mindestens Faktor 10 schnellere festgestellt. Getestete Strings von mehreren Tausend Zeichen. Da kannst du die Arrayvariante dahinsiechen sehen.
Schlage zur Kennzeichnung von langsammen Code ein neues Smily vor
https://www.google.de/search?client=…KHSJtAkAQhyYIIg
Da nicht alle die Shoutbox mitlesen, bzw. als Gäste keinen Zugriff darauf haben, hier ein kleiner Nachtrag :
BugFix hat in der Shoutbox folgenden Thread verlinkt :
StringReplace mit RegExp-Pattern und Manipulation jedes Matches per Iteration
Erwartungsgemäß ist die Funktion von Taz77 (Beitrag #4), speziell bei großen Texten, erheblich schneller.
EDIT : Bezgl. der Aussage zur Geschwindigkeit gibt es neue Erkenntnisse ! Interessierte User sollten sich daher die Beiträge #21 und #22 ansehen !!
Ich habe meinen trivialen Codeschnipsel (Beitrag #5) auch nicht gepostet, um gegen die o.a. Funktion anzutreten !
Für weniger versierte User, die eine einfache und für sie nachvollziehbare Lösung suchen, mag sie trotzdem hilfreich sein.
Gruß Musashi
Bei 2 möglichen Treffern brauchst du gar nicht erst vergleichen, die gemessene Zeit reflektiert dann eher deine Raumtemperatur oder die Lautstärke der vorbeifahrenden Straßenbahn als die tatsächlich benötigte Zeit.
Hehe, sehr treffend formuliert!
Zuerst einmal: Hut ab für die Funktion von @Taz27 - hat er super gemacht! - In Zeile 9 (Post #4 von BugFix) fehlt meiner Meinung nach aber bei StringInStr() ein $STR_CASESENSE.
Ich bin jetzt mal hingegangen und habe einen kleinen Test geschrieben, der alle meine Textdateien zu einer Datei verknüpft und in dieser dann die Umlaute ersetzt.
So sieht das Ergebnis bei mir aus:
Anzahl der geladenen Textdateien = 186
Länge der zusammengefügten Textdatei = 1650849 Bytes
_StringRegExpReplace_Simple Substitutions = 2959 Time: 178.625131 ms
_StringRegExpReplace_Callback Substitutions = 2959 Time: 315.959992 msUnd nun?
;-- TIME_STAMP 2017-11-04 21:13:50 v 0.1
#Region ;************ Includes ************
#include <File.au3>
#EndRegion ;************ Includes ************
Global $g_iCount = 0, $g_bSaveDiff = False ; True = $sReplace1 und $sReplace2 speichern, wenn unterschiedlich
_Example()
Func _Example()
Local $hFile, $iLen, $sString = '', $sSpacer = '************************************************************************', _
$aFileList = _FileListToArray('f:\Eigene Dateien\TxT\', '*.txt', $FLTA_FILES, False)
If @error Then Exit @error
For $i = 1 To $aFileList[0] Step 1
$sString &= StringFormat('%s\r%s\r%s\r\r', $sSpacer, 'f:\Eigene Dateien\TxT\' & $aFileList[$i], $sSpacer)
$hFile = FileOpen('f:\Eigene Dateien\TxT\' & $aFileList[$i], $FO_ANSI)
$sString &= FileRead($hFile) & @CRLF & @CRLF
$iLen += @extended
FileClose($hFile)
Next
Local $sReplace1 = $sString, $sReplace2 = $sString
Local $hTimer1 = TimerInit()
_StringRegExpReplace_Simple($sReplace1)
Local $iCount = @extended
Local $fDiff1 = TimerDiff($hTimer1)
Local $hTimer2 = TimerInit()
_StringRegExpReplace_Callback($sReplace2, '([äöüÄÖÜß])', '_MyCallbackReplace("$1")')
Local $fDiff2 = TimerDiff($hTimer2)
ConsoleWrite('Anzahl der geladenen Textdateien = ' & $aFileList[0] & @CRLF)
ConsoleWrite(StringFormat('Länge der zusammengefügten Textdatei = %i Bytes\r\r', $iLen))
ConsoleWrite(StringFormat('_StringRegExpReplace_Simple Substitutions = %5i Time: %f ms\r', $iCount, $fDiff1))
ConsoleWrite(StringFormat('_StringRegExpReplace_Callback Substitutions = %5i Time: %f ms\r', $g_iCount, $fDiff2))
;~ ConsoleWrite('$sReplace1 = ' & $sReplace1 & @CRLF)
;~ ConsoleWrite('$sReplace2 = ' & $sReplace2 & @CRLF & @CRLF)
Local $bSave = False
If $sReplace1 <> $sReplace2 Then
ConsoleWrite('! Ops... Zeichen stimmen nicht mehr überein!' & @CRLF)
$bSave = True
ElseIf $iCount <> $g_iCount Then
ConsoleWrite('! Ops... Länge stimmt nicht mehr überein!' & @CRLF)
$bSave = True
EndIf
If $g_bSaveDiff And $bSave Then
$hFile = FileOpen('m:\Replace1.txt', $FO_OVERWRITE + $FO_ANSI)
FileWrite($hFile, $sReplace1)
FileClose($hFile)
$hFile = FileOpen('m:\Replace2.txt', $FO_OVERWRITE + $FO_ANSI)
FileWrite($hFile, $sReplace2)
FileClose($hFile)
EndIf
EndFunc ;==>_Example
Func _StringRegExpReplace_Simple(ByRef $sString)
Local $iCount = 0
Local $aReplace = [['Ä', 'Ae'], ['Ö', 'Oe'], ['Ü', 'Ue'], ['ä', 'ae'], ['ö', 'oe'], ['ü', 'ue'], ['ß', 'ss']]
For $i = 0 To UBound($aReplace) - 1 Step 1
$sString = StringRegExpReplace($sString, $aReplace[$i][0], $aReplace[$i][1])
$iCount += @extended
Next
$sString = StringReplace($sString, Chr(26), "'", 0, 2)
Return SetExtended($iCount)
EndFunc ;==>_StringRegExpReplace_Simple
Func _MyCallbackReplace($_sMatch)
Local Static $sReplace = 'äöüÄÖÜß' ; durchsuchen mit StringInStr -- Pos ist Index für Replace Array
Local Static $aReplace = ['bleibt-leer', 'ae', 'oe', 'ue', 'Ae', 'Oe', 'Ue', 'ss'] ; Ersetzungen
Local $iPos = StringInStr($sReplace, $_sMatch, $STR_CASESENSE) ; Hier fehlte das $STR_CASESENSE
If $iPos = 0 Then Return $_sMatch ; kann eigentlich nicht passieren
$g_iCount += 1
Return $aReplace[$iPos]
EndFunc ;==>_MyCallbackReplace
; #FUNCTION# ====================================================================================================================
; Name ..........: _StringRegExpReplace_Callback
; Description ...: Replaces ByRef all matches in a string by manipulation of the matches in a callback function
; Parameters ....: $sString String to manipulate
; ...............: $sPattern RegExp pattern for the match
; ...............: $sCallback Callback function as string, i.e. "MyCallback('$1')" -- '$1' represents the match
; .....optional..: $sBefore String to insert before the manipulated match
; .....optional..: $sAfter String to insert after the manipulated match
; Return values .: Success 1
; ...............: Failure 0 set error = 1
; Author ........: Taz77
; ===============================================================================================================================
Func _StringRegExpReplace_Callback(ByRef $sString, $sPattern, $sCallback, $sBefore = '', $sAfter = '')
$sString = Execute("'" & StringRegExpReplace(StringReplace($sString, "'", Chr(26), 0, 2), $sPattern, $sBefore & "'&" & $sCallback & "&'" & $sAfter) & "'")
If @error Then
ConsoleWrite('_StringRegExpReplace_Callback error! Pattern: "' & $sPattern & '", Callback: "' & $sCallback & '"' & @LF)
Return SetError(1, 0, 0)
EndIf
$sString = StringReplace($sString, Chr(26), "'", 0, 2)
Return 1
EndFunc ;==>_StringRegExpReplace_CallbackUnd nun?
Interessante Frage
Ich habe das Skript von Bitnugger einfach mal durchlaufen lassen.
Einzige Änderung :
Statt $sString aus diversen Textdateien zusammenzubauen, habe ich einen Basisstring 200.000 mal 'aufaddiert'. Das wäre als Buch zwar ausgesprochen reizlos, sollte dem Replace aber eigentlich egal sein.
Konsolenausgabe :
Basisstring = 'Satz mit Ä Ö Ü ä ö ü ß zum Ersetzen von Ä Ö Ü ä ö ü ß '
Anzahl Wiederholungen = 200.000 mal
Länge des generierten $sString = 10.800.000 Bytes
_StringRegExpReplace_Simple Substitutions = 2800000 Time: 2435.909239 ms
_StringRegExpReplace_Callback Substitutions = 2800000 Time: 31493.990628 ms
Ob das Ganze als belastbares Testverfahren taugt, möchte ich nicht beurteilen
Gruß Musashi