Fehler in der deutschen Hilfe bitte hier melden (Hilfedatei 3.3.14.2 2017.11.12)

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Zweifelhaft war bei Interpredation der englischen Hilfe ja nicht die Tatsache dass bei beim Quellpfad der Dateiname, mit oder ohne Platzhalter angegeben werden muss/kann (sonst macht es ja keinen Sinn-filecopy muß ja schließlich wissen was copiert werden soll) sondern die nicht klar beschriebene Tatsache, dass der Zielpfad einen anderen Dateinamen als den der Quelldatei enthalten darf. Oder anders ausgedrückt, die zu kopierende Datei darf auch umbenannt werden - und das direkt beim Kopiervorgang. Ich hatte mir die Frage selbst mal gestellt und die Antwort hier gefunden https://www.autoitscript.com/forum/topic/15…a-new-filename/

- freundlicherweise kam die Antwort von water :).

Aber auch nach meiner Textänderung bleiben noch Unklarheiten - denn auch im Zielpfad dürfen Platzhalter vorkommen - das steht auch nirgends --> ich habe ein neues Hilfefile angehängt...

@ bittnugger... s Übersetzung dürfte keinen Dateinamen enthalten... und auch keine Wildcards (in deutscher Sprache: Platzhalter)... das bitte mußt Du mir schon näher erklären --> denn, diesen Satz verstehe ich nicht.

@ water..... was ist ein aggresiver Unterton?

Gruß

Peter

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Tweaky

Hier etwas neues ? Schau bitte mal hier vorbei:

_Array: Daten aus Ini generieren und an FileCopyEx übergeben.

Ich habe da etwas zu einem Bug ? in @sciptDir geschrieben Post #6.

Ist das etwas was man mal in der deutschen Hilfe ausführen sollte? Wenn ja --> Text Datei ich erledige es dann. Falls ich es nicht verständlich beschrieben habe -- > bitte nachfragen.

Danke

Peter

**Bitnugger**

Wenn du explizit ein Verzeichnis als Quelle und Ziel angibst, dann dürfen Quelle und Ziel natürlich auch nur Verzeichnisse sein. Genau das hast du mit Quellverzeichnis und Zielverzeichnis auch getan.

Dies hatte ich mit beinahe denselben Worten auch in diesem Satz geschrieben... noch treffender und verständlicher kann ich es nicht formulieren.

Zitat von Bitnugger

...weil ja für Quelle und Ziel eindeutig und unmissverständlich ein Verzeichnis angegeben wird... und das ist es wohl auch, was water dir damit mitteilen wollte.

Einen schönen Tag noch...

**Tweaky**

Peter S. Taler

würde da nichts ergänzen, da es bereits wie von AspirinJunkie erwähnt drin steht

>>Makros<<

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Tweaky

jupp - wer lesen kann ist klar im Vorteil. Ich stolpere da immer wieder mal drüber - weil es in vielen Scripts "untergeht". Wenn ich die bei mir ausprobiere (F = bei mr eine RAM Disk) fliegen Scripts immer nach F:\ und da passiert das öfter mal. Hatte ehrlicherweise nie nachgesehen ob das auch in de Hilfe steht. Aber da ich noch nie gesehen habe - dass das einer "abfängt" dachte ich.....

Somit erledigt. Sorry wenn ich unnütz "Arbeit gemacht habe"

Gruß

Peter

**Tweaky**

Passt schon. Macht keine unnötige Arbeit. Die Hilfe ist mit Sicherheit noch an vielen Stellen verbesserbar.

fakeraol

Ja, z.B. bei "AutoItSetOption" > "GUICoordMode" > 2

Diese "cell"s tauchen da einfach so aus dem Nichts auf, und warum man für "current cell" -1,-1 statt einfach 0,0 angeben soll, ist logisch auch nicht nachvollziehbar, zumal -1 dadurch unnötigerweise für die Positionierung nicht nutzbar ist. Statt von "Zellen" zu sprechen, sollte erklärt werden, daß jedes Control relativ zum vorhergehenden ausgerichtet wird

Und daß ControlGetPos bei @SW_MAXIMIZE "falsche" Werte (die vor der Maximierung, die für @SW_RESTORE gespeichert bleiben) liefert, sollte auch erwähnt werden.

**Tweaky**

fakeraol

zu AutoItSetOption: Ändere du mal den Hilfetext mal so um, wie du es besser verstehen würdest.

zu ControlGetPos: Zeig mal ein Beispiel wo das so ist,

**Bitnugger**

Zitat von Tweaky

zu AutoItSetOption: Ändere du mal den Hilfetext mal so um, wie du es besser verstehen würdest.

Dies kann er doch nur dann tun, wenn er ihn verstehen würde... hier ist die englische und auch die deutsche Hilfe aber auch nicht leicht zuverstehen.

So würde ich es schreiben...

Code

Alters the position of a control defined by GUICtrlSetPos().
0 = relative position to the start of the last control (upper left corner).
1 = (default) absolute coordinates still relative to the dialog box.
2 = cell positioning relative to current cell. A -1 for left or top parameter don't increment the start.
So next line is -1, offset; next cell is offset,-1; current cell is -1,-1.
Obviously, "offset" can not be -1 because it is reserved to indicate a non-increment. However, you can use a multiple of the width to skip or go back.

