- Offizieller Beitrag
Möchte man für die FritzBox einen Anrufmonitor auf dem PC laufen lassen, so kann man dazu die FritzBox über den TCP-Port 1012 abfragen.
Dieser muss vorher aber geöffnet werden:
; Zum öffnen des Ports muss man (einmalig), an einem an die FritzBox angeschlossenen Telefon, folgendes eingeben:
; Port öffnen: #96*5*
; Port schliessen: #96*4*
Danach reicht ein einfaches Script, um die Meldungen zu empfangen:
Spoiler anzeigen
Opt('TrayAutoPause', 0)
HotKeySet('{ESC}', '_End')
TCPStartup()
Global $sTelList = @ScriptDir & '\Anrufliste.txt' ; <- Datei, in der die Anrufe gespeichert werden
[/autoit] [autoit][/autoit] [autoit]Global $sFritzBoxIP = TCPNameToIP('fritz.box') ; <- IP-Adresse der Fritzbox ermitteln
[/autoit] [autoit][/autoit] [autoit]; Zum öffnen des Ports muss man (einmalig), an einem an die FritzBox angeschlossenen Telefon, folgendes eingeben:
; Port öffnen: #96*5*
; Port schliessen: #96*4*
Global $sFritzBoxPort = 1012 ; <- TCP-Port zur Abfrage der Fritzbox
Global $hFritzSocket = TCPConnect($sFritzBoxIP, $sFritzBoxPort) ; <- Verbindung zur Fritzbox herstellen
If $hFritzSocket = -1 Then Exit MsgBox(0, 'Fehler!', 'Es konnte keine Verbindung zur FritzBox hergestellt werden.')
TrayTip('FritzBox', 'Anrufmonitor aktiv', 1000)
Global $sFritzRecv = ''
While Sleep(50)
$sFritzRecv = TCPRecv($hFritzSocket, 2048)
If $sFritzRecv <> '' Then _TelRing($sFritzRecv)
WEnd
Func _TelRing($sRecv)
ConsoleWrite($sRecv & @CR)
Local $aMsg = StringSplit($sRecv, ';')
If Not IsArray($aMsg) Then Return
If $aMsg[0] < 5 Then Return
Switch $aMsg[2]
Case 'RING'
FileWriteLine($sTelList, $aMsg[1] & ' Tel.-Nr.: ' & $aMsg[4])
TrayTip('Anruf', $aMsg[4], 30, 1)
Case 'DISCONNECT'
TrayTip('', '', 0)
EndSwitch
EndFunc ;==>_TelRing
Func _End()
TCPCloseSocket($hFritzSocket)
TCPShutdown()
Exit
EndFunc ;==>_End
Das funktioniert auf jeden Fall mit der 7170 und der 7490. Diese beiden Boxen besitze ich und damit ist das Script getestet.
Es sollten aber auch die anderen FritzBoxen funktionieren. Ich würde mich über entsprechende Rückmeldungen freuen.
Funktionierende Fritzboxen (getestet):
Oscar: 7170 und 7490
UEZ: 7362 SL
Simulac2: 7330