AutoIt-Hackathon #3 "alte Zeiten"

**Schnuffel**

Hallo und herzlich willkommen zum AutoIt-Hackathon #3

Alles was ihr zur Teilnahme braucht, ist das Script, das unten im Code-Block eingefügt ist.
Kopiert es vollständig in euren Editor und lest euch die Anleitung genau durch.

Ihr könnt eigene Funktionen erstellen, Globale Variablen deklarieren usw ...

Gewonnen hat, dessen Script die Tests zu 100% bewältigt und am schnellsten ist.

Postet eure Lösung hier in diesen Thread. Abschreiben bringt nix, wenn die Lösung richtig ist.

Klinkt euch gerne auf Discord mit ein (am Besten mit Audio, so könnt ihr weiter coden und wir können euch schwitzen hören)

Ich wünsche allen Teilnehmern
happy coding

PS: Für künftige Hackathons ist es hilfreich zu wissen, wann die meisten Interessierten Zeit haben.
Tragt euch bei Interesse in dieses Tool ein, dann kann ich planen. Danke

Abfrage Zeitfenster Hackathon - nuudel

Trage hier deine möglichen Zeiten ein, zu denen du an einem Live-Hackathon teilnehmen könntest. Der Zeitraum umfasst i.d.R. 1-2 Std. Die Tage sind nur…

nuudel.digitalcourage.de

AutoIt

