EXIF-Rename

**Oscar**

Hintergrundgeschichte:
Mein Schwager hat tausende JPG-Bilder auf seinem Rechner, die meistens von irgendwelchen Digitalkameras oder Smartphones stammen. Alle mit mehr oder weniger kryptischen Dateinamen plus Zaehler.
Zum Teil mit identischen Dateinamen in unterschiedlichen Unterverzeichnissen. Ich schlug ihm vor, dass er diese doch wenigstens nach Datum/Uhrzeit umbenennen kann, um da etwas Ordnung reinzubekommen. Also habe ich mal wieder AutoIt bemüht und ihm ein Programm geschrieben, welches anhand der EXIF-Daten einen entsprechenden Dateinamen generiert und die Datei so umbenennt.

Technisches:
Das auslesen der EXIF-Daten kann man entweder mit den GDI+ Funktionen erledigen, was allerdings relativ lange dauert, weil man das Bild erst komplett in den Speicher laden muss. Bei mehreren Hundert Bilder dauert das seeehr lange.
Also habe ich im Internet recherchiert und mir den Aufbau der Struktur direkt in den Binärdaten der Datei angesehen. So kann man die EXIF-Daten sehr viel schneller auslesen, weil man nur wenige Bytes der Datei einlesen muss.
Problematisch war, dass mein Schwager auch Bilder hat, die keinerlei EXIF-Daten enthalten und diverse Bilder, bei denen die EXIF-Daten fehlerhaft sind. Also habe ich noch eine Fallback-Funktion eingebaut, bei der in diesen Fällen das Dateierstellungsdatum verwendet wird und falls das JPG selbst kaputt ist (da waren auch einige dabei), wird "1900-01-01__00-00-00" als Dateiname zurückgegeben. Auf diese Weise sieht er gleich, woran er ist.

Naja, lange Rede kurzer Sinn: Vielleicht könnt ihr ja auch so ein Programm gebrauchen.

Eigenschaften:

- "Drag and drop" von Verzeichnissen/Dateien auf ein markiertes Feld im Hauptfenster.

- Verzeichnisse können auch rekursiv eingelesen werden (das kann u.U. aber sehr lange dauern, wenn dort mehrere Tausend Bilder liegen)

- Hauptfenster kann "Immer im Vordergrund" gesetzt werden.

- Ein bereits bestehender Dateiname wird an das EXIF-Datum/Uhrzeit angehängt, wenn der Haken im Listview gesetzt ist.

- Über das Kontextmenü beim Listview kann man das markieren/anhaken etwas komfortabler erledigen.

- Eine Vorschau-Funktion, wenn man eine Datei im Listview doppelt anklickt.

Das Script gibt es als ZIP-Archiv im Anhang zum download.

Screenshot:

**water**

Danke!! Das schaue ich mir gleich an!
So was ähnliches habe ich mir auch schon gebastelt - aber auf Basis des Aufnahmedatums von _FileGetProperty bzw. in einem weiteren Versuch auf Basis von ExifTool.
War aber trotzdem noch ne ziemliche Fummlerei

**Tweaky**

Finde das Tool super und schnell.
Weißt du auch wie man Exif.Photo.DateTimeDigitized und Exif.Photo.DateTimeOriginal auslesen kann?

**Oscar**

Zitat von Tweaky

Weißt du auch wie man Exif.Photo.DateTimeDigitized und Exif.Photo.DateTimeOriginal auslesen kann?

Ich habe Dir mal die Funktion umgeschrieben:

AutoIt

 #include <FileConstants.au3>
#include <WinAPIConv.au3>
#include <WinAPIFiles.au3>
#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>


$sEXIF_DT = _GetExifDateTime('test.jpg')
ConsoleWrite($sEXIF_DT & @CRLF)

