Ballontipp bei Programmstart anzeigen an definierter Stelle

hipfzwirgel

Hallo Gemeinde,

ist es möglich, einen BallonTooltipp unmittelbar nach dem Start einer Gui, an einer bestimmten Stelle für 10 Sekunden anzeigen zu lassen?

Beispielcode:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ListBoxConstants.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
	Local $sMESSAGE = "||"

	GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

	Local $idMylist = GUICtrlCreateList("", 64, 32, 121, 97, BitOR($WS_VSCROLL, $LBS_USETABSTOPS))
	GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
	GUICtrlSetData(-1, "||")
	GUICtrlSetData(-1, "1. Item")
	Local $idButton_Close = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

	GUISetState(@SW_SHOW)

	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton_Close
				MsgBox($MB_SYSTEMMODAL, "", "the closing button has been clicked", 2)
				Exit
		EndSwitch
	WEnd
EndFunc   ;==>Example

Alles anzeigen

Der Beispielcode zeigt eine Gui mit einer Listbox an, welche zwei Einträge hat.
Ich möchte, dass wenn die Gui gestartet wird, der BallontoolTip direkt angezeigt wird und auf den zweiten Eintrag (hier: 1. Item) zeigt, für
10 Sekunden.

AutoIt

; ich habe es mit:

ToolTip("Beispieltext", x, n, "INFO", 1, 1)
Sleep(10000)
ToolTip("")

; versucht. Leider sind die Koordinaten x und n aber immer auf den Desktop bezogen und nicht auf das Control, bzw. die Stelle
wo ich den Tip gerne hätte. Gerade auch wenn die GUI an anderer Stelle erscheint.

**Schnuffel**

stumpf, aber funktioniert:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ListBoxConstants.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
	Local $sMESSAGE = "||"

	$GUI = GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

	Local $idMylist = GUICtrlCreateList("", 64, 32, 121, 97, BitOR($WS_VSCROLL, $LBS_USETABSTOPS))
	GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
	GUICtrlSetData(-1, "||")
	GUICtrlSetData(-1, "1. Item")
	Local $idButton_Close = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

	GUISetState(@SW_SHOW)
	$f = WinGetPos($GUI)
	$a = ControlGetPos("","", $idMylist)
	ToolTip("Beispieltext", $f[0]+$a[0]+40, $f[1]+$a[1]+$a[3]-50, "INFO", 1, 1)
	Sleep(10000)
	ToolTip("")

	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton_Close
				MsgBox($MB_SYSTEMMODAL, "", "the closing button has been clicked", 2)
				Exit
		EndSwitch
	WEnd
EndFunc   ;==>Example

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi hipfzwirgel , hi Schnuffel 👋 ,

deine "stumpfe" Variante funktioniert wunderbar Schnuffel .
Sie hat nur die kleine Einschränkung, dass während der 10 Sekunden die GUI nicht verwendbar ist.
Also eine Interaktion mit dem Button (ich nehme an da kommen noch mehr dazu) nicht möglich ist, da ja das Skript durch das Sleep() blockiert ist.

Daher habe ich mit deinen Werten aus WinGetPos() und ControlGetPos() eine Variante mit einem Timer gebastelt.
Somit kann während der Anzeige auch noch die GUI "bedient" werden, falls dies gewünscht ist. Wenn nicht, dann bitte Variante 1 nutzen 😅 .

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

