Gesamtzeit richtig berechnen

OhnePlan

Hallo liebe Community,

ich arbeite an einem größeren Projekt in dem ich unter anderem die Aktuelle Spielzeit und die Gesamtspielzeit berechnen will. Ich habe das nun in einem kleinen Test-Projekt aufgebaut. Leider funktioniert die Berechnung der Gesamtspielzeit während das Spiel (in dem Fall das Programm Notepad) läuft nicht, und ich komme einfach nicht weiter. Evtl kann mir hier ja jemand helfen.

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <Process.au3>
#include <Date.au3>

Global $regKey = "HKEY_CURRENT_USER\Software\aMyCompany\MyGame"
Global $regValuePlayTime = "TotalPlaytime"
Global $REG_STR_TYP = "REG_SZ"
Global $iStartTime = 0
Global $iWarningCounter = 1
Global $iTimeToWarning = 60   ; Anzahl der Minuten bis zur nächsten Warnung (Default: 60)
Global $iTotalPlaytime = 0
Global $sPlayTimeColor = "#008000"
Global $sSpielProcess = "Notepad.exe"
Global $hSpielHandle = -1
Global $sTitleSpiel = "Unbenannt"
Global $iStartTimeOfGame = 1 * 1000	;in Millisekunden

; Gesamtspielzeit aus der Registrierung lesen
$iTotalPlaytime = RegRead($regKey, $regValuePlayTime)
If @error Then
    ConsoleWrite("Fehler beim Lesen der Registry")
    $iTotalPlaytime = 0
EndIf

ConsoleWrite("Gesamtspielzeit: " & _ConvertToTime($iTotalPlaytime) & @CRLF)

Global $hWH = GUICreate("Spielzeit Aufzeichnung", 100, 200, -1, -1)
Global $hButtonSpielen = GUICtrlCreateButton("Spielen", 10, 20, 80, 30)
Global $hButtonAktSpielzeit = GUICtrlCreateButton("Spielzeit", 10, 60, 80, 30)
Global $hButtonGesSpielzeit = GUICtrlCreateButton("GesSpielzeit",10,100,80,30)

GUISetState()

	While 1
		If _SpielLaueft($sSpielProcess, $hSpielHandle, $sTitleSpiel, $iStartTime, $iStartTimeOfGame) Then	; Überwache die Spielzeit nur, wenn das Spiel läuft
			_MonitorPlayingTime($iStartTime, $iTimeToWarning, $iWarningCounter)
		Else
			If $hSpielHandle <> -1 And Not ProcessExists($sSpielProcess) And $iStartTime <> 0 Then
				_StopGame($iStartTime, $hSpielHandle, $iTotalPlaytime, $sPlayTimeColor)
			EndIf
		EndIf

		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				;$iTotalPlaytime = 0
				RegWrite($regKey, $regValuePlayTime, $REG_STR_TYP, $iTotalPlaytime)
				If @error Then ConsoleWrite("Fehler beim Schreiben in die Registry")
				ProcessClose($sSpielProcess)
				Exit
			Case $hButtonSpielen
				Run("notepad.exe")
			Case $hButtonAktSpielzeit
				ConsoleWrite("Aktuelle Spielzeit: " & _CurrentPlayTime($iStartTime) & @CRLF)

			Case $hButtonGesSpielzeit
				If _SpielLaueft($sSpielProcess, $hSpielHandle, $sTitleSpiel, $iStartTime, $iStartTimeOfGame) Then
					$elapsedTime = _GetElapsedTime($iStartTime)
					If $iTotalPlaytime >= $elapsedTime / 1000 Then
						$iTotalPlaytime -= $elapsedTime / 1000 ; Ziehe vergangene Spielzeit von der Gesamtspielzeit ab
					Else
						$iTotalPlaytime = 0 ; Setze die Gesamtspielzeit auf 0, wenn sie unter 0 fällt
					EndIf
					RegWrite($regKey, $regValuePlayTime, $REG_STR_TYP, $iTotalPlaytime)
					If @error Then ConsoleWrite("Fehler beim Schreiben in die Registry")
				EndIf
				ConsoleWrite("Aktuelle Spielzeit: " & _CurrentPlayTime($iStartTime) & @CRLF)
				ConsoleWrite("Gesamtspielzeit: " & _ConvertToTime($iTotalPlaytime) & @CRLF)
		EndSwitch
	WEnd

	Exit
