Autoit Spiel (Logik)

xSunLighTx3

Hey Com

momentan probiere ich ein Spiel zu programmieren, welches eigentlich jeder kennt.
Es heißt breakout. Eigentlich habe ich schon alles aber ein Bug stört total.

Wenn sich die Kugel auf ein Objekt (Rechteck) bewegt, muss ich ja wissen, ob es sich oben/unten oder
links/rechts vom Objekt befindet, sodass ich den Winkel (EInfallswinkel=Ausfallswinkel)
richtig einstellen kann.

Das eigentliche Problem besteht darin, dass sich die Kugel ja nicht immer um +1 Koordinaten
bewegt. Und ich weiß jetzt nicht wie ich das abfragen soll, in welcher Richtung sich die Kugel
des Objektes befindet, falls sie es berührt, weil theoretisch könnte es ja auch einen Pixel in dem
Objekt sein und nicht immer genau am Rand vom Objekt. Deswegen habe ich z.B schon versucht,
einen bestimmten Abstand abzufragen, wo sich die Kugel mit welcher Geschwindigkeit befinden kann,
wenn es ein Objekt berührt. Aber dann überkreuzen sich die Abfragen und der Winkel stimmt nicht
mehr, wenn es auf ganz bestimmten Stellen auf das Objekt prallt.

Ich habe mir mal ein Projekt in C++ angesehen und da wird es so deklariert:

C

Dim speed As Single = 5
Dim xVel As Single = Math.Cos(speed) * speed
Dim yVel As Single = Math.Sin(speed) * speed

Aber da gibt es das Problem nicht. Hat jemand damit auch Erfahrungen
gemacht oder weiß eine Lösung? Ich bin echt ratlos.

Liebe Grüße,
xSunLighTx3

**chip**

Weiß nicht in wie weit das performant ist, aber eine Möglichkeit wäre es nicht ständig zu prüfen ob eine Kollision stattfindet sonder nach einem Abpraller einmal berechnen wo und wann sie stattfindet. Wenn du weißt wo in der Flugbahn hast du den Winkel und durch die Geschwindigkeit der Kugel weißt du wann sie dort ankommt.

**Andy**

Zitat von xSunLighTx3

Das eigentliche Problem besteht darin, dass sich die Kugel ja nicht immer um +1 Koordinaten
bewegt.

Natürlich tut sie das...
Nur wirst du aus Geschwindigkeitsgründen die DARSTELLUNG DER KUGEL (genauer, des Kreises) immer um mehrere "Pixel" verschieben.
Da die Berührung des Kreises mit einem der Rechtecke immer nur (idealerweise) an einem Punkt/Pixel stattfindet, ist die Berechnung simpel:

- Der Kreis besteht aus dem Mittelpunkt C und dem Radius r
- Das Rechteck besteht aus 4 Eckpunkten ABUW, Teile in 4 Strecken auf: AB,BU,UW,WA

- Wenn der Abstand des Kreismittelpunktes zu einer der Strecken kleiner/gleich r, gibt es eine Berührung.
Beispiel für Abfrage, ob der Kreis die Strecke AB berührt, dazu benötigt man nur die Streckenlängen AB, AC und BC (diese Berechnung sollte wohl kein Problem darstellen^^)
Jetzt zur Auswertung:
Wenn AC<=r oder BC<=r dann Berührung!

BC² ist das Quadrat der Strecke BC usw, zuerst wird der Abstand des Kreismittelpunktes C senkrecht zur Strecke AB berechnet:
x = (BC²-AC²-AB²)/(-2*AB)
Auswertung:
Wenn x>=0 und x<=AB und sqrt(AC²-x²)<=r dann Berührung!

Script:

AutoIt

#include <GDIPlus.au3>
#include <GDIPlus.au3>
_GDIPlus_Startup()
$hGUI = GUICreate("", 500, 500)
GUISetState(@SW_SHOW)
$hGr = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsClear($hGr, 0xFFFFFFFF)
$hBrush_rot = _GDIPlus_PenCreate(0xFFFF0000, 3)                  ;rot
$hBrush_gruen = _GDIPlus_PenCreate(0xFF00FF00, 3)                ;grün
$killpen = _GDIPlus_PenCreate(0xFFFFFFFF)                        ;hintergrund
;Strecke AB
$Ax = 200
$Ay = 150
$Bx = 350
$By = 260
_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_rot)
;Kreismittelpunkt und Radius
$Cx = 180
$Cy = 240
$r = 40
For $x = 1 To 150
    _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - $r, $Cy - $r, 2 * $r, 2 * $r) ;Kreis zeichnen
    If Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By) Then
        WinSetTitle($hGUI, "", "BERÜHRUNG!!!!!!")
        _GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_rot)
        Sleep(80)
    Else
        WinSetTitle($hGUI, "", "")
        _GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_gruen)
    EndIf
    Sleep(80)
    _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - $r, $Cy - $r, 2 * $r, 2 * $r, $killpen) ;Kreis löschen
    $Cx = $Cx + 1                                               ;nächste koordinate Kreis
    $Cy = $Cy - 1
Next
_GDIPlus_GraphicsDispose($hGr)
_GDIPlus_Shutdown()
Func Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By)  ;Kreismittelpunkt und Radius, Streckenbegrenzung
    Local $AB2 = ($By - $Ay) ^ 2 + ($Bx - $Ax) ^ 2               ;AB²
    Local $AC2 = ($Cy - $Ay) ^ 2 + ($Cx - $Ax) ^ 2               ;AC²
    Local $BC2 = ($Cy - $By) ^ 2 + ($Cx - $Bx) ^ 2               ;BC²
    If Sqrt($AC2) <= $r Or Sqrt($BC2) <= $r Then Return 2        ;Berührung Endpunkt Gerade
    Local $x = ($BC2 - $AC2 - $AB2) / (-2 * Sqrt($AB2))
    If $x >= 0 And $x <= Sqrt($AB2) And Sqrt($AC2 - $x ^ 2) <= $r Then Return 1 ;Berührung Strecke
    Return 0
EndFunc                                                          ;==>Beruehrung_Kreis_Strecke

Alles anzeigen

//EDIT Beachte die Vereinfachung bei der Rückgabe der Funktion! 1 wenn die Strecke berührt wurde, 2 wenn einer der "Ecken"(Endpunkte) berührt wurden. das braucht man für die anschließende Berechnung der Winkel für den weiteren Flug...

