Func so lange ausführen wie GUI Button gedrückt wird... (Funk Taster)

rollod

Hi.

Ich suche nach einer Möglickeit eine Funktion exact so lange ausgeführt wird, wie auf einem GUI Button in dem Scropt gedrückt wird. Ähnlich wie eine TX FunkTaste...

Hintergrund: Ich scripte gerade ein Tool mit dem Kameraden der Freiwilligen Feuerwehr in Corona Zeiten über Internet Funken üben sollen.

Ich habe dazu in Autoit eine GUI mit einem Button erstellt (GUICtrlCreateButton) als Sende Taste.

Hier kann ich ja aber immer nur die GUIGetMsg() auslesen wenn einmal geklickt wurde, oder?

Wie kriege ich das hin, das eine Funktion so lange ausgeführt wird wie der Button mittels Linker Maustaste festgehalten wird?

Die Funkton sendet dabei einfach einen Hotkey mittesl Send in ein anderes Fenster und soll halt wieder aufhören wenn der Button los gelassen wird...

Jemand eine Idee? Kann mir eigentlich nicht vorstellen das es schwierig ist, bin aber in dern Foren und Anleitungen irgendwie nicht fündig geworden, oder ich suche falsch...

Viele Grüße

Stefan

**alpines**

Ich bin mir nicht sicher, ob Buttons standardmäßig eine Funktion/ein Event dafür anbieten aber mit $GUI_EVENT_PRIMARYDOWN und $GUI_EVENT_PRIMARYUP kannst du herausfinden ob die Maustaste gedrückt wird.

Du könntest es einfach so kombinieren, dass du GUIGetMsg mit dem advanced Parameter = 1 nutzt, dann kriegst du auch gleichzeitig die Koordinaten, von wo der Klick ausgelöst wurde.

Jetzt musst du nur noch im Event die Koordinaten mit denen des Buttons vergleichen, liegen sie dadrin, soll gesendet werden.

Wird die Maustaste wieder angehoben, dann soll abgebrochen werden.

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global Const $BUTTON_X = 32
Global Const $BUTTON_Y = 32
Global Const $BUTTON_WIDTH = 235
Global Const $BUTTON_HEIGHT = 129

GUICreate("Form1", 310, 219, 192, 124)
$hButton = GUICtrlCreateButton("Klick && halte mich", $BUTTON_X, $BUTTON_Y, $BUTTON_WIDTH, $BUTTON_HEIGHT)

GUISetState(@SW_SHOW)

While Sleep(10)
    $nMsg = GUIGetMsg(1)

    Switch $nMsg[0]
        Case $GUI_EVENT_CLOSE
            Exit

        Case $GUI_EVENT_PRIMARYDOWN
            ; $nMsg[3] = X
            ; $nMsg[4] = Y

            Local $iMouseX = $nMsg[3]
            Local $iMouseY = $nMsg[4]

            If $iMouseX >= $BUTTON_X And $iMouseX <= $BUTTON_X + $BUTTON_WIDTH _
                And $iMouseY >= $BUTTON_Y And $iMouseY <= $BUTTON_Y + $BUTTON_HEIGHT Then

                GUICtrlSetData($hButton, "Sende Daten")
            EndIf

        ;Alternativ ginge auch $hButton, weil das Event nur ausgelöst wird,
        ;wenn der Button wieder losgelassen wurde
        Case $GUI_EVENT_PRIMARYUP
            GUICtrlSetData($hButton, "Klick && halte mich")
    EndSwitch
WEnd

Alles anzeigen

**water**

Der Wert von GUIGetMsg wird standardmäßig erst gesetzt, wenn die Maus losgelassen wird.

Aber mit folgendem Ansatz könnte es vielleicht gehen. Dabei wird aber kein Button, sondern eine Taste (hier 'k') verwendet.

C

#include <Misc.au3>
#include <GUIConstantsEx.au3>
Global $hDLL = DllOpen("user32.dll")
Global $bKeyPressed = False

Global $hGUI = GUICreate("", 300, 100, 100, 100)
Global $hlabel = GUICtrlCreateLabel("", 10, 10, 130, 80)
GUISetState(@SW_SHOW)     ; will display an empty dialog box

; Loop until the user exits.
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
    If _IsPressed("4B", $hDLL) Then     ; "K" pressed?
        $bKeyPressed = True
        GUICtrlSetData($hlabel, "pressed")
    ElseIf $bKeyPressed = True Then
        GUICtrlSetData($hlabel, "released")
        $bKeyPressed = False
    EndIf
    Sleep(10)
WEnd

Alles anzeigen

Alpines Lösung ist eindeutig eleganter

**Alina**

wenn man bei alpines seinem beispiel hinter zeile 32 folgendes einfügt bleibt der button gedrückt, oder?
MsgBox(0,"Button wird gehalten","Button wird gehalten bis er erneut gedrückt wird. ",1)

rollod

Hey Leute.

Vielen Dank für Eure Hilfe und Tipps!

Ich bin wirklich mit der Lösung von alpines ein ganzes Stück weiter gekommen, und das Funktioniert für mich jetzt auch so.

Viele Grüße!

**Alina**

Beitrag somit "erledigt" ?

**Bitnugger**

Hier noch eine andere Lösung:

AutoIt

