Guis Buggen in einander

Floooooo24

Guten Morgen zusammen,

Ich habe das Problem, das bei mir ab und zu zwei GUIs aus einem Skript in einander buggen. das sieht dan so aus:

eigentlich sollte es so aussehen:

die Zweite GUI sollte am anfang eigentlich versteckt sein, wesshalb ich sie auch am Anfang geziehlt verstecke mit dem Befehlt:

Code

GUISetState(@SW_HIDE, $hNewError)

da ich mir nicht sicher bin, ob es sinnvoll ist die 1000 zeilen code die das gesamte Programm hat, erstmal nur der teil in dem die zweite GUI erstellt wird:

Code

;----------------------------------------------------------------------------
;Create New Error-GUI
;----------------------------------------------------------------------------

;GUI create
Local $hNewError = _Metro_CreateGUI("New Error", 500, 300, -1, -1, True) ;Erstellt die GUI
GUISetState(@SW_HIDE, $hNewError) ;Versteckt die GUI $hNewError

;Create Control-Buttons (oben rechts)
Local $Control_Buttons = _Metro_AddControlButtons(True, False, False, False, False)

;create Gui flags
Local $GUI_CLOSE_BUTTON_NewError = $Control_Buttons[0]

;----------------------------------------------------------------------------
;Design New Error-GUI
;----------------------------------------------------------------------------

;Create Treeview
Local $gTreeview_New = GUICtrlCreateTreeView(0 + $hGUI_OffsetX, 10 + $hGUI_OffsetY, 200, 250) ;Erstellt eine Treelist
GUICtrlSetBkColor($gTreeview_New, "0x" & Int(StringRight($GUIThemeColor, 6)) + 052005) ;setzt die Hintergrundfarbe
GUICtrlSetColor($gTreeview_New, $ButtonTextColor) ;setzt die Textfarbe
GUICtrlSetFont($gTreeview_New, 11) ;setzt die Textgröße

Local $gLabelName_New = GUICtrlCreateLabel("Erorr Name: ", 210 + $hGUI_OffsetX, 10 + $hGUI_OffsetY, 150, 25) ;Erstellt ein Label
GUICtrlSetColor($gLabelName_New, $ButtonTextColor) ;setzt die Textfarbe
GUICtrlSetFont($gLabelName_New, 13) ;setzt die Textgröße

Local $gEditName_New = GUICtrlCreateEdit("",210 + $hGUI_OffsetX, 35 + $hGUI_OffsetY, 260, 25, BitOR($ES_AUTOHSCROLL, $ES_AUTOVSCROLL), 0) ;Erstellt ein Edit
GUICtrlSetBkColor($gEditName_New, "0x" & Int(StringRight($GUIThemeColor, 6)) + 252525) ;setzt die Hintergrundfarbe
GUICtrlSetColor($gEditName_New, $ButtonTextColor) ;setzt die Textfarbe
GUICtrlSetFont($gEditName_New, 13, Default, Default, "Courier New") ;setzt die Textgröße und die Schrifftart

Local $gLabelBeschreibung_New = GUICtrlCreateLabel("Description: ", 210 + $hGUI_OffsetX, 70 + $hGUI_OffsetY, 150, 25) ;Erstellt ein Label
GUICtrlSetColor($gLabelBeschreibung_New, $ButtonTextColor) ;setzt die Textfarbe
GUICtrlSetFont($gLabelBeschreibung_New, 13) ;setzt die Textgröße

Local $gEditBeschreibung_New = GUICtrlCreateEdit("",210 + $hGUI_OffsetX, 95 + $hGUI_OffsetY, 260, 100, BitOR($ES_WANTRETURN, $ES_AUTOHSCROLL, $ES_AUTOVSCROLL), 0) ;Erstellt ein Edit
GUICtrlSetBkColor($gEditBeschreibung_New, "0x" & Int(StringRight($GUIThemeColor, 6)) + 252525) ;setzt die Hintergrundfarbe
GUICtrlSetColor($gEditBeschreibung_New, $ButtonTextColor) ;setzt die Textfarbe
GUICtrlSetFont($gEditBeschreibung_New, 13, Default, Default, "Courier New") ;setzt die Textgröße und die Schrifftart

