Button / Icons aus DB bzw. Array erstellen

gmmg

Hallo Zusammen,

ich bin aktuell am umstellen unseres IT-Helpdesk Tools. Ziel der Umstellung ist es die Icons dynamisch aus einem Array bzw. Datenstring zu erstellen. Die Daten dafür kommen aus einer Access DB.

Aktuell wird für jedes Icon mit der Zeile "GUICTRLCreateIcon" einzeln erstellt.

AutoIt

$ico01 = GUICtrlCreateIcon(@ScriptDir & "\bin\icons\Prog1.ico",25, $ico_left, 70, 40, 40)
$label01 = GUICtrlCreateLabel("Prog1",$label_left, 115,$label_length,25)
GUICtrlSetTip($ico01, "Prog1")
GUICtrlSetTip($label01, "Prog1")

Maximal sollen es 12 oder 13 Icons werden.

Hier mal ein Bild der GUI

Ich bin der Meinung es gab da mal ein Beispiel für eine dynamische Erstellung, ich finde aber grad nichts dazu.

Hat das jemand schonmal umgesetzt?

Gruß gmmg

gmmg

Im engl. Forum habe ich ein Beispiel für die Button Erstellung gefunden.

Mal sehen, ob ich damit weiter komme.

C

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

; Create an array to hold the button data and the control Ids
Global $aButtons[5][2]
; Add the data
For $i = 0 To 4
    $aButtons[$i][0] = "Button " & $i & " pressed"
Next

$hGUI = GUICreate("Test", 500, 500)

; Create the buttons and add their ControlIDs to the array
For $i = 0 To UBound($aButtons) - 1
    $aButtons[$i][1] = GUICtrlCreateButton("Button " & $i, 10, 10 + (40 * $i), 80, 30)
Next

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        ; Was the ControlID a button?
        Case Else
            For $i = 0 To UBound($aButtons) - 1
                If $iMsg = $aButtons[$i][1] Then
                    ; If so then display the data
                    MsgBox($MB_SYSTEMMODAL, "Button Pressed", $aButtons[$i][0])
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

Alles anzeigen

gmmg

Habe schon eine erste Version gebaut, funktioniert aber noch nicht so wie gewünscht.

Hat noch einer eine Idee dazu?

AutoIt

#AutoIt3Wrapper_UseX64=y

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>
#include <D:\Scripte\ArrayMultiColSort\ArrayMultiColSort.au3>

;--------- MSAccess DB ------------
$dbname = @ScriptDir & "\bin\db\Helpdesk.accdb"

$tblname001 = "Systeme"

Local $Connection = _Start_Connection($dbname & ";")

Local $GetData = _Get_Records("SELECT * FROM " & $tblname001 & ";")

_Close_Connection()
;----------------------------------
;----- Sort Array nach Col3 -------
;sortiere nach Col3
Global $aSortData[][] = [ _
        [3, 0]]

; Sort and display array
_ArrayMultiColSort($GetData, $aSortData)
;_ArrayDisplay($GetData)
;----------------------------------

$aIcons = $GetData
$aLabels = $GetData

For $a = 0 To UBound ($GetData) -1
       ;MsgBox(0,"", $GetData[$i][1])
    $aIcons[$a][0] = $GetData[$a][1]
    $aLabels[$a][0] = $GetData[$a][1]
Next


$hGUI = GUICreate("GUI Test", 800, 720)