Die Berechnung, ob die Linie den Kreis berührt, dauert auf meinem Rechner ca. 0.03ms .
Angenommen, das Spiel enthält 100 "Bricks", das ergibt 400 Linien/Seitenwände a 0.03ms ergibt 12ms für die Berechnung der Kollision ALLER 100 Bricks mit dem Kreis....

Wenn eine Kollision festgestellt wurde, ist der Rest doch nur noch den weiteren Winkel für die Flugrichtung anpassen. Das kann man sehr leicht machen, denn man weiß ja, ob eine obere, untere, rechte oder linke Seitenwand oder eine "Ecke" (Endpunkt der Strecke) getroffen wurde!

Alternativ könnte man "Raytraycing" machen, so wie es von Chip vorgeschlagen wurde. Dabei würde man parallele "Strahlen" von der Kreishälfte in Flugrichtung "aussenden" und schauen, wo diese ein (und welches) Objekt/Seitenteil treffen. Auf dem Weg des Kreises bis zum Kollisionspunkt hat man nichts weiteres zu tun als den Kreis darzustellen...
Es bietet sich an, nicht von jedem Punkt des Halbkreises ein "Ray" auszusenden, je nach Größe des Kreises und der Rechengeschwindigkeit reichen 10-12 Strahlen sicher aus.
Da nur der Kollisionspunkt "Ray" mit den Seitenwänden abgefragt werden muss (also nur der Schnittpunkt zweier Linien) ist die Berechnung schnell erledigt.
Wenn man dann noch clever selektiert ("rechte" Seitenwände können nur von einem nach links fliegenden Kreis getroffen werden, "untere" Seitenwände nur von einem nach oben fliegenden Kreis usw.), dann reduziert sich die Berechnung massiv! Dazu noch eine clevere Anordnung der Seitenteile im Array und auch AutoIt hat massig Zeit übrig um für ausreichende FPS zu sorgen

**Mars**

Das mit den Strahlen hatte ich irgendwo schonmal ausprobiert. Wenn ich mich nicht irre haben 3 Strahlen ausgereicht, nämlich in Flugrichtung mit den Startpunkten Senkrecht links, senkrecht rechts am Kreis und einer in der Mitte. Da man via Vektorrechnung und ohne "feste" Schritte Arbeitet überprüft man nur ob die Strecken (Bewegungsvektoren) andere Strecken schneiden, und das tun sie unabhängig von der Objektgröße.

Das Vorgehen bei "korrekter" Kollision ist wie folgt: ("Zeit zwischen den Frames" = T = 1)
- Man hat z.B. 10 Kugeln.
- Man überprüft ob es im nächsten Frame überhaupt irgendeine Kollision gibt. Wenn nein -> bewegen, fertig. Wenn ja gehts weiter.
- Man findet die zeitlich gesehen erste Kollision (zum Zeitpunkt t < T) und berechnet diese. Man bewegt alle Kugeln um ihrem Richtungsvektor mit Faktor dt/T.
- Man führt den vorherigen Schritt solange aus, bis die zeitlich gesehen nächste Kollision bei einem t > T stattfindet. Dann bewegt man die Kugeln noch das kleine Stück (im Normalfall der Faktor 1 - t) bis T voll ist, und hat den zu berechnenden Frame fertig.

Edit: Das ist hier nur die Weganleitung, wie man die Kollisionen im Konkreten berechnet kann man woanderst nachlesen

xSunLighTx3

Danke für eure awesome Hilfe. Ich glaube raytraycing ist mir noch zu schwer. :x (Hab mal sowas Ähnliches versucht, aber da bin ich schon mit der DrawLine überfordert, die richtig zu setzen. )

Ich hab das jetzt mal mit einem Rechteck versucht und irgendwie klappt es da nicht. Bestimmt habe ich was falsch gemacht. :o

AutoIt

#include <GDIPlus.au3>
#include <GDIPlus.au3>
_GDIPlus_Startup()
$hGUI = GUICreate("", 500, 500)
GUISetState(@SW_SHOW)
$graphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsClear($graphic, 0xFFFFFFFF)
$hBrush_rot = _GDIPlus_PenCreate(0xFFFF0000, 3)                  ;rot
$hBrush_gruen = _GDIPlus_PenCreate(0xFF00FF00, 3)                ;grün
$killpen = _GDIPlus_PenCreate(0xFFFFFFFF)                        ;hintergrund
;Strecke AB
$Ax = 200
$Ay = 150
$Bx = 70
$By = 10
;~ _GDIPlus_GraphicsDrawLine($graphic, $Ax, $Ay, $Bx, $By, $hBrush_rot)
_GDIPlus_GraphicsDrawRect($graphic, $Ax, $Ay, $Bx, $By, $hBrush_rot)
;Kreismittelpunkt und Radius
$Cx = 180
$Cy = 200
$r = 20
For $x = 1 To 150
    _GDIPlus_GraphicsDrawEllipse($graphic, $Cx - $r, $Cy - $r, 2 * $r, 2 * $r) ;Kreis zeichnen


  If Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By) Then
;~         _GDIPlus_GraphicsDrawLine($graphic, $Ax, $Ay, $Bx, $By, $hBrush_rot)
		_GDIPlus_GraphicsDrawRect($graphic, $Ax, $Ay, $Bx, $By, $hBrush_rot)
    Else
;~         _GDIPlus_GraphicsDrawLine($graphic, $Ax, $Ay, $Bx, $By, $hBrush_gruen)
		_GDIPlus_GraphicsDrawRect($graphic, $Ax, $Ay, $Bx, $By, $hBrush_gruen)
    EndIf


    Sleep(80)
    _GDIPlus_GraphicsDrawEllipse($graphic, $Cx - $r, $Cy - $r, 2 * $r, 2 * $r, $killpen) ;Kreis löschen
    $Cx = $Cx + 1                                               ;nächste koordinate Kreis
    $Cy = $Cy - 1