Bestimmt, wie die Position eines Controls durch GUICtrlSetPos definiert wird.
0 = relative Position zum Anfang des letzten Controls (obere linke Ecke).
1 = absolute Koordinaten (Standard) relativ zur Dialog Box.
2 = Zellenorientierte Positionierung relativ zur aktuellen Zelle. Eine -1 für den linken oder oberen Parameter erhöht nicht den Start.
Ist die nächste Zeile -1, Offset; nächste Zelle ist Offset, -1; aktuelle Zelle ist -1, -1.
Offensichtlich kann "Offset" nicht -1 sein, weil dieser reserviert ist, um ein Nicht-Inkrement anzugeben. Sie können jedoch ein Vielfaches der Breite verwenden, um zu überspringen oder zurückzugehen.

Alles anzeigen

Zitat von Tweaky

zu ControlGetPos: Zeig mal ein Beispiel wo das so ist,

Bitte schön... der Wert in der rot ausgegebenen Zeile - wenn das Fenster maximiert ist, hat sich geändert...

AutoIt

;-- TIME_STAMP   2018-01-01 11:22:43   v 0.1

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $WIN_STATE_VISIBLE   = 2        ; Fenster ist sichtbar.
Global $WIN_STATE_MINIMIZED = 16    ; Fenster ist minimiert.
Global $WIN_STATE_MAXIMIZED = 32    ; Fenster ist maximiert.

#Region - GUI Create
Local $hGUI = GUICreate('ControlGetPos-Test', 400, 200)
Local $idButton = GUICtrlCreateButton('Exit', 10, 10, 380, 25)
#EndRegion

; Position wie beim Erstellen angegeben
GUISetState($hGUI)
_GetControlPos($hGUI, 'ControlGetPos-Test', $idButton)

; Maximieren
GUISetState(@SW_MAXIMIZE, $hGUI)
_GetControlPos($hGUI, 'ControlGetPos-Test', $idButton)

; Restaurierte Position - wie beim Erstellen angegeben.
GUISetState(@SW_RESTORE, $hGUI)
_GetControlPos($hGUI, 'ControlGetPos-Test', $idButton)

; Minimieren
GUISetState(@SW_MINIMIZE, $hGUI)
_GetControlPos($hGUI, 'ControlGetPos-Test', $idButton)

;~ Exit

Func _GetControlPos($hWnd, $sText, $iCtrlID)
    Local Static $iHeader, $aHeader = ['WinPos ($hGUI)', 'CtrlPos ($idButton)', '$WIN_STATE_VISIBLE', '$WIN_STATE_MINIMIZED', '$WIN_STATE_MAXIMIZED', '@SW_RESTORE']

    Local $aWinPos = WinGetPos($hWnd)
    Local $aCtrlPos = ControlGetPos($hWnd, $sText, $iCtrlID)

    Local $iState = WinGetState($hWnd), $aState[1][4], $sColor

    If BitAND($iState, $WIN_STATE_VISIBLE)   = $WIN_STATE_VISIBLE Then
        $aState[0][0] = 'Fenster ist sichtbar'
        If BitAND($iState, $WIN_STATE_MAXIMIZED) = $WIN_STATE_MAXIMIZED Then
            $aState[0][1] = 'Fenster ist maximiert.'
            $sColor = '!'
        ElseIf BitAND($iState, $WIN_STATE_MINIMIZED) = $WIN_STATE_MINIMIZED Then
            $aState[0][2] = 'Fenster ist minimiert.'
            $sColor = '-'
        Else
            $aState[0][3] = 'Restaurierte Position - wie beim Erstellen angegeben.'
            $sColor = '+'
        EndIf
    Else
        $aState[0][0] = 'Fenster ist nicht sichtbar.'
        $sColor = '@'
    EndIf

    If $iHeader = '' Then
        ConsoleWrite(StringFormat('> %-42s | %-42s | %-30s | %-23s | %-23s |%s\r', $aHeader[0], $aHeader[1], $aHeader[2], $aHeader[3], $aHeader[4], $aHeader[5]))
        $iHeader = True
    EndIf
    ConsoleWrite(StringFormat('%s x:%7i, y:%7i, w:%7i, h:%7i | x:%7i, y:%7i, w:%7i, h:%7i | %-30s | %-23s | %-23s | %-30s\r', _
        $sColor, _
        $aWinPos[0], $aWinPos[1], $aWinPos[2], $aWinPos[3], _
        $aCtrlPos[0], $aCtrlPos[1], $aCtrlPos[2], $aCtrlPos[3], _
        $aState[0][0], $aState[0][1], $aState[0][2], $aState[0][3]))
EndFunc

#Region - GUI SwitchLoop
;~ Local $iState
;~ While True
;~     Switch GUIGetMsg()
;~         Case $GUI_EVENT_CLOSE, $idButton
;~             Exit
;~     EndSwitch
;~ WEnd
#EndRegion

Alles anzeigen

fakeraol

Nach rumspielen mit dem Beispiel von GUISetCoord verstehe ich jetzt, wie es funktioniert. Die Beschreibung bleibt selbst jetzt unverständlich.

"AutoItSetOption" > "GUICoordMode" > 2 positioniert relativ zur unteren rechten Ecke des vorhergehenden Controls. Ausnahme: mit "-1" übernimmt man die top/left-Werte des vorherigen Controls.

Um ein Control genau 1px höher/links als das vorige zu positionieren (-1 ist ja reserviert für "gleicher Abstand von oben/links"), muß man es mit negativen Werten um ("Höhe/Breite des vorigen Controls" + 1) nach oben/links verschieben/positionieren.