Func _GetExifDateTime($sImgfile)
	Local $tDT, $hFile, $tBuffer, $nBytes, $iSOI, $iMarker, $iMarkerLength, $iTIFFbegin, $tTIFF
	Local $tEntry, $iTyp, $iOffset, $iTagCount, $iError = 0, $iTmpOffset, $sRet, $iX, $iY
	$tDT = DllStructCreate('char DT[20]')
	$hFile = _WinAPI_CreateFile($sImgfile, 2, 2) ; Datei zum lesen oeffnen
	If $hFile = 0 Then Return SetError(1, 0, '')
	$tBuffer = DllStructCreate('ushort SOI')
	_WinAPI_ReadFile($hFile, $tBuffer, DllStructGetSize($tBuffer), $nBytes)
	$iSOI = _WinAPI_SwapWord($tBuffer.SOI)
	If $iSOI = 0xFFD8 Then ; wenn Marker: Start of Image (SOI) vorhanden, dann JPG
		$tBuffer = DllStructCreate('ushort Marker;ushort Length')
		Do
			If Not _WinAPI_ReadFile($hFile, $tBuffer, DllStructGetSize($tBuffer), $nBytes) Then
				$iError = 2 ; Fehler beim Lesen oder Dateiende erreicht
				ExitLoop
			EndIf
			$iMarker = _WinAPI_SwapWord($tBuffer.Marker)
			If $iMarker < 0xFF00 Then
				$iError = 3 ; JPG ohne Exif-Marker
				ExitLoop
			EndIf
			$iMarkerLength = _WinAPI_SwapWord($tBuffer.Length)
			If $iMarker = 0xFFE1 Then ExitLoop ; wenn Marker: 0xFFE1, dann Schleife verlassen (vermutlich Exifdaten)
			_WinAPI_SetFilePointer($hFile, $iMarkerLength - 2, $FILE_CURRENT) ; zum naechsten Marker springen
		Until $iError > 0
		If $iError Then ; wenn keine Exifdaten vorhanden, dann beenden
			_WinAPI_CloseHandle($hFile)
			Return SetError($iError, 0, '')
		EndIf
		$tBuffer = DllStructCreate('char Exif[6]') ; Struktur fuer String "Exif" und zwei Nullbytes
		_WinAPI_ReadFile($hFile, $tBuffer, DllStructGetSize($tBuffer), $nBytes)
		If $tBuffer.Exif = 'Exif' Then ; wenn zusaetzlich "Exif" vorhanden, dann handelt es sich um ein JPG mit Exifdaten
			$iTIFFbegin = _WinAPI_GetFilePointerEx($hFile) ; Anfang des TIFF-Headers merken
			$tTIFF = DllStructCreate('ushort Endian; ushort Code; ulong Offset') ; Struktur des TIFF-Headers
			_WinAPI_ReadFile($hFile, $tTIFF, DllStructGetSize($tTIFF), $nBytes)
			For $i = 0 To 1 ; es gibt zwei Image File Directories (IFDs)
				$tBuffer = DllStructCreate('ushort TagCount') ; die Anzahl der TAGs in dem IFD
				_WinAPI_ReadFile($hFile, $tBuffer, DllStructGetSize($tBuffer), $nBytes)
				$tEntry = DllStructCreate('align 1; ushort Typ; ushort Datatyp; ulong Length; ulong Offset') ; Struktur der Eintraege
				Do
					If Not _WinAPI_ReadFile($hFile, $tEntry, DllStructGetSize($tEntry), $nBytes) Then ExitLoop 2
					; Die Daten können unterschiedlich kodiert sein: 0x4D4D = BigEndian oder 0x4949 = LittleEndian
					$iTyp = ($tTIFF.Endian = 0x4D4D ? _WinAPI_SwapWord($tEntry.Typ) : $tEntry.Typ)
					$iOffset = ($tTIFF.Endian = 0x4D4D ? _WinAPI_SwapDWord($tEntry.Offset) : $tEntry.Offset)
					Switch $iTyp
						Case 0xA002 ; X-Aufloesung
							$iX = $iOffset
						Case 0xA003 ; Y-Aufloesung
							$iY = $iOffset
						Case 0x0132, 0x9003, 0x9004
							; 0x0132 = Erstellungsdatum (ExifDTCreated)
							; 0x9003 = Aufnahmedatum (ExifDTOrig)
							; 0x9004 = Digitalisierungsdatum (ExifDTDigitized)
							$iTmpOffset = _WinAPI_GetFilePointerEx($hFile)
							_WinAPI_SetFilePointer($hFile, $iTIFFbegin + $iOffset)
							_WinAPI_ReadFile($hFile, $tDT, 0x14, $nBytes) ; und ist 20 Bytes (0x14) lang.
							$sRet &= '0x' & Hex($iTyp, 4) & ' -> ' & $tDT.DT & @CRLF
							_WinAPI_SetFilePointer($hFile, $iTmpOffset)
						Case 0x8769 ; Position auf den naechsten IFD
							_WinAPI_SetFilePointer($hFile, $iTIFFbegin + $iOffset)
							ExitLoop
					EndSwitch
					$iTagCount += 1 ; Anzahl der Tags erhoehen
				Until $iTagCount > $tBuffer.TagCount
				$iTagCount = 0
			Next
			$sRet &= $iX & 'x' & $iY & @CRLF
		EndIf
	EndIf
	_WinAPI_CloseHandle($hFile)
	Return $sRet