Next
_GDIPlus_GraphicsDispose($graphic)
_GDIPlus_Shutdown()
Func Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By)  ;Kreismittelpunkt und Radius, Streckenbegrenzung
    Local $AB2 = ($By - $Ay) ^ 2 + ($Bx - $Ax) ^ 2               ;AB²
    Local $AC2 = ($Cy - $Ay) ^ 2 + ($Cx - $Ax) ^ 2               ;AC²
    Local $BC2 = ($Cy - $By) ^ 2 + ($Cx - $Bx) ^ 2               ;BC²
    If Sqrt($AC2) <= $r Or Sqrt($BC2) <= $r Then Return 2        ;Berührung Endpunkt Gerade
    Local $x = ($BC2 - $AC2 - $AB2) / (-2 * Sqrt($AB2))
    If $x >= 0 And $x <= Sqrt($AB2) And Sqrt($AC2 - $x ^ 2) <= $r Then Return 1 ;Berührung Strecke
    Return 0
EndFunc                                                          ;==>Beruehrung_Kreis_Strecke

Alles anzeigen

**Andy**

Zitat von xSunLighTx3

Ich hab das jetzt mal mit einem Rechteck versucht

Was habe ich denn oben geschrieben?

Zitat von Andy

Das Rechteck besteht aus 4 Eckpunkten ABUW, Teile in 4 Strecken auf: AB,BU,UW,WA

Wie soll denn eine Funktion, die Beruehrung_Kreis_Strecke() heißt, etwas anderes machen als den Berührungspunkt von einem Kreis und einer Strecke berechnen?
DU sollst aus dem Rechteck 4 Strecken(Seitenteile) machen, und die kannst du dann mit der Funktion überprüfen.

Zitat von xSunLighTx3

aber da bin ich schon mit der DrawLine überfordert,

Wenn du mit Trigonometrie, also simplen Sinus, Cosinus, Tangens auch so überfordert bist, solltest du dich dahingehend DRINGEND fit machen....
Wie siehts damit aus, den Kreis auf einem völlig leeren Spielfeld an den Wänden abprallen zu lassen, bekommst du das hin?

xSunLighTx3

Oh Mist, sorry hab das vorhin falsch interpretiert oder war einfach neben der Spur.
Ich glaube so müsste das ca. stimmen oder? Da fehlen noch die Auswertungen der
returns von der Funktion Beruehrung_Kreis_Strecke().

AutoIt

#include <GDIPlus.au3>
#include <GDIPlus.au3>
_GDIPlus_Startup()
$hGUI = GUICreate("", 500, 500)
GUISetState(@SW_SHOW)
$hGr = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsClear($hGr, 0xFFFFFFFF)
$hBrush_rot = _GDIPlus_PenCreate(0xFFFF0000, 3)                  ;rot
$hBrush_gruen = _GDIPlus_PenCreate(0xFF00FF00, 3)                ;grün
$killpen = _GDIPlus_PenCreate(0xFFFFFFFF)                        ;hintergrund
;Strecke AB
$Ax = 200 ; brick X1
$Ay = 150 ; brixk Y1
$Bx = $Ax + 70 ; brick X2
$By = $Ay ; brick Y2


;Kreismittelpunkt und Radius
$Cx = 180 ; ball X1
$Cy = 240 ; ball Y1
$r = 10 ; ball R


For $x = 1 To 150
    _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - $r, $Cy - $r, 2 * $r, 2 * $r) ;Kreis zeichnen


	If _BallHitBrick($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By, 70, 10) Then
		_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_rot) ; oben wagerecht
		_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay +10, $Bx, $By +10, $hBrush_rot) ; unten wagerecht
		_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay-1, $Ax, $Ay+12, $hBrush_rot) ; links senkrecht
		_GDIPlus_GraphicsDrawLine($hGr, $Ax+70, $Ay-1, $Ax+70, $Ay+12, $hBrush_rot) ; rechts senkrecht
	Else
		_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_gruen) ; oben wagerecht
		_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay +10, $Bx, $By +10, $hBrush_gruen) ; unten wagerecht
		_GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay-1, $Ax, $Ay+12, $hBrush_gruen) ; links senkrecht
		_GDIPlus_GraphicsDrawLine($hGr, $Ax+70, $Ay-1, $Ax+70, $Ay+12, $hBrush_gruen) ; rechts senkrecht
	EndIf


;~ 	_GDIPlus_GraphicsDrawRect($hGr, $Ax, $Ay+22, 70, 10, $hBrush_gruen) ; brick example


    Sleep(80)
    _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - $r, $Cy - $r, 2 * $r, 2 * $r, $killpen) ;Kreis löschen
    $Cx = $Cx + 1                                               ;nächste koordinate Kreis
    $Cy = $Cy - 1
Next


_GDIPlus_GraphicsDispose($hGr)
_GDIPlus_Shutdown()


Func _BallHitBrick($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By, $len = 70, $wid = 10)


	If Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By) Then ; oben wagerecht
		Return 1
	ElseIf Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay +$wid, $Bx, $By +$wid) Then ; unten wagerecht
		Return 2
	ElseIf Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay-1, $Ax, $Ay+$wid +2) Then ; links senkrecht
		Return 3
	ElseIf Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax+$len, $Ay-1, $Ax+$len, $Ay+$wid +2) Then ; links senkrecht
		Return 4
	EndIf


	Return 0
EndFunc


Func Beruehrung_Kreis_Strecke($Cx, $Cy, $r, $Ax, $Ay, $Bx, $By)  ;Kreismittelpunkt und Radius, Streckenbegrenzung
    Local $AB2 = ($By - $Ay) ^ 2 + ($Bx - $Ax) ^ 2               ;AB²
    Local $AC2 = ($Cy - $Ay) ^ 2 + ($Cx - $Ax) ^ 2               ;AC²
    Local $BC2 = ($Cy - $By) ^ 2 + ($Cx - $Bx) ^ 2               ;BC²
    If Sqrt($AC2) <= $r Or Sqrt($BC2) <= $r Then Return 2        ;Berührung Endpunkt Gerade
    Local $x = ($BC2 - $AC2 - $AB2) / (-2 * Sqrt($AB2))
    If $x >= 0 And $x <= Sqrt($AB2) And Sqrt($AC2 - $x ^ 2) <= $r Then Return 1 ;Berührung Strecke
    Return 0
EndFunc                                                          ;==>Beruehrung_Kreis_Strecke

Alles anzeigen

Mit Sin und Cos habe ich schon den Ausfallswinkel berechnet.

Danke nochmal für die Hilfe!, hast es echt drauf.

**Andy**

