GUI Labels als Array ansprechen

BehindSouls

Hallo, ich habe schon fleißig gegoogelt aber für AutoIT leider keine Lösung gefunden, ich habe folgendes Problem:

Ich habe 10 Labels die ich gerne als Array behandeln würde sodass ich deren Text je nach dem was die Funktion zurück gibt ändern kann.

Beispiel:

Ich habe eine Funktion die 10 Links einliest und diese auf ihre Verfügbarkeit überprüft, das ist alles als Array geschehen,

nun sollen die Ergebnisse in der GUI angezeigt werden. Heißt das erste Ergebnis ist 1 -> Label1 = 1, das zweite Ergebnis ist 5, Label2 = 5.

Im Endeffekt also label[$x] = ergebnis[$x]

Vielen Dank für jegliche Hilfe.

**alpines**

Wieso löst du das ganze denn nicht mit einer For-Schleife?

Du kannst doch dann, wenn die die Labelcontrols in einem Array erstellst dann dein Ergebnisarray iterieren und GUICtrlSetData zum Setzen der Ergbenisse verwenden.

AutoIt

Local $aControls[2] = [$hLabel1, $hLabel2]

For $i = 0 To UBound($aControls) - 1
    $iErgebnis = _DoSomething()

    GUICtrlSetData($aControls[$i], "Ergebnis: " & $iErgebnis)
Next

BehindSouls

Vielen Dank, das habe ich gesucht!

Ich wusste nur nicht, wie ich die Label von der Syntax her korrekt und effizient ansprechen kann.

**chesstiger**

Das erinnert mich an was. Hab genau sowas mal gebastelt, um ein paar (interne) Hosts per Ping auf Verfügbarkeit zu prüfen. Das war vor einiger Zeit das Haupt-Ferndiagnosewerkzeug bei uns in der Firma (Anruf bei mir -> "Starte mal das Programm und sag mir mal, ob was rot ist!" -> "Jaaa, die 192.168.123.100 ist rot!" -> "Geh mal in mein Büro und mach den Medion-Rechner wieder an!").

In einer Datei namens hosts.txt im Arbeitsverzeichnis stehen die ganzen Hosts, einer pro Zeile.

Code

#include <StaticConstants.au3>

Global Enum $SCHEME_SUCCESS, $SCHEME_FAILURE, $SCHEME_PINGING, $SCHEME_UNKNOWN

Exit main() ;exit application with exit code <return of main()>

Func main()
    Local $hWnd, $acLabels[0], $asHosts[0]
    Local $iWinHeight, $iTop, $iHeight
    Local $cGoButton

    $asHosts = FileReadToArray("hosts.txt")
    ReDim $acLabels[UBound($asHosts)]

    $iWinHeight = 400
    $hWnd = GUICreate("BatchPing", 600, $iWinHeight)
    GUISetBkColor(0xffffff) ;white background
    GUISetFont(12, 8.5, 0, "Segoe UI")
    For $i = 0 To UBound($acLabels) - 1
        $iHeight = ($iWinHeight - 20) / UBound($acLabels)
        $iTop = Int(10 + $i * $iHeight)
        ConsoleWrite("Create Label at y = " & $iTop & " with height = " & $iHeight & @CRLF)
        $acLabels[$i] = GUICtrlCreateLabel($asHosts[$i], 10, $iTop, 300, $iHeight + 1, $SS_CENTER + $SS_CENTERIMAGE)
        labelSetScheme(-1, $SCHEME_UNKNOWN)
    Next
    $cGoButton = GUICtrlCreateButton("Ping!", 320, 10, 270, 80)
    GUISetState()

    While True
        Switch GUIGetMsg()
            Case -3
                Return 0
            Case $cGoButton
                batchPing($asHosts, $acLabels)
        EndSwitch
    WEnd
EndFunc

Func batchPing($asHosts, $acLabels, $iTimeOut = 1000)
    Local $cLabel, $iPing
    For $cLabel In $acLabels
        labelSetScheme($cLabel, $SCHEME_UNKNOWN)
    Next
    For $i = 0 To UBound($asHosts) - 1
        labelSetScheme($acLabels[$i], $SCHEME_PINGING)
        GUICtrlSetData($acLabels[$i], $asHosts[$i] & " (Ping)")
        $iPing = Ping($asHosts[$i], $iTimeOut)
        If @error Then
            labelSetScheme($acLabels[$i], $SCHEME_FAILURE)
            GUICtrlSetData($acLabels[$i], $asHosts[$i] & " (Error)")
        Else
            labelSetScheme($acLabels[$i], $SCHEME_SUCCESS)
            GUICtrlSetData($acLabels[$i], $asHosts[$i] & " (" & $iPing & " ms)")
        EndIf
    Next
EndFunc