#cs 	 		****************** AutoIt Hackathon 2025 ******************

	  Teil 3 - "alte Zeiten"
	  für AutoIt Version >= 3.3.16.1
	  Aufgabe:	Erstelle zwei Funktionen: _IntegerToRoman() & _RomanToInteger ( + eine Bonus-Aufgabe _DateToRoman() )
 	 		****************** AutoIt Hackathon 2025 ******************
			1: _IntegerToRoman($sInteger)	erhält eine Integer Zahl ( 0 < Zahl < 4000 ) und gibt diese als Ausdruck einer römischen Zahl zurück
				originale Beschreibung: https://leetcode.com/problems/integer-to-roman/description/

				Sieben verschiedene Symbole stellen römische Ziffern mit den folgenden Werten dar:
					Symbol Wert
					I 1
					V 5
					X 10
					L 50
					C 100
					D 500
					M 1000

				Römische Ziffern werden durch Anhängen der Umrechnungen von Dezimalstellenwerten vom höchsten zum niedrigsten Wert gebildet.
				Für die Umwandlung einer Dezimalstelle in eine römische Zahl gelten die folgenden Regeln:

				Wenn der Wert nicht mit 4 oder 9 beginnt, wählen Sie das Symbol des maximalen Wertes, der von der Eingabe subtrahiert werden kann,
				hängen Sie dieses Symbol an das Ergebnis an, subtrahieren Sie seinen Wert und wandeln Sie den Rest in eine römische Zahl um.
				Wenn der Wert mit 4 oder 9 beginnt, verwenden Sie die subtraktive Form, die ein Symbol vom folgenden Symbol subtrahiert,
				z. B. 4 ist 1 (I) weniger als 5 (V): IV und 9 ist 1 (I) weniger als 10 (X): IX.
				Es werden nur die folgenden subtraktiven Formen verwendet: 4 (IV), 9 (IX), 40 (XL), 90 (XC), 400 (CD) und 900 (CM).
				Nur Potenzen von 10 (I, X, C, M) können höchstens 3 Mal hintereinander angehängt werden,
				um Vielfache von 10 darzustellen. Sie können 5 (V), 50 (L) oder 500 (D) nicht mehrfach anhängen.
				Wenn Sie ein Symbol 4 Mal anhängen müssen, verwenden Sie die subtraktive Form.

				Wandeln Sie eine ganze Zahl in eine römische Zahl um.
				Beispiel 1:
					Eingabe: $sInteger = 3749
					Ausgabe: "MMMDCCXLIX"

					Erläuterung:
					3000 = MMM als 1000 (M) + 1000 (M) + 1000 (M)
					 700 = DCC als 500 (D) + 100 (C) + 100 (C)
					  40 = XL als 10 (X) weniger von 50 (L)
					   9 = IX als 1 (I) weniger von 10 (X)
					Hinweis: 49 ist nicht 1 (I) weniger von 50 (L), da die Umrechnung auf Dezimalstellen basiert.

				Beispiel 2:
					Eingabe: $sInteger = 58
					Ausgabe: "LVIII"

					Erläuterung:
					50 = L
					 8 = VIII

				Beispiel 3:
					Eingabe: $sInteger = 1994
					Ausgabe: "MCMXCIV"

					Erläuterung:
					1000 = M
					 900 = CM
					  90 = XC
					   4 = IV

				Beschränkungen:
					1 <= $sInteger <= 3999

			2: _RomanToInteger($sRoman) 	erhält eine Ausdruck einer römische Zahl und gibt die Jahreszahl als Integer zurück
				originale Beschreibung: https://leetcode.com/problems/roman-to-integer/description/

				Die römischen Ziffern werden durch sieben verschiedene Symbole dargestellt: I, V, X, L, C, D und M.
					Symbol Wert
					I 1
					V 5
					X 10
					L 50
					C 100
					D 500
					M 1000

				Zum Beispiel wird 2 als II in römischen Zahlen geschrieben, einfach zwei Einsen addiert. 12 wird als XII geschrieben,
				was einfach X + II ist. Die Zahl 27 wird als XXVII geschrieben, d. h. XX + V + II.

				Römische Ziffern werden normalerweise von links nach rechts von der größten zur kleinsten Zahl geschrieben.
				Die Zahl für vier ist jedoch nicht IIII. Stattdessen wird die Zahl Vier als IV geschrieben.
				Da die Eins vor der Fünf steht, subtrahieren wir sie und erhalten vier.
				Das gleiche Prinzip gilt für die Zahl Neun, die als IX geschrieben wird. Es gibt sechs Fälle, in denen die Subtraktion verwendet wird:

					I kann vor V (5) und X (10) gesetzt werden, um 4 und 9 zu bilden.
					X kann vor L (50) und C (100) platziert werden, um 40 und 90 zu ergeben.
					C kann vor D (500) und M (1000) platziert werden, um 400 und 900 zu ergeben.

				Wandeln Sie eine römische Zahl in eine ganze Zahl um.

				Beispiel 1:
					Eingabe: s = "III"
					Ausgabe: 3
					Erläuterung: III = 3.

				Beispiel 2:
					Eingabe: s = "LVIII"
					Ausgabe: 58
					Erläuterung: L = 50, V= 5, III = 3.

				Beispiel 3:
					Eingabe: s = "MCMXCIV"
					Ausgabe: 1994
					Erläuterung: M = 1000, CM = 900, XC = 90 und IV = 4.

				Beschränkungen:
					1 <= $sRoman.length <= 15
					s enthält nur die Zeichen ('I', 'V', 'X', 'L', 'C', 'D', 'M').
					Es wird garantiert, dass s eine gültige römische Zahl im Bereich [1, 3999] ist.

	Bonus Aufgabe:
			3: _DateToRoman() erhält ein Datum im Format "YYYY/MM/DD[ HH:MM:SS]" wobei eine Zeitangabe optional, aber möglich ist
				Erstelle eine Funktion	die ein Date-Format im "römischen Format" zurückgibt.
				Die Trennzeichen sollen dabei unverändert erhalten bleiben.

				zusätzliche Funktionen können erstellt werden, müssen aber im Lösungspost mit angegeben werden.
				Es gilt der Code-Block, der im Thread als Antwort gepostet wird.
				Als einzige Vorgabe für das Script wird die jeweilige Funktion samt Namen vorgegeben.
				Diese sind unten ersichtlich, müssen so verwendet werden und aus ihnen muss das Ergebnis als Return erfolgen.

      Prüfung:  Die Funktion _Check() beinhaltet beispielhafte Prüfungsdatensätze und jeweils einen Hash der Lösung
				Die Ausgabe zeigt an, wie viel Prozent dein Script bereits erfüllt.
				Sobald dein Script 100% korrekt ist, poste dein Script im Thread

	   Sieger:	GEWONNEN HAT, ...

PS:				Die Verwendung von #includes ist gestattet, müssen aber im Script mit angegeben werden!