Hi,
"so ähnlich" habe ich mir das gedacht
Allerdings hast du mit AutoIt das Problem, dass du nicht viel Rechenzeit zur Verfügung hast. Daher auch der Hinweis auf die Seitenwände der Rechtcke.
Deine Funktion _BallHitBrick() funktioniert natürlich nur, weil dein Ball von unten kommt...
Fliegt der Ball von oben nach unten, wird die Kollision erst festgestellt, wenn die untere Seitenwand berührt wird

Löse dich von dem RECHTECK!
Wenn dein Ball nach rechts oben fliegt, kann NIEMALS ein linkes oder ein oberes Seitenteil getroffen werden, die Kollisions-Überprüfung reduziert sich auf die HÄLFTE!!!
Hast du dir mal Gedanken gemacht, wie du die 100 Rechtecke nacheinander auf Kollision prüfen willst?

Ich glaube, ich hack mal die 100 Zeilen zusammen um das Spiel zu programmieren^^

**Mars**

Die Kollisionsberechnung für 1000 Rechtecke geht in konstanter Zeit und dauert genausolang wie die Kollisionserkenung von einem einzigen Rechteck. Nimm eine Bitmap in Spielfeldgröße mit der Farbe 0x00000000, anschließend nummerierst du alle Rechtecke mit 0x00000001, usw usw und zeichnest diese in die Bitmap. Dann kann man per Pixelgetcolor (oder per Dllstruct, wenn man es schnell haben will) innerhalb weniger Takte wissen ob in der Nähe des Balls ein Rechteck ist. Anschließend überprüft man die Vektorkollision (Also die Rechnung für die Bewegung des Balls) nur mit den Rechtecken die in der direkten Umgebung des Balls sind (sollten immer unter 8 Stück sein, sonst wirds unlogisch :D).

xSunLighTx3

Zitat von Andy

Deine Funktion _BallHitBrick() funktioniert natürlich nur, weil dein Ball von unten kommt...
Fliegt der Ball von oben nach unten, wird die Kollision erst festgestellt, wenn die untere Seitenwand berührt wird

Maaahlzeit,
Bei mir funktioniert das (der Ball kommt von oben rechts und fliegt nach unten links)
[Blockierte Grafik: http://puu.sh/rwfM5/6ee4a62258.png]

Oder habe ich das falsch verstanden? Das mit der Reduzierung kann man dann ja einbauen,
wenn:

AutoIt

$deg = ACos(-1) / 180
$ballSpeed = 7
$ballAngle = 270
$ballX1 += Cos($ballAngle * $deg) * $ballSpeed
$ballY1 -= Sin($ballAngle * $deg) * $ballSpeed

berechnet ist.

Zitat von Andy

Hast du dir mal Gedanken gemacht, wie du die 100 Rechtecke nacheinander auf Kollision prüfen willst?

Man könnte ja die Distanz berechnen: d=sqrt( (x2−x1)²+(y2−y1)² )
Aber ob das viel schneller ist, weiß ich auch nicht ehrlich gesagt.

Zitat von Mars

Die Kollisionsberechnung für 1000 Rechtecke geht in konstanter Zeit und dauert genausolang wie die Kollisionserkenung von einem einzigen Rechteck. Nimm eine Bitmap in Spielfeldgröße mit der Farbe 0x00000000, anschließend nummerierst du alle Rechtecke mit 0x00000001, usw usw und zeichnest diese in die Bitmap. Dann kann man per Pixelgetcolor (oder per Dllstruct, wenn man es schnell haben will) innerhalb weniger Takte wissen ob in der Nähe des Balls ein Rechteck ist. Anschließend überprüft man die Vektorkollision (Also die Rechnung für die Bewegung des Balls) nur mit den Rechtecken die in der direkten Umgebung des Balls sind (sollten immer unter 8 Stück sein, sonst wirds unlogisch :D).

Hätten die dann nicht alle Rechtecke eine Farbe oder makiert man das intern?

**Andy**

Hi,
hat mir natürlich keine Ruhe gelassen

AutoIt

#include <GDIPlus.au3>
#include <GDIPlus.au3>
_GDIPlus_Startup()




$width = 700
$height = 500


Global $A[5][100][100]                         ;flags für alle seitenteile
Global $W[5]                                   ;oben unten rechts links


Global $debug = 0                              ;0 für volle Geschwindigkeit
Global $debugsleep = 500                       ;sleep für die debugmeldungen


Opt("GUIOnEventMode", 1)




$hGUI = GUICreate("Bricks", $width, $height, 10, 10)
GUISetOnEvent(-3, "_EXIT")






GUISetState(@SW_SHOW)
$hGr = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsClear($hGr, 0xFFFFFFFF)


$hBrush_rot = _GDIPlus_PenCreate(0xFFFF0000, 3) ;rot
$hBrush_gruen = _GDIPlus_PenCreate(0xFF00FF00, 3) ;grün
$hBrush_gelb = _GDIPlus_PenCreate(0xFF00FFFF, 3) ;gelb
Global $killpen = _GDIPlus_PenCreate(0xFFFFFFFF, 3) ;hintergrund
$pengruen = _GDIPlus_PenCreate(0xFF00FF00)


$misses = 0                                    ;überflüssige Berechnungen ob Brick getroffen


;Bricks erstellen
$Breite = 50
$Hoehe = 25


;Seitenteile
$O = 1                                         ;oben
$U = 2                                         ;unten
$R = 3                                         ;rechts
$L = 4                                         ;links






$AnzahlBricks = 0


;Seitenteile definieren und spielfeld zeichnen
For $x = 2 To ($width - $Breite * 2) / $Breite
    For $y = 2 To ($height - 200) / $Hoehe
        $col = 0xFF0F0000 + 2550 * $x + 20 * $y ;farbe
        $hBrush = _GDIPlus_PenCreate($col, 3)
        $A[$O][$x][$y] = 1
        _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite, $y * $Hoehe, $x * $Breite + $Breite - 5, $y * $Hoehe, $hBrush)
        $A[$U][$x][$y] = 1
        _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite, $y * $Hoehe + $Hoehe - 5, $x * $Breite + $Breite - 5, $y * $Hoehe + $Hoehe - 5, $hBrush)
        $A[$L][$x][$y] = 1
        _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite, $y * $Hoehe, $x * $Breite, $y * $Hoehe + $Hoehe - 5, $hBrush)
        $A[$R][$x][$y] = 1
        _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite + $Breite - 5, $y * $Hoehe, $x * $Breite + $Breite - 5, $y * $Hoehe + $Hoehe - 5, $hBrush)
        $AnzahlBricks += 1
    Next