; Create the buttons and add their ControlIDs to the array
For $b = 0 To UBound($aIcons) - 1

    $aIcons[$b][1] = GUICtrlCreateIcon(@ScriptDir & "\bin\icons\" & $aIcons[$b][2],25, 10 + (60 * $b), 70, 40, 40)
    GUICtrlSetTip($aIcons[$b][1], $aIcons[$b][0])

Next

For $c = 0 To UBound($aLabels) - 1

    $aLabels[$c][1] = GUICtrlCreateLabel($aLabels[$c][1], 25 + (60 * $c), 115, 60, 30)
    GUICtrlSetTip($aLabels[$c][1], $aLabels[$c][0])

Next


GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        ; Was the ControlID a button?
;~         Case Else
;~             For $x = 0 To UBound($aIcons) - 1
;~                 If $iMsg = $aIcons[$x][1] Then
;~                     ; If so then display the data
;~                     MsgBox(0, "Label clicked", $aIcons[$x][0])
;~                     ; No point in looking further
;~                     ExitLoop
;~                 EndIf
;~             Next
    EndSwitch

WEnd

Alles anzeigen

Gruß gmmg

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi gmmg ,

ist der zweite Parameter iconName, der Funktion GUICtrlCreateIcon() gewollt die Zahl 25 (in Zeile 44) oder nicht?

Ansonsten ist es auch noch hilfreich, wenn du uns die beiden UDFs noch zu Verfügung stellst, damit man auch wirklich testen kann 😉 .

AutoIt

#include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>
#include <D:\Scripte\ArrayMultiColSort\ArrayMultiColSort.au3>

Viele Grüße
Sven

gmmg

Hallo Sven,

bei dem Create Icon kommt die Nummer daher, dass ich die Icons in einer DLL gespeichert hatte.

Die udf 'S gibt es hier im engl. Forum

ArrayMultiColSort -New Release 06 April 2019

[New Release] - 06 April 2019 Added: Error-checking for sensible column numbers in the $aSortData array, with an additional error status.…

www.autoitscript.com

Yet another Access UDF( but different - *.accdb only)

Hi all,This is an UDF for working with Access(2007 above) databases. I would like to say thanks to @spudw2k for his wonderful ADODB udf. That is my…

www.autoitscript.com

Gruß gmmg

Velted

Zitat von gmmg

Habe schon eine erste Version gebaut, funktioniert aber noch nicht so wie gewünscht.

Moin, wie wäre es denn gewünscht?

Geht es nur darum eine variable Zahl von Icons (mit einer bekannten Maximalzahl) und zugehörigen Texten in zwei Reihen neben/untereinander anzuzeigen (wobei die Icon-IDs und der gemeinsame Text für 'Unterschrift' und Tooltip aus einer Access-DB geladen werden)?

Und, wie sollen sie eingelesenen Werte sortiert werden (bzw. was steht in den Spalten 0 -3)?

gmmg

Hallo Velted,

genau, ich möchte die X Anzahl an Icons Nebeneinander anzeigen + die Labels entsprechend unter dem jeweiligen Icon.

Label Texte, der Icon Name und der ToolTip kommen aus der DB, wobei der Tooltip im ersten Step gleich dem Label Text sein kann.

Was in meinem Beispiel nicht funktioniert, beim Scriptstart wird gleich die MsgBox(0, "Label clicked") angezeigt, obwohl ich selbst ja noch auf kein Label oder Icon geklickt habe.

In der Access DB habe ich für die Sortierung einfach eine Spalte mit Zahlenwerten 01-13 die ja dann mit dem ArraySort Absteigend sortiert werden.

Code

_ArrayMultiColSort($GetData, $aSortData)

so sieht die Access DB aus

System ist dann = Label Text und Tooltipp

Gruß gmmg

gmmg

Ich habe in die Access DB jetzt noch ein Spalte für die Label ID bzw. Icon ID aufgenommen und schreibe dann die Werte beim erstellen in diese Spalte.

$aLabels[$i][4]

$aIcons[$i][4]

Das anklicken der Icon und Label funktioniert jetzt auch. Hier war der Fehler, dass in der DB nicht alle Felder mit Icon Werten gefüllt waren, somit 0 Werte drin standen.

Spoiler anzeigen

AutoIt

#AutoIt3Wrapper_UseX64=y

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>
#include <D:\Scripte\ArrayMultiColSort\ArrayMultiColSort.au3>

;--------- MSAccess DB ------------
$dbname = @ScriptDir & "\bin\db\Helpdesk.accdb"

$tblname001 = "Systeme"

Local $Connection = _Start_Connection($dbname & ";")

Local $Array_Systeme = _Get_Records("SELECT * FROM " & $tblname001 & ";")

_Close_Connection()
;----------------------------------
;----- Sort Array nach Col3 -------
;sortiere nach Col3
Global $aSortData[][] = [ _
        [3, 0]]

; Sort and display array
_ArrayMultiColSort($Array_Systeme, $aSortData)
;_ArrayDisplay($Array_Systeme)
;----------------------------------

Local $aIcons = $Array_Systeme
Local $aLabels = $Array_Systeme

$hGUI = GUICreate("GUI Test", 800, 720)

; Create the buttons and add their ControlIDs to the array
For $i = 0 To UBound($Array_Systeme) - 1

    $aIcons[$i][4] = GUICtrlCreateIcon(@ScriptDir & "\bin\icons\" & $Array_Systeme[$i][2],"", 11 + (60 * $i), 70, 40, 40)
    GUICtrlSetTip($aIcons[$i][4], $Array_Systeme[$i][1])

     ;$aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 20 + (59 * $i), 115, 60, 30)
     $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 10 + (60 * $i), 115, 60, 30,0x01) ;center Txt
     GUICtrlSetTip($aLabels[$i][4], $Array_Systeme[$i][1])