Ich halte es für dringend nötig, für "GUICoordMode" ein Beispielscript einzubauen, in dem alle drei Positionierungsvarianten vorgeführt werden.

zu ControlGetPos:

(resizen und beobachten, wie sich die Werte verändern und das Group-Control neu positioniert wird. Dann maximieren, und beobachten, daß das Group-Control nicht neu positioniert wird, weil ControlGetPos immer noch die gleichen Werte wie vor der Maximierung zurückliefert.)

Nach dem Restore wird Group übrigens nochmal falsch positioniert, anscheinend nach der Position , die das Input vorher, während der Maximierung hatte.

AutoIt

#include <GUIConstants.au3>
$MainGUI = GUICreate("", 600, 600, -1, -1,  $WS_MINIMIZEBOX + $WS_MAXIMIZEBOX + $WS_SIZEBOX)
    GUIRegisterMsg($WM_SIZE, "_WM_SIZE")
    $patternGroup = GUICtrlCreateGroup("", 10, 210, 570, 60)
    GUICtrlSetResizing (-1,$GUI_DOCKHEIGHT + $GUI_DOCKRIGHT + $GUI_DOCKLEFT)
    Global $g_idPattern = GUICtrlCreateInput("", 70, 230, 500, 30)
    GUICtrlSetResizing (-1,$GUI_DOCKHEIGHT + $GUI_DOCKRIGHT + $GUI_DOCKLEFT)
GUISetState(@SW_SHOW)
    
    
Func _WM_SIZE($hWnd, $Msg, $wParam, $lParam)
    Local $InputPos = ControlGetPos($MainGUI, "",$g_idPattern)
    GUICtrlSetData($g_idPattern, "GUICtrlGetPos( Left: "&$InputPos[0]&", Top: "&$InputPos[1]&", Width: "&$InputPos[2]&", Height: "&$InputPos[3]&")")
    Local $GroupPos = ControlGetPos($MainGUI, "",$patternGroup)
    GUICtrlSetPos($patternGroup, Default, $InputPos[1] - 18, $GroupPos[2], Default)
    Return $GUI_RUNDEFMSG
EndFunc

While GUIGetMsg() <> -3
WEnd

Alles anzeigen

Noch ein Punkt:

In der Hilfe sind diverse Beispiele verlinkt, die ihre Ausgabe in die Console machen. Außer bei den Console*-Funktionen wäre es viel sinnvoller, die Ausgabe in einer MsgBox zu machen, damit Anfänger sie nach Click auf "Open this Script" auch sehen können.

Außerdem sollte bei ConsoleWrite zumindest für den auf der AutoIt-Seite empfohlenen Editor erklärt werden, wie man eine Ausgabe in die Console erreicht. In Notepad++ musste ich dazu händisch einen Button anlegen, der das Script an AutoIt übergibt. An solchen Hürden scheitert teilweise die Motivation von Anfängern, weiter zu machen.

**Oscar**

Wenn Du schon WM_SIZE benutzt, kannst Du auch gleich die GUI-Elemente anhand der neuen Client-Coordinaten neu ausrichten.

Das ist zwar mehr Programmieraufwand, aber man kann selbst genau bestimmen, welches Element in welcher Position bleibt bzw. verschoben wird:

AutoIt

#include <GUIConstants.au3>
Global $iGuiW = 600, $iGuiH = 400
Global $MainGUI = GUICreate("", $iGuiW, $iGuiH, -1, -1,  $WS_MINIMIZEBOX + $WS_MAXIMIZEBOX + $WS_SIZEBOX)
Global $patternGroup = GUICtrlCreateGroup("", 10, 210, 580, 65)
Global $g_idPattern = GUICtrlCreateInput("", 30, 230, 540, 30)
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_SIZE, "_WM_SIZE")

While GUIGetMsg() <> -3
WEnd

Func _WM_SIZE($hWnd, $Msg, $wParam, $lParam)
    Local $iW = BitAND($lParam, 0x0000ffff) ; Low-Order-Word = new Client-Width
    Local $iH = BitShift(BitAND($lParam, 0xffff0000), 16) ; Hi-Order-Word = new Client-Height
    GUICtrlSetPos($patternGroup, Round(10 / $iGuiW * $iW), 210, Round(580 / $iGuiW * $iW), 65)
    GUICtrlSetPos($g_idPattern, Round(30 / $iGuiW * $iW), 230, Round(540 / $iGuiW * $iW), 30)
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

fakeraol

Oscar

Danke für den Tip, damit lässt sich der Bug (?) von ControlGetPos im Fullscreen-Modus umgehen, was allerdings nichts daran ändert, daß ControlGetPos da nicht die richtigen Werte liefert. Das sollte in der Hilfe erwähnt werden.

fakeraol

Hab den Regexp-Tester aus der Hilfe jetzt mal entsprechend Oscars Vorschlag umgebaut. ~~Das Ergebnis ist ebenso unbefriedigend. Die Radio-Controls springen auf und ab und überlagern sich teilweise beim Resizen:~~