Next


$t = 0


;Kreismittelpunkt und Radius
$Cx = 180
$Cy = 360
$Radius = 12


;startwinkel flugbahn
Global $fx = 1.7
Global $fy = -1.7
Global $fps
;Ball startet nach oben rechts, alle rechten und oberen Seitenteile ausblenden
Seitenteile_ausblenden($fx, $fy)


AdlibRegister("CalcFPS", 1000)




While 1                                        ;


    _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - $Radius, $Cy - $Radius, 2 * $Radius, 2 * $Radius) ;Kreis zeichnen
    If $debug Then Sleep(20)
    sleep(1)


    ;Seitenteil getroffen?
    For $x = 2 To ($width - $Breite * 2) / $Breite
        If $x > ($Cx - 5 * $Radius) / $Breite And $x < ($Cx + 5 * $Radius) / $Breite Then ;nur die Seitenteile im Abstand vom doppelten Radius abfragen
            For $y = 2 To ($height - 200) / $Hoehe
                If $y > ($Cy - 5 * $Radius) / $Hoehe And $y < ($Cy + 5 * $Radius) / $Hoehe Then ;nur die Seitenteile im Abstand vom doppelten Radius abfragen


                    For $t = 1 To 4            ;alle Seitenteile,oben,unten,rechts,links
                        If $A[$t][$x][$y] = 1 Then ;nur wenn das Seitenteil existiert


                            If $debug Then _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - 5 * $Radius, $Cy - 5 * $Radius, 10 * $Radius, 10 * $Radius, $pengruen)
;~ consolewrite($x&"   "&$y&@crlf)


                            If $W[$t] = 1 Then ; nur wenn seitenteil aktiv


                                $Ax = $x * $Breite
                                $Bx = $x * $Breite + $Breite - 5
                                Switch $t
                                    Case 1     ;oben
                                        $Ay = $y * $Hoehe
                                        $By = $y * $Hoehe
                                        If $debug Then ConsoleWrite("oben" & @CRLF)
                                    Case 2     ;unten
                                        $Ay = $y * $Hoehe + $Hoehe - 5
                                        $By = $y * $Hoehe + $Hoehe - 5
                                        If $debug Then ConsoleWrite("unten" & @CRLF)
                                    Case 3     ;rechts
                                        $Ax = $x * $Breite + $Breite - 5
                                        $Ay = $y * $Hoehe
                                        $Bx = $x * $Breite + $Breite - 5
                                        $By = $y * $Hoehe + $Hoehe - 5
                                        If $debug Then ConsoleWrite("rechts" & @CRLF)
                                    Case 4     ;links
                                        $Ay = $y * $Hoehe
                                        $Bx = $x * $Breite
                                        $By = $y * $Hoehe + $Hoehe - 5
                                        If $debug Then ConsoleWrite("links" & @CRLF)
                                EndSwitch


                                If $debug Then _GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_rot)


                                $timer1 = TimerInit()
                                Switch Beruehrung_Kreis_Strecke($Cx, $Cy, $Radius, $Ax, $Ay, $Bx, $By)
                                    Case 0     ;nichts berührt
                                        $misses += 1


                                    Case 1     ;strecke berührt


                                        If $debug Then
                                            WinSetTitle($hGUI, "", "BERÜHRUNG Strecke!!!!!!")
                                            _GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_gelb)
                                            Sleep($debugsleep)
                                        EndIf


                                        _deleteBrick($t, $x, $y)
                                        If $t = 1 Or $t = 2 Then $fy = -$fy ;oben oder unten getroffen, richtung umkehren
                                        If $t = 3 Or $t = 4 Then $fx = -$fx ;rechts oder links
                                        Seitenteile_ausblenden($fx, $fy)
                                        ExitLoop 3
                                    Case 2     ;ecke berührt


                                        If $debug Then
                                            WinSetTitle($hGUI, "", "BERÜHRUNG Ecke!!!!!!")
                                            _GDIPlus_GraphicsDrawLine($hGr, $Ax, $Ay, $Bx, $By, $hBrush_gelb)
                                            Sleep($debugsleep)
                                        EndIf


                                        _deleteBrick($t, $x, $y)
                                        $fx = -Random(0.8, 1.2) * $fx
                                        $fy = -Random(0.8, 1.2) * $fy


                                        Seitenteile_ausblenden($fx, $fy)
;~                                         $fy = -$fy ;oben oder unten
;~                                         $fx = -$fx ;rechts oder links


                                        ExitLoop 3
                                EndSwitch
;~     Sleep(20)
;~                         ConsoleWrite(TimerDiff($timer1) & @CRLF)
                            EndIf
                        EndIf
                    Next
                EndIf
            Next
        EndIf
    Next




    ;in der Nähe der Wand?
    If $Cy < 1.2 * $Radius Or $Cy > $height - 1.2 * $Radius Then
        ;Wand oben oder unten getroffen?
        If Beruehrung_Kreis_Strecke($Cx, $Cy, $Radius, 0, 0, $width, 0) Or Beruehrung_Kreis_Strecke($Cx, $Cy, $Radius, 0, $height, $width, $height) Then
            $fy = -$fy
            Seitenteile_ausblenden($fx, $fy)
        EndIf
    EndIf
    If $Cx < 1.2 * $Radius Or $Cx > $width - 1.2 * $Radius Then
        ;Wand rechts oder links getroffen?
        If Beruehrung_Kreis_Strecke($Cx, $Cy, $Radius, $width, 0, $width, $height) Or Beruehrung_Kreis_Strecke($Cx, $Cy, $Radius, 0, 0, 0, $height) Then
            $fx = -$fx
            Seitenteile_ausblenden($fx, $fy)
        EndIf
    EndIf


    _GDIPlus_GraphicsDrawEllipse($hGr, $Cx - $Radius, $Cy - $Radius, 2 * $Radius, 2 * $Radius, $killpen) ;Kreis löschen
    $Cx = $Cx + $fx                            ;nächste koordinate Kreis
    $Cy = $Cy + $fy
    $fps += 1


WEnd