Local $gSaveButton_New = _Metro_CreateButton("Save", 210 + $hGUI_OffsetX, 210 + $hGUI_OffsetY, 260, 50) ;Erstellt einen Button

$root = _GUICtrlTreeView_AddChild($gTreeview_New, "", "Datenbank") ;definiert den Pfad, aus dem, die Ordner aufgelistet werden sollen
_SearchFolder(@ScriptDir & "\Datenbank", $root, False, Default, $gTreeview_New) ;Startet die auflistung der Datein und Ordnern und ergänzt sie in der Treeview

Alles anzeigen

vielen Dank schon mal

Gruß

Flo

**water**

Habe keine Ahnung in diese Himmelsrichtung, aber im engl. Wiki gibt es ein Tutorial dazu: https://www.autoitscript.com/wiki/Managing_Multiple_GUIs

Floooooo24

So wirklich hat mir das leider nicht geholfen, aber danke.

gibt es noch weitere Ideen was ich falsch gemacht haben könnte?

BananaJoe

Wenn ich mit 2 GUIs arbeite verwende ich immer @SW_DISABLE/@SW_ENABLE und @SW_RESTORE

Floooooo24

Ich habe @SW_Show/@SW_Hide verwendet, da die zweite GUI komplett verschwinden soll, was @SW_Disable nicht macht, wenn ich es richtig verstanden habe

**BugFix**

Zitat von Floooooo24

_Metro_CreateButton

Ich kenne die Funktion nicht, vermute aber mal in der Richtung den Fehler.

Wenn das Erstellen von Control in eine Funktion ausgelagert wird, die selbst das Handle des Fensters anfordert, für das sie aktiv werden soll (ist ja sinnvoll), muss gewährleistet werden dass in der Funktion Folgendes zu finden ist:

AutoIt

Func _CreateCtrl($hGui,.....)
    Local $hOld = GuiSwitch($hGui)
    ...
    ...
    GuiSwitch($hOld)
EndFunc

Nur so ist gewährleistet, dass die Control auch sicher auf dem gewünschten Fenster erstellt werden.

**autoBert**

Zitat von BugFix

Ich kenne die Funktion nicht, vermute aber mal in der Richtung den Fehler.

Zitat von BugFix

Nur so ist gewährleistet, dass die Control auch sicher auf dem gewünschten Fenster erstellt werden.

Dem kann ich mich nur anschliessen, denn möglicherweise hat der Autor der verwendeten UDF (Metro Gui?) leicht geschludert. Wenn der Autor bekannt solltest du also Kontakt mit ihm aufnehmen. Da du ja auch in https://www.autoitscript.com/forum/topic/20…bugging-to-one/ suchst ein kleines :thumbdown:

mfg (auto)Bert

Floooooo24

hi,

Danke für die hilfe.