PS: Nach weiteren Anpassungen ist das Ergebnis jetzt befriedigend.

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GuiConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <StringConstants.au3>
#include <WindowsConstants.au3>
#include <IE.au3>
Global Const $g_sSep = Chr(11) ; --> 0x0B = VT - use as a separator for use in the combo control. By default this uses a "|" and this charactor is likely to be used in a pattern file
Opt("GUIDataSeparatorChar", $g_sSep)
Global $g_sInitialDir = @ScriptDir
Global Const $GREEN = 0xAAFFD5
Global Const $GREY = 0xD4D0C8
Global Const $RED = 0xFF8888
Global Const $BLACK= 0x000000
Global Const $BLUE = 0x0000FF
Global Const $SOFTYELLOW = 0xFBFFC6
Global Const $YELLOW = 0xFFFC8A
Global $StringToTest ; $StringToTest holds the currently selected tab for the input string to be tested (ie from the edit box or from the text file)
; results from StringRegExp come in 3 forms: a single string (rtn flag 0), a single array (rtn flag 1,2,3) or an array of arrays (rtn flag 4)
Global $g_bResultTrueFalseExpected = False
Global $g_bArrayOfArraysExpected = False
Global $g_sPatterns = readDatFile()
Global $iGuiW = 632, $iGuiH = 628
GUIRegisterMsg($WM_GETMINMAXINFO, "WM_GETMINMAXINFO")
GUIRegisterMsg($WM_SIZE, "_WM_SIZE")
$hMainForm = GUICreate("StringRegExp Idea by w0uter, modified Steve8tch and fakeraol", $iGuiW, $iGuiH, -1, -1, $WS_MINIMIZEBOX + $WS_MAXIMIZEBOX + $WS_SIZEBOX)
$WindowSize = WinGetPos($hMainForm)

Local $Tab = GUICtrlCreateTab(10, 10, 610, 190)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
Global $Tabitem1 = GUICtrlCreateTabItem("Test text")
Local $InputEditBox = GUICtrlCreateEdit("", 20, 40, 590, 150, BitOR($ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL, $ES_AUTOVSCROLL, $ES_AUTOHSCROLL))
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKHEIGHT)
GUICtrlSetBkColor($InputEditBox, $SOFTYELLOW)
Global $Tabitem2 = GUICtrlCreateTabItem("Load text from File")
Local $Browse = GUICtrlCreateButton("Browse for file", 20, 40, 100, 20)
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKSIZE)
Global $PathToInputFile = GUICtrlCreateEdit("", 130, 40, 480, 20, BitOR($ES_WANTRETURN, $WS_HSCROLL, $ES_AUTOHSCROLL))
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKHEIGHT)
Global $InputFromFile = GUICtrlCreateEdit("", 20, 70, 590, 120, BitOR($ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL, $ES_AUTOVSCROLL, $ES_AUTOHSCROLL))
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT)
GUICtrlSetBkColor($InputFromFile, $SOFTYELLOW)
Global $Tabitem3 = GUICtrlCreateTabItem("Get website text/HTML")
$WebTextButton = GUICtrlCreateButton("Text", 20, 40, 60, 20)
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKSIZE)
$WebHTMLButton = GUICtrlCreateButton("HTML", 85, 40, 60, 20)
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKSIZE)
$WebADDRInput = GUICtrlCreateInput("", 155, 40, 453, 20)
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT + $GUI_DOCKHEIGHT)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, "http://...")
$InputFromWeb = GUICtrlCreateEdit("", 20, 70, 590, 120)
GUICtrlSetResizing (-1,$GUI_DOCKTOP + $GUI_DOCKLEFT)
GUICtrlSetBkColor(-1, $SOFTYELLOW)

GUICtrlCreateTabItem("");

$patternGroup = GUICtrlCreateGroup("The pattern", 10, 210, 610, 60)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
Local $Test = GUICtrlCreateButton("Test", 20, 234, 40, 20, $BS_DEFPUSHBUTTON)
GUICtrlSetResizing (-1,$GUI_DOCKSIZE + $GUI_DOCKLEFT)
Global $Pattern = GUICtrlCreateCombo("", 70, 230, 500, 30)
GUICtrlSetFont($Pattern, 14, -1, -1, "Arial")
GUICtrlSetColor($Pattern, $BLUE)
GUICtrlSetBkColor($Pattern, $YELLOW)
GUICtrlSetData($Pattern, $g_sPatterns, "(.*)")
Global $DoPtnAdd = GUICtrlCreateButton("Add", 584, 225, 30, 18)
Local $DoPtnDel = GUICtrlCreateButton("Del", 584, 245, 30, 18)

Global $Radio_0 = GUICtrlCreateRadio("Match", 15, 300, 115, 18)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
Global $Radio_1 = GUICtrlCreateRadio("ArrayMatch", 15, 318, 115, 18)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
GUICtrlSetState($Radio_1, $GUI_CHECKED)
Global $Radio_2 = GUICtrlCreateRadio("ArrayFullMatch", 15, 336, 115, 18)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
Global $Radio_3 = GUICtrlCreateRadio("ArrayGlobalMatch", 15, 354, 115, 18)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
Global $Radio_4 = GUICtrlCreateRadio("ArrayGlobalFullMatch", 15, 372, 115, 18)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
$returnGroup = GUICtrlCreateGroup("       Return Flag", 10, 280, 125, 120) ; created after its content controls to avoid overlap on resizing
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE)

$offsetGroup = GUICtrlCreateGroup("           Offset", 10, 410, 125, 50)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE)
Global $Offset = GUICtrlCreateInput("1", 40, 430, 60, 20)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE)

