_IsPressed in einer Schleife bei vielen Tasten langsam

Cape-City

Hi,

ich frage mit meinem Script ca. 50 Tasten ab, mit jeder Taste wird das Script langsamer (auch wenn gar keine Taste gedrückt wurde).
Gibt es eine Möglichkeit diese Abfrage zu beschleunigen? Als Beispiel ist das Beispiel aus der Hilfe, welches ich aber so in der Form übernommen habe.
Ich weiß nicht ob eine Switch/Case Funktion Beschleunigung bringen würde, aber ich bekomme aus _IsPressed ja keine grundsätzliche Antwort ob überhaupt
eine Taste gedrückt wurde. Dann bräuchte ich ja erst den Rest gar nicht befragen.

C

#include <Misc.au3>
#include <MsgBoxConstants.au3>


Local $hDLL = DllOpen("user32.dll")


While 1
    If _IsPressed("10", $hDLL) Then
        ConsoleWrite("_IsPressed - Shift Key was pressed." & @CRLF)
        ; Wait until key is released.
        While _IsPressed("10", $hDLL)
            Sleep(250)
        WEnd
        ConsoleWrite("_IsPressed - Shift Key was released." & @CRLF)
    ElseIf _IsPressed("1B", $hDLL) Then
        MsgBox($MB_SYSTEMMODAL, "_IsPressed", "The Esc Key was pressed, therefore we will close the application.")
        ExitLoop
    EndIf
    Sleep(250)
WEnd


DllClose($hDLL)

Alles anzeigen

**Bitnugger**

Die Funktion _WinAPI_GetKeyboardState() kopiert den Status der 256 Virtual Keys in einen Buffer, den du dann in einer Schleife auslesen kannst.

**Andy**

Hi,
_ispressed() ist wieder mal so eine Schwachsinnsfunktion, die niemand wirklich braucht!
In jedem Uralt-Basic und in jeder anderen vernünftigen Programmiersprache gibts einen inkey-Befehl, welcher einfach die gedrückte Taste bzw. den Tastaturcode zurück gibt!
Aber da die AutoIt-Dev´s ja eher Angst vor Scriptkiddies mit Keylogger-Ambitionen haben, statt Tastaturabfragen ordentlich zu bearbeiten, bleibt wieder mal nichts weiter übrig, als die üblichen API-funktionen zu bemühen....
Das kann man so machen

AutoIt

Global $__inkey_flag=false
Global $__Tasta_code[256][2], $hDLL = DllOpen("user32.dll")




$hgui = GUICreate("Tasten...", 400, 200)
GUISetState()


$label1 = GUICtrlCreateLabel("", 10, 10, 300, 30)
$label2 = GUICtrlCreateLabel("", 10, 40, 300, 30)
$label3 = GUICtrlCreateLabel("", 10, 70, 300, 30)


GUICtrlSetData($label1, "Bitte Tasten (auch gleichzeitig) drücken")


While GUIGetMsg() <> -3
    $a = _inkey()                                 ;Tastenanzeige
    GUICtrlSetData($label2, "Taste(n) : " & $a)
    $a = _inkey(1)                                ;hexcodes
    GUICtrlSetData($label3, "Hexcodes : " & $a)
WEnd