Next

;_ArrayDisplay($aIcons)
;_ArrayDisplay($aLabels)

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        ; Was the ControlID a button?
        Case Else
            For $x = 0 To UBound($Array_Systeme) - 1
                If $iMsg = $aLabels[$x][4] or $iMsg = $aIcons[$x][4] Then
                    ; If so then display the data
                    MsgBox(0, "Label clicked", $aLabels[$x][1])
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

Alles anzeigen

Hier mal mit Fixer Ausrichtung der Labels

AutoIt

#AutoIt3Wrapper_UseX64=y

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>
#include <D:\Scripte\ArrayMultiColSort\ArrayMultiColSort.au3>

;--------- MSAccess DB ------------
$dbname = @ScriptDir & "\bin\db\Helpdesk.accdb"

$tblname001 = "Systeme"

Local $Connection = _Start_Connection($dbname & ";")

Local $Array_Systeme = _Get_Records("SELECT * FROM " & $tblname001 & ";")

_Close_Connection()
;----------------------------------
;----- Sort Array nach Col3 -------
;sortiere nach Col3
Global $aSortData[][] = [ _
        [3, 0]]

; Sort and display array
_ArrayMultiColSort($Array_Systeme, $aSortData)
;_ArrayDisplay($Array_Systeme)
;----------------------------------

Local $aIcons = $Array_Systeme
Local $aLabels = $Array_Systeme

$hGUI = GUICreate("GUI Test", 800, 720)

; Create the buttons and add their ControlIDs to the array
For $i = 0 To UBound($Array_Systeme) - 1

    $aIcons[$i][4] = GUICtrlCreateIcon(@ScriptDir & "\bin\icons\" & $Array_Systeme[$i][2],"", 20 + (60 * $i), 70, 40, 40)
    GUICtrlSetTip($aIcons[$i][4], $Array_Systeme[$i][1])

    ;$aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 25 + (60 * $i -4), 115, 60, 30)

    IF $i = 0 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 30 + (60 * $i), 115, 60, 30)
    IF $i = 1 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 30 + (60 * $i), 115, 60, 30)
     IF $i = 2 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 25 + (60 * $i), 115, 60, 30)
    IF $i = 3 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 26 + (60 * $i), 115, 60, 30)
    IF $i = 4 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 20 + (60 * $i), 115, 60, 30)
    IF $i = 5 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 20 + (60 * $i), 115, 60, 30)
    IF $i = 6 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 22 + (60 * $i), 115, 60, 30)
    IF $i = 7 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 24 + (60 * $i), 115, 60, 30)
    IF $i = 8 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 20 + (60 * $i), 115, 60, 30)
    IF $i = 9 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 22 + (60 * $i), 115, 60, 30)
    IF $i = 10 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 30 + (60 * $i), 115, 60, 30)
    IF $i = 11 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 25 + (60 * $i), 115, 60, 30)
    IF $i = 12 Then $aLabels[$i][4] = GUICtrlCreateLabel($Array_Systeme[$i][1], 17 + (60 * $i), 115, 60, 30)

     GUICtrlSetTip($aLabels[$i][4], $Array_Systeme[$i][1])

Next

_ArrayDisplay($aIcons)
_ArrayDisplay($aLabels)

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        ; Was the ControlID a button?
        Case Else
            For $x = 0 To UBound($Array_Systeme) - 1
                If $iMsg = $aLabels[$x][4] or $iMsg = $aIcons[$x][4] Then
                    ; If so then display the data
                    MsgBox(0, "Label clicked", $aLabels[$x][1])
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