#ce
; Um dein Script zu überprüfen, drücke F5.

; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================
Func _IntegerToRoman($sInteger)
	Local $Return

	Return $Return
EndFunc   ;==>_IntegerToRoman
Func _RomanToInteger($sRoman)
	Local $Return

	Return $Return
EndFunc   ;==>_RomanToInteger

; Bonus-Aufgabe für Ambitionierte ;-)
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
	Local $Return

	Return $Return
EndFunc   ;==>_DateToRoman
; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================















; Funktion zur Überprüfung des eigenen Scripts. Nicht mit in den Thread laden!
#include <Crypt.au3>
_Check_IntegerToRoman()
_Check_RomanToInteger()
_Check_DateToRoman()

Func _Check_IntegerToRoman()
	Local $aPruefDaten[][] = [[], _
			[1, "0xA83DD0CCBFFE39D071CC317DDF6E97F5C6B1C87AF91919271F9FA140B0508C6C"], _
			[46, "0x101AC3C99D6FCEDF8C1A6E3EAC18697FB4BEAA4E4510A45C14D5233F3A09D459"], _
			[728, "0x0934E3E7BF156E0EC2E6535F53A15A8E549315B40CA4EB849DBFD8ABCDB32BD1"], _
			[1999, "0xC92979E7626148228B837A2904992490E20AFCB7E145F2C15F3B528FDB1BA566"], _
			[2476, "0xC386049C1C68575AB4C0EA9AE781FF294080179B552619253DB5F92B4C4D0380"], _
			[3888, "0x567A7E66D8EFD19459873F5836896987ECC6B07BF42C7EB98834B952EA39B0EA"]]
	Local $aTestdaten[5]
	Local $correct = 0
	For $i = 1 To UBound($aPruefDaten) - 1
		$CryptResultData = _Crypt_HashData(_IntegerToRoman($aPruefDaten[$i][0]), $CALG_SHA_256)
		If $CryptResultData = $aPruefDaten[$i][1] Then $correct += 1
	Next
	ConsoleWrite("Testergebnis _IntegerToRoman: " & 100 / (UBound($aPruefDaten) - 1) * $correct & "%" & @CRLF)
EndFunc   ;==>_Check_IntegerToRoman
Func _Check_RomanToInteger()
	Local $aPruefDaten[][] = [["", ""], _
			["XXIX", "0x79095D9004930C349E99C30F6C93E7BB5541F6EF7BB6883C04163E94CF82110A"], _
			["CXXII", "0x4F55412B85445F7D15757C8214BE4581AB8A98AF792A98F3FD2D049FFCCDC494"], _
			["CCCLIX", "0xD727F912336CA13E8E9BA1372377E3AC970AE44FE3306151E96516970B235659"], _
			["MCDLV", "0x66B962775512A326EF7A82D11F2CB7EC6A16DCEB2F1A3489373F0119A7F7A021"], _
			["MMCDXLIX", "0xEF3F5A3D3B8D5019C747679E70654A4A28F8771CD63C5B30C3A5742B6FBA7074"], _
			["MMMCCCXXXIX", "0x54ACE80191BB37C31A8F7EBEAA062AFD02BE72FBD755637AC68FC1AD2D03B9BB"]]
	Local $aTestdaten[5]
	Local $correct = 0
	For $i = 1 To UBound($aPruefDaten) - 1
		$CryptResultData = _Crypt_HashData("Testdaten:" & _RomanToInteger($aPruefDaten[$i][0]), $CALG_SHA_256)
		If $CryptResultData = $aPruefDaten[$i][1] Then $correct += 1
	Next
	ConsoleWrite("Testergebnis _RomantoInteger: " & 100 / (UBound($aPruefDaten) - 1) * $correct & "%" & @CRLF)
