GUI ohne Close-Button?

;https://www.autoitscript.com/forum/topic/162915-re-enable-closure-x/?do=findComment&comment=1185617
;Synix
#include <GUIConstants.au3>
Global Const $SC_CLOSE = 0xF060
;Global Const $MF_BYCOMMAND = 0x00000000
;;Global Const $MF_BYPOSITION = 0x00000400
Global Const $MF_DISABLED = 0x00000002
;Global Const $MF_ENABLED = 0x00000000
Global Const $MF_GRAYED = 0x00000001


$hGUI = GUICreate("Example", 200, 22, -1, -1, BitOR($WS_CAPTION, $WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SYSMENU))
$hSystemMenu = _WinAPI_GetSystemMenu($hGUI)
_WinAPI_EnableMenuItem($hSystemMenu, $SC_CLOSE, $MF_DISABLED)
GUICtrlCreateLabel("only minimize and maximize buttons works", 5, 5)
GUISetState()


While 1
    $idMsg = GUIGetMsg()
    Switch $idMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WinAPI_EnableMenuItem($hMenu, $iItem, $iEnable)
    #cs
        Parameters
        $hMenu
        A handle to the menu.

        $iItem
        The menu item to be enabled, disabled, or grayed, as determined by the uEnable parameter. This parameter specifies an item in a menu bar, menu, or submenu.

        $iEnable
        Controls the interpretation of the $iItem parameter and indicate whether the menu item is enabled, disabled, or grayed. This parameter must be a combination of the following values.

        Values:
        MF_BYCOMMAND
        0x00000000L
        Indicates that $iItem gives the identifier of the menu item. If neither the MF_BYCOMMAND nor MF_BYPOSITION flag is specified, the MF_BYCOMMAND flag is the default flag.

        MF_BYPOSITION
        0x00000400L
        Indicates that $iItem gives the zero-based relative position of the menu item.

        MF_DISABLED
        0x00000002L
        Indicates that the menu item is disabled, but not grayed, so it cannot be selected.

        MF_ENABLED
        0x00000000L
        Indicates that the menu item is enabled and restored from a grayed state so that it can be selected.

        MF_GRAYED
        0x00000001L
        Indicates that the menu item is disabled and grayed so that it cannot be selected.

        Return value
        The return value specifies the previous state of the menu item (it is either MF_DISABLED, MF_ENABLED, or MF_GRAYED).
        If the menu item does not exist, the return value is -1.
    #ce
    $aResult = DllCall("user32.dll", "bool", "EnableMenuItem", "hwnd", $hMenu, "uint", $iItem, "uint", $iEnable)
    If @error Then Return SetError(@error, @extended, 0)

    Return $aResult[0]
EndFunc   ;==>_WinAPI_EnableMenuItem

Func _WinAPI_GetSystemMenu($hWnd, $bRevert = False)
    #cs
        Parameters
        $hWnd
        A handle to the window that will own a copy of the window menu.

        $bRevert
        The action to be taken.
        If this parameter is FALSE, GetSystemMenu returns a handle to the copy of the window menu currently in use. The copy is initially identical to the window menu, but it can be modified.
        If this parameter is TRUE, GetSystemMenu resets the window menu back to the default state. The previous window menu, if any, is destroyed.

        Return value
        If the $bRevert parameter is FALSE, the return value is a handle to a copy of the window menu.
        If the $bRevert parameter is TRUE, the return value is NULL.
    #ce

    $aResult = DllCall("user32.dll", "hwnd", "GetSystemMenu", "hwnd", $hWnd, "bool", $bRevert)
    If @error Then Return SetError(@error, @extended, 0)

    ;uncomment the following line to replicate the winapi return if $bRevert is true (otherwise $aResult[0] will be 0x00000000)
;~     If $bRevert = True Then $aResult[0] = Null

    Return $aResult[0]
EndFunc   ;==>_WinAPI_GetSystemMenu

#include <WindowsConstants.au3>
#include <GuiMenu.au3>

; Standard: Icon + Titel + MinBox + MaxBox + CloseButton
_GuiStyle()

Func _GuiStyle($iStyle=-1)
    Local $hGui = GUICreate('Test',400,300, -1, -1, BitOR($WS_CAPTION, $WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SYSMENU))
    _GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hGui), $SC_CLOSE, $MF_DISABLED, False)
    Local $exit = GUICtrlCreateButton('Exit', 50,50,80,25)
    GUISetState()
    While 1
        If GUIGetMsg() = $exit Then Return
    WEnd
EndFunc