Alles anzeigen

Gruß gmmg

Velted

Moin,

danke für die Erläuterungen. Das bringt mich auf ein paar Ideen:

Kann man sich die Werte aus der Access-DB nicht schon sortiert nach der Spalte "Sortierung" ausgeben lassen? SQL kennt ja die Option SELECT ... ORDER BY ...;.
Wenn nicht, brauchst Du jedenfalls nicht die Funktion _ArrayMultiColSort(), weil Du ja nur nach einer Spalte sortierst. Das 'normale' _ArraySort() mit $iSubItem = 3 sollte reichen.
Für die Labels verwendest Du eine Folge von Ifs, deren Anweisung sich nur in der X-Position unterscheiden. Es sollte möglich sein, die erforderliche Maximalbreite zu ermitteln und die Texte mit dem Stil $SS_CENTER = 0x01 zu zentrieren. Dann kannst Du auch für die Labels eine konstante Ausgangsposition verwenden und sie wie die Icons handhaben.

gmmg

Moin @Velved,

Stimmt, mit der SQL OrderBY Option klappt es auch. Das ändere ich gleich mal ab.

Local $Array_Systeme = _Get_Records("SELECT * FROM " & $tblname001 & " Order By Sortierung ASC " & ";")

Und für die Labels hatte ich das bereits mit dem $SS_Center=0x01 so umgesetzt, das passt jetzt auch.

Gruß gmmg

Velted

Gut. Ich habe das "Hier mal mit Fixer Ausrichtung der Labels" als "Hier mal mit gefixter Ausrichtung der Labels" gelesen und mich auf das falsche Skript konzentriert.

Ist jetzt alles so, wie Du es wolltest?

gmmg

Ja, das passt.

Habe aber noch eine ToDo. Ist es möglich die Schriftgröße zu ändern, wenn ich die Maus über das Icon oder Label bewege?

Wie ein Hover effekt.

**BugFix**

Zitat von gmmg

Habe aber noch eine ToDo. Ist es möglich die Schriftgröße zu ändern, wenn ich die Maus über das Icon oder Label bewege?

Der einfachste Weg:

Erstelle zwei Label übereinander, mit jeweils unterschiedlicher Schriftgröße. Das zm Hovern setzt du auf HIDE.

GUIGetCursorInfo liefert die ID des Ctrl über dem die Maus ist, damit kannst du zwischen den Ctrl SHOW/HIDE switchen.

gmmg

Hallo BugFix,

mit den dynamisch erzeugten Label und Icons, habe ich es noch nicht geschafft, die Infos mit GUIGetCursorInfo(4) auszulesen.

Als Grundlage dient ja der Quelltext aus Post2. Ich habe hier bestimmt einen Denkfehler.

Gruß gmmg

gmmg

Den ToolTip kann ich mit folgendem Beispiel manipulieren.

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>

; Create an array to hold the button data and the control Ids
Global $aLabels[5][2]
; Add the data
For $i = 0 To 4
    $aLabels[$i][0] = "Label " & $i & " clicked"
Next

$hGUI = GUICreate("Test", 500, 500)

; Create the Lables and add their ControlIDs to the array
For $i = 0 To UBound($aLabels) - 1
    ;$aLables[$i][1] = GUICtrlCreateButton("Button " & $i, 10, 10 + (40 * $i), 80, 30)
    $aLabels[$i][1] = GUICtrlCreateLabel("Label " & $i, 10 + (60 * $i), 20, 60, 30, 0x01)
    GUICtrlSetTip($aLabels[$i][1], "Test Label " & $i)
Next

GUISetState()


While 1

    $GGCI = GUIGetCursorInfo($hGUI)
    If $GGCI[4] = 0 Then GUICtrlSetTip($aLabels[1][1], "Test Label - 1 - 0815")

    $iMsg = GUIGetMsg()

    Switch $iMsg

        Case $GUI_EVENT_CLOSE
            Exit
        ; Was the ControlID a button?

        Case Else
            For $i = 0 To UBound($aLabels) - 1
                If $iMsg = $aLabels[$i][1] Then
                    ; If so then display the data
                    MsgBox($MB_SYSTEMMODAL, "Label clicked", $aLabels[$i][0])
                    ConsoleWrite($aLabels[$i][0])
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