;########################################################################

	Func _SpielLaueft($_sProcessName, ByRef $_hSpielHandle, $_sSpielTitel, ByRef $_iStartTime, $_iStartTimeOfGame)
		If ProcessExists($_sProcessName) Then
			If $_iStartTime = 0 Then
				WinActivate($_sSpielTitel)
				WinWaitActive($_sSpielTitel, "", 30)
				 Sleep($_iStartTimeOfGame) ; Warte 15 Sekunden, um die Startverzögerung zu berücksichtigen
				$_iStartTime = _Date_Time_GetTickCount()
				$_hSpielHandle = WinGetHandle($_sSpielTitel)
				ConsoleWrite("Spiel startet..." & @CRLF)
				ConsoleWrite("Spielzeit wird aufgezeichnet" & @CRLF)
			EndIf
			Return True
		Else
			Return False
		EndIf
	EndFunc

	Func _MonitorPlayingTime($_iStartTime, $_iTimeToWarning, ByRef $_iWarningCounter)

		Local $elapsedTime = _Date_Time_GetTickCount() - $_iStartTime
		If $elapsedTime >= $_iTimeToWarning * 60000 * $_iWarningCounter Then
			ConsoleWrite("Du spielst bereits seit " & ($_iTimeToWarning * $_iWarningCounter) & " Minuten." & @CRLF)
			$_iWarningCounter += 1
		EndIf
	EndFunc

	Func _StopGame(ByRef $_iStartTime, ByRef $_hSpielHandle, ByRef $_iTotalPlaytime, $_sPlayTimeColor)
		If $_iStartTime = 0 Then Return

		Local $elapsedTime = _Date_Time_GetTickCount() - $_iStartTime
		; Füge die Spielzeit der aktuellen Sitzung zur Gesamtspielzeit hinzu
		$_iTotalPlaytime += $elapsedTime ;/ 1000  ;Teile durch 1000, um Sekunden zu erhalten

		ConsoleWrite("Aktuelle Spielzeit nach Beenden: " & _ConvertToTime($elapsedTime) & @CRLF)
		ConsoleWrite("Neue Gesamtspielzeit nach Beenden: " & _ConvertToTime($_iTotalPlaytime) & @CRLF)

		; Zurücksetzen der Startzeit und des Spielhandles
		$_iStartTime = 0
		$_hSpielHandle = -1
	EndFunc

	Func _CurrentPlayTime($_iStartTime)
		If $_iStartTime <> 0 Then
			Local $elapsedTime = _Date_Time_GetTickCount() - $_iStartTime
			Local $sCurrentPlayTime = _ConvertToTime($elapsedTime)
			Return $sCurrentPlayTime
		EndIf
	EndFunc

	Func _ConvertToTime($milliseconds)
		Local $years = Int($milliseconds / (86400000 * 365))
		Local $days = Int(($milliseconds - ($years * 86400000 * 365)) / 86400000)
		Local $hours = Int(Mod($milliseconds, 86400000) / 3600000)
		Local $minutes = Int(Mod($milliseconds, 3600000) / 60000)
		Local $seconds = Int(Mod($milliseconds, 60000) / 1000)
		Local $timeString = ""

		If $years > 0 Then
			$timeString &= $years & " Jahre, "
		EndIf

		If $days > 0 Then
			$timeString &= $days & " Tage, "
		EndIf

		If $hours > 0 Then
			$timeString &= $hours & " Stunden, "
		EndIf

		If $minutes > 0 Then
			$timeString &= $minutes & " Minuten, "
		EndIf

		If $seconds > 0 Then
			$timeString &= $seconds & " Sekunden, "
		EndIf

		If StringLen($timeString) > 0 Then
			$timeString = StringTrimRight($timeString, 2) ; Entferne das letzte Komma und Leerzeichen
		Else
			$timeString = "0 Sekunden"
		EndIf

		Return $timeString
	EndFunc

	Func _GetElapsedTime($_iStartTime)
	  Local $iCurrentTime = _Date_Time_GetTickCount()
	  Local $iTimeDiff = $iCurrentTime - $_iStartTime
	  
	  If $iTimeDiff < 0 Then
		$iTimeDiff += 0xFFFFFFFF ; Berücksichtigt 32-Bit-Überlauf
	  EndIf

	  Return $iTimeDiff
	EndFunc

Alles anzeigen

Vielen lieben Dank

Gruß OhnePlan

**Moombas**

Müsste RegWrite($regKey, $regValuePlayTime, $REG_STR_TYP, $iTotalPlaytime) nicht eher in die Funktion _StopGame() (Oder danach)?

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi OhnePlan ,

ich habe das Skript noch nicht ganz reviewed, keine Zeit, doch zwei kleine Auffälligkeiten bekommt man (Warnungen geworfen), wenn du folgende Direktiven verwendest (ggf. hilft es etwas). Ist nicht die Begründung zu deiner Fragestellung, aber eine Randnotiz.

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