EndFunc   ;==>_Check_RomanToInteger
Func _Check_DateToRoman() ;Date range  = 01.01.0001 - 31.12.3999 (remember, in roman is no "0" !)
	Local $aPruefDaten[][] = [["", ""], _
			["01/05/1028", ""0x5CD51BB77D63FFDACB6BFCBC3C6C1D1B3056A3E140DF629CAC6D49D551BE55EA""], _
			["23/05/2011 12", "0x13D4359153330C8587D7DB313A8C8758DE26B0FAA53FC93DACDBDED553F8694B"], _
			["05/05/1777 16:22", "0xAFD10C28163A328A2C25783D70457DF4D63928CB00004715D648BB0D889A5703"], _
			["31/12/2679 14:55:38", "0xDEE1E331FB56FA93C4EA51AACBF578A44149505A7A4239CC2D8D6058DC179BF7"]]
	Local $aTestdaten[5]
	Local $correct = 0
	For $i = 1 To UBound($aPruefDaten) - 1
		$CryptResultData = _Crypt_HashData("Test:" & _DateToRoman($aPruefDaten[$i][0]), $CALG_SHA_256)
		If $CryptResultData = $aPruefDaten[$i][1] And $CryptResultData <> '0xE3B0C44298FC1C149AFBF4C8996FB92427AE41E4649B934CA495991B7852B855' Then $correct += 1
	Next
	ConsoleWrite("Testergebnis _DateToRoman: " & 100 / (UBound($aPruefDaten) - 1) * $correct & "%" & @CRLF)
EndFunc   ;==>_Check_DateToRoman

Alles anzeigen

**AspirinJunkie**

Na dann meine Lösung - tatsächlich durchaus eine Herausforderung für mich gewesen:

AutoIt

Func _IntegerToRoman($dInt)
	Local $aRoman[][2] = [["M", 1000],["CM", 900],["D", 500],["CD", 400],["C", 100],["XC", 90],["L", 50],["XL", 40],["X", 10],["IX", 9],["V", 5],["IV", 4],["I", 1]]
	Local $sReturn = ""
	For $i = 0 To UBound($aRoman) - 1 
		If $dInt <= 0 Then ExitLoop
		While $dInt >= $aRoman[$i][1]
			$sReturn &= $aRoman[$i][0]
			$dInt -= $aRoman[$i][1]
		WEnd
	Next
	Return $sReturn
EndFunc   ;==>_IntegerToRoman

Func _RomanToInteger($sRoman)
	Local $dInt = 0, $dCurr, $dVorher, $aRoman[][2] = [["M", 1000],["D", 500],["C", 100],["L", 50],["X", 10],["V", 5],["I", 1]], $mRoman[]
	For $i = 0 To UBound($aRoman) - 1
		$mRoman[$aRoman[$i][0]] = $aRoman[$i][1]
	Next
	For $cChar in StringSplit($sRoman, '', 3)
		$dCurr = $mRoman[$cChar]
		$dInt += $dCurr > $dVorher ? $dCurr - 2 * $dVorher : $dCurr
		$dVorher = $dCurr
	Next
	Return $dInt
EndFunc   ;==>_RomanToInteger

; Bonus-Aufgabe für Ambitionierte ;-)
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
	Return Execute('"' & StringRegExpReplace($sDate, "(\d+)", '" & _IntegerToRoman($1) & "') & '"')
EndFunc   ;==>_DateToRoman

Alles anzeigen

**Mars**

AutoIt

; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================
Func _IntegerToRoman($sInteger)
	Local $Return
	Local Static $M[], $K
	If Not UBound($M) Then
		$M[1] = 'I'
		$M[5] = 'V'
		$M[10] = 'X'
		$M[50] = 'L'
		$M[100] = 'C'
		$M[500] = 'D'
		$M[1000] = 'M'
		$K = MapKeys($M)
	EndIf
	For $r = UBound($K) - 1 To 0 Step -1
		While $sInteger >= $K[$r]
			$Return &= $M[$K[$r]]
			$sInteger -= $K[$r]
		WEnd
	Next
	$Return = StringReplace($Return, 'IIII', 'IV')
	$Return = StringReplace($Return, 'VIV' , 'IX')
	$Return = StringReplace($Return, 'XXXX', 'XL')
	$Return = StringReplace($Return, 'LXL' , 'XC')
	$Return = StringReplace($Return, 'CCCC', 'CD')
	$Return = StringReplace($Return, 'DCD' , 'CM')
	Return $Return