$errorGroup = GUICtrlCreateGroup("@error     @extended", 10, 470, 125, 50)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE)
Global $Err = GUICtrlCreateInput("", 20, 490, 40, 20, $ES_READONLY)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE)
Global $Ext = GUICtrlCreateInput("", 70, 490, 50, 20, $ES_READONLY)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE)

Local $_Help = GUICtrlCreateButton("StringRegExp HELP", 10, 544, 120, 30)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKSIZE + $GUI_DOCKBOTTOM)

$outputGroup = GUICtrlCreateGroup("Output", 145, 280, 475, 295)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
Global $Out = GUICtrlCreateEdit("", 155, 296, 455, 270, BitOR($ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL, $ES_AUTOVSCROLL, $ES_AUTOHSCROLL))
GUICtrlSetResizing (-1,$GUI_DOCKLEFT)
GUICtrlSetBkColor($Out, $SOFTYELLOW)

Global $TimerDisplay = GUICtrlCreateLabel("Time (ms)", 3, 583, 132, 20, $SS_SUNKEN)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKBOTTOM + $GUI_DOCKSIZE)
Global $StatusBar = GUICtrlCreateLabel("Status..", 140, 583, 487, 20, $SS_SUNKEN)
GUICtrlSetResizing (-1,$GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

$StringToTest = $InputEditBox ; default - read the string to be tested from the edit box
; setup tool tips
; GUICtrlSetTip required IE version 5+
If Number(StringLeft(RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer", "Version"), 1)) > 4 Then
    GUICtrlSetTip($Radio_0, "Returns 1 (matched) or 0 (no match)", "Return Flag= 0", 1, 1)
    GUICtrlSetTip($Radio_1, "Returns an array containing the matches.", "Return Flag = 1", 1, 1)
    GUICtrlSetTip($Radio_2, "Returns the full matched string AND an array containing the matches (Perl / PHP style).", "Return Flag = 2", 1, 1)
    GUICtrlSetTip($Radio_3, "Returns an array containing the global matches.", "Return Flag = 3", 1, 1)
    GUICtrlSetTip($Radio_4, "Returns an array of arrays containing the full matched strings AND global matches. (Perl / PHP style).", "Return Flag = 4", 1, 1)
    GUICtrlSetTip($Offset, "[optional] The string position to start the match (starts at 1) The default is 1.", "Offset option", 1, 1)
Else
    GUICtrlSetTip($Radio_0, "Returns 1 (matched) or 0 (no match)")
    GUICtrlSetTip($Radio_1, "Returns an array containing the matches.")
    GUICtrlSetTip($Radio_2, "Returns the full matched string AND an array containing the matches (Perl / PHP style).")
    GUICtrlSetTip($Radio_3, "Returns an array containing the global matches.")
    GUICtrlSetTip($Radio_4, "Returns an array of arrays containing the full matched strings AND global matches. (Perl / PHP style).")
    GUICtrlSetTip($Offset, "[optional] The string position to start the match (starts at 1) The default is 1.")
EndIf

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Test
            doStringRegExpTest()
        Case $Browse
            doBrowseForFile()
        Case $WebTextButton
            _IELoadWaitTimeout(30000)
            GUICtrlSetData($InputFromWeb, "Please wait...")
            $oIE = _IECreate(GUICtrlRead($WebADDRInput), 0, 0)
            If @error = 6 Then 
                GUICtrlSetData($InputFromWeb, "Load Timeout")
            Else
                GUICtrlSetData($InputFromWeb, _IEBodyReadText($oIE))
            EndIf
            _IEQuit($oIE)
        Case $WebHTMLButton
            _IELoadWaitTimeout(30000)
            GUICtrlSetData($InputFromWeb, "Please wait...")
            $oIE = _IECreate(GUICtrlRead($WebADDRInput), 0, 0)
            If @error = 6 Then 
                GUICtrlSetData($InputFromWeb, "Load Timeout")
            Else
                GUICtrlSetData($InputFromWeb, _IEBodyReadHTML($oIE))
            EndIf
            _IEQuit($oIE)
        Case $Tab
            Switch GUICtrlRead($Tab)
                Case 0
                    $StringToTest = $InputEditBox
                Case 1
                    $StringToTest = $InputFromFile
                Case 2
                    $StringToTest = $InputFromWeb
            EndSwitch
        Case $DoPtnAdd
            doPtnAdd(GUICtrlRead($Pattern))
        Case $DoPtnDel
            doPtnDel(GUICtrlRead($Pattern))
        Case $_Help
            doDisplayHelp()
    EndSwitch
WEnd

Func doStringRegExpTest()
    Local $aA, $aB ;use for arrays
    Local $i, $j ; use for stepping through arrays
    Local $c ;  counter
    Local $hTimer, $t ; use for timing
    Local $iErr, $iExt ; use to hold result of @error and @extended
    Local $sResult = "" ; use to hold result
    Local $iStrLgth ; use to the string length of the number of results expected. (eg Use in the StringFormat function
    Local $x, $y ; local vars.
    GUICtrlSetData($Out, "")
    GUICtrlSetData($StatusBar, "Performing test..... please wait.")
    GUICtrlSetBkColor($StatusBar, $GREEN)
    ;set up timer
    $hTimer = TimerInit()
    $aA = StringRegExp(GUICtrlRead($StringToTest), GUICtrlRead($Pattern), getReturnFlag(), getOffset())
    $iErr = @error
    $iExt = @extended
    $t = TimerDiff($hTimer)
    GUICtrlSetData($TimerDisplay, $t & "  ms")
    GUICtrlSetData($Err, $iErr)
    GUICtrlSetData($Ext, $iExt)
    Select
        Case $iErr = 0
            GUICtrlSetData($StatusBar, "Valid pattern - updating display.   Please wait....")
            GUICtrlSetBkColor($StatusBar, $GREEN)
        Case $iErr = 1
            GUICtrlSetData($StatusBar, "Array is invalid. No matches")
            GUICtrlSetBkColor($StatusBar, $RED)
        Case $iErr = 2
            GUICtrlSetData($StatusBar, "Bad pattern, (array is invalid). @extended = offset of error in pattern.")
            GUICtrlSetBkColor($StatusBar, $RED)
    EndSelect
    If $iErr = 0 Then
        $x = UBound($aA)
        If $g_bArrayOfArraysExpected Then
            $y = UBound($aA[0])
            $x *= $y
        EndIf
        $iStrLgth = StringLen(String($x - 1))
        If $g_bArrayOfArraysExpected Then ; results -> array of arrays expected
            $c = 0 ; use $c as a counter to help display the results
            If UBound($aA) Then
                For $i = 0 To UBound($aA) - 1
                    $aB = $aA[$i]
                    For $j = 0 To UBound($aB) - 1
                        $sResult &= StringFormat("%0" & $iStrLgth & "i", $c) & ' => ' & $aB[$j] & @CRLF
                        $c += 1
                    Next
                    $sResult &= @CRLF
                Next
                GUICtrlSetData($Out, $sResult)
                GUICtrlSetData($StatusBar, "Complete")
            EndIf
        ElseIf $g_bResultTrueFalseExpected Then ; result string expected
            If $aA = 1 Then
                $sResult &= "1   <-- SUCCESS, matches found" & @CRLF
            Else
                $sResult &= "0   <-- FAIL, no matches found" & @CRLF
            EndIf
            GUICtrlSetData($Out, $sResult)
            GUICtrlSetData($StatusBar, "Complete")
        Else ; a single array expected
            If UBound($aA) Then
                For $i = 0 To UBound($aA) - 1
                    $sResult &= StringFormat("%0" & $iStrLgth & "i", $i) & ' => ' & $aA[$i] & @CRLF
                Next
                GUICtrlSetData($Out, $sResult)
                GUICtrlSetData($StatusBar, "Complete")
            EndIf
        EndIf
    EndIf
EndFunc

Func getReturnFlag()
    $g_bArrayOfArraysExpected = False
    $g_bResultTrueFalseExpected = False
    Switch $GUI_CHECKED
        Case GUICtrlRead($Radio_0)
            $g_bResultTrueFalseExpected = True
            Return $STR_REGEXPMATCH
        Case GUICtrlRead($Radio_1)
            Return $STR_REGEXPARRAYMATCH
        Case GUICtrlRead($Radio_2)
            Return $STR_REGEXPARRAYFULLMATCH
        Case GUICtrlRead($Radio_3)
            Return $STR_REGEXPARRAYGLOBALMATCH
        Case GUICtrlRead($Radio_4)
            $g_bArrayOfArraysExpected = True
            Return $STR_REGEXPARRAYGLOBALFULLMATCH
    EndSwitch
EndFunc

Func getOffset()
    Local $x
    $x = Int(GUICtrlRead($Offset))
    If @error Then
        Return 1
    Else
        Return $x
    EndIf
EndFunc

Func doBrowseForFile()
    Local $sFilePath, $sFileTxt
    $sFilePath = FileOpenDialog("Select text file to test", $g_sInitialDir, "Text files (*.*)", 1)
    $g_sInitialDir = StringTrimRight($sFilePath, StringInStr($sFilePath, "\", "-1"))
    GUICtrlSetData($StatusBar, "Loading file..")
    GUICtrlSetBkColor($StatusBar, $GREEN)
    GUICtrlSetData($PathToInputFile, $sFilePath)
    $sFileTxt = FileRead($sFilePath)
    GUICtrlSetData($StatusBar, "File loaded... updating display")
    GUICtrlSetData($InputFromFile, $sFileTxt)
    GUICtrlSetData($StatusBar, "")
    GUICtrlSetBkColor($StatusBar, $GREY)
EndFunc

Func readDatFile()
    Local $sDat, $sOut = ""
    Local $sHeader = "[do not delete this file - Patterns are listed below]" & @CRLF
    Local $sDatFile = @AppDataDir & "\StringRegExpGUIPattern.dat"
    If FileExists($sDatFile) = 0 Then
        $sDat = $sHeader & "(.*)"
        FileWrite($sDatFile, $sDat)
        $sOut = "(.*)"
    Else
        $sDat = FileRead($sDatFile)
        $sDat = StringReplace($sDat, $sHeader, "") ; strip out header line
        ;Strip out any leading or trailing @CRLF
        If StringLeft($sDat, 2) = @CRLF Then $sDat = StringTrimLeft($sDat, 2)
        If StringRight($sDat, 2) = @CRLF Then $sDat = StringTrimRight($sDat, 2)
        If $sDat <> "" Then ; we should have 1 or more patterns
            $sOut = StringReplace($sDat, @CRLF, $g_sSep)
        Else
            FileWrite($sDatFile, $sHeader & "(.*)")
            $sOut = "(.*)"
        EndIf
    EndIf
    Return $sOut
EndFunc

Func doPtnDel($x)
    Local $sDat
    Local $sDatFile = @AppDataDir & "\StringRegExpGUIPattern.dat"
    $sDat = FileRead($sDatFile)
    ;now find and remove this entry from the dat file
    $sDat = StringReplace($sDat, $x, "")
    ;If $x was in the middle of the dat file - we will now need to find and remove any double @CRLF entries
    $sDat = StringReplace($sDat, @CRLF & @CRLF, @CRLF)
    ;If $x was at the beginning or the end of the file - we now need to stop off a leading or trailing @CRLF entry
    If StringLeft($sDat, 2) = @CRLF Then $sDat = StringTrimLeft($sDat, 2)
    If StringRight($sDat, 2) = @CRLF Then $sDat = StringTrimRight($sDat, 2)
    ;Now delete the previous dat file and create a new one
    If FileDelete($sDatFile) Then
        FileWrite($sDatFile, $sDat)
    Else
        MsgBox($MB_SYSTEMMODAL, "***ERROR**", "Failed to delete  entry from the dat file" & @CRLF & _
                "Reason: Failed to delete old file.")
    EndIf
    ;Now read in new dat file
    $g_sPatterns = readDatFile()
    GUICtrlSetData($Pattern, $g_sSep & $g_sPatterns, "(.*)")
EndFunc   ;==>doPtnDel

Func doPtnAdd($x)
    Local $sDat
    Local $sDatFile = @AppDataDir & "\StringRegExpGUIPattern.dat"
    $sDat = FileRead($sDatFile)
    ;now add this entry to the end of the dat file
    $sDat &= @CRLF & $x
    ;Now delete the previous dat file and create a new one
    If FileDelete($sDatFile) Then
        FileWrite($sDatFile, $sDat)
    Else
        MsgBox($MB_SYSTEMMODAL, "***ERROR**", "Failed to delete  entry from the dat file" & @CRLF & _
                "Reason: Failed to delete old file.")
    EndIf
    ;Now read in new dat file
    $g_sPatterns = readDatFile()
    GUICtrlSetData($Pattern, $g_sSep & $g_sPatterns, $x)
EndFunc   ;==>doPtnAdd

Func doDisplayHelp()
    Local $iErr = 0
    If @Compiled = 0 Then
        Local $sPathToHelpFile = StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 0, -1))
        Run($sPathToHelpFile & "AutoIt3Help.exe StringRegExp")
        $iErr = @error
    Else
        ; X64 running support
        Local $sWow64 = ""
        If @AutoItX64 Then $sWow64 = "\Wow6432Node"

        ;Try and file to help file (if available at all)
        ;get AutoIt install dir
        Local $sPathToAutoIt = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir")
        $iErr = @error

        If $iErr = 0 Then
            Run($sPathToAutoIt & "\AutoIt3Help.exe StringRegExp")
            $iErr = @error
        EndIf
    EndIf
    If $iErr Then MsgBox($MB_SYSTEMMODAL, "error", "Cannot find help file - sorry")
EndFunc

Func WM_GETMINMAXINFO($hwnd, $Msg, $wParam, $lParam)
    #forceref $hwnd, $Msg, $wParam, $lParam
    Local $tagMaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($tagMaxinfo, 7,  $WindowSize[2]) ; min X
    DllStructSetData($tagMaxinfo, 8,  $WindowSize[3]) ; min Y
    DllStructSetData($tagMaxinfo, 9,  @DesktopWidth)  ; max X
    DllStructSetData($tagMaxinfo, 10, @DesktopHeight) ; max Y
    Return 0
EndFunc

Func _WM_SIZE($hWnd, $Msg, $wParam, $lParam)
    Local $iW = BitAND($lParam, 0x0000ffff) ; Low-Order-Word = new Client-Width
    Local $iH = BitShift(BitAND($lParam, 0xffff0000), 16) ; Hi-Order-Word = new Client-Height
    LOcal $iM = Floor($iH * .39)

    GUICtrlSetPos($Tab,                  10,         10, $iW -  20, $iM -  45)
    GUICtrlSetPos($InputEditBox,      20,         40, $iW -  40, $iM -  85)
    GUICtrlSetPos($WebADDRInput,     155,         40, $iW - 175,        20)
    GUICtrlSetPos($InputFromFile,      20,         70, $iW -  40, $iM - 115)
    GUICtrlSetPos($PathToInputFile,  130,         40, $iW - 150,        20)
    GUICtrlSetPos($InputFromWeb,      20,         70, $iW -  40, $iM - 115)
    GUICtrlSetPos($patternGroup,      10, $iM -  25, $iW -  20,        60)
    GUICtrlSetPos($Test,              20,        235,        40,        20)
    GUICtrlSetPos($Pattern,              70, $iM -   5, $iW - 120,        30)
    GUICtrlSetPos($DoPtnAdd,    $iW - 45, $iM -  10,        30,        18)
    GUICtrlSetPos($DoPtnDel,    $iW - 45, $iM +  10,        30,        18)
    GUICtrlSetPos($returnGroup,          10, $iM +  45,       125,       120)
    GUICtrlSetPos($Radio_0,              15, $iM +  65,       117,        18)
    GUICtrlSetPos($Radio_1,              15, $iM +  83,       117,        18)
    GUICtrlSetPos($Radio_2,              15, $iM + 101,       117,        18)
    GUICtrlSetPos($Radio_3,              15, $iM + 119,       117,        18)
    GUICtrlSetPos($Radio_4,              15, $iM + 137,       117,        18)
    GUICtrlSetPos($offsetGroup,          10, $iM + 175,       125,        50)
    GUICtrlSetPos($Offset,              40, $iM + 195,        60,        20)
    GUICtrlSetPos($errorGroup,          10, $iM + 235,       125,        50)
    GUICtrlSetPos($Err,               20, $iM + 255,        40,        20)
    GUICtrlSetPos($Ext,               70, $iM + 255,        50,        20)
                                                                            

    GUICtrlSetPos($outputGroup,         145, $iM +  45, $iW - 155, $iH - ($iM + 74))
    GUICtrlSetPos($Out,                 155, $iM +  61, $iW - 175, $iH - ($iM + 101))

    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**Andy**

Zitat von fakeraol

Hab den Regexp-Tester aus der Hilfe jetzt mal entsprechend Oskars Vorschlag umgebaut. Das Ergebnis ist ebenso unbefriedigend. Die Radio-Controls springen auf und ab und überlagern sich teilweise beim Resizen:

was sich bei mir (Win10) beheben lässt durch weglassen von GUI_DOCKSIZE, also

Code

$returnGroup = GUICtrlCreateGroup("       Return Flag", 10, 280, 125, 120)
    GUICtrlSetResizing (-1,$GUI_DOCKSIZE + $GUI_DOCKLEFT)
Global $Radio_0 = GUICtrlCreateRadio("Match", 15, 300, 115, 18)
    GUICtrlSetResizing (-1, $GUI_DOCKLEFT)
Global $Radio_1 = GUICtrlCreateRadio("ArrayMatch", 15, 318, 115, 18)
    GUICtrlSetResizing (-1, $GUI_DOCKLEFT)
    GUICtrlSetState($Radio_1, $GUI_CHECKED)
Global $Radio_2 = GUICtrlCreateRadio("ArrayFullMatch", 15, 336, 115, 18)
    GUICtrlSetResizing (-1, $GUI_DOCKLEFT)
Global $Radio_3 = GUICtrlCreateRadio("ArrayGlobalMatch", 15, 354, 115, 18)
    GUICtrlSetResizing (-1, $GUI_DOCKLEFT)
Global $Radio_4 = GUICtrlCreateRadio("ArrayGlobalFullMatch", 15, 372, 115, 18)
    GUICtrlSetResizing (-1, $GUI_DOCKLEFT)

Alles anzeigen

fakeraol

Danke Andy , habs mal oben im Post angepasst, und noch ein paar Kleinigkeiten.

Dann könnte der jetzt mit in die Hilfe übernommen werden (im "Tutorial - Regular Expression").

~~PS NOCH NICHT! Sind noch Fehler drin.~~ ~~Jetzt sollte alles funktionieren.~~ ~~Ruckelt immer noch was, muß aber erst mal weg, kümmer mich später drum.~~

So, soweit möglich, ruckeln und flackern beseitigt. Falls nochmal jemand drüberschauen mag ... ansonsten ist das Script jetzt fertig.

* Resource aus dem Netz laden

* Gui resizable
_____________________________________________________________________________________________________________________

Placeholder für Input, etc. setzen mit $EM_SETCUEBANNER - könnte man noch mit aufnehmen in die Hilfe.

https://www.autoitscript.com/forum/topic/16…comment=1226083

**Tweaky**

fakeraol

wegen dem Regexp-Tester:

welche Version hast du als Basis verwendet? Wäre es nicht sinnvoll die übersetzte Version der deutschen Hilfe zu verwenden?

fakeraol

Den aus der Hilfe 3.3.12.0 , gibts da noch nen Neueren?

Übersetzung kann ich guttenbergen.

**Tweaky**

Na die aus der aktuellen deutschen Hilfe von 3.3.14.2 (siehe meine Signatur oder Downloadbox im Forum).

Das ist die Hilfeversion für die du hier ja auch die ganze Zeit Fehler meldest oder etwa nicht?

fakeraol

Hab die beiden (DE 3.3.14.2 und EN 3.3.12.0) mal verglichen. Bis auf die Strings sind sie gleich (funktional).

Ich hab grad beide (DE und EN) nebeneinander geöffnet, und da die en schon 'ne StringRegExpGUIPattern.dat angelegt hat, spuckt die DE jetzt in dem Pattern-Combo die (EN) Header-Zeile mit aus.

Wenn ich die readDatFile()-Funktion mittels FileReadToArray() umbaue, fällt das Geraffel zur Entfernung der Zeilenumbrüche weg, und die erste Zeile lässt sich unabhängig vom (DE oder EN) Inhalt "entsorgen". Die ganze Funktion lässt sich viel kompakter (und weniger fehleranfällig) schreiben, mach ich mich morgen abend mal dran.

Übersetzung mach ich dann gleich mit.

Fehler/Verbesserungen melde ich auf Basis der Online-Hilfe.

**Tweaky**

Zitat von fakeraol

Placeholder für Input, etc. setzen mit $EM_SETCUEBANNER - könnte man noch mit aufnehmen in die Hilfe.

https://www.autoitscript.com/forum/topic/16…comment=1226083

Hab ich nun bei den Bemerkungen von GUICtrlCreateInput ergänzt.