Func labelSetScheme($cLabel, $iScheme)
    Switch $iScheme
        Case $SCHEME_SUCCESS
            GUICtrlSetBkColor($cLabel, 0xccff33)
            GUICtrlSetColor($cLabel, 0x336600)
        Case $SCHEME_FAILURE
            GUICtrlSetBkColor($cLabel, 0xff9933)
            GUICtrlSetColor($cLabel, 0x993300)
        Case $SCHEME_PINGING
            GUICtrlSetBkColor($cLabel, 0xffff66)
            GUICtrlSetColor($cLabel, 0x996633)
        Case Else
            GUICtrlSetBkColor($cLabel, 0xffffff)
            GUICtrlSetColor($cLabel, 0x000000)
    EndSwitch
EndFunc

Alles anzeigen

BehindSouls

Siehr sehr gut aus, ungefähr in diese Richtung solls auch gehen!

Danke fürs teilen des Codes

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

chesstiger

Habe den Code gerade mal ausgeführt - kann es sein dass da eine kleine "Ungereimtheit" darin steckt? Der ausführende Rechner steht bei mir in der Hosts.txt. Dadurch wird versucht den Rechner auf dem DEIN Programm ausgeführt wird anzupingen mit dem Ergebnis ROT. Was ja def. falsch ist.

Natürlich könnte man den "Start" Rechner aus der Hosts.txt raus lassen - aber dann müßte man ja für jeden Rechner im Netz eine eigene Hosts.txt erstellen.

Ev. Die IP des Start Rechners ermitteln und dann "zwangsweise" auf Grün setzen bzw. die "Start" Rechner IP erst gar nicht anpingen...

Danke für den netten Code

Gruß

Peter

PS.. ICh wollte nicht in Deinem Code rumfummeln . BS = XP SP3

**autoiter**

Hallo Peter S. Taler

Prüfe doch mal selbst den Ping Befehl mit deiner IP.

Ich glaube da liegt eher ein Problem mit deinem System oder Netzwerk vor.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Hmmm,

ich kann das tatsächlich nicht nachvollziehen. Da ich aber nicht farbenblind bin.... :

Anyway der eigene Computer ist tatsächlich auch grün.

Ziehe # 6 mit dem Ausdruck des Bedauerns zurück, Habe Code compiliert - kommt in den Wekzeugkasten - sollte das nochmal vorkommen (Grün /Rot eigene IP) versuche ich dem auf den Grund zu gehen.

Gruß

Peter

**autoiter**

Peter S. Taler

Es könnte vllt. sein, dass mal ein Ping verloren geht. Zur Sicherheit könntest du den Ping in eine eigene For Schleife packen und max. dreimal ausführen, bis das Ergebnis kein Fehler ist oder die Durchläufe absolviert sind. Das würde das Skript auch nicht ewig langsamer machen.

**Bitnugger**

Zitat von autoiter

Es könnte vllt. sein, dass mal ein Ping verloren geht. Zur Sicherheit könntest du den Ping in eine eigene For Schleife packen und max. dreimal ausführen,

Mit anderen Worten... den Parameter $iTimeOut auf 3000 setzen.

Habe das Script bei mir getestet und es läuft einwandfrei und ohne Fehler.

Die Funktion labelSetScheme habe ich allerdings etwas verkürzt...

AutoIt

Func labelSetScheme($cLabel, $iScheme)
    Local Static $aSchemes = [[0xCCFF33, 0x336600], [0xFF9933, 0x993300], [0xFFFF66, 0x996633], [0xFFFFFF, 0x000000]]
;~     If $iScheme < 0 Or $iScheme >= UBound($aSchemes) Then Return SetError(1, 0, False)
    GUICtrlSetBkColor($cLabel, $aSchemes[$iScheme][0])
    GUICtrlSetColor($cLabel, $aSchemes[$iScheme][1])
EndFunc

**autoiter**

Zitat von Bitnugger

Mit anderen Worten... den Parameter $iTimeOut auf 3000 setzen.

Hehe, nein das meinte ich nicht Bitnugger

Ich habe wirklich spekuliert, dass mal ein Ping verloren gehen kann. Daher würde ich eine Wiederholung vorziehen. Ist aber vllt. Quatsch und mein persönlicher Voodoo Zauber

**Bitnugger**

Zitat von autoiter

Ich habe wirklich spekuliert, dass mal ein Ping verloren gehen kann.

Nun, bis data ist mir noch nie ein Ping verloren gegangen... und wäre dem so, würde ich das Problem nicht einfach mit einer For-Schleife kaschieren, sondern die Ursache dafür finden wollen.

**chesstiger**

Bitnugger

Ja, so kann man es kürzen. Macht ab einer gewissen Komplexität auch Sinn. Ich hatte Langeweile und habe das ganze bspw. noch um ein paar Icons erweitert:

C