EndFunc   ;==>_IntegerToRoman
Func _RomanToInteger($sRoman)
	Local $Return
	Local Static $M[], $K
	If Not UBound($M) Then
		$M['I'] = 1
		$M['V'] = 5
		$M['X'] = 10
		$M['L'] = 50
		$M['C'] = 100
		$M['D'] = 500
		$M['M'] = 1000
		$K = MapKeys($M)
	EndIf
	$sRoman = StringReplace($sRoman, 'CM', 'DCD', 0, 1)
	$sRoman = StringReplace($sRoman, 'CD', 'CCCC', 0, 1)
	$sRoman = StringReplace($sRoman, 'XC', 'LXL', 0, 1)
	$sRoman = StringReplace($sRoman, 'XL', 'XXXX', 0, 1)
	$sRoman = StringReplace($sRoman, 'IX', 'VIV', 0, 1)
	$sRoman = StringReplace($sRoman, 'IV', 'IIII', 0, 1)
	For $c In StringSplit($sRoman, '', 2)
		$Return += $M[$c]
	Next
	Return $Return
EndFunc   ;==>_RomanToInteger

; Bonus-Aufgabe für Ambitionierte ;-)
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
	;If Not StringInStr($sDate, ' ', 0, 1) Then Return '' ; Das hier ist ein Joke. Natürlich muss diese Zeile weg :)
	Local $Return, $aDate = StringSplit(StringReplace(StringReplace($sDate, ' ', ':', 0, 1), '/', ':', 0, 1), ':', 2)
	For $i = 0 To UBound($aDate) - 1 Step 1
		$Return &= _IntegerToRoman($aDate[$i]) & ($i < UBound($aDate) - 1 ? ($i < 2 ? '/' : $i = 2 ? ' ' : ':') : '')
	Next
	Return $Return
EndFunc   ;==>_DateToRoman
; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================

Alles anzeigen

**Schnuffel**

AutoIt

Func _IntegerToRoman($sInteger)
	Local $Return, $nAct, $aSign[5][3] = [['', '', ''], ["I", "V", "X"], ["X", "L", "C"], ["C", "D", "M"], ['M', '', '']]
	For $i = StringLen($sInteger) To 1 Step -1
		$nAct = StringLeft($sInteger, 1)
		Switch $nAct
			Case 1 To 3
				For $j = 1 To $nAct
					$Return &= $aSign[$i][0]
				Next
			Case 4
				$Return &= $aSign[$i][0] & $aSign[$i][1]
			Case 5 To 8
				$Return &= $aSign[$i][1]
				For $j = 1 To $nAct - 5
					$Return &= $aSign[$i][0]
				Next
			Case 9
				$Return &= $aSign[$i][0] & $aSign[$i][2]
		EndSwitch
		$sInteger = StringTrimLeft($sInteger, 1)
	Next
	Return $Return
EndFunc   ;==>_IntegerToRoman
Func _RomanToInteger($sRoman)
	Local $Return, $aRoman = StringSplit($sRoman, ''), $mMap[]
	$mMap["I"] = 1
	$mMap["V"] = 5
	$mMap["X"] = 10
	$mMap["L"] = 50
	$mMap["C"] = 100
	$mMap["D"] = 500
	$mMap["M"] = 1000
	For $i = 1 To $aRoman[0]
		If $i < $aRoman[0] Then
			If $mMap[$aRoman[$i + 1]] <= $mMap[$aRoman[$i]] Then
				$Return += $mMap[$aRoman[$i]]
				ContinueLoop
			EndIf
			If $mMap[$aRoman[$i + 1]] > $mMap[$aRoman[$i]] Then
				$Return -= $mMap[$aRoman[$i]]
			EndIf
		Else
			$Return += $mMap[$aRoman[$i]]
		EndIf
	Next
	Return $Return