EndFunc   ;==>_GetExifDateTime

Alles anzeigen

**Oscar**

Wenn Du mehrere Exif-Einträge brauchst, dann ist es besser/schneller, den gesamten Exifbereich auf einmal einzulesen und die Daten im Speicher zu interpretieren.

Das habe ich mal in dieser Funktion gemacht:

AutoIt

#include <FileConstants.au3>
#include <WinAPIConv.au3>
#include <WinAPIFiles.au3>
#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>


$sEXIF_DT = _GetExifDateTime('test.jpg')
ConsoleWrite($sEXIF_DT & @CRLF)

Func _GetExifDateTime($sImgfile)
	Local $hFile, $tBuffer, $iSOI, $iError, $iMarker, $iMarkerLength, $nBytes, $sRet = ''
	$hFile = _WinAPI_CreateFile($sImgfile, 2, 2) ; Datei zum lesen oeffnen
	If $hFile = 0 Then Return SetError(1, 0, $sRet)
	$tBuffer = DllStructCreate('align 1;ushort SOI')
	_WinAPI_ReadFile($hFile, $tBuffer, DllStructGetSize($tBuffer), $nBytes)
	$iSOI = _WinAPI_SwapWord($tBuffer.SOI)
	If $iSOI <> 0xFFD8 Then ; Marker: Start of Image (SOI) nicht vorhanden, dann
		_WinAPI_CloseHandle($hFile)
		Return SetError(2, 0, $sRet)
	Else ; Marker: SOI vorhanden, dann handelt es sich um eine JPG-Datei
		$tBuffer = DllStructCreate('align 1;ushort Marker;ushort Length')
		While True
			If Not _WinAPI_ReadFile($hFile, $tBuffer, DllStructGetSize($tBuffer), $nBytes) Then
				_WinAPI_CloseHandle($hFile)
				Return SetError(3, 0, $sRet) ; Fehler beim Lesen oder Dateiende erreicht
			EndIf
			$iMarker = _WinAPI_SwapWord($tBuffer.Marker)
			If $iMarker < 0xFF00 Then
				_WinAPI_CloseHandle($hFile)
				Return SetError(4, 0, $sRet) ; JPG ohne Exif-Marker
			EndIf
			$iMarkerLength = _WinAPI_SwapWord($tBuffer.Length)
			If $iMarker = 0xFFE1 Then ExitLoop ; wenn Marker: 0xFFE1, dann Schleife verlassen (vermutlich Exifdaten)
			_WinAPI_SetFilePointer($hFile, $iMarkerLength - 2, $FILE_CURRENT) ; zum naechsten Marker springen
		WEnd
		Local $tExif, $pExif, $iTIFFbegin, $tTIFF, $tEntry, $iDatatyp, $iTyp, $iData, $iX, $iY, $tDT, $sDT, $iTagCount
		$tExif = DllStructCreate('align 1;char buf[' & $iMarkerLength & ']') ; Buffer fuer den Exif-Bereich erstellen
		$pExif = DllStructGetPtr($tExif) ; Pointer auf den Buffer
		_WinAPI_ReadFile($hFile, $tExif, DllStructGetSize($tExif), $nBytes) ; den gesamten Exif-Bereich einlesen
		_WinAPI_CloseHandle($hFile) ; Datei schliessen
		$tBuffer = DllStructCreate('align 1;char Exif[6]', $pExif) ; Struktur fuer String "Exif" und zwei Nullbytes
		If $tBuffer.Exif = 'Exif' Then ; wenn zusaetzlich "Exif" vorhanden, dann handelt es sich um ein JPG mit Exifdaten
			$pExif += DllStructGetSize($tBuffer)
			$iTIFFbegin = $pExif ; Anfang des TIFF-Headers merken
			$tTIFF = DllStructCreate('align 1;ushort Endian;ushort Code;ulong Offset', $pExif) ; Struktur des TIFF-Headers
			$pExif += DllStructGetSize($tTIFF)
			For $iIFD = 0 To 1 ; es gibt zwei Image File Directories (IFDs)
				$tBuffer = DllStructCreate('align 1;ushort TagCount', $pExif) ; die Anzahl der TAGs in dem IFD
				$pExif += DllStructGetSize($tBuffer)
				Do
					$tEntry = DllStructCreate('align 1;ushort Typ;ushort Datatyp;ulong Length;ulong Data', $pExif) ; Struktur der Eintraege
					$pExif += DllStructGetSize($tEntry)
					$iTyp = ($tTIFF.Endian = 0x4D4D ? _WinAPI_SwapWord($tEntry.Typ) : $tEntry.Typ)
					$iDatatyp = ($tTIFF.Endian = 0x4D4D ? _WinAPI_SwapWord($tEntry.Datatyp) : $tEntry.Datatyp)
					$iData = ($tTIFF.Endian = 0x4D4D ? _WinAPI_SwapDWord($tEntry.Data) : $tEntry.Data)