#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Global Enum $SCHEME_SUCCESS, $SCHEME_FAILURE, $SCHEME_PINGING, $SCHEME_UNKNOWN
Global Enum $CHILD, $ICON, $LABEL

Exit main() ;exit application with exit code <return of main()>

Func main()
    Local $hWnd, $acHosts[0][0], $asHosts[0]
    Local $iWinHeight, $iTop, $iHeight
    Local $cGoButton, $cTimeOutInput
    ;generate host list
    $asHosts = FileReadToArray("hosts.txt")
    ReDim $acHosts[UBound($asHosts)][3]
    ;create main window
    $iWinHeight = 400
    $hWnd = GUICreate("BatchPing", 600, $iWinHeight)
    GUISetBkColor(0xffffff) ;white background
    GUISetFont(12, 8.5, 0, "Segoe UI")
    For $i = 0 To UBound($acHosts) - 1
        $iHeight = ($iWinHeight - 20) / UBound($acHosts)
        $iTop = Int(10 + $i * $iHeight)
        ;child window for background changing icon
        $acHosts[$i][$CHILD] = GUICreate("", $iHeight, $iHeight + 1, 10, $iTop, $WS_CHILD, -1, $hWnd)
        GUISetState()
        $acHosts[$i][$ICON]  = GUICtrlCreateIcon("shell32.dll", -50, 0, 0, $iHeight, $iHeight, $SS_CENTERIMAGE)
        GUISwitch($hWnd) ;back to main window
        $acHosts[$i][$LABEL] = GUICtrlCreateLabel($asHosts[$i], 10 + $iHeight, $iTop, 300 - $iHeight, $iHeight + 1, $SS_CENTER + $SS_CENTERIMAGE)
        hostSetScheme($acHosts, $i, $SCHEME_UNKNOWN)
    Next
    $cGoButton = GUICtrlCreateButton("Ping!", 320, 10, 270, 80)
    $cTimeOutInput = GUICtrlCreateInput("1000", 320, 100, 140, 40, $ES_NUMBER)
    GUICtrlCreateLabel(" ms", 460, 100, 130, 40)
    GUICtrlSetFont(-1, 20)
    GUICtrlSetFont($cTimeOutInput, 20)
    GUICtrlCreateUpdown($cTimeOutInput, 0x80 + 0x20)
    GUISetState()
    ;main loop
    While True
        Switch GUIGetMsg()
            Case -3
                Return 0
            Case $cGoButton
                batchPing($asHosts, $acHosts, GUICtrlRead($cTimeOutInput))
        EndSwitch
    WEnd
EndFunc

Func batchPing($asHosts, $acHosts, $iTimeOut = 1000)
    Local $iPing
    For $i = 0 To UBound($acHosts) - 1
        hostSetScheme($acHosts, $i, $SCHEME_UNKNOWN)
    Next
    For $i = 0 To UBound($asHosts) - 1
        hostSetScheme($acHosts, $i, $SCHEME_PINGING)
        GUICtrlSetData($acHosts[$i][$LABEL], $asHosts[$i] & " (Ping)")
        $iPing = Ping($asHosts[$i], $iTimeOut)
        If @error Then
            hostSetScheme($acHosts, $i, $SCHEME_FAILURE)
            GUICtrlSetData($acHosts[$i][$LABEL], $asHosts[$i] & " (Error)")
        Else
            hostSetScheme($acHosts, $i, $SCHEME_SUCCESS)
            GUICtrlSetData($acHosts[$i][$LABEL], $asHosts[$i] & " (" & $iPing & " ms)")
        EndIf
    Next
EndFunc

Func hostSetScheme($acHosts, $i, $iScheme)
    Local Enum $BG, $FG, $IC
    Local Static $aiColors = [[0xccff33, 0x336600, -165], _
        [0xff9933, 0x993300, -78], _
        [0xffff66, 0x996633, -210], _
        [0xffffff, 0x000000, -50]]
    Local $hOldWnd
    GUICtrlSetImage($acHosts[$i][$ICON], "shell32.dll", $aiColors[$iScheme][$IC], 0)
    $hOldWnd = GUISwitch($acHosts[$i][$CHILD])
    GUISetBkColor($aiColors[$iScheme][$BG])
    GUISwitch($hOldWnd)
    GUICtrlSetBkColor($acHosts[$i][$ICON], $aiColors[$iScheme][$BG])
    GUICtrlSetBkColor($acHosts[$i][$LABEL], $aiColors[$iScheme][$BG])
    GUICtrlSetColor($acHosts[$i][$LABEL], $aiColors[$iScheme][$FG])
EndFunc

Alles anzeigen

Das Child Window pro Zeile ist notwendig, damit man den Hintergrund der Icons mitverändern kann. Woher diese seltsame Abstufung kommt, weiß ich aber leider auch nicht...