Func CalcFPS()
    WinSetTitle($hGUI, "", "Misses. " & $misses & "   FPS: " & $fps)
    $fps = 0
EndFunc                                        ;==>CalcFPS


Func _deleteBrick($t, $x, $y)                  ;alle 4 Seitenteile löschen
    $A[$O][$x][$y] = 0
    _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite, $y * $Hoehe, $x * $Breite + $Breite - 5, $y * $Hoehe, $killpen)
    $A[$U][$x][$y] = 0
    _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite, $y * $Hoehe + $Hoehe - 5, $x * $Breite + $Breite - 5, $y * $Hoehe + $Hoehe - 5, $killpen)
    $A[$R][$x][$y] = 0
    _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite, $y * $Hoehe, $x * $Breite, $y * $Hoehe + $Hoehe - 5, $killpen)
    $A[$L][$x][$y] = 0
    _GDIPlus_GraphicsDrawLine($hGr, $x * $Breite + $Breite - 5, $y * $Hoehe, $x * $Breite + $Breite - 5, $y * $Hoehe + $Hoehe - 5, $killpen)
    $AnzahlBricks -= 1
    If $AnzahlBricks = 0 Then Exit (MsgBox(0, "Bricks", "Spielfeld leer!"))
EndFunc                                        ;==>_deleteBrick
;==>


Func Beruehrung_Kreis_Strecke($Cx, $Cy, $R, $Ax, $Ay, $Bx, $By) ;Kreismittelpunkt und Radius, Streckenbegrenzung
    Local $AB2 = ($By - $Ay) ^ 2 + ($Bx - $Ax) ^ 2 ;AB²
    Local $AC2 = ($Cy - $Ay) ^ 2 + ($Cx - $Ax) ^ 2 ;AC²
    Local $BC2 = ($Cy - $By) ^ 2 + ($Cx - $Bx) ^ 2 ;BC²


    If Sqrt($AC2) <= $R Or Sqrt($BC2) <= $R Then Return 2 ;Berührung Endpunkt Gerade


    $Beruehrung_Abstand_von_A = ($BC2 - $AC2 - $AB2) / (-2 * Sqrt($AB2)) ;Abstand von A bis Berührpunkt
    If $Beruehrung_Abstand_von_A >= 0 And $Beruehrung_Abstand_von_A <= Sqrt($AB2) And Sqrt($AC2 - $Beruehrung_Abstand_von_A ^ 2) <= $R Then Return 1 ;Berührung Strecke


    Return 0


EndFunc                                        ;==>Beruehrung_Kreis_Strecke


Func atan2($y, $x)
    Return (2 * ATan($y / ($x + Sqrt($x * $x + $y * $y))))
EndFunc                                        ;==>atan2






Func _EXIT()
    _GDIPlus_GraphicsDispose($hGr)
    _GDIPlus_Shutdown()
    Exit
EndFunc                                        ;==>_EXIT




Func Seitenteile_ausblenden($fx, $fy)          ;blendet alle Seitenteile aus, die nicht zu treffen sind
    If $fx >= 0 Then                           ;wenn ball nach rechts fliegt, dann keine rechten Seitenteile prüfen
        $W[$R] = 0
        $W[$L] = 1
    Else
        $W[$R] = 1
        $W[$L] = 0
    EndIf
    If $fy >= 0 Then                           ;wenn ball nach unten fliegt, dann keine unteren Seitenteile prüfen
        $W[$U] = 0
        $W[$O] = 1
    Else
        $W[$U] = 1
        $W[$O] = 0
    EndIf
EndFunc                                        ;==>Seitenteile_ausblenden

Alles anzeigen

Schnell zusammengehackt, ohne den Sleep(1) in Zeile 87 habe ich knapp 500FPS...
Oben im Script kann man eine Variable $debug setzen, dann sieht man, wie ich versucht habe, die Kollisionsberechnungen zu minimieren.
Ich detektiere zwei Treffer, einmal auf die Fläche(Linie) eines der Seitenteile und dann die "Ecke". Bei einem Eckentreffer habe ich mir die Winkelberechnung geschenkt (es wird sowieso kein einziger Winkel berechnet!) und den Ball in eine zufällige Richtung zurückgeworfen.
Es werden nur Kollisionen berechnet, wenn AKTIVE Seitenteile in der Nähe sind. Aktiv heisst, das sind nur die, die aus der Richtung des Balls überhaupt getroffen werden können!
Diese werden im debug-Modus rot eingefärbt, die "Nähe" für die Kollisionsberechnung wird durch den grünen Kreis sichtbar gemacht.
Die im Fensterrahmen dargestellten "Misses" sind die Kollisionsberechnungen, welche keinen Treffer ergeben haben.

xSunLighTx3

Fette Sache, Andy.

und dieser Code... Das muss man erstmal alles durchstudieren.
Echt geil, vielen Dank fürs veröffentlichen des Skripts, hilft mir einiges weiter.

**Andy**

Man kann das natürlich wesentlich vereinfachen, indem man Rechtecke verwendet und für die Kollisionsabfrage auch das oben schon besprochene "Raytracing".
Allerdings ist das nicht ganz so einfach wie von Mars vermutet. Bei großen Kugeln und kleinen Rechtecken muß man mehrere Strahlen verwenden um den genauen Kollisionspunkt zu finden. Es reicht ja nicht, DASS eine Kollision stattfindet, sondern man muss auch wissen WO! Das wird vor allem dann interessant, wenn sich mehrere Objekte bewegen. Intersection von Rechtecken (der Weg der Kugel beschreibt ja ein Rechteck und der "erste zu treffende" Brick) ist da sicherlich ein Ansatz.

Mir ging es jedenfalls darum, die "Logik" umzusetzen, so wenige wie möglich Kollisionsabfragen einzubauen. Man wartet so lange, bis Objekte sich in der unmittelbaren Nähe befinden und lässt erst dann eine Kollisionsabfrage laufen.

xSunLighTx3

Ja klar, man könnte die Berechnungszeiten auf heftigster Ebene minimieren.
Aber dein Skript hat ja gezeigt, dass AutoIt doch noch ein wenig was drauf hat.

bazii

Hallo,

bitte entschuldigt. Aber vielleicht hilft das hier (in AutoIt geschrieben) weiter. Ich weiß nicht mehr wo ich diese Zip-Datei her habe. Wahrscheinlich aus dem autoitscript.com/forum. Über Google konnte ich es allerdings nicht mehr finden. Jedoch ist es fast genau das, was Du suchst meine ich. Die Zip ist groß (11,7 MB), weil Sound und Bilder integriert sind.