EndFunc   ;==>_RomanToInteger
; Bonus-Aufgabe für Ambitionierte ;-)
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
	Local $Return
	If StringLen($sDate) > 10 And StringInStr($sDate, " ") Then
		Local $aTemp = StringSplit($sDate, ' '), $aDate = StringSplit($aTemp[1], '/'), $aTime = StringSplit($aTemp[2], ':')
		For $k = 1 To $aDate[0]
			$Return &= _IntegerToRoman($aDate[$k]) & "/"
		Next
		$Return = StringTrimRight($Return, 1) & " "
		For $k = 1 To $aTime[0]
			$Return &= _IntegerToRoman($aTime[$k]) & ":"
		Next
		$Return = StringTrimRight($Return, 1)
	Else
		Local $aDate = StringSplit($sDate, '/')
		For $k = 1 To $aDate[0]
			$Return &= _IntegerToRoman($aDate[$k]) & "/"
		Next
		$Return = StringTrimRight($Return, 1)
	EndIf
	Return $Return
EndFunc   ;==>_DateToRoman

Alles anzeigen

**UEZ**

AutoIt

Func _IntegerToRoman($sInteger)
	Local $Return = "", $i, $j[] = [1, 4, 5, 9], $num = $sInteger, $value, $sRoman = "IIVIXXLXCCDCM" ;alle möglichen Zeichenpaare der römischen Zahlensymbole kompakt aneinandergereiht
	For $i = 12 To 0 Step -1
		$value = $j[Mod($i, 4)] * 10 ^ BitShift($i, 2) ;berechnet den konkreten Wert für die aktuelle Position, z.B. 1000, 900, 500, 400, ..., 1
		While $num >= $value
			$Return &= StringMid($sRoman, $i + 1, Mod($i, 2) + 1) ;die passenden römischen Zeichen (1 oder 2 Buchstaben) werden aus $sRoman extrahiert und angehängt
			$num -= $value
		WEnd
	Next
	Return $Return
EndFunc   ;==>_IntegerToRoman

Func _RomanToInteger($sRoman)
	Local $i, $Return = 0, $map[13][2] = [["M", 1000], ["CM", 900], ["D", 500], ["CD", 400], ["C", 100], ["XC", 90], ["L", 50], ["XL", 40], ["X", 10], ["IX", 9], ["V", 5], ["IV", 4], ["I", 1]]
	$sRoman = StringUpper($sRoman)
	While StringLen($sRoman) > 0
		For $i = 0 To UBound($map) - 1
			If StringLeft($sRoman, StringLen($map[$i][0])) = $map[$i][0] Then
				$Return += $map[$i][1]
				$sRoman = StringTrimLeft($sRoman, StringLen($map[$i][0]))
				ExitLoop
			EndIf
		Next
	WEnd
	Return $Return
EndFunc   ;==>_RomanToInteger

; Bonus-Aufgabe für Ambitionierte ;-)
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD [HH:MM:SS]", Output in same date-format with roman sign
	Local $aTokens = StringRegExp($sDate, "(\d{2})/(\d{2})/(\d{4})(?: (\d{2})(?::(\d{2}))?(?::(\d{2}))?)?", 1), $ub = UBound($aTokens)
	Return StringFormat("%02s/%02s/%04s %02s:%02s:%02s", _IntegerToRoman($aTokens[0]), _IntegerToRoman($aTokens[1]), _IntegerToRoman($aTokens[2]), $ub > 3 ? _IntegerToRoman($aTokens[3]) : "",  $ub > 4 ? _IntegerToRoman($aTokens[4]) : "",  $ub > 5 ? _IntegerToRoman($aTokens[5]) : "")
EndFunc   ;==>_DateToRoman

Alles anzeigen

**chesstiger**

Die Bonusaufgabe schaue ich mir morgen mal noch an:

AutoIt

Func _IntegerToRoman($num)
	Local Static $4 = ["", "M", "MM", "MMM", "MMMM"]
	Local Static $3 = ["", "C", "CC", "CCC", "CD", "D", "DC", "DCC", "DCCC", "CM"]
	Local Static $2 = ["", "X", "XX", "XXX", "XL", "L", "LX", "LXX", "LXXX", "XC"]
	Local Static $1 = ["", "I", "II", "III", "IV", "V", "VI", "VII", "VIII", "IX"]
	Return 	$4[Int($num / 1000)] & _
			$3[Int(Mod($num, 1000) / 100)] & _
			$2[Int(Mod($num, 100) / 10)] & _
			$1[Mod($num, 10)]