Alles anzeigen

gmmg

für das 2 label klappt die Änderung jetzt auch. Lässt sich aber sicherlich noch optimieren oder in eine Funktion packen.

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <Array.au3>

; Create an array to hold the button data and the control Ids
Global $aLabels1[5][2]

; Add the data
For $i = 0 To 4
    $aLabels1[$i][0] = "Label " & $i & " clicked"
Next

$hGUI = GUICreate("Test", 500, 500)

; Create the Lables and add their ControlIDs to the array
For $i = 0 To UBound($aLabels1) - 1
    ;$aLables[$i][1] = GUICtrlCreateButton("Button " & $i, 10, 10 + (40 * $i), 80, 30)
    $aLabels1[$i][1] = GUICtrlCreateLabel("Label " & $i, 10 + (60 * $i), 20, 60, 30, 0x01)
    GUICtrlSetTip($aLabels1[$i][1], "Test Label " & $i)

    $l1 = 0

Next

GUISetState()


While 100

    $GGCI = GUIGetCursorInfo($hGUI)

    If $GGCI[4] = $aLabels1[1][1] Then
        If $l1 = 0 Then
            GUICtrlSetTip($aLabels1[1][1], "Test Label - 1 - 0815")
            GUICtrlSetFont($aLabels1[1][1], 9, 700, 0, "Arial")
            $l1 = 1
        EndIf

    Else
        If $l1 = 1 Then

            GUICtrlSetFont($aLabels1[1][1], 9, 250, 0, "Arial")
            $l1 = 0
        EndIf

    EndIf

    $iMsg = GUIGetMsg()

    Switch $iMsg

        Case $GUI_EVENT_CLOSE
            Exit
        ; Was the ControlID a button?

        Case Else
            For $i = 0 To UBound($aLabels1) - 1
                If $iMsg = $aLabels1[$i][1] Then
                    ; If so then display the data
                    MsgBox($MB_SYSTEMMODAL, "Label clicked", $aLabels1[$i][0])
                    ConsoleWrite($aLabels1[$i][0])
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

Alles anzeigen

Gruß gmmg

**BugFix**

Ich hatte gerade mal erstellt: Maus über Button - Label darunter wird Text vergrößert:

AutoIt

Global $aButtonLabel[5][3] = [ _
    [0,0,'Text 1'],[0,0,'Text 2'],[0,0,'Text 3'],[0,0,'Text 4'],[0,0,'Text 5']]
Global $diff = 40, $y = 10, $w = 30, $h = 30, $iFontSize = 12

$hGui = GUICreate('Test')

For $i = 0 To UBound($aButtonLabel) -1
    $aButtonLabel[$i][0] = GUICtrlCreateButton('', 40 + $i*$diff + $i*$w, $y, $w, $h)
    $aButtonLabel[$i][1] = GUICtrlCreateLabel($aButtonLabel[$i][2], 20 + $i*$diff + $i*($w), $y+$h+10, $w+40, 17, 0x01) ; $SS_CENTER
Next

GUISetState()

While True
    _Hover(GUIGetCursorInfo()[4])
    Switch GUIGetMsg()
        Case -3
            Exit
    EndSwitch
WEnd


Func _Hover($_ID)
    Local Static $iLastHover = -1
    Local $iHover = -1
    If ($iLastHover > -1) And $aButtonLabel[$iLastHover][0] = $_ID Then Return
    For $i = 0 To UBound($aButtonLabel) -1
        If $_ID = $aButtonLabel[$i][0] Then ; Maus über Button
            $iHover = $i
            ExitLoop
        EndIf
    Next
    If $iHover > -1 Then
        If $iLastHover <> $iHover Then
            If $iLastHover > -1 Then GUICtrlSetFont($aButtonLabel[$iLastHover][1], Default)
            GUICtrlSetFont($aButtonLabel[$iHover][1], $iFontSize)
            $iLastHover = $iHover
        EndIf
    Else
        If $iLastHover > -1 Then
            GUICtrlSetFont($aButtonLabel[$iLastHover][1], Default)
            $iLastHover = -1
        EndIf
    EndIf
EndFunc

Alles anzeigen

gmmg

BugFix : Vielen Dank.

Ich versuche das mal in mein Script zu übernehmen.

Gruß gmmg

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)