Hier der Link zu meiner Dropbox: _Arkanoid.rar
Event. kann mir jemand einen Link nennen, wo ich die Datei sinnvoller hochladen kann damit meine Dropbox nicht überläuft. Ich habe einen eigenen Server, möchte aber mit dem Upload hier keine Werbung für meine HP machen.

Also, hier der Inhalt der AutoIt Datei:

AutoIt: Arkanoid.au3

#include <misc.au3>
#include <sound.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Local $vx, $vy, $by = 530, $wdt = 800,  $hdt = 600,  $py = 550, $pw = 100, $px = $wdt/2 - $pw/2, $ph = 20, $bw = 15
Local $bh = 15, $bx = $wdt/2.05, $P1, $nk[11][11], $kick, $score, $B1, $pontos, $enemy[11][11], $nx[11][11], $str[10]
Local $nw[11][11], $nh[11][11], $life, $itens, $fase, $time, $pause, $delay,$start, $ps, $aux[10][10],$ini[10], $rest
Local $cores[9]=[0xccffff, 0xccff00, 0x00ff00, 0x999999, 0x009900, 0x0066ff, 0xff0000, 0xff9900,0x9900ff], $ny[11][11]


If Not FileExists("Record.ini") Then IniWrite("Record.ini", "Record", "Pts", $score)
$score = IniRead("Record.ini", "Record", "Pts", "$score")
$som = _SoundOpen("f22.wav")
_SoundPlay($som)


$gui =	GUICreate("", $wdt, $hdt, -1, -1, $WS_EX_CLIENTEDGE )
  		GUISetState()
$pic =	GUICtrlCreatePic("Ark1.bmp", 0, 0, $wdt, $hdt)
		GUISetBkColor(0x000000)
$Ds  =	GUICtrlCreateLabel( "                                          Hi-Score   " & $score, 0, 0, $wdt, 30)
		GUICtrlSetColor(-1, 0xffffff)
		GUICtrlSetFont(-1, 20, 800)
$P1  = 	GUICtrlCreateButton("", $wdt, $py, $pw, $ph)
		GUICtrlSetBkColor(-1, 0xf0fdfd)
$B1  = 	GUICtrlCreateButton("", $wdt, $by, $bw, $bh)
		GUICtrlSetBkColor(-1, 0x00000f0)


Func    GameOver($g)
	If  $g      =  0 Then
		$fase   =  0
		$life   =  3
		$pontos =  0
		GUICtrlSetImage($pic,"img0.bmp")
	EndIf
		$vy     =  9
		$itens  =  0
		GUICtrlSetData($Ds, "     Vidas " & $life & "                      Pontos  "& $pontos & "              Hi-Score   " & $score)
		GUICtrlSetBkColor($Ds, 0xff0000)
		GUICtrlSetColor($Ds, 0x000000)
		GUICtrlSetFont($Ds, 20, 800)
		$time  = 0
		For $i = 0 To 9
			$ini[$i] = IniRead("Mapa.ini", "Mapa", "linha" & $i + $fase*10, "")
			$str = StringSplit($ini[$i], ",", 2)
			For $j = 0 To 9
				$aux[$i][$j] = $str[$j]
				$nx[$i][$j]  = $j * 80
				$ny[$i][$j]  = $i * 30 + 35
				$nw[$i][$j]  = 80
				$nh[$i][$j]  = 30
				If Number($aux[$i][$j]) Then
					$enemy[$i][$j]= GUICtrlCreateButton("", $nx[$i][$j], $ny[$i][$j], $nw[$i][$j], $nh[$i][$j])
					GUICtrlSetBkColor(-1, $cores[$aux[$i][$j]])
					$nk[$i][$j] = Number($aux[$i][$j])
				Else
					$itens  += 1
					$nx[$i][$j] = -200
					$ny[$i][$j] = -200
				EndIf
				Timer()
			Next
			Timer()
		Next
		$delay = 0
		While $delay <> 119 And $start
			Display("   STAGE " & $fase + 1)
			Timer()
		WEnd
EndFunc


Func Som($sn)
	_SoundStop($som)
	$som = _SoundOpen("f" & $sn & ".wav")
	_SoundPlay($som)
EndFunc