;~ 					ConsoleWrite(StringFormat('!> Zeile:%i, Typ: 0x%.4X, Datatyp: %i, RawData: %i\r\n', @ScriptLineNumber, $iTyp, $iDatatyp, $iData))
					Switch $iTyp
						Case 0xA002 ; X-Aufloesung
							$iX = $iData
						Case 0xA003 ; Y-Aufloesung
							$iY = $iData
						Case 0x0132, 0x9003, 0x9004
							; 0x0132 = Erstellungsdatum (ExifDTCreated)
							; 0x9003 = Aufnahmedatum (ExifDTOrig)
							; 0x9004 = Digitalisierungsdatum (ExifDTDigitized)
							$tDT = DllStructCreate('align 1;char DT[20]', $iTIFFbegin + $iData)
							$sDT = StringReplace(StringLeft($tDT.DT, 10), ':', '/') & StringMid($tDT.DT, 11)
							$sRet &= '0x' & Hex($iTyp, 4) & ' ' & $sDT & @CR
						Case 0x8769 ; Position auf den naechsten IFD
							$pExif = $iTIFFbegin + $iData
							ExitLoop
					EndSwitch
					$iTagCount += 1 ; Anzahl der Tags erhoehen
				Until $iTagCount > $tBuffer.TagCount
				$iTagCount = 0
			Next
			$sRet = 'Resolution: ' & $iX & 'x' & $iY & @CR & $sRet
		EndIf
	EndIf
	Return $sRet
EndFunc

Alles anzeigen

**SOLVE-SMART**

Hi und Danke Oscar für dein EXIF_Rename Tool 👌 .
Bisher habe ich immer per ExifTool solche Dinge erledigt, doch dein Ansatz gefällt mir recht gut und ich schaue mal wie ich ihn für mich entsprechend anpassen werde.

Doch dazu würde ich gern wissen ob du das Tool unter irgendeiner Lizenz zu Verfügung stellst?

BSD, MIT, The Unlicense oder wie es AspirinJunkie gelegentlich macht, mit der allseits beliebten WTFPL license ?
Denn falls nicht, darf niemand (No license) dein Tool verwenden/modifizieren etc.

--------

Ansonsten ein paar kleine Korinthenkacker Anmerkungen meinerseits 😂:

Zeile 163: $tRect ==> already declared/assigned
Zeile 425: $sOldDir ==> wird nicht benutzt (kann also in Zeile 423 zusammen mit "$sNum" gelöscht werden)

Nochmals Danke 🤝 .

Viele Grüße
Sven

**SOLVE-SMART**

Nachtrag: Habe eben deinen rechtlichen Vermerk gesehen. Ist eine Art benutzerdefinierte Lizenz, okay. Doch damit fällt meine Modifikation "offiziell" weg. Bleibt es dabei Oscar ?

Viele Grüße
Sven

**Oscar**

Zitat von SOLVE-SMART

Doch damit fällt meine Modifikation "offiziell" weg. Bleibt es dabei Oscar ?

Den letzten Satz von dem "Rechtlichen" kannst Du auch streichen. Es ging mir eher darum, dass das Programm nicht etwas abgeändert und dann verkauft wird.