Func _inkey($flag = 0)                            ;gibt die gleichzeitig gedrückten Tasten zurück, wenn flag=1 gibt dann tastaturcode zurück


    If $__inkey_flag = False Then                 ;first run
        $__inkey_flag = True
        $tastacode = "01 Left mouse button,02 Right mouse button,04 Middle mouse button (three-button mouse),05 Windows 2000/XP: X1 mouse button,06 Windows 2000/XP: X2 mouse button,08 BACKSPACE,09 TAB,0C CLEAR,0D ENTER,10 SHIFT,11 CTRL,12 ALT,13 PAUSE,14 CAPS LOCK,1B ESC,20 SPACEBAR,21 PAGE UP,22 PAGE DOWN,23 END,24 HOME,25 LEFT ARROW,26 UP ARROW,27 RIGHT ARROW,28 DOWN ARROW,29 SELECT,2A PRINT,2B EXECUTE,2C PRINT SCREEN,2D INS,2E DEL,30 0,31 1,32 2,33 3,34 4,35 5,36 6,37 7,38 8,39 9,41 A,42 B,43 C,44 D,45 E,46 F,47 G,48 H,49 I,4A J,4B K,4C L,4D M,4E N,4F O,50 P,51 Q,52 R,53 S,54 T,55 U,56 V,57 W,58 X,59 Y,5A Z,5B Left Windows,5C Right Windows,60 Numeric pad 0,61 Numeric pad 1,62 Numeric pad 2,63 Numeric pad 3,64 Numeric pad 4,65 Numeric pad 5,66 Numeric pad 6,67 Numeric pad 7,68 Numeric pad 8,69 Numeric pad 9,6A Multiply,6B Add,6C Separator,6D Subtract,6E Decimal,6F Divide,70 F1,71 F2,72 F3,73 F4,74 F5,75 F6,76 F7,77 F8,78 F9,79 F10,7A F11,7B F12,7C-7F F13  - F16,80H-87H F17  - F24,90 NUM LOCK,91 SCROLL LOCK,A0 Left SHIFT,A1 Right SHIFT,A2 Left CONTROL,A3 Right CONTROL,A4 Left MENU,A5 Right MENU,BA ;,BB =,BC ,,BD -,BE .,BF /,C0 `,DB [,DC \,DD ]"
        $a = StringSplit($tastacode, ",", 1)      ;string am komma splitten


        For $i = 1 To UBound($a) - 1              ;$tastacodes in Array
            $__Tasta_code[Dec(StringLeft($a[$i], 2))][1] = StringTrimLeft($a[$i], 3)
        Next
    EndIf


    $string = ""                                  ;gedrückte Tasten
    For $i = 1 To 254                             ;eigentlich nur bis 221
      $key = DllCall($hDLL, "short", "GetAsyncKeyState", "int", $i)


        If BitAND($key[0], 0x8000) Then           ;MSB gesetzt
            If $flag Then
                $string &= "0x" & Hex($i, 2) & "+"
            Else
                If $__Tasta_code[$i][1] = "" Then $__Tasta_code[$i][1] = "unknown  code=0x" & Hex($i, 2) & " ";falls Tastencode unbekannt
                $string &= $__Tasta_code[$i][1] & "+"
            EndIf
        EndIf
    Next
    $string = StringTrimRight($string, 1)         ;+ am Ende entfernen
    Return $string                                ;string zurückgeben


EndFunc                                           ;==>_inkey

Alles anzeigen

oder so

AutoIt

$hGui = GUICreate("Example 1 - Press any key to exit...", 400, 100)
GUISetState()
$sKeyboardState = _WinAPI_GetKeyboardState(1)
While _WinAPI_GetKeyboardState(1) = $sKeyboardState
    Sleep(100)
WEnd
GUIDelete($hGui)


Sleep(500)


$hGui = GUICreate('Example 2 - Press "A" to exit...', 400, 200)
GUISetState()
$aKeyboardStateOld = _WinAPI_GetKeyboardState()
While 1
    $aKeyboardState = _WinAPI_GetKeyboardState()
    If $aKeyboardState[65] <> $aKeyboardStateOld[65] Then ExitLoop
    Sleep(100)
WEnd
GUIDelete($hGui)


Sleep(500)


$hGui = GUICreate('Example 3 - Type...', 400, @DesktopHeight - 100)
$hLabel = GUICtrlCreateLabel("", 2, 2, 396, @DesktopHeight - 104)
GUISetState()
While GUIGetMsg() <> -3
    $aKeyboardState = _WinAPI_GetKeyboardState()
    $sKeys = "I" & @TAB & "CHR" & @TAB & "State" & @TAB & "Toogle" & @LF
    For $i = 10 To 90
        $sKeys &= $i & @TAB & Chr($i) & @TAB & BitAND($aKeyboardState[$i], 0xF0) & @TAB & BitAND($aKeyboardState[$i], 0x0F) & @LF
    Next
    GUICtrlSetData($hLabel, $sKeys)
    Sleep(100)
WEnd