;-- TIME_STAMP   2020-12-08 15:14:28   v 0.1

#include <APISysConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>

Global $g_hGUI, $g_idButton, $g_hButton

_Example()

Func _Example()
    $g_hGUI = GUICreate("Form1", 320, 320)
    $g_idButton = GUICtrlCreateButton("Klick && halte mich", 20, 20, 280, 280)
    $g_hButton = GUICtrlGetHandle($g_idButton)

    GUISetState(@SW_SHOW)

    Local $aMsg, $iFlags = BitOR($CWP_SKIPINVISIBLE, $CWP_SKIPDISABLED, $CWP_SKIPTRANSPARENT)
    While 1
        ; When using the "advanced" parameter the information is returned in an array with extended information:
        ; $aMsg[0] = 0 or Event ID or Control ID
        ; $aMsg[1] = The window handle the event is from
        ; $aMsg[2] = The control handle the event is from (if applicable)
        ; $aMsg[3] = The current X position of the mouse cursor (relative to the GUI window)
        ; $aMsg[4] = The current Y position of the mouse cursor (relative to the GUI window)
        $aMsg = GUIGetMsg(1)

        Switch $aMsg[0]
            Case $GUI_EVENT_CLOSE
                Exit

            Case $GUI_EVENT_PRIMARYDOWN
                If _GetChildWindowFromPointEx($g_hGUI, $aMsg[3], $aMsg[4], $iFlags) = $g_hButton Then
                    GUICtrlSetData($g_idButton, "Sende Daten")
                EndIf

            Case $GUI_EVENT_PRIMARYUP
                GUICtrlSetData($g_idButton, "Klick && halte mich")
        EndSwitch
    WEnd
EndFunc   ;==>_Example

Func _GetChildWindowFromPointEx($_hWnd, $_x, $_y, $_iFlags = 0)
    Local Static $tPOINT = DllStructCreate($tagPOINT)
    DllStructSetData($tPOINT, 'X', $_x)
    DllStructSetData($tPOINT, 'Y', $_y)
    Return _WinAPI_ChildWindowFromPointEx($_hWnd, $tPOINT, $_iFlags)
EndFunc   ;==>_GetChildWindowFromPointEx

Alles anzeigen

Professor Bernd

Und hier eine etwas kürzere Version von Bitnugger's Lösung, per GUIGetCursorInfo() statt Koordinaten.

AutoIt

#include <GUIConstantsEx.au3>

_Example()

Func _Example()

    GUICreate("Form1", 320, 320)
    Local $idButton = GUICtrlCreateButton("Klick && halte mich", 20, 20, 280, 280)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit

            Case $GUI_EVENT_PRIMARYDOWN
                Local $aCI = GUIGetCursorInfo()
                If $aCI[4] = $idButton Then GUICtrlSetData($idButton, "Sende Daten")

            Case $GUI_EVENT_PRIMARYUP
                GUICtrlSetData($idButton, "Klick && halte mich")
        EndSwitch
    WEnd
EndFunc   ;==>_Example

Alles anzeigen

Edit: "$bSend" entfernt, dessen Sinn sich mir nicht erschlossen hat.

Edit 2: Nach Hinweis von Bitnugger Switch GUIGetMsg($GUI_EVENT_ARRAY)[0] durch Switch GUIGetMsg() ersetzt. Hinweis auf "advanced" Parameter ist dann auch nicht mehr nötig.

**Bitnugger**

Zitat von Professor Bernd

Switch GUIGetMsg($GUI_EVENT_ARRAY)[0]

Wenn du eh nur das Event auswertest, reicht Switch GUIGetMsg().

Zitat von Professor Bernd

$aCI = GUIGetCursorInfo()
If Not $bSend And $aCI[4] = $g_idButton Then

Hier solltest du besser auch prüfen, ob kein Fehler aufgetreten ist, da $aCI in dem Fall kein Array ist.

If Not @error And Not $bSend And $aCI[4] = $g_idButton Then

Professor Bernd

Zitat von Bitnugger

Wenn du eh nur das Event auswertest, reicht Switch GUIGetMsg().

Sowas blödes. Danke für den Hinweis! Werde ich im Posting oben gleich korrigieren.

Zitat von Bitnugger

Hier solltest du besser auch prüfen, ob kein Fehler aufgetreten ist, da $aCI in dem Fall kein Array ist.
If Not @error And Not $bSend And $aCI[4] = $g_idButton Then

Auch da hast du recht.

Ich habe "$bSend" aus deinem Code entfernt. Hatte das einen tieferen Sinn?

**Bitnugger**

Zitat von Professor Bernd

Ich habe "$bSend" aus deinem Code entfernt. Hatte das einen tieferen Sinn?

Ja, hatte es. Beim Testen hatte ich eine Version, die nur mit GUIGetCursorInfo arbeitete, also ohne $GUI_EVENT_PRIMARYDOWN und $GUI_EVENT_PRIMARYUP. Ohne $bSend wird GUICtrlSetData dann bei jedem Durchlauf ausgeführt, solange die primäre Maustaste gedrückt bleibt. Mit $GUI_EVENT_PRIMARYDOWN (wird nur 1x gesendet, solange die Maustaste gedrückt bleibt) ist $bSend aber nicht mehr nötig.

Professor Bernd

Alles klar.