EndFunc

Func _RomanToInteger($roman)
    Local Static $lookup = "M1000D500C100L50X10V5I1"
    Local $value = 0, $last = 0, $num
    For $i = 1 To StringLen($roman)
        $num = Int(StringMid($lookup, StringInStr($lookup, StringMid($roman, $i, 1)) + 1))
        $value += $num - 2 * ($num > $last) * $last
        $last = $num
    Next
    Return $value
EndFunc

Alles anzeigen

**Kanashius**

Etwas später, aber besser spät als nie

AutoIt

; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================
Func _IntegerToRoman($sInteger)
	Local Static $arPattern=["", "I", "II", "III", "IV", "V", "VI", "VII", "VIII", "IX"]
	Local Static $arNumbers=[["I", "V"], ["X", "L"], ["C", "D"], ["M", ""], ["", ""]]
	Local $arData = StringSplit($sInteger, "", 3)
	Local $sResult = ""
	For $i=0 To UBound($arData)-1 Step 1
		Local $sSym1 = $arNumbers[UBound($arData)-$i-1][0]
		Local $sSym2 = $arNumbers[UBound($arData)-$i-1][1]
		Local $sSym3 = $arNumbers[UBound($arData)-$i][0]
		$sResult &= StringReplace(StringReplace(StringReplace($arPattern[$arData[$i]], "X", $sSym3), "V", $sSym2), "I", $sSym1)
	Next
	Return $sResult
EndFunc   ;==>_IntegerToRoman
Func _RomanToInteger($sRoman)
	Local $arData = StringSplit($sRoman, "", 3), $iResult = 0, $iBefore = 0
	For $i=0 To UBound($arData)-1 Step 1
		Local $iAdd = 0
		Switch $arData[$i]
			Case "M"
				$iAdd+=1000
			Case "D"
				$iAdd+=500
			Case "C"
				$iAdd+=100
			Case "L"
				$iAdd+=50
			Case "X"
				$iAdd+=10
			Case "V"
				$iAdd+=5
			Case "I"
				$iAdd+=1
		EndSwitch
		If $iBefore<$iAdd Then
			$iResult-=$iBefore*2
		EndIf
		$iResult+=$iAdd
		$iBefore = $iAdd
	Next
	Return $iResult
EndFunc   ;==>_RomanToInteger
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
	Local $arDate = StringRegExp($sDate, "\d+", 3)
	$sDate = StringRegExpReplace($sDate, "\d+", "$")
	For $i=0 To UBound($arDate)-1
		$sDate = StringReplace($sDate, "$", _IntegerToRoman($arDate[$i]), 1)
	Next
	Return $sDate
EndFunc   ;==>_DateToRoman
; ================================= entferne alle Leer- und Kommentarzeilen und poste diesen Code-Block im Thread ==================================

Alles anzeigen

**Moombas**

Kurze Anmerkung und Tipp für andere: Dein Text bei der Bonusaufgabe ist irreführend "Input date in the format "YYYY/MM/DD[ HH:MM:SS]" denn tatsächlich übergibst und erwartest du es anders (Beispiel: "31/12/2679 14:55:38"). Du müsstest also bei dem Text YYYY und DD tauschen und die [ weg lassen, das hat mich kurz verwirrt. Die tatsächliche Anforderung wäre hier also: "Input date in the format "DD/MM/YYYY HH:MM:SS" ".

AutoIt