; #FUNCTION# ====================================================================================================================
; Name...........:     _WinAPI_GetKeyboardState
; Description ...:     Returns the status of the 256 virtual keys
; Syntax.........:     _WinAPI_GetKeyboardState($iFlag=0)
; Parameters ....:     $iFlag   - Return Type
;                      0 Returns an array[256]
;                    1 Returns a string
; Return values .:     Success  - Array[256] or String containing status of 256 virtual keys
;                      Failure  - False
; Author ........:     Eukalyptus
; Modified.......:
; Remarks .......:     If the high-order bit is 1, the key is down; otherwise, it is up.
;                    If the key is a toggle key, for example CAPS LOCK, then the low-order bit is 1
;                    when the key is toggled and is 0 if the key is untoggled
; Related .......:     _IsPressed
; Link ..........;
; Example .......;
; ===============================================================================================================================
Func _WinAPI_GetKeyboardState($iFlag = 0)
    Local $aDllRet, $lpKeyState = DllStructCreate("byte[256]")
    $aDllRet = DllCall("User32.dll", "int", "GetKeyboardState", "ptr", DllStructGetPtr($lpKeyState))
    If @error Then Return SetError(@error, 0, 0)
    If $aDllRet[0] = 0 Then
        Return SetError(1, 0, 0)
    Else
        Switch $iFlag
            Case 0
                Local $aReturn[256]
                For $i = 1 To 256
                    $aReturn[$i - 1] = DllStructGetData($lpKeyState, 1, $i)
                Next
                Return $aReturn
            Case Else
                Return DllStructGetData($lpKeyState, 1)
        EndSwitch
    EndIf
EndFunc   ;==>_WinAPI_GetKeyboardState

Alles anzeigen

oder so

AutoIt

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>


OnAutoItExitRegister('OnAutoItExit')


Global $hmod, $hHook, $hStub_KeyProc, $buffer = '',$scannerbufferflag=0


$hStub_KeyProc = DllCallbackRegister('_KeyProc', 'long', 'int;wparam;lparam')
$hmod = _WinAPI_GetModuleHandle(0)
$hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hStub_KeyProc), $hmod)
While Sleep(100)
WEnd


Func _EvaluateKey($keycode)
	consolewrite ($keycode&@crlf)
	Switch $keycode


		case asc("~")  ;tilde als startzeichen
			$scannerbufferflag=1  ;nur scannereingaben aufzeichnen
			Tooltip("Scancode start!")
		Case 48 To 57 ; 0 - 9
			ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $buffer = ' & chr($keycode) & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
			if $scannerbufferflag=1 then
				$buffer &= Chr($keycode)
				tooltip ("Scanner sendet: "&$buffer)
			endif
		Case 13 ; RETURN


			if $scannerbufferflag=1 then


				Tooltip("Scanner hat gesendet: " & $buffer)
			Endif
			$buffer = ''
			$scannerbufferflag=0
		Case 27 ; ESC
			Exit
		Case Else
			$buffer = ''
	EndSwitch
EndFunc   ;==>_EvaluateKey


Func _KeyProc($nCode, $wParam, $lParam)
	Local $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
	If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
	If $wParam = $WM_KEYDOWN Then _EvaluateKey(DllStructGetData($tKEYHOOKS, 'vkCode'))
	Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc


Func OnAutoItExit()
	_WinAPI_UnhookWindowsHookEx($hHook)
	DllCallbackFree($hStub_KeyProc)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

oder so

Tastatur für Bildschirm

Cape-City

Super! Danke! Das hilft mir schon etwas weiter. Ich habe derweil doch etwas im Internet gefunden. Das hat seinen Reiz,
es wird nur einmal aufgerufen und ändert dann ohne weiteres Aufrufen eine Variable im Wert auf 1, wenn eine Taste
gedrückt wurde. Schick wäre natürlich eine Kombi aus beiden, nicht nur das "im Hintergrund" warten, sondern auch den
gedrückten Tastenwert zurück geben. Dann spart man noch zusätzlich Zeit beim auswerten der gedrückten Taste.

Code

Global Const $WH_KEYBOARD_LL = 13
Global Const $HC_ACTION = 0


ToolTip("When your ready press a key")


$pllkb = DllCallbackRegister ("_llkb", "lparam", "int;wparam;lparam")
$hModule = DllCall("kernel32.dll", "ptr", "GetModuleHandle", "ptr", 0)
$hModule = $hModule[0]
$hHkk = DllCall("user32.dll", "ptr", "SetWindowsHookEx", "int", $WH_KEYBOARD_LL, "ptr", DllCallbackGetPtr($pllkb), "ptr", $hModule, "dword", 0)
$hHkk = $hHkk[0]