while GUIGetMsg() <> -3
	$bx += $vx
	$by += $vy
	Select
		Case Not $start
			While  Not $start
				If _IsPressed(20) Then
					$start = 1
					GUICtrlDelete($Ps)
					SoundPlay("coin.wav", 1)
					Som(0)
					Delgui(0)
					GameOver(0)
				ElseIf $life >= 0 Then
					Display("  S t a r t ! ! ")
				EndIf
				If $life < 0 Then
					If $delay =  0 Then GUICtrlSetData($Ds, "                                           Game Over")
					If $delay = 60 Then GUICtrlSetData($Ds, "   Vidas 0" & "                    Pontos " & $pontos & "               HI-SCORE " & $score)
					Display("Game Over")
				EndIf
				If _IsPressed("1b") Then Exit
				If _SoundStatus($som) = "Stopped" Then
					$som = _SoundOpen("f.wav")
					_SoundPlay($som)
				EndIf
			WEnd
		Case _SoundStatus($som) = "Stopped"
			_SoundPlay($som)
		Case _IsPressed("0d") And Not $pause
			$pause = 1
		Case Not _IsPressed("0d") And $pause = 1
			Pause()
		Case _IsPressed(27) And $px + $pw < $wdt
			$px += 10
		Case _IsPressed(25) And $px >   0
			$px -= 10
	EndSelect


	Select
		Case $bx + $bw > $wdt - ($bw/2)
			$vx *= -1                         ;bol batendo direita  da parede
			_SoundPlay("bup.wav")
			$bx -= 1
			If $vx < 5 Then $vx -=  1
		Case $bx       <        ($bw/2)       ;bol batendo esquerda da parede
			$vx *= -1
			_SoundPlay("bup.wav")
			$bx += 1
			If $vx < 5 Then $vx +=  1
		Case $by       <   25 + ($bh/2)       ;bol batendo em  cima da parede
			$vy *= -1
			$by += 1
			_SoundPlay("bup.wav")
			If $vy < 8 Then $vy +=  1
		Case $by > $hdt     		  ;bol batendo em baixo da parede
			_SoundStop($som)
			SoundPlay("die.wav", 1)
			If $life >= 0 Then _SoundPlay($som)
			$px = ($wdt / 2) - ($pw / 2)
			$by  =  $py - 21 + Random(0,2)
			$bx  = $px + ($pw/2)+ Random(0,2)
			$life -= 1
			$time = 0
			$kick = 0
			GUICtrlSetPos($P1, $wdt/2 - $pw/2, $py )
			GUICtrlSetPos($B1, -100, $py )
			$delay = 0
			While $delay <> 119 And $life >= 0
				Display("   STAGE " & $fase + 1)
				Timer()
			WEnd
	EndSelect
	If $by + $bh > $py  Then
		If $bx + $bw > $px And $bx < $px + $pw And $by < $py + $ph/10  Then ;colidindo com o player
			_SoundPlay("pas.wav")
			$vy  *= -1
			$by  -=  1
			If $bx + $bw/2 < $px + $pw/2 Then
				$vx =  -($px+$pw/2 - $bx - $bw/2)/5
			ElseIf $bx - $bw/2 > $px + $pw/2 Then
				$vx = ($px + $pw/2 - $bx + $bw/2)/5 *-1
			EndIf
		EndIf
	EndIf


	For $i = 0 To 10
		For $j = 0 To 10
			If $by > $ny[$i][$j] Then
				If $by < $ny[$i][$j] + ($nh[$i][$j]) And $nx[$i][$j] < $bx And $nx[$i][$j] > $bx - $nw[$i][$j] Then
					$vy *= -1
					$nk[$i][$j]-=  1
					If Not $nk[$i][$j] Then
						$ny[$i][$j] = -100
						$nx[$i][$j] = -100
						SoundPlay("dw.wav")
						GUICtrlDelete($enemy[$i][$j])
						$itens  += 1
						$pontos += 5
						If $vy < 10 Then $vy += $itens/100
					Else
						GUICtrlSetData($enemy[$i][$j], $nk[$i][$j])
						GUICtrlSetFont($enemy[$i][$j], 16,800)
						SoundPlay("kkick.wav")
						$pontos += 3
					EndIf
				EndIf
			EndIf
		Next
	Next
		If $itens >= 100 Then
			$fase += 1
			GUICtrlSetImage($pic,"img" & $fase & ".bmp")
			Som($fase)
			Delgui(1)
			If $fase >  9 Then Exit
			If $fase < 10 Then GameOver(1)
			If $pontos > 1000 Then $life += 1
		EndIf
	GUICtrlSetPos($B1, $bx, $by )
	GUICtrlSetPos($P1, $px, $py )
	$delay = 101
	Display("")
	If $life  < 0 Then
		IniWrite("Record.ini", "Record", "pts", $score)
		_SoundStop($som)
		$start = 0
	EndIf
WEnd


Func Delgui($mod)
	For $i = 0 To 10
		For $j = 0 to 10
			GUICtrlDelete($enemy[$i][$j])
		Next
	Next
	GUICtrlSetPos($P1, $wdt)
	GUICtrlsetPos($B1, $wdt)
	If $mod = 1 Then
		$vx = 5
		$by = 540
		$py = 550
		$bx = $wdt/2
		$px = $wdt/2 - $pw/2
	EndIf
EndFunc


Func Display($dmod)
	If $rest <> $life & $pontos Then
		If $score <= $pontos Then $score = $pontos
		GUICtrlSetData($Ds, "     Vidas 0" & $life & "                    Pontos " & $pontos & "               HI-SCORE " & $score)
		$rest = $life & $pontos
	EndIf
		If $delay = 1 Or $delay = 40 Or $delay = 80 Then
			$Ps = GUICtrlCreateLabel($dmod, $wdt / 2.7, 360, 230, 45)
			    If $dmod = "  S t a r t ! ! " Then 	GUICtrlSetPos(-1, $wdt / 2.7, 250, 240, 50)
				GUICtrlSetColor(-1, 0xffffff)
				GUICtrlSetFont(-1, 30, 800)
				GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
			ElseIf $delay = 20 Or $delay = 60 Or $delay = 100 Then
				GUICtrlDelete(-1)
			EndIf
			If $delay > 120 Then $delay = 0
			$delay += 1
		Timer()
EndFunc


Func Timer()
	$td = 0
	$ti = @MSEC
	Sleep(1)
	While $td < 1
		Sleep(1)
		$td += @MSEC
	WEnd
EndFunc


Func Pause()
	_SoundPause($som)
	While $pause
		Display(" P A U S E !! ")
		Timer()
		GUICtrlSetPos($P1, $px, $py)
		If _IsPressed("0d") Then $pause = 2
		If Not _IsPressed("0d") And $pause = 2 Then $pause = 0
	WEnd
	_SoundResume($som)
EndFunc

Alles anzeigen

Allerdings ist die Geschwindigkeit von Andy's Script mit diesem nicht vergleichbar. Also das Script von Andy läuft bei mir viel flüssiger. Auf meinem Notebook ruckelt es zumindest mit der Arkanoid.au3. Aber ich finde zum einen die Aufmachung und zum anderen die Umsetzung des Spieles sehr gut. Event. könnten sich die Scripte und die Ideen ergänzen.

**Andy**

Zum Arkanoid:
Sehr gut gemacht, eigene Maps supereinfach zu erstellen, klasse Sound, ausreichende Grafik, was will man mehr

Genau SO muss das aussehen und sich spielen lassen! Dazu noch simpel programmiert, wirklich gute Arbeit!

Yjuq

Mal ne doofe Frage, wo nimmt er die Bilder her o,O

**Andy**

Zitat von Make-Grafik

Mal ne doofe Frage, wo nimmt er die Bilder her o,O

Sieh zu, dass du mal etwas Schlaf bekommst!
Guckst du Ordner!

Yjuq

Mein Ordner ist komplett leer bis auf das Skript, daher verwundert mich das ja o.o

**Andy**

"Solo" startet das Script nicht . Vielleicht solltest du doch mal über das Ausschlafen nachdenken, wir haben Wochenende
"Früher" konnte man mal Programme aus ZIP-Dateien heraus starten, die haben die benötigten Dateien selbstständig aus der ZIP extrahiert....