Wie wärs denn mit _GDIPlus_GraphicsDrawPath?
Ich würde mir einfach die gewünschte Funktion via _GDIPlus_GraphicsDrawLine selbst basteln. Wenn du das Array für DrawCurve bereits hast, kannst du via DrawLine immer Punkt [i] und Punkt [i+1] verbinden (beginnend bei 1 und endend ein Element vor dem letzten Element).
so ... ich habe jetzt mal die einzelnen Punkte mit dem Befehl _GDIPlus_GraphicsDrawLine verbinden lassen.
An den jeweiligen Anfangs- und Endpunkten der Linien habe ich einen kleinen Kreis gezeichnet (im Beispiel nur alle 100 Linien; sonst sieht man nichts, da nur Kreis neben Kreis gezeichnet wird und am Ende eine dicke Linie mit der Stärke des Kreisdurchmessers zu sehen ist. Alle Linien verschwinden dadrin.)
Vorher habe ich aber die Kurve mit dem Befehl _GDIPlus_GraphicsDrawCurve anzeigen lassen.
Die gezeichnete Kurve mit Hilfe von _GDIPlus_GraphicsDrawCurve deckt sich mit den Einzellinien (durch _GDIPlus_GraphicsDrawLine gezeichnet)
Was nicht passt sind die Kreise ! Eigentlich sollten die durch die Anfangs- und Endpunkte der einzelnen Linien gehen ... irgendwaie stimmt da aber was nicht ...
Woran liegt das, das die Kreise fast immer UNTER der Linie liegen ?? Nur im schrägen Teil der Kurve passen die Kreise.
Anbei mal nen Screenshot.
Kennt jemand das Problem ?
_GDIPlus_GraphicsDrawCurve($hImage, $aPixelKoord, $hBlackPenSmall)
MsgBox(0, "Info 1", "Kurve mit _GDIPlus_GraphicsDrawCurve erstellt.")
Local $j, $x1, $x2, $y1, $y2
For $j = 1 To UBound($aPixelKoord) - 2 Step 100
If $j = 1 Then
$x1 = $aPixelKoord[$j][0]
$y1 = $aPixelKoord[$j][1]
Else
$x2 = $aPixelKoord[$j+1][0]
$y2 = $aPixelKoord[$j+1][1]
_GDIPlus_GraphicsDrawLine($hImage, $x1, $y1, $x2, $y2, $hBlackPenSmall)
$x1 = $x2
$y1 = $y2
EndIf
Next
MsgBox(0, "Info 2", "Graph mit _GDIPlus_GraphicsDrawDraw erstellt.")
For $j = 1 To UBound($aPixelKoord) - 1 Step 100
_GDIPlus_GraphicsDrawEllipse($hImage, $aPixelKoord[$j][0], $aPixelKoord[$j][1], 5, 5, $hBlackPenSmall)
Next
MsgBox(0, "Info 3", "Kreise ergänzt.")Spontan würde ich mal raten, dass die Koordinaten der Ellipsen falsch sind. Das sind x,y-Koordinaten für den das Boundingbox-Rectangle in welcher die Ellipse gezeichnet wird.
Du müsstest die Ellipse also um Width/2 und Height/2 nach links respektive oben verschieben damits zentriert auf dem Punkt ist.
die x,y-Koordinaten sind die gleiche, mit denen die Linien gezeichnet werden. Ich verwende ja das selbe Array (die Koordinaten liegen in einem Array).
Das kann es also nicht sein ...
Hast du meinen Beitrag überhaupt gelesen?
... außerdem - ich oberen Teil (schräger Graph) passt es doch ! ... und anschließend nicht mehr ???? hhmmmm ..
Sollte auch nicht überraschen, es sieht so aus als ob es passt, aber es passt nicht. Die Linie davor verläuft im selben Winkel, deshalb scheint es so aus als ob die Ellipse auf der Koordinate liegt, tut sie aber nicht.
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 615, 437, 192, 124)
GUISetState(@SW_SHOW)
#include <GDIPlus.au3>
_GDIPlus_Startup()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($Form1)
Local $aRandomDots[30][2]
For $i = 0 To UBound($aRandomDots) - 1
$aRandomDots[$i][0] = $i * (615 / UBound($aRandomDots))
$aRandomDots[$i][1] = Random(0, 437, 1)
Next
For $i = 0 To UBound($aRandomDots) - 2
_GDIPlus_GraphicsDrawLine($hGraphics, _
$aRandomDots[$i][0], _
$aRandomDots[$i][1], _
$aRandomDots[$i + 1][0], _
$aRandomDots[$i + 1][1] _
)
_GDIPlus_GraphicsDrawEllipse($hGraphics, $aRandomDots[$i][0], $aRandomDots[$i][1], 10, 10)
Next
MsgBox(0, 0, "Falsche Darstellung")
_GDIPlus_GraphicsClear($hGraphics, 0xFFFFFFFF)
For $i = 0 To UBound($aRandomDots) - 2
_GDIPlus_GraphicsDrawLine($hGraphics, _
$aRandomDots[$i][0], _
$aRandomDots[$i][1], _
$aRandomDots[$i + 1][0], _
$aRandomDots[$i + 1][1] _
)
_GDIPlus_GraphicsDrawEllipse($hGraphics, $aRandomDots[$i][0] - 10/2, $aRandomDots[$i][1] - 10/2, 10, 10)
Next
MsgBox(0, 0, "Korrekte Darstellung")
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEndDu hast einfach nur ein Brett vorm Kopf, so eine Darstellung hat schon viele irritiert. Hier mal ein kleiner Sketch damit du dir das einfacher Visualisieren kannst:
Mein Fehler war, das ich tatsächlich davon ausgegangen bin, das man den Mittelpunkt des Kreises angibt ...
Das hat mich schon vor mehr als 10 Jahren gestört: GDI+ Kreis mit Mittelpunktkoordinaten zeichnen
Habe mal ein Beispiel zu frei rotierbarem Text gemacht, ich hoffe das Löst dein Problem.
#include <GDIPlus.au3>
Opt('GUIOnEventMode', 1)
Global Const $sTitle = 'Test'
Global Const $iW = 400
Global Const $iH = 400
Global $bExit = False
_GDIPlus_Startup()
Global $hGUI = GUICreate($sTitle, $iW, $iH + 30)
Global $hGFX = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global $hBMP = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGFX)
Global $hBUF = _GDIPlus_ImageGetGraphicsContext($hBMP)
Global $hFAM = _GDIPlus_FontFamilyCreate('Arial')
Global $hFON = _GDIPlus_FontCreate($hFAM, 35, 0, 2)
Global $hFOR = _GDIPlus_StringFormatCreate()
Global $hBRU = _GDIPlus_BrushCreateSolid(0xFF303030)
Global $hMAT = _GDIPlus_MatrixCreate()
Global $hSLI = GUICtrlCreateSlider(10, $iH + 5, $iW - 20, 20)
_GDIPlus_GraphicsSetTextRenderingHint($hBUF, 4)
GUISetOnEvent(-3, 'EVENT', $hGUI)
OnAutoItExitRegister('Xit')
GUISetState(@SW_SHOW, $hGUI)
While Not $bExit And Sleep(10)
_GDIPlus_GraphicsClear($hBUF, 0xFFE0E0E0)
Local $tRect = _GDIPlus_RectFCreate(200, 200)
Local $alpha = GUICtrlRead($hSLI) * 360/100
_GDIPlus_MatrixTranslate($hMAT, -200, -200, True) ; MatrixRotate geht immer um den Ursprung. Ist der Text bei (x,y)=(200,200), muss die Matrix dementsprechend verschoben werden.
_GDIPlus_MatrixRotate($hMAT, $alpha, True) ; Rotation um irgendeinen Winkel
_GDIPlus_MatrixTranslate($hMAT, 200, 200, True) ; Matrix zurückverschieben
_GDIPlus_GraphicsSetTransform($hBUF, $hMAT) ; Matrix anwenden
_GDIPlus_GraphicsDrawStringEx($hBUF, 'Kraft[N]', $hFON, $tRect, $hFOR, $hBRU) ; Text zeichnen
_GDIPlus_MatrixTranslate($hMAT, -200, -200, True) ; Rücktransformation damit man danach noch andere sachen Zeichnen kann
_GDIPlus_MatrixRotate($hMAT, -$alpha, True)
_GDIPlus_MatrixTranslate($hMAT, 200, 200, True)
_GDIPlus_GraphicsSetTransform($hBUF, $hMAT) ; Matrix anwenden Jetzt ist wieder alles beim alten.
_GDIPlus_GraphicsDrawStringEx($hBUF, 'Kraft[N]', $hFON, $tRect, $hFOR, $hBRU) ; Text zeichnen (der hier wird jetzt statisch sein und kann sich nicht drehen)
_GDIPlus_GraphicsDrawImageRect($hGFX, $hBMP, 0, 0, $iW, $iH)
WEnd
Func EVENT()
Switch @GUI_CtrlId
Case -3
$bExit = True
EndSwitch
EndFunc
Func Xit()
_GDIPlus_MatrixDispose($hMAT)
_GDIPlus_BrushDispose($hBRU)
_GDIPlus_StringFormatDispose($hFOR)
_GDIPlus_FontDispose($hFON)
_GDIPlus_FontFamilyDispose($hFAM)
_GDIPlus_GraphicsDispose($hBUF)
_GDIPlus_BitmapDispose($hBMP)
_GDIPlus_GraphicsDispose($hGFX)
_GDIPlus_Shutdown()
EndFuncEdit: Habe mir jetzt WriteRotate nicht ausprobiert, aber allgemein ist WinAPI und GDI+ nur in einigen Fällen kompatibel, im Allgemeinen greifen die Funktionen nicht ineinander. Man kann kein Rechteck via WinAPI auf ein GDI+ GFX zeichnen und kein GDI+ Rechteck auf einen usw...
lg
M
Mars Hatte der TE hier (RE: Text 90° gedreht in GUI) nochmal separat gefragt, ist gelöst.
Leider verbleibt der Text nicht in der GUI wenn man das Fenster minimiert / maximiert oder ein anderes Fenster sich darüber legt.
Stimmt, das ist ein Nachteil bei allen Zeichenoperationen mit _WinAPI_.... Da muss man die Message WM_Activate registrieren und erneut zeichnen lassen.
EDIT: Hier mal als Bsp.
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
Global $hGui = GUICreate('Test')
GUISetState()
_Draw($hGui) ; erstmaliger Aufruf erst NACH GuiSetState, da die GUI als Context benötigt wird
GuiRegisterMsg(0x0006, '_WM_HANDLER') ; WM_ACTIVATE
Global $bReDraw = False
Do
If $bRedraw Then
$bRedraw = False
_Draw($hGui)
EndIf
Until GUIGetMsg() = -3
Func _Draw($_hGUI)
_WriteRotateText($_hGUI, 'Hallo AutoIt', 10, 100, 90, 12)
_WriteRotateText($_hGUI, 'Hallo AutoIt', 50, 20, 270, 12, 400, 1, -1, -1, -1, False) ; mit "False" das Löschen der GUI vorm Zeichnen verhindern
EndFunc
Func _WM_HANDLER($hWnd, $iMsg, $iwParam, $ilParam)
Local $bActive = False
Local $iLow = BitAND($iwParam, 0xFFFF) ; Low Word
If $iLow = 1 Or $iLow = 2 Then $bActive = True ; WA_ACTIVE, WA_CLICKACTIVE
If $bActive Then $bRedraw = True ; nur wenn aktiv
Return 0
EndFunc
;==================================================================================================
; Function Name: _WriteRotateText($hWnd, $sWrite, $iX, $iY, $iDeg, $iSize [, $iWeight=400 _
; .............. [, $iType=1 [, $sFont=-1 [, $iCol=-1 [, $iBkCol=-1 [,$bRedraw=True]]]]]])
; Description: Schreibt einen Text mit bestimmtem Winkel in das angegebene Fenster
; Parameter(s): $hWnd Handle des Fensters
; ............. $sWrite der zu schreibende Text
; ............. $iX x-Position auf dem Fenster
; ............. $iY y-Position auf dem Fenster
; ............. $iDeg Rotationswinkel des Textes
; ............. $iSize Höhe des Textes
; ....optional: $iWeight Fontbreite 0 - 1000 (Standard 400)
; ....optional: $iType Fonttyp 1=normal (Standard); 2=Italic; 4=Underline; 8=StrikeOut
; ............. 1 oder 2 können mit 4 und 8 kombiniert werden (5;9 od. 6;10)
; ....optional: $sFont Fontname -1=Font der Form (Standard)
; ....optional: $iCol Fontfarbe -1=schwarz (Standard)
; ....optional: $iBkCol Hintergrundfarbe -1=Hintergrundfarbe des Fensters (Standard)
; ....optional: $bRedraw True=Fenster vorher neu zeichnen (vorige Beschriftung löschen - Standard)
; Requirement(s): #Include <WinAPI.au3>; #include <StructureConstants.au3>; #include <WindowsConstants.au3>
;==================================================================================================
Func _WriteRotateText($hWnd, $sWrite, $iX, $iY, $iDeg, $iSize, $iWeight=400, $iType=1, $sFont=-1, $iCol=-1, $iBkCol=-1, $bRedraw=True)
If $bRedraw Then _WinAPI_RedrawWindow($hWnd)
Local $tRect = DllStructCreate($tagRECT)
DllStructSetData($tRect, 'Left', $iX)
DllStructSetData($tRect, 'Top', $iY)
Local $rotate = $iDeg *10
If ($rotate = 900) Or ($rotate = 1800) Or ($rotate = 2700) Then $rotate += 1
Local $RotateMe = DllStructCreate($tagLOGFONT)
DllStructSetData($RotateMe, 'Escapement', $rotate)
DllStructSetData($RotateMe, 'Height', ($iSize * -20)/_WinAPI_TwipsPerPixelY())
If $iWeight <> 400 Then DllStructSetData($RotateMe, 'Weight', $iWeight)
If BitAND($iType, 2) Then DllStructSetData($RotateMe, 'Italic', True)
If BitAND($iType, 4) Then DllStructSetData($RotateMe, 'Underline', True)
If BitAND($iType, 8) Then DllStructSetData($RotateMe, 'StrikeOut', True)
If $sFont <> -1 Then DllStructSetData($RotateMe, 'FaceName', $sFont)
Local $rFont = _WinAPI_CreateFontIndirect($RotateMe)
Local $hDC = _WinAPI_GetDC($hWnd)
If $iCol <> -1 Then _WinAPI_SetTextColor($hDC, $iCol)
If $iBkCol <> -1 Then _WinAPI_SetBkColor($hDC, $iBkCol)
_WinAPI_SelectObject($hDC, $rFont)
_WinAPI_DrawText($hDC, $sWrite, $tRect, BitOR($DT_NOCLIP,$DT_NOPREFIX))
_WinAPI_ReleaseDC($hWnd, $hDC)
EndFunc ;==>_WriteRotateTextStimmt, das ist ein Nachteil bei allen Zeichenoperationen mit _WinAPI_.... Da muss man die Message WM_Activate registrieren und erneut zeichnen lassen.
das ist nicht alles. Ein MouseOver killt mir auch den Text ...
aber sonst - sehr gut gemacht - so wollte ich das auch haben ...
Ein MouseOver killt mir auch den Text ...
?? - Das kann ich nicht reproduzieren. Ist auch nicht erklärbar, da durch MouseOver das Fenster nicht den Fokus verliert und aktiv bleibt. Oder schreibst du in einen Bereich über dem die Maus ihren Zeiger ändert?