Ich hab vergessen, zu erwähnen, das ich die UDF verwende. Eure Vermutung, das dort GuiSwitch( fehlt ist richtig. es müsste doch ausreichen, wenn ich das selbst in meinem Code mache richtig?GrußFlo

**BugFix**

Zitat von Floooooo24

es müsste doch ausreichen, wenn ich das selbst in meinem Code mache richtig?

Ja, vor dem Aufruf der UDF-Funktion und danach zurück. Ob der Fehler darin begründet liegt ist nur eine Vermutung, aber du kannst zumindest weiter eingrenzen.

Was natürlich auch sein kann:

Du verwendest für deine Ctrl x und y und für Breite u. Höhe nimmst du die Default-Werte. DAS ist immer eine schlechte Idee, da du dann keine Ahnung hast, welche Dimensionen deine Ctrl verwenden und ob sie nicht auch über den Fensterrand hinausragen.

Floooooo24

Ich werde es so bald ich kann ausprobieren.

Die _Metro_CreateGUI weicht etwas von der GUICreate ab:

Code

; #FUNCTION# ====================================================================================================================
; Name ..........: _Metro_CreateGUI
; Description ...: Creates a modern borderless GUI with the colors of the selected theme.
; Syntax ........: _Metro_CreateGUI($Title, $Width, $Height[, $Left = -1[, $Top = -1[, $AllowResize = False[, $ParentGUI = ""]]]])
; Parameters ....: $Title               - Title of the window
;                  $Width               - Width
;                  $Height              - Height
;                  $Left                - [optional] Window pos X. Default is -1.
;                  $Top                 - [optional] Window pos Y. Default is -1.
;                  $AllowResize         - [optional] True/False. Default is False. ;Enables resizing + drag move for the gui.
;                  $ParentGUI           - [optional] Handle to the parent gui. Default is "".
; Return values .: Handle to the created gui
; Example .......: _Metro_CreateGUI("Example", 500, 300, -1, -1, True)
; ===============================================================================================================================
Func _Metro_CreateGUI($Title, $Width, $Height, $Left = -1, $Top = -1, $AllowResize = False, $ParentGUI = "")

Alles anzeigen

MojoeB

Ich glaube du rufst eine gui in der funktion gui auf.

Ich habe dir mal ein kleines beispiel erstellt wie ich das mache um bei großen Projekten etwas die Übersicht zu wahren.

Vielleicht hilft dir das.

C

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <array.au3>
Global $01, $02
$01 = gui()
GUISetState(@SW_SHOW, $01)
$02 = gui2()
$handels = _array_handels()
$btns = _array_btns()
$testarray2 = LESE_CTRL_($btns)

_ArrayDisplay($handels, 'test handels')
_ArrayDisplay($testarray2, 'test btns')


While (1)
    $amsg = GUIGetMsg($GUI_EVENT_ARRAY)
    Switch $amsg[1]
        Case $handels[0]
            Switch $amsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $btns[0]
                    MsgBox(0, 'ÄÄ', 'GUI2 öffnen')
                    GUISetState(@SW_SHOW, $handels[1])
            EndSwitch

        Case $handels[1]
            Switch $amsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $btns[1]
                    MsgBox(0, 'ÄÄ', 'GUI1 öffnen und 2 schließen')
                    GUISetState(@SW_HIDE, $handels[1])
                    GUISetState(@SW_SHOW, $handels[0])
            EndSwitch
    EndSwitch
WEnd

Func gui()
    Local $array[0]
    Local $aNames[0]
    Local $aRead[0]
    _ArrayAdd($array, GUICreate("Form1", 574, 340, 192, 124))
    _ArrayAdd($aNames, 'HANDEL')
    _ArrayAdd($aRead, GUICtrlRead($array[0], 1))
    _ArrayAdd($array, GUICtrlCreateLabel("GUI 1", 48, 136, 32, 17))
    _ArrayAdd($aNames, 'LABEL')
    _ArrayAdd($aRead, GUICtrlRead($array[1], 1))
    _ArrayAdd($array, GUICtrlCreateButton("Button1", 256, 176, 137, 33))
    _ArrayAdd($aNames, 'BTN')
    _ArrayAdd($aRead, GUICtrlRead($array[2], 1))
    GUISetState(@SW_HIDE)
    $array = element_list($array, $aNames, $aRead, 4)
    Return $array
EndFunc   ;==>gui

Func gui2()
    Local $array[0]
    Local $aNames[0]
    Local $aRead[0]
    _ArrayAdd($array, GUICreate("Form2", 574, 340, 192, 124))
    _ArrayAdd($aNames, 'HANDEL')
    _ArrayAdd($aRead, GUICtrlRead($array[0], 1))
    _ArrayAdd($array, GUICtrlCreateLabel("GUI 2", 48, 136, 32, 17))
    _ArrayAdd($aNames, 'LABEL')
    _ArrayAdd($aRead, GUICtrlRead($array[1], 1))
    _ArrayAdd($array, GUICtrlCreateButton("Button2", 256, 176, 137, 33))
    _ArrayAdd($aNames, 'BTN')
    _ArrayAdd($aRead, GUICtrlRead($array[2], 1))
    GUISetState(@SW_HIDE)
    $array = element_list($array, $aNames, $aRead, 4)
    Return $array
EndFunc   ;==>gui2




Func element_list($array, $aArray01, $aArray02, $iO)
    $iCount = UBound($array)
    Local $a2Dresult[$iCount][$iO]
    For $i = 0 To $iCount - 1 Step 1
        $a2Dresult[$i][0] = $array[$i]
        $a2Dresult[$i][1] = $aArray01[$i]
        $a2Dresult[$i][2] = $aArray02[$i]
        $a2Dresult[$i][3] = $i
    Next
    Return $a2Dresult
EndFunc   ;==>element_list


Func _create_array_($array, $mArray, $string, $opt = 0)
    Local $cont[0]
    For $i = 0 To UBound($array) - 1 Step 1
        $sArray = $array[$i][1]
        If $sArray = $string Then
            _ArrayAdd($cont, $array[$i][0])
        EndIf
    Next
    If $opt = 1 Then
        For $i = 0 To UBound($mArray) - 1 Step 1
            _ArrayAdd($cont, $mArray[$i])
        Next
    EndIf
    Return ($cont)
EndFunc   ;==>_create_array_
Func _array_handels()
    Local $aArray[0]
    $aArray = _create_array_($02, '', 'HANDEL', 0)
    $aArray = _create_array_($01, $aArray, 'HANDEL', 1)
    Return $aArray
EndFunc   ;==>_array_handels

Func _array_btns()
    Local $aArray[0]
    $aArray = _create_array_($02, '', 'BTN', 0)
    $aArray = _create_array_($01, $aArray, 'BTN', 1)
    Return $aArray
EndFunc   ;==>_array_btns




Func LESE_CTRL_($array)
    Local $sArray[0]
    For $i = 0 To UBound($array) - 1 Step 1
        $string = $array[$i]
        _ArrayAdd($sArray, GUICtrlRead($array[$i], 1))
    Next
    Return $sArray
EndFunc   ;==>LESE_CTRL_

Alles anzeigen

**autoBert**

MojoeB : Dieser "Mixed Mode" erfordert Konzentration und Disziplin. Manche Profi's meinen deshalb nur für Sie und Ihresgleichen Farben geschmückten zu Erlauben. Von mir jedenfalls ein . Wenn du jetzt noch Profis wie BugFix , Oscar oder Andy dazu bringst das Beispiel aufzuHübschen hast du SchlagArtig eine ganze Reihe:

mfg (auto)Bert

**BugFix**

Zitat von autoBert

das Beispiel aufzuHübschen

Was stellst du dir darunter vor?

Es ist ein Bsp. zu einer konkreten Konstellation, somit nicht direkt für eine allgemeingültige UDF nutzbar.

Aber was am Inhalt verbessert werden kann:

- Array-Funktionen sind nicht nötig. Die Anzahl der Elemente sind bekannt, das Array kann somit mit erforderlicher Zahl deklariert und per Indexierung belegt werden.

- Speichern der Ctrl-Namen ist nicht erforderlich, kann bei Bedarf über die ID abgefragt werden (s. hier: GuiCtrlInfo.au3)

- Ich würde z.B. ein gemeinsames 2D-Array für hWnd und ID führen: [[hWnd_1,ID_1], [hWnd_1,ID_2],..,[hWnd_1,ID_n],[hWnd_2,ID_1], [hWnd_2,ID_2],..,[hWnd_2,ID_n]] , aber das ist Geschmackssache

Velted

Moin,

Dein Codeschnipsel ist leider nicht wirklich hilfreich.

Die _Metro_Create-Funktionen arbeiten wie die GUICtrlCreate-Funktionen mit dem 'aktuellen' GUI-Fenster. Deshalb gibt es auch kein internes GUISwitch(). Wenn ein Fensterhandle gebraucht wird, wird das mit einer internen Funktion geholt:

AutoIt

Func GetCurrentGUI() ;Thanks @binhnx
    Local $dummyCtrl = GUICtrlCreateLabel("", 0, 0, 0, 0)
    Local $hCurrent = _WinAPI_GetParent(GUICtrlGetHandle($dummyCtrl))
    GUICtrlDelete($dummyCtrl)
    Return $hCurrent
EndFunc   ;==>GetCurrentGUI

Wenn also normale oder auch Metro-Controls im falschen Fenster landen. kann das nur daran liegen, dass sich zwischen dem Erstellen des Zielfensters und dem Hinzufügen von Controls das 'aktuelle' Fenster geändert hat. Das geht allerdings nur mit einem GUISwitch(), GUICreate() und vielleicht auch (sollte jedenfalls) GUIDelete(). Ich halte das deshalb für einen Designfehler.

MojoeB

Zitat von BugFix

- Array-Funktionen sind nicht nötig. Die Anzahl der Elemente sind bekannt, das Array kann somit mit erforderlicher Zahl deklariert und per Indexierung belegt werden.
- Speichern der Ctrl-Namen ist nicht erforderlich, kann bei Bedarf über die ID abgefragt werden (s. hier: GuiCtrlInfo.au3)
- Ich würde z.B. ein gemeinsames 2D-Array für hWnd und ID führen: [[hWnd_1,ID_1], [hWnd_1,ID_2],..,[hWnd_1,ID_n],[hWnd_2,ID_1], [hWnd_2,ID_2],..,[hWnd_2,ID_n]] , aber das ist Geschmackssache

Hey Bugfix habs mir mal GuiCtrlInfo.au3 grad angesehen ich glaub das wird mir für die Zukunft eine menge zeit sparen

Zitat von autoBert

Dieser "Mixed Mode" erfordert Konzentration und Disziplin.

JA das hab ich gemerkt :D, danke für

gmmg

Hallo Floooooo24,

hast du mal versucht die $ParentGUI anzugeben?

_Metro_CreateGUI($Title, $Width, $Height[, $Left = -1[, $Top = -1[, $AllowResize = False[, $ParentGUI = ""]]]])

; #FUNCTION# ====================================================================================================================

; Name ..........: _Metro_CreateGUI

; Description ...: Creates a modern borderless GUI with the colors of the selected theme.

; Syntax ........: _Metro_CreateGUI($Title, $Width, $Height[, $Left = -1[, $Top = -1[, $AllowResize = False[, $ParentGUI = ""]]]])

; Parameters ....: $Title - Title of the window

; $Width - Width

; $Height - Height

; $Left - [optional] Window pos X. Default is -1.

; $Top - [optional] Window pos Y. Default is -1.

; $AllowResize - [optional] True/False. Default is False. ;Enables resizing + drag move for the gui.

; $ParentGUI - [optional] Handle to the parent gui. Default is "".

; Return values .: Handle to the created gui

; Example .......: _Metro_CreateGUI("Example", 500, 300, -1, -1, True)

; ===============================================================================================================================

Benutze selbst immer mal die _Metro_CreateGUI, habe aber bisher keine 2 GUI's in einem Script benötigt.

Gruß gmmg

Floooooo24

Guten Tag zusammen,

Danke für eure ganze Hilfen. Die $ParentGUI habe ich ergänz, aber ich glaube tatsächlich, dass das Problem wo danders liegt:

Ich habe einen Dbugger in das Programm eingebunden, welcher wohl ein paar Probleme macht, zumindest in einem anderen skript, bei dem ich durch zufall drauf gekommen bin.

Dort sind beim verwenden von GUICtrlSetGraphic() immer wieder Programmzeilen nicht richtig ausgeführt worden.

hier fehlt zum Beispiel ein Bezier und eine Line, welche dann durch das schließen der Form ersetzt wurde.

Erst als ich den Debugger am Anfang nicht stoppen lies gab es keine Probleme mehr.

Kennt ihr einen guten Debugger, der nicht solche probleme hat?

Gruß Flo