Func _IntegerToRoman($sInteger)
Local $Return = ''
	If not (($sInteger >= 1) and ($sInteger <= 3999)) then Return False
	While $sInteger <> 0
		Select
			Case $sInteger >= 1000
				 $Return &= 'M'
				 $sInteger -= 1000
			Case $sInteger >= 500
				 If $sInteger >= 900 then
					$Return &= 'CM'
					$sInteger -= 900
				 Else
					$Return &= 'D'
					$sInteger -= 500
				 EndIf
			Case $sInteger >= 100
				 If $sInteger >= 400 then
					$Return &= 'CD'
					$sInteger -= 400
				 Else
					$Return &= 'C'
					$sInteger -= 100
				 EndIf
			Case $sInteger >= 50
				 If $sInteger >= 90 then
					$Return &= 'XC'
					$sInteger -= 90
				 Else
					$Return &= 'L'
					$sInteger -= 50
				 EndIf
			Case $sInteger >= 10
				 If $sInteger >= 40 then
					$Return &= 'XL'
					$sInteger -= 40
				 Else
					$Return &= 'X'
					$sInteger -= 10
				 EndIf
			Case $sInteger >= 5
				 If $sInteger >= 9 then
					$Return &= 'IX'
					$sInteger -= 9
				 Else
					$Return &= 'V'
					$sInteger -= 5
				 EndIf
			Case $sInteger >= 1
				 If $sInteger >= 4 then
					$Return &= 'IV'
					$sInteger -= 4
				 Else
					$Return &= 'I'
					$sInteger -= 1
				 EndIf
		EndSelect
	WEnd
	Return $Return
EndFunc   ;==>_IntegerToRoman
Func _RomanToInteger($sRoman)
Local $Return, $aRoman = StringSplit($sRoman, ''), $Value, $Value2
Local Const $I =    1
Local Const $V =    5
Local Const $X =   10
Local Const $L =   50
Local Const $C =  100
Local Const $D =  500
Local Const $M = 1000
	If not (($aRoman[0] >= 1) and ($aRoman[0] <= 15)) then Return False
	For $Char = 1 to $aRoman[0]
		$Value  = Execute('$' & $aRoman[$Char])
		If $Char < $aRoman[0] then
			$Value2 = Execute('$' & $aRoman[$Char+1])
		Else
			$Value2 = 0
		EndIf
		If $Value < $Value2 Then
			$Return += $Value2 - $Value
			$Char += 1
		Else
			$Return += $Value
		EndIf
	Next
	Return $Return
EndFunc   ;==>_RomanToInteger
; Bonus-Aufgabe für Ambitionierte ;-)
Func _DateToRoman($sDate) ;Input date in the format "YYYY/MM/DD[ HH:MM:SS]", Output in same date-format with roman sign
Local $Return, $Year, $Month, $Day, $Hour, $Minute, $Sec, $aDate
	$aDate  = StringSplit($sDate, '/')
	$Day    = _IntegerToRoman($aDate[1])
	$Month  = _IntegerToRoman($aDate[2])
	$Return = $Day & '/' & $Month & '/'
	If not StringInStr($aDate[3], ' ') then ;only date
		$Year    = _IntegerToRoman($aDate[3])
		$Return &= $Year
	Else
		$aDate  = StringSplit($aDate[3], ' ')
		$Year   = _IntegerToRoman($aDate[1])
		$Return &= $Year
		If not StringInStr($aDate[2], ':') then ;only hour
			$Hour   = _IntegerToRoman($aDate[2])
			$Return &= ' ' & $Hour
		Else
			$aDate  = StringSplit($aDate[2], ':')
			$Return &= ' ' & _IntegerToRoman($aDate[1])
			For $Row = 2 to $aDate[0]
				$Return &= ':' & _IntegerToRoman($aDate[$Row])
			Next
		Endif
	EndIf
	Return $Return
EndFunc   ;==>_DateToRoman

Alles anzeigen

~~Die Bonusaufgabe hole ich ggf. noch nach~~

So, Bonusaufgabe mit drin

**Kanashius**

Zitat von Moombas

Die tatsächliche Anforderung wäre hier also: "Input date in the format "DD/MM/YYYY HH:MM:SS" "

Die [] klammern werden tatsächlich normalerweise so angegeben um zu signaliesieren, dass etwas optional ist. Richtig wäre also eher: DD/MM/YYYY[ HH[:MM[:SS]]], da die Zeit nochmal mehrere optionale Felder hat.

Aber ja, ich bin auch darüber gestolpert... Das erste mal mit DD/MM/YYYY statt YYYY/MM/DD und dann mit dem optionalen,... Irgendwann hab ich mir gedacht, ich ignorier das vorgegebene Muster und ersetze einfach alle Zahlen, dann ist definitiv alles abgedeckt

**Moombas**

Ja, so habe ich das im Prinzip auch gemacht

Schnuffel 11. Mai 2025 um 20:00