#include-once
#include <GUIConstantsEx.au3>
#include <ListBoxConstants.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
	Local $hGUI    = GUICreate('My GUI list')
    Local $cList   = GUICtrlCreateList('', 64, 32, 121, 97, BitOR($WS_VSCROLL, $LBS_USETABSTOPS))
                     GUICtrlSetLimit(-1, 200) ; To limit horizontal scrolling.
                     GUICtrlSetData(-1, '||1. Item')
    Local $idClose = GUICtrlCreateButton('my closing button', 64, 160, 175, 25)

	GUISetState(@SW_SHOW)

    Local $mGui[]
          $mGui.Data = WinGetPos($hGUI)
          $mGui.XPos = $mGui.Data[0]
          $mGui.YPos = $mGui.Data[1]

    Local $mListControl[]
          $mListControl.Data   = ControlGetPos('', '', $cList)
          $mListControl.XPos   = $mListControl.Data[0]
          $mListControl.YPos   = $mListControl.Data[1]
          $mListControl.Height = $mListControl.Data[3]

    Local $mToolTip[]
          $mToolTip.XPos = $mGui.XPos + $mListControl.XPos + 48
          $mToolTip.YPos = $mGui.YPos + $mListControl.YPos + $mListControl.Height - 48

    ToolTip('Beispieltext', $mToolTip.XPos, $mToolTip.YPos, 'INFO', 1, 1)

    Local Const $iSecondsToWait = 5 * 1000
    Local $bShouldBallonTipBeDisplayed = True
    Local $hTimer = TimerInit()

	While True
        If $bShouldBallonTipBeDisplayed Then
            If TimerDiff($hTimer) >= $iSecondsToWait Then
                ToolTip('')
                $bShouldBallonTipBeDisplayed = False
            EndIf
        EndIf

		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idClose
				MsgBox('', '', 'the closing button has been clicked', 2)
				ExitLoop
		EndSwitch
	WEnd

    GUIDelete($hGUI)
EndFunc

Alles anzeigen

Einen angenehmen Abend euch noch 🤝 .

Viele Grüße
Sven

**water**

Ich verwende die _GUIToolTip* Funktionen von AutoIt.
Mit _GUIToolTip_SetDelayTime lässt sich die Anzeigedauer einstellen.

hipfzwirgel

Hallo Zusammen,

bitte entschuldigt die späte Rückmeldung und vielen lieben Dank für eure Denkanstöße und Mühen.

Ich werde den Vorschlag von Schnuffel und Solve Smart morgen mal testen.

@ water: das hatte ich auf Vorschlag von ChatGpt auch versucht aber leider nicht hinbekommen. I-wie wurde entweder der Ballontip nicht angezeigt oder an falscher Stelle.

**water**

Ich poste demnächst ein Beispiel wie ich es einsetze

**water**

So, hier ein Beispiel mit _GUIToolTip:

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <ToolTipConstants.au3>

; Max. Time to display the Tooltip (10 seconds)
$iToolTipMaxDisplayTime = 10000

$hGUIMain = GUICreate("TestToolTip", 810, 839, 100, 100)
; Select the icon to use for the Tooltip
$idIcon1 = GUICtrlCreateIcon("shell32.dll", 24, 125, 38, 22, 22)
$hIcon1 = GUICtrlGetHandle($idIcon1)
$hToolTip1 = _GUIToolTip_Create($hGUIMain, BitOR($TTS_CLOSE, $TTS_BALLOON))
_GUIToolTip_SetMaxTipWidth($hToolTip1, 400)
_GUIToolTip_SetDelayTime($hToolTip1, $TTDT_AUTOPOP, $iToolTipMaxDisplayTime)
_GUIToolTip_AddTool($hToolTip1, 0, "Test.", $hIcon1, Default, Default, Default, Default, BitOR($TTF_SUBCLASS, $TTF_IDISHWND, $TTF_CENTERTIP))
_GUIToolTip_SetTitle($hToolTip1, "Testitel", $TTI_INFO)
GUISetState(@SW_SHOW)
; Move the mouse to the Icon Coordinate so the Tooltip gets displayed
Opt("MouseCoordMode", 0)
MouseMove(135, 70, 0)
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			ExitLoop
	EndSwitch
WEnd
; Destroy the tooltip control
_GUIToolTip_Destroy($hToolTip1)
GUIDelete($hGUIMain)

Alles anzeigen

**Kanashius**

Du wolltest den ToolTip ja auf dem ListItem haben:
Du kannst die Position und Größe des Items mit _GuiCtrlListBox_GetItemRect abfragen.

Ich hab mal ein Beispiel erstellt. Dabei werden auch mehrere ToolTips hintereinander angezeigt, ohne dass die GUI blockiert.
Ich hab als alternative zu den Timern mal AdlibRegister genutzt.

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ListBoxConstants.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
	Local $mGuiData[]
	Local $sMESSAGE = "||"

	$mGuiData.hGui = GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

	$mGuiData.idList = GUICtrlCreateList("", 64, 32, 121, 97, BitOR($WS_VSCROLL, $LBS_USETABSTOPS))
	GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
	GUICtrlSetData(-1, "||")
	GUICtrlSetData(-1, "1. Item")
	$mGuiData.idButtonClose = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)
	$mGuiData.idButtonToolTip = GUICtrlCreateButton("show tooltips", 64, 200, 175, 25)

	GUISetState(@SW_SHOW)

	_showTooltips($mGuiData)

	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $mGuiData.idButtonClose
				MsgBox($MB_SYSTEMMODAL, "", "the closing button has been clicked", 2)
				Exit
			Case $mGuiData.idButtonToolTip
				_showTooltips($mGuiData)
		EndSwitch
	WEnd
EndFunc   ;==>Example

Func _showTooltips(ByRef $mGuiData, $bContinue = False)
	Local Static $iCurrent = 0
	Local Static $mData
	If $mGuiData<>Default Then $mData = $mGuiData
	If Not $bContinue Then $iCurrent = 0
	Switch $iCurrent
		Case 0 ; first toolbar
			Local $arPos = _GuiCtrlListBox_GetGlobalItemPos($mData.idList, 1)
			_showToolTip($arPos[0] + ($arPos[2]*0.2), $arPos[1] + ($arPos[3]*0.9), "Listview item", 5)
		Case 1 ; second toolbar
			Local $arPos = _windowGetPos(GUICtrlGetHandle($mData.idButtonClose))
			_showToolTip($arPos[0] + ($arPos[2]/2), $arPos[1] + ($arPos[3]/2), "Close button", 3)
		Case 2 ; ...

		Case Else
			; Done
	EndSwitch
	$iCurrent += 1
EndFunc

Func _windowGetPos($hGui)
	Local $tagRect = _WinAPI_GetWindowRect($hGui)
	Local $arPos = [DllStructGetData($tagRect, 1), DllStructGetData($tagRect, 2), DllStructGetData($tagRect, 3) - DllStructGetData($tagRect, 1), DllStructGetData($tagRect, 4) - DllStructGetData($tagRect, 2)]
	Return $arPos
EndFunc

Func _GuiCtrlListBox_GetGlobalItemPos($idList, $iIndex)
	Local $arCtrlPos = _windowGetPos(GUICtrlGetHandle($idList))
	Local $arItemPos = _GUICtrlListBox_GetItemRect($idList, 1)

	Local $arRes = [$arCtrlPos[0]+$arItemPos[0], $arCtrlPos[1]+$arItemPos[1], $arItemPos[2]-$arItemPos[0], $arItemPos[3]-$arItemPos[1]]
	Return $arRes
EndFunc

Func _showToolTip($x, $y, $sMessage, $iTimeS, $sTitle = "INFO", $iIcon = 1, $iOptions = 1)
	ToolTip($sMessage, $x, $y, $sTitle, $iIcon, $iOptions)
	AdlibRegister("_hideToolTip", $iTimeS*1000)
EndFunc

Func _hideToolTip()
	ToolTip("")
	AdlibUnRegister("_hideToolTip")
	Local $oTmp = Default
	_showTooltips($oTmp, True)
EndFunc

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi water , hi Kanashius 👋 ,

beide eure Ansätze finde ich gut, wobei ich das Beispiel von Water doch besser finde. UDF eingebunden und "die richtigen Funktionen" genutzt, fertig.
Wenn man die GUIToolTip.au3 nicht kennt, nutzen möchte etc., ist deine Variante Kanashius meiner Meinung nach eine gute Alternative.

-- Alle Wege führen nach Rom --

Angenehmen Abend euch allen noch.

Viele Grüße
Sven

hipfzwirgel

Hallo alle miteinander,

zunächst meinen aller herzlichsten Dank für eure Beteiligung!!! Euer Einsatz möge mit dauerhaftem Sommerwetter und unbeschreiblich großem Reichtum
vergolten werden.

Die Version von Water hat natürlich auch Charme aber es macht mir den Anschein, dass es nicht zu gehen scheint, die
_GUIToolTip-Methoden anzuzeigen ohne zu hoovern. Zumindest konnte ich dafür noch keine Lösung finden.
Vielleicht hat ja Water dazu eine Idee?

Der Ballontip sollte ja gleich zu Programmstart angezeigt werden, da das Programm nur startet, wenn ein
Eintrag (Listitem verweist auf eine Datei in einem Ordner der mit FilelisttoArray ausgelesen wird, um das Listenfeld dynamisch zu erstellen. Ohne Eintrag kein Array => Programmabsturz) im Listenfeld existiert. Wenn nicht lass ich einen Dummyeintrag erstellen vor dem tatsächlichen Proggi-Start. Der Ballontip soll dann beim Anzeigen der Gui darüber informieren,
dass wenn ein weiterer Eintrag erstellt wurde, der Dummyeintrag gelöschte werden darf/kann. Dafür eignet sich die Hooverei natürlich nicht so gut.

**Schnuffel**

wenn ich das so lese schreit das ja gast nach einem child Fenster. Das kannst du gestalten wie du willst. Kann auch so aussehen wie ein Ballon oder eine Wolke oder, …

Gibt sicher reichlich beispiele für popup child window

**Moombas**

Zitat von hipfzwirgel

...Der Ballontip soll dann beim Anzeigen der Gui darüber informieren,
dass wenn ein weiterer Eintrag erstellt wurde, der Dummyeintrag gelöschte werden darf/kann. Dafür eignet sich die Hooverei natürlich nicht so gut.

Warum machst du den Dummyeintrag nicht "einzigartig" und prüfst beim anlegen eines Eintrags ob dieser vorhanden ist und löscht ihn nebenbei.

Das wäre nicht nur Benutzerfreundlicher, sondern spart dir auch deinen Balloon tipp oder ähnliches.

**water**

Zitat von hipfzwirgel

Ohne Eintrag kein Array => Programmabsturz)

Sehe ich das richtig, dass, wenn dieses Problem vom Skript umgangen wird, die ganze Sache mit dem BalloonTip nicht mehr notwendig ist?

hipfzwirgel

Hallole,

danke für eure Eingaben.

@ Moombas: das ich daran nicht selbst gedacht habe...

@ water: eigentlich ja. Was uns ja wieder zur Idee von Moombas zurückführt

**water**

Zitat von hipfzwirgel

da das Programm nur startet, wenn ein
Eintrag (Listitem verweist auf eine Datei in einem Ordner der mit FilelisttoArray ausgelesen wird, um das Listenfeld dynamisch zu erstellen. Ohne Eintrag kein Array => Programmabsturz

Das ist das Ursprungsproblem:
Falls die Datei nicht existiert oder keine Einträge beinhaltet, gibt es keinen Array aber zumindest einen Fehlercode.
Mein Ansatz: Diesen Fehlercode abfangen und dann den notwendigen Array im Skript selbst erstellen. Dadurch stürzt das Programm nicht mehr ab - Problem erledigt.

Details kann ich deinen bisherigen Code-Snippets nicht entnehmen, man müsste daher an dieser Lösung noch feilen

**Moombas**

Stimme da water zu, das Problem an der Wurzel fassen.
Sprich vom Prinzip: If not IsArray($DeinArray) then dosomethingelse()

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)