$AKeyWasPressed = 0


While 1
    Sleep(100)
    If $AKeyWasPressed = 1 then Exitloop
WEnd
    ToolTip("")


Msgbox(0,"","A key was pressed")




Func _llkb($nCode, $wParam, $lParam)
    If $nCode = $HC_ACTION Then $AKeyWasPressed = 1
    Return _CallNextHookEx($hHkk, $nCode, $wParam, $lParam)
EndFunc ;==>_llkb


Func _CallNextHookEx($hhk, $nCode, $wParam, $lParam)
    Local $aTmp = DllCall("user32.dll", "lparam", "CallNextHookEx", "ptr", $hhk, "int", $nCode, "wparam", $wParam, "lparam", $lParam)
    Return $aTmp[0]
EndFunc ;==>_CallNextHookExj

Alles anzeigen

Cape-City

@Andy,

sehe gerade das dein letztes Beispiel das ja macht .

OK, dann denke ich, ist dieser Thread erledigt!

**Mars**

Nur der Vollständigkeit halber eine Version mit Events und GUI:

AutoIt

Opt('GUIOnEventMode', 1)
Global $hGUI, $aAccel[0][2]
$hGUI = GUICreate('Test', 256, 256)
GUISetOnEvent(-3, 'EVENT', $hGUI)
Global $a, $b, $c
$a = AddKey($aAccel, 'a')
$b = AddKey($aAccel, 'b')
$c = AddKey($aAccel, 'c')
GUISetAccelerators($aAccel, $hGUI)
GUISetState(@SW_SHOW, $hGUI)
While Sleep(100)
WEnd
Func EVENT()
	Switch @GUI_CtrlId
		Case -3
			Exit
		Case $a
			ToolTip('A Gedrückt')
		Case $b
			ToolTip('B Gedrückt')
		Case $c
			ToolTip('C Gedrückt')
	EndSwitch
EndFunc
Func AddKey(ByRef $a, $1)
	Local $u = UBound($a)
	ReDim $a[$u + 1][2]
	$a[$u][0] = $1
	$a[$u][1] = GUICtrlCreateDummy()
	GUICtrlSetOnEvent($a[$u][1], 'EVENT')
	Return $a[$u][1]
EndFunc

Alles anzeigen

lg
M

Cape-City

Die letzte Variante ist auch interessant, da ja ebenfalls nur reagiert wird, wenn eine Taste gedrückt wurde, man weiß welche es war und kann entsprechend reagieren
und viel besser, es wird nur reagiert, wenn die GUI tatsächlich im Focus ist. Aber wie kann man hier denn "Enter", "Coursor Up", "Num 0", etc abfragen?

**autoiter**

Hi @Cape-City,

schau dir dazu mal den Send-Befehl in der Hilfe an.

AutoIt

Opt('GUIOnEventMode', 1)
Global $hGUI, $aAccel[0][2]
$hGUI = GUICreate('Test', 256, 256)
GUISetOnEvent(-3, 'EVENT', $hGUI)
Global $a, $b, $c, $d
$a = AddKey($aAccel, 'a')
$b = AddKey($aAccel, 'b')
$c = AddKey($aAccel, 'c')
$d = AddKey($aAccel, '{Enter}')
GUISetAccelerators($aAccel, $hGUI)
GUISetState(@SW_SHOW, $hGUI)
While Sleep(100)
WEnd
Func EVENT()
	Switch @GUI_CtrlId
		Case -3
			Exit
		Case $a
			ToolTip('A Gedrückt')
		Case $b
			ToolTip('B Gedrückt')
		Case $c
			ToolTip('C Gedrückt')
		Case $d
			ToolTip('Enter Gedrückt')
	EndSwitch
EndFunc
Func AddKey(ByRef $a, $1)
	Local $u = UBound($a)
	ReDim $a[$u + 1][2]
	$a[$u][0] = $1
	$a[$u][1] = GUICtrlCreateDummy()
	GUICtrlSetOnEvent($a[$u][1], 'EVENT')
	Return $a[$u][1]
EndFunc

Alles anzeigen

**Mars**

Ich weiß leider nicht wie genau die GUISetAccelerators Funktion intern arbeitet. Es kann sein, dass es auf den ersten Blick nach Konstantem Rechenaufwand aussieht (also, dass es egal ist ob man eine oder 100 Tasten registriert). Möglicherweise ist im Hintergrund aber auch eine linear skalierende Funktion am Werk, sodass es bei einer großen Anzahl registrierter Tasten auch langsam wird.

Zudem muss man sich das Verhalten beim Tastendruck verinnerlichen. Wenn man drückt und gedrückt lässt wird sofort ein Event gesendet, dann kommt eine kurze Pause und dann kommen Events im Regelmäßigen Abstand (Gleiches Motto wie ein Textfeld in das man einen Buchstaben eintippt und die Taste gedrückt hält). _IsPressed und andere Funktionen können herausfinden ob die Taste in diesem Augenblick gedrückt ist, GUISetAccelerators kann das nicht, ob du die Taste nach 0.1 oder nach 0.2 Sek loslässt wird keinen Unterschied bei den Events machen.

lg
M

Cape-City

Zitat von Mars

Zudem muss man sich das Verhalten beim Tastendruck verinnerlichen. Wenn man drückt und gedrückt lässt wird sofort ein Event gesendet, dann kommt eine kurze Pause und dann kommen Events im Regelmäßigen Abstand (Gleiches Motto wie ein Textfeld in das man einen Buchstaben eintippt und die Taste gedrückt hält). _IsPressed und andere Funktionen können herausfinden ob die Taste in diesem Augenblick gedrückt ist, GUISetAccelerators kann das nicht, ob du die Taste nach 0.1 oder nach 0.2 Sek loslässt wird keinen Unterschied bei den Events machen.

Das stimmt, das hatte ich bei _IsPressed auch eingebaut. Hier war es auch ein Problem und man hatte richtig den Effekt des
Tastenprellens. Bei einer deiner Methoden (habe sie mal ein wenig aufgehübscht), passiert das nicht. Klar kommt die Taste immer
wieder, wenn man sie gedrückt hält, aber beim normalen Drücken (auch etwas länger) passiert nichts. Es gibt unter Windows
ja auch diese Tastenanschlagverzögerung, ich denke das genau diese hier greift. Zudem muss man bei _IsPressed und dem Warten
bis die Taste wieder "released" wurde aufpassen, das Script pausiert dann an der Stelle

C

#include-once
#include <WinAPI.au3>
#include <WindowsConstants.au3>


;
;
; $KeyPressed has to be global declared as FALSE, befor running _WhichKey_Startup()
; _WhichKey_Startup() has to run once, thereafter $KeyPressed contains always the pressed key
; _WhichKey_Shutdown() has to be run once, when your script is ending
;
; Code Example:
;
; #include <_WhichKeyWasPressed.au3> ;==> name of this script
;
; Global $KeyPressed = False
; _WhichKey_Startup()
;
; While Sleep(100)
;	If $KeyPressed Then DoSomething()
; WEnd
;
; Func DoSomething()
;	ConsoleWrite ("ASCII Code: " & $KeyPressed & @CRLF)
;	Switch $KeyPressed
;		Case 27
;			_WhichKey_Shutdown()
;			Exit
;	EndSwitch
;	$KeyPressed = False
; EndFunc
;


Func _WhichKey_Startup()


	Global $hmod, $hHook, $hStub_KeyProc


	$hStub_KeyProc = DllCallbackRegister('_KeyProc', 'long', 'int;wparam;lparam')
	$hmod = _WinAPI_GetModuleHandle(0)
	$hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hStub_KeyProc), $hmod)


EndFunc ;==>_WhichKey_Startup


Func _KeyProc($nCode, $wParam, $lParam)


	Local $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)


	If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
	If $wParam = $WM_KEYDOWN Then $KeyPressed = DllStructGetData($tKEYHOOKS, 'vkCode')


	Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)


EndFunc   ;==>_KeyProc


Func _WhichKey_Shutdown()


	_WinAPI_UnhookWindowsHookEx($hHook)
	DllCallbackFree($hStub_KeyProc)


EndFunc   ;==>_WhichKey_Shutdown

Alles anzeigen