Alternative zu "Sleep"

Was heißt denn für dich "vollständig gestartet"?
Wenn du auf ein Fenster warten willst: WinWait

Wenn du warten willst, bis das Programm fertig ist: RunWait

Kanashius fragte wie du "vollständig gestartet" definierst.
Erst wenn dies klar ist kann man überlegen mit welchen Mitteln man dies programmiertechnisch angeht.

Schau dir das mal an: https://www.autoitscript.com/autoit3/docs/f…hellExecute.htm

Du bekommst die PID zurück, mit der prüfst du in einer Schleife ob der Prozess noch läuft (https://www.autoitscript.com/autoit3/docs/f…ocessExists.htm) und wenn nicht -> Schleife Beenden (https://www.autoitscript.com/autoit3/docs/keywords/ExitLoop.htm) und den Link löschen.

Oder du wartest bis der Link erstellt wurde (https://www.autoitscript.com/autoit3/docs/f…/FileExists.htm) und löscht ihn dann...

Es gibt also viele Wege zum Erfolg.

nachdem eine Setup.exe aufgerufen wird, gehe ich davon aus, dass auf deren Beendigung gewartet werden soll.

Dazu würde ich einfach

ShellExecuteWait("C:\Users\stefa\Downloads\WhatsAppSetup.exe")

verwenden

Guck mal in die Hilfe unter Makros.

Der Zusammenhang ist ganz einfach

1. Du führst mit ShellExecute und ShellExecuteWait 2x das Setup aus, d.h. eins von beiden kannst Du Dir sparen.

2. Das Setup ruft dann über die .lnk-Datei vom Desktop das Programm auf C:\Users\<User>\AppData\Local\WhatsApp\WhatsApp.exe (<User> ist dabei Dein Benutzername)

Du musst warten bis dieses Programm beendet ist, dann erst kannst Du die .lnk-Datei auch wieder löschen.

Zitat von smu

Wie lautet der Platzhalter für "stefa", wenn ich stattdessen den angemeldeten Nutzer nehmen möchte?

@Username

Edit : ID des gerade angemeldeten Nutzers (entspricht der Systemvariable %USERNAME%).

Zitat von smu

Entschuldigung, wo finde ich das? Bin neu hier.

Die von BugFix angesprochene Hilfe findest Du unter : Makroreferenz

Lade mal die Datei manuell herunter. Starte die Setup-Datei und verbinde Dein Handy mit dem Computer.

Dann hast Du die .lnk-Datei auf Deinem Desktop. Klick mit der rechten Maustaste drauf und gehe auf Eigenschaften. Da siehst Du dann den Dateipfad.

Die Setup-Datei (die Du herunterlädst) installiert die Datei in den Pfad, den ich beschrieben haben (darum ja Setup) und startet diese danach.

Langer Rede kurzer Sinn: Möchtest Du ein fertiges Script oder Hilfe, um es selbst zu erstellen? Hier bei Hilfe und Unterstützung gibt es normalerweise Hilfe zur Selbsthilfe, ich kann Dir aber auch ein ganzes Script posten, wenn Du willst.

Kennst Du ConsoleWrite? Füge diese hinzu, so dass Du immer sehen kannst, was passiert

Mein Vorschlag:

ConsoleWrite('+> Deleting File' & @CRLF)
FileDelete("C:\Users\stefa\Downloads\WhatsAppSetup*.exe") ; da kannst Du den * eigentlich wegmachen, da es nur eine Datei ist
ConsoleWrite('+> Downloading file. This may take some time...' & @CRLF)
InetGet("https://web.whatsapp.com/desktop/windows/release/x64/WhatsAppSetup.exe", "C:\Users\stefa\Downloads\WhatsAppSetup.exe")
ConsoleWrite('+> File downloaded - executing file' & @CRLF)
ShellExecuteWait("C:\Users\stefa\Downloads\WhatsAppSetup.exe")

; jetzt startet das Setup und das Setup startet automatisch die Datei in Deiner Zeile 4
; Du musst jetzt schauen, ob diese Datei noch läuft
; Schau Dir dazu mal ProcessList() an, das gibt ein Array zurück - also auch _ArrayDisplay()
; Wenn dieser Prozess nicht mehr läuft, dann:

ConsoleWrite('+> Process is closed - deleting .lnk-file' & @CRLF)
FileDelete("C:\Users\stefa\Desktop\WhatsApp.lnk")

Exit

Hoffe, es hilft. Wenn nicht, dann einfach weiter fragen

Also...

normalerweise wird hier ein Problem geschildert das man selber nicht lösen kann.

Du hast zu Beginn deines Posts den Fehler aller Fehler gemacht. Du hast dir selbst eine Lösung ausgedacht und suchst nach einer Umsetzung dafür.

ABER

Deine Lösung ist einfach nicht gut. Daher sind auch die Lösungsansätze die wir liefern nicht sonderlich gut.

Ich unterstelle jetzt mal was du erreichen möchtest:

- Download von WhatsAppSetup.exe

- Start der Installation von WhatsApp Setup.exe

- Nach Installation --> "aufräumen"

Den Doanload hast du ja schon hinbekommen, sehr gut

Mit der Installation ist das so eine Sache. I.d.R. haben diese Installer-Programme je nachdem mit welchem Installer diese erstellt wurden, verschiedene "Switches" mit denen die Installation gesteuert werden kann. Unter anderem auch ein Schalter für die "leise" Installation. Diese installiert das Programm mit den "default" Einstallungen ohne Anzeige einer GUI und ohne Usereingaben.

In diesem Fall würde der Schalter vermutlich folgendermaßen aussehen: "/S"

Als Codezeile:

ShellExecuteWait("C:\Users\stefa\Downloads\WhatsAppSetup.exe", "/S")

Wenn du die Parametrierung eines Befehls in autoit sehen willst, dann markieren den gesamten Befehl und drücke F1:

Function ShellExecuteWait

ShellExecuteWait ( "filename" [, "parameters" [, "workingdir" [, "verb" [, showflag]]]] )Mit dieser Codezeile wird das Installationsprogramm gestartet, angewiesen die Installation bis zum Ende ohne Usereingaben auszuführen (/S)und zu warten, bis dieses Programm fertig ist (Process beendet)Was du danch mit den "Überresten" machst ist dann ein eigenes Thema

Zitat von smu

Entschuldigung, wo finde ich das?

Bin neu hier.

Moin smu.
smudo oder nicht smudo, das ist hier die Frage. Okay, SPASS.

Als ich mit AutoIt begann, war mein erstes Handeln, einmal mir einen großen Überblick der Hilfedatei zu verschaffen. Dann hatte ich ein erstes Problem, habe mit den Schlagwörtern die mir im Kopf waren, in der Hilfedatei nach Lösungen zu kommen. Einige konnte ich lösen, andere bekam ich hier sehr gute und "liebe" Hilfe.

Was ich damit sagen möchte ist, Du hast schon den Hinweis bekommen, das es die Hilfe gibt und das Du für Dein Problem dort mal bei Makros schauen darfst, da dir dort die Hilfe geboten wird bzw. Ansätze dafür. Ich sitze heute noch oft länger in der Hilfedatei fest und sucher und suche, aber es braucht immer wieder Geduld. Gerade als Neuling" ist es für viele nicht leicht mit etwas Neuem klar zu kommen. Egal ob es EDV / IT ist oder sonst etwas. Oder man versucht ohne die schriftliche Hilfe klar zu kommen. Ist doch wie bei einem neuen Gerät, das man das erste mal aufbaut und einstellt (z. B. TV). Wozu eine Gebrauchsanweisung lesen, das muss auch so klappen, ansonsten wird der technische Dienst des Herrstellers kontaktiert. Und wenn dann alles läuft hat man dann die Zeit die Gebrauchsanweisung zu lesen.

Und gaaaanz wichtig: "Lächeln & Geduld". Die Ungeduld parkt bei mir, das Lächel können wir uns teilen.

Zitat von smu

Wird das aufpoppende WhatsApp-Fenster letztendlich aus Zeile 3 oder Zeile 4 heraus gestartet?

Das ConsoleWrite von BananaJoe ist auf jeden Fall schon mal eine gute Idee...

Damit bekommst du aber keine Info darüber, wem das Fenster gehört oder von wem der Proccess gestart wurde ... dafür muss man schon etwas mehr tun.

Hier mal ein kleines Bsp., wie ich mir solche Infos anzeigen lasse, wenn ich ein neues Script schreibe:

;-- TIME_STAMP   2021-11-08 20:33:14

; Nur nötig, wenn du Infos über fremde Processe haben willst (s. _GetProcessUser). Achtung: Hinter #RequireAdmin darf kein Kommentar stehen!!!
;~ #RequireAdmin

#include <Array.au3>
#include <WinAPIHObj.au3>
#include <WinAPIProc.au3>

_GetProcInfo_Example()

Func _GetProcInfo_Example()
    Local $sNewFile = @ScriptDir & '\NeueTextdatei.txt'
    If Not FileExists($sNewFile) Then FileWrite($sNewFile, 'Testdatei, die mit Notepad geöffnet werden soll...')
    Local $iPID = Run('notepad.exe' & ' ' & $sNewFile)
    _PrintVar('$iPID', $iPID)
    Local $sProcessFileName = _WinAPI_GetProcessFileName($iPID)
    _PrintVar('$sProcessFileName', $sProcessFileName)
    Local $sCommandLine = _WinAPI_GetProcessCommandLine($iPID)
    _PrintVar('$sCommandLine', $sCommandLine)

    Local $aProcessUser = _GetProcessUser($iPID)
    _PrintVar('$aProcessUser', _ArrayToString($aProcessUser, '|', -1, -1, @CRLF & '>' & @TAB & @TAB))

    ; ProcessWindows anzeigen
    Local $bVisible = True, $aProcessWindows = _WinAPI_EnumProcessWindows($iPID, $bVisible) ; Handle|ClassName, ...
    ReDim $aProcessWindows[$aProcessWindows[0][0] + 1][3] ; Spalte für Title hinzufügen
    For $i = 1 To $aProcessWindows[0][0] Step 1
        $aProcessWindows[$i][2] = WinGetTitle($aProcessWindows[$i][0])
    Next
    _PrintVar('$aProcessWindows', _ArrayToString($aProcessWindows, '|', -1, -1, @CRLF & StringFormat('>%'&StringLen(@ScriptLineNumber) + 14&'s', ''))) ; Handle|ClassName|Title

    ConsoleWrite(@CRLF)
    ; Von welchem Proccess wurde Notepad gestartet?
    Local $iParentPID = _WinAPI_GetParentProcess($iPID)
    _PrintVar('$iParentPID', $iParentPID)
    Local $sParentProcessFileName = _WinAPI_GetProcessFileName($iParentPID)
    _PrintVar('$sParentProcessFileName', $sParentProcessFileName)
    Local $sParentCommandLine = _WinAPI_GetProcessCommandLine($iParentPID)
    _PrintVar('$sParentCommandLine', $sParentCommandLine)

    ConsoleWrite(@CRLF)
    ; Hier noch eine Ausgabe mit _PrintVar, bei der ein Fehler aufgetreten ist.
    Local $sShowExecuteError = Execute('#Alexa, go get some beer!')
    _PrintVar('$sShowExecuteError', $sShowExecuteError)

    ; @@ Debug(45) :      $sShowExecuteError               ==>>
    ; Wenn du einen Doppelklick auf so ^^ eine Zeile in dem Ausgabefenster machst, setzt SciTE das Caret in diese Zeile... hier wäre es die Zeile 45!!!

    ; Aufräumen
    MsgBox(64, @ScriptName, 'Klick auf OK, um Notepad zu beenden und die Textdatei wieder zu löschen.')
    ProcessClose($iPID)
    FileDelete($sNewFile)
EndFunc   ;==>_GetProcInfo_Example

Func _GetProcessUser($iPID)
    If IsAdmin() Then
        ; Enable "SeDebugPrivilege" privilege for obtain full access rights to another processes
        Local $aAdjust, $hToken = _WinAPI_OpenProcessToken(BitOR($TOKEN_ADJUST_PRIVILEGES, $TOKEN_QUERY))
        _WinAPI_AdjustTokenPrivileges($hToken, $SE_DEBUG_NAME, $SE_PRIVILEGE_ENABLED, $aAdjust)
    EndIf

    ; Retrieve the user (account) name, domain (computer) name for the specified process
    Local $aProcessUser = _WinAPI_GetProcessUser($iPID)

    If IsAdmin() Then
        ; Enable SeDebugPrivilege privilege by default
        _WinAPI_AdjustTokenPrivileges($hToken, $aAdjust, 0, $aAdjust)
        _WinAPI_CloseHandle($hToken)
    EndIf

    Return $aProcessUser
EndFunc   ;==>_GetProcessUser

Func _PrintVar($sVarName, $sValue, $iScriptLineNumber = @ScriptLineNumber, $iError = @error, $iExtended = @extended)
    If $iError Or $iExtended Then
;~         ConsoleWrite(StringFormat('@@ Debug(%i) : \t %-32s ==>> %s\n!  $iError = %i \t $iExtended = %i\n', $iScriptLineNumber, $sVarName, $sValue, $iError, $iExtended))
        ConsoleWrite(StringFormat('@@ Debug(%i) : \t %-32s ==>> %s\n-%' & StringLen($iScriptLineNumber) + 14&'s$iError = %i \t $iExtended = %i\n', $iScriptLineNumber, $sVarName, $sValue, '', $iError, $iExtended))
    Else
        ConsoleWrite(StringFormat('@@ Debug(%i) : \t %-32s ==>> %s\n', $iScriptLineNumber, $sVarName, $sValue))
    EndIf
EndFunc   ;==>_PrintVar