Code

(61,48) : warning: $elapsedTime possibly not declared/created yet
$elapsedTime = _GetElapsedTime($iStartTime)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

Code

(104,98) : warning: $_sPlayTimeColor: declared, but not used in func.
Func _StopGame(ByRef $_iStartTime, ByRef $_hSpielHandle, ByRef $_iTotalPlaytime, $_sPlayTimeColor)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

Viele Grüße
Sven

**Alina**

Mal eine Frage. Wenn Du ein Spiel spielst, dann startet doch ein Prozess. Wieso fragest Du nicht ab ob der Prozess läuft oder nicht? Wenn er läuft spielst Du, schreibst die aktuelle Zeit in z. B. eine Ini-Datei und wenn der Prozess nicht läuft schreibst Du es wieder in die Ini. Die zweite ZTeit minus die erste Zeit ist die Zeit die Du gespielst hast. DIese speicherst Du dann wieder. Wenn Du dann z. B. einen Tag später wieder spielst, machst Du das ganze wieder von vorne. Nur das Du die gesamte Spielzeit vom VOrtag zu dre vom aktuellen Tag zusammenrechnen musst. So würde ich sinngemäß vorgehen. Aber es kann auch sein das es so nicht möglich ist, aber es soll für Dich eine Anregung sein, es vielleicht mleichter lösen zu können.

OhnePlan

Hallo SOLVE-SMART ,

danke für das kleine Feedback, ist "gefixt". $_sPlayTimeColor war noch ein Überbleibsel vom großen Projekt.

Hallo Alina ,

das ist nicht das Problem, so ähnlich funktioniert auch alles. Ich will nur die Gesamtspielzeit errechnen, während ich Spiele. Die Gesamtspielzeit wenn das Spiel geschlossen wird funktioniert.

**Alina**

Gesamtspielzeit von aktueller Spielesitzung oder Gesamtspielzeit seit Du jemals das Spiel gestartet hast?
Blau oder grün ?
Beides geht doch ideal über das was ich oben vorgeschlagen habe.

OhnePlan

Gesamtspielzeit von aktueller Spielesitzung

Habe ich. Es geht um die Gesamtspielzeit seit ich jemals das Spiel gestartet habe. Führe dazu doch einfach mal mein Script aus. Wenn du weißt, wie es funktioniert, dann bitte erleuchte mich ^^. Ich bekomm es nicht hin.

**Moombas**

Aber die Berechnung ist doch Prinzipiell die Gleiche, nur das du andere Start- und End-Werte hast.

Also was funktioniert dabei nicht (genaue Beschreibung)?

Tipp: Baue eine Funktion die diese Berechnung macht und nutze sie für beide á la: $diff = _calculateDiff($StartTime, $Endtime) die dir dann immer einfach den Wert zurück gibt.

Wenn das dann bei einem von beidem nicht passt, weißt du das entweder die Startzeit oder die Endzeit nicht passt.
Btw.: Hast du diese mal geprüft ob diese stimmen?

**Alina**

OhnePlan

Script habe ich gerade leidr keine Zeit. Vielleicht heute Abend, muss ich mal sehen.

Sehe Dir mal in der Hilfe ProcessExists und alles was Bezug auf Process hat an.
Da kannst Du auf den Prozess, also Dein Spiel reagieren.

edit:
Gerade über die Suchfunktion gefunden: Laufzeit berechnen
Gib das mal als Suche ein. Da wirst Du fündig, gleich auf Seite 1.

Link geht schneller : Programmlaufzeit von AspirinJunkie

**Moombas**

Zitat von OhnePlan

Gesamtspielzeit von aktueller Spielesitzung
Habe ich. Es geht um die Gesamtspielzeit seit ich jemals das Spiel gestartet habe. Führe dazu doch einfach mal mein Script aus. Wenn du weißt, wie es funktioniert, dann bitte erleuchte mich ^^. Ich bekomm es nicht hin.

Auch wenn man es leicht ändern kann und in deinem Fall überschaubar ist: ich für meinen Teil werde niemals fremden Code ausführen der (weder lesend noch schreibend) auf die Registry zugreift.

**Alina**

Moombas da gebe ich Dir recht !!!

Vielleicht hilft Dir das auch weiter:

Müsste aber noch überarbeitet werden.
Unter anderem hier: escndv.exe <--- tauschen durch Deine Startdatei vom Spiel:
Und die Ausgabe der MsgBox muss auch nicht sein, das ist nur als Beispiel.

AutoIt

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

Global $sLogFile = @ScriptDir & "\escndv_runtime.log"

Func WriteRuntimeLog($iRuntime)
Local $hFile = FileOpen($sLogFile, $FO_OVERWRITE)
If $hFile = -1 Then
MsgBox($MB_OK, "Fehler", "Konnte Log-Datei nicht öffnen!")
Return
EndIf

FileWrite($hFile, $iRuntime)
FileClose($hFile)
EndFunc

Func ReadRuntimeLog()
If Not FileExists($sLogFile) Then Return 0

Local $hFile = FileOpen($sLogFile, $FO_READ)
If $hFile = -1 Then Return 0

Local $sContent = FileRead($hFile)
FileClose($hFile)

Return $sContent
EndFunc

Func UpdateRuntimeLog($iRuntimeToAdd)
Local $iTotalRuntime = ReadRuntimeLog() + $iRuntimeToAdd
WriteRuntimeLog($iTotalRuntime)
EndFunc

While 1
Local $iStartTime = TimerInit()

Run("escndv.exe") ; Starte das Programm escndv.exe

While ProcessExists("escndv.exe")
; Warte, bis das Programm escndv.exe beendet wird
Sleep(1000)
WEnd

Local $iElapsedTime = TimerDiff($iStartTime)
Local $iElapsedTimeInSeconds = Round($iElapsedTime / 1000, 0)

UpdateRuntimeLog($iElapsedTimeInSeconds)

$iTotalRuntime = ReadRuntimeLog()

MsgBox($MB_OK, "Laufzeit von escndv.exe", "Das Programm escndv.exe lief für insgesamt " & $iTotalRuntime & " Sekunden.")
Exit
WEnd

Alles anzeigen

OhnePlan

Alina vielen Dank für deine Hilfe, das bringt mich leider nicht weiter.

Die aktuelle Spielzeit habe ich ermittelt, auch wenn ich das Spiel schließe wird die Spielzeit auf die Gesamtspielzeit addiert und beim Neustart des Autoit-Programmes korrekt eingelesen und angezeigt.
Was allerdings nicht funktioniert: Während ich spiele, möchte ich die Gesamtspielzeit ermittelt. Sprich die gespeicherte Gesamtspielzeit + Aktuelle Spielzeit und das eben immer wenn ich auf den Gesamtspielzeit-Button klicke. Außerdem muss dann, bei beenden des Spieles (und die _StopGame Funktion greift) die Gesamtspielzeit richtig berechnet und gespeichert werden. Ich wäre sehr dankbar, wenn jemand das Script ausführt um evtl. das Problem besser zu verstehen. Ich komme hier leider nicht weiter. Notfalls passe ich es auch an, sodass nicht in die Registry sondern in eine TXT oder INI Datei geschrieben wird.

Vielen Dank,

Gruß OhnePlan

**Schnuffel**

wenn du mit Registry Einträgen arbeitest, dann speichere doch einfach den letzten Start des Spiels auch in dem Zweig.

Dann kannst du immer gegen die aktuelle Uhrzeit prüfen bei Spielzeit-Abfrage oder Abfrage Gesamtspielzeit.

setze bei Spielstart ein: RegWrite($regKey, "StartPlayTime", $REG_STR_TYP, _NowCalc())

und prüfe im Spiel oder für gesamt gegen den jeweiligen Wert in der Registry mit _DateDiff()

OhnePlan

Weiß mir mit meinem Script keiner Rat?

**Schnuffel**

Alina hat dir doch ein brauchbares Beispiel geliefert.

Velted

Moin, auch wenn ich die auf Spiele ausgerichteten Skripte nicht gern unterstütze: Ich kann Dein Problem nicht finden.

Du verwaltest eine "bisherige Gesamtspielzeit" in der Registrierung. Die kannst Du beim Start des Skripts einlesen. Sie kann sich nicht verändern.

Das Skript startet das Spiel. Du musst Dir also nur einmal den Startzeitpunkt merken.

Wenn Du auf "Aktuelle Spielzeit" drückst, musst Du die Differenz zur Startzeit berechnen. Wie Du sagst, klappt das bereits.

Wenn Du auf "Aktuelle Gesamtzeit" drückst, musst Du die "Aktuelle Spielzeit" berechnen und den beim Start des Skripts eingelesenen Wert aus der Registrierung addieren.

Wenn das Spiel (btw. das Skript?) beendet wird, musst Du die "Aktuelle Spielzeit" berechnen, den beim Start des Skripts eingelesenen Wert aus der Registrierung addieren und das Ergebnis in die Registrierung zurückschreiben.

Wo klemmt es?

OhnePlan

Guten Morgen,

ich habs hinbekommen. Muss zugeben, so ein bisschen stand ich schon aufm Schlauch :D.

Danke für Eure Hilfe

Gruß OhnePlan

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)