DNS-Server IP auslesen

xXIVXx

ich will die ip angezeigt bekommen die man von ipconfig /all kennt

da steht weiter unten DNS-Server: 192.168.000.000

gibt es zufällig eine Funktion integriert in Autoit die ich nicht gefunden habe

**alpines**

AutoIt bietet keine internen Methoden dafür, du kannst allerdings die Google Suche verwenden und direkt Resultate finden.

Du kannst aber auch die Standardausgabe von ipconfig /all lesen und dann parsen.

**Bitnugger**

Zitat von xXIVXx

da steht weiter unten DNS-Server: 192.168.000.000

Das steht da garantiert nicht!

192.168.0.1 - ja, das kann...

Willst du tatsächlich den DNS-Server oder aber deine lokale IP haben? Dafür hätte ich ein Script.

**alpines**

Zitat von Bitnugger

Das steht da garantiert nicht!

Ich denke er hätte es wie 192.168.xxx.xxx gemeint.

Zitat von Bitnugger

Willst du tatsächlich den DNS-Server oder aber deine lokale IP haben? Dafür hätte ich ein Script.

@IPAddress1

**Bitnugger**

Zitat von alpines

@IPAddress1

Das ist sehr unzuverlässig, denn diese Makros liefern die IP-Adressen der ersten vier vorhandenen Netzwerk-Adaper... welche davon dann die lokale IP ist, bleibt dann zu raten.

Deshalb mache ich es lieber so...

**Oscar**

Das hier sollte doch ausreichen:

AutoIt

TCPStartup()
$sIP = TCPNameToIP(@ComputerName)
TCPShutdown()
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sIP = ' & $sIP & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

**alpines**

Zitat von Bitnugger

Das ist sehr unzuverlässig, denn diese Makros liefern die IP-Adressen der ersten vier vorhandenen Netzwerk-Adaper... welche davon dann die lokale IP ist, bleibt dann zu raten.

Meistens hat man nur einen Adapter installiert, sollte man trotzdem zwei oder mehrere haben ist es meistens trotzdem @IPAddress1.

Ansonsten kannst du prüfen ob die leer ist und dann die nächste nehmen, das ist zumindest die schnellste und einfachste Variante.

Hab in meinem System auch mehrere Adapter gehabt (physische sowie emulierte) und nie Probleme gehabt.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Mit Verlaub wie steht es damit:

ipconfig /all > F:\1.txt

Das Textfile kann man dann mit autoit nach allen Regeln der Kunst auseinandernehmen oder auch zusammensetzen ?

Im Zweifel bekommt man eben die Adressen aller Adapter....

Gruß

Peter

**alpines**

Zitat von Peter S. Taler

Mit Verlaub wie steht es damit:

ipconfig /all > F:\1.txt

Zitat von alpines

Du kannst aber auch die Standardausgabe von ipconfig /all lesen und dann parsen.

Ob ich jetzt in eine Datei schreibe oder mit StdOutRead lese spielt glaube ich keine Rolle.

**autoiter**

Hallo alpines

ich habe mit @IPAddress1 schon häufiger Probleme gehabt. Aktuell etwa belegt eine VPN Software diesen Platz..

Hier gibt es auch noch ein paar schöne Methoden dazu von UEZ und Micha_he: Zuverlässig eigene IP auslesen?

**alpines**

Zitat von autoiter

ich habe mit @IPAddress1 schon häufiger Probleme gehabt. Aktuell etwa belegt eine VPN Software diesen Platz..

Selbst bei VPNs hatte ich das Problem nicht, naja, kopiert man sich eine UDF rein ist ja halb so wild.

Micha_he

Auf Basis der damaligen Idee nach niedrigster Metric zu wählen, hier eine WMI-Variante für die DNS-Einträge:

AutoIt

MsgBox(0,"Low Metric DNS", _LowMetricAllDNS())

Func _LowMetricAllDNS($sHost = ".")
    Local $objAdapter, $iMetric = 500, $sDNS
    Local $EachDNS
    Local $objWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & $sHost & "\root\cimv2")
    If Not IsObj($objWMIService) Then Return SetError(1, 0, 0)
    Local $colAdapter = $objWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration WHERE IPEnabled = True", "WQL", 0x30)
    If IsObj($colAdapter) Then
        For $objAdapter In $colAdapter
            If $objAdapter.IPConnectionMetric < $iMetric Then
                $sDNS = ""
                If IsArray($objAdapter.DNSServerSearchOrder) Then
                    For $EachDNS In $objAdapter.DNSServerSearchOrder
                        $sDNS &= $EachDNS & "|"
                    Next
                    $sDNS = StringTrimRight($sDNS, 1)
                    $iMetric = $objAdapter.IPConnectionMetric
                EndIF
            EndIf
        Next
        If $sDNS Then Return $sDNS
    EndIf
    Return SetError(2, 0, 0)
EndFunc

Alles anzeigen

xXIVXx

Zitat von Micha_he

Auf Basis der damaligen Idee nach niedrigster Metric zu wählen, hier eine WMI-Variante für die DNS-Einträge:

AutoIt

MsgBox(0,"Low Metric DNS", _LowMetricAllDNS())

Func _LowMetricAllDNS($sHost = ".")
    Local $objAdapter, $iMetric = 500, $sDNS
    Local $EachDNS
    Local $objWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & $sHost & "\root\cimv2")
    If Not IsObj($objWMIService) Then Return SetError(1, 0, 0)
    Local $colAdapter = $objWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration WHERE IPEnabled = True", "WQL", 0x30)
    If IsObj($colAdapter) Then
        For $objAdapter In $colAdapter
            If $objAdapter.IPConnectionMetric < $iMetric Then
                $sDNS = ""
                If IsArray($objAdapter.DNSServerSearchOrder) Then
                    For $EachDNS In $objAdapter.DNSServerSearchOrder
                        $sDNS &= $EachDNS & "|"
                    Next
                    $sDNS = StringTrimRight($sDNS, 1)
                    $iMetric = $objAdapter.IPConnectionMetric
                EndIF
            EndIf
        Next
        If $sDNS Then Return $sDNS
    EndIf
    Return SetError(2, 0, 0)
EndFunc

Alles anzeigen

Vielen Dank für deine Mühe. Genau das wollte ich

**Bitnugger**

Auf dieser Seite wird sehr gut erklärt, nach welchen Regeln den verschiedenen Adaptern eine Metric zugewiesen wird.

Hier noch zwei Varianten, um die lokalen IPs zu ermitteln:

AutoIt

Local $iPID = Run('powershell.exe ipconfig | sls "ipv4"', '', @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
$aIP = StringRegExp(StdoutRead($iPID), '(?:.+:)(.+)', 3)
_ArrayDisplay($aIP, 'powershell - $aIP')

$iPID = Run('ipconfig.exe /all', '', @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
$aIP = StringRegExp(StdoutRead($iPID), '(?:IPv4.+: )(.+)(?:\(.+)', 3)
_ArrayDisplay($aIP, 'ipconfig - $aIP')