GDI+ Rotating Earth build 2017-03-17

**UEZ**

Mal wieder was in GDI+: Echtzeit Projektion und Rotation einer Earth Map (600x300) auf eine Kugel.

Earth4_600x300.jpg ==> Rotating Earth.jpg

Leider ist die Animation nicht besonders performant, aber sieht dafür hübsch aus.

Inspiriert durch Eukalyptus' Black Hole Code. U

Source Code ist nicht vollständig!

AutoIt

;coded by UEZ build 2017-02-25
#pragma compile(Icon, "c:\Program Files (x86)\AutoIt3\Icons\au3.ico")
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/so /pe /rm
#AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_stripped.au3"
#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit
Global Const $iW = 800, $iH = 500, $iWh = $iW / 2, $iHh = $iH / 2, $sTitle = "GDI+ Rotating Earth coded by UEZ 2017"
Global Const $fPi = ACos(-1), $fRad = $fPi / 180, $fDeg = 180 / $fPi
AutoItSetOption("GUIOnEventMode", 1)
GDIPlus_RotatingEarth()
AutoItSetOption("GUIOnEventMode", 0)
_GDIPlus_Shutdown()
Func GDIPlus_RotatingEarth()
	$bExit = False
	$hGUI = GUICreate($sTitle, $iW, $iH) ;, 0, 0, $WS_POPUP)
	GUISetState(@SW_SHOW, $hGUI)
;~ 	GUISetCursor(16, 1)
	;create canvas elements
	Local Const $hDC = _WinAPI_GetDC($hGUI)
	Local Const $hHBitmap = _WinAPI_CreateCompatibleBitmap($hDC, $iW, $iH)
	Local Const $hDC_backbuffer = _WinAPI_CreateCompatibleDC($hDC)
	Local Const $DC_obj = _WinAPI_SelectObject($hDC_backbuffer, $hHBitmap)
	Local Const $hCanvas = _GDIPlus_GraphicsCreateFromHDC($hDC_backbuffer)
	_GDIPlus_GraphicsSetSmoothingMode($hCanvas, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
	_GDIPlus_GraphicsSetPixelOffsetMode($hCanvas, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
	Local Const $hBrush_Clr = _GDIPlus_BrushCreateSolid(0xFF000000), _
				$hBrush_FPS = _GDIPlus_BrushCreateSolid(0xFFF0F0F0), _
				$hFormat_FPS = _GDIPlus_StringFormatCreate(), _
				$hFamily_FPS = _GDIPlus_FontFamilyCreate("Arial"), _
				$hFont_FPS = _GDIPlus_FontCreate($hFamily_FPS, 8), _
				$tLayout_FPS = _GDIPlus_RectFCreate(0, 0, 60, 16), _
				$hImage_Earth = _GDIPlus_BitmapCreateFromMemory(_Earth()), _
				$hImage_Galaxy = _GDIPlus_BitmapCreateFromMemory(_Galaxy()), _
				$hMatrix = _GDIPlus_MatrixCreate(), $hPath = _GDIPlus_PathCreate()
	Local $aDim = _GDIPlus_ImageGetDimension($hImage_Earth)
	Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hImage_Earth)
	_GDIPlus_GraphicsDrawStringEx($hGfx, "Coded by UEZ 2017 ;-)", $hFont_FPS, _GDIPlus_RectFCreate(0, $aDim[1] / 2 - 4, 120, 12), $hFormat_FPS, $hBrush_FPS)
	_GDIPlus_ImageDispose($hGfx)
	Local Const $hTexture_Earth = _GDIPlus_TextureCreate($hImage_Earth)
	DllCall($__g_hGDIPDll, "int", "GdipTranslateTextureTransform", "ptr", $hTexture_Earth, "float", -200, "float", 0, "long", 0)
	Local $iDiameter = $aDim[0] < $aDim[1] ? $aDim[0] : $aDim[1], _
		  $iDiameter2 = $iDiameter / 2, _
		  $fDX = ($iW - $iDiameter) / 2, $fDY = ($iH - $iDiameter) / 2
	_GDIPlus_PathAddEllipse($hPath, $fDX - 1, $fDY - 1, $iDiameter + 2, $iDiameter + 2)
	Local Const $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
	_GDIPlus_PathBrushSetCenterColor($hBrush, 0x04000008)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, $fDX + $iDiameter2 + 1, $fDY + $iDiameter2 + 1)
    _GDIPlus_PathBrushSetSurroundColor($hBrush, 0xF0000000)
	_GDIPlus_PathBrushSetGammaCorrection($hBrush, 1)
	_GDIPlus_PathBrushSetFocusScales($hBrush, 0.5, 0.5)
	$iFPS = 0
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit_About")
	AdlibRegister("CalcFPS", 1000)
	Local $fScale, $fTmp, $iStep = 2 ;the higher $iStep is the faster the animation & lower the quality.
	Do
;~ 		DllCall($__g_hGDIPDll, "int", "GdipFillRectangle", "handle", $hCanvas, "handle", $hBrush_Clr, "float", 0, "float", 0, _
;~ 				"float", $iW, "float", $iH) ;erase canvas background
;~ 		_WinAPI_BitBlt($hDC_backbuffer, 0, 0, $iW, $iH, $hDC_backbuffer, 0, 0, $BLACKNESS)
		_GDIPlus_GraphicsDrawImageRect($hCanvas, $hImage_Galaxy, 0, 0, $iW, $iH)
		DllCall($__g_hGDIPDll, "int", "GdipTranslateTextureTransform", "ptr", $hTexture_Earth, "float", 0.75, "float", 0, "long", 0)
		For $i = 1 To $iDiameter2 Step $iStep
			$fScale = 1 + $i / $iDiameter2
			_GDIPlus_MatrixSetElements($hMatrix, 1, 0, 0, 1, 0, 0)
			_GDIPlus_MatrixTranslate($hMatrix, $fDX + $iDiameter2, $fDY + $iDiameter2)
			_GDIPlus_MatrixScale($hMatrix, $fScale, $fScale)
			_GDIPlus_MatrixTranslate($hMatrix, -$iDiameter2, -$iDiameter2)
			_GDIPlus_GraphicsSetTransform($hCanvas, $hMatrix)
			DllCall($__g_hGDIPDll, "int", "GdipFillEllipse", "handle", $hCanvas, "handle", $hTexture_Earth, _
								   "float", $i, "float", $i, "float", $iDiameter - $i * 2, "float", $iDiameter - $i * 2)
		Next
		_GDIPlus_MatrixSetElements($hMatrix, 1, 0, 0, 1, 0, 0)
		_GDIPlus_GraphicsSetTransform($hCanvas, $hMatrix)
		_GDIPlus_GraphicsFillRect($hCanvas, $fDX, $fDY, $iDiameter, $iDiameter, $hBrush)
		_GDIPlus_GraphicsDrawStringEx($hCanvas, "FPS: " & $iShowFPS, $hFont_FPS, $tLayout_FPS, $hFormat_FPS, $hBrush_FPS) ;draw background message text
		_WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hDC_backbuffer, 0, 0, $SRCCOPY) ;blit drawn bitmap to GUI
		$iFPS += 1
		If $bExit Then ExitLoop
	Until Not Sleep(10)
	AdlibUnRegister("CalcFPS")
	;release resources
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_PathDispose($hPath)
	_GDIPlus_MatrixDispose($hMatrix)
	_GDIPlus_ImageDispose($hImage_Earth)
	_GDIPlus_ImageDispose($hImage_Galaxy)
	_GDIPlus_BrushDispose($hTexture_Earth)
	_GDIPlus_FontDispose($hFont_FPS)
	_GDIPlus_FontFamilyDispose($hFamily_FPS)
	_GDIPlus_StringFormatDispose($hFormat_FPS)
	_GDIPlus_BrushDispose($hBrush_Clr)
	_GDIPlus_BrushDispose($hBrush_FPS)
	_GDIPlus_GraphicsDispose($hCanvas)
	_WinAPI_SelectObject($hDC_backbuffer, $DC_obj)
	_WinAPI_DeleteDC($hDC_backbuffer)
	_WinAPI_DeleteObject($hHBitmap)
	_WinAPI_ReleaseDC($hGUI, $hDC)
	GUIDelete($hGUI)
EndFunc   ;==>GDIPlus_RotatingEarth
Func _Exit_About()
	$bExit = True
EndFunc   ;==>_Exit_About
Func CalcFPS() ;display FPS
	$iShowFPS = $iFPS
	$iFPS = 0
EndFunc   ;==>CalcFPS
;Code below was generated by: 'File to Base64 String' Code Generator v1.20 Build 2016-12-01
...

Alles anzeigen

Bitte Dateianhang herunterladen!

Mit der Variable $iStep in Zeile 73 kann man die Geschwindigkeit anpassen. Je höher desto schneller, aber die Qualität wird auch schlechter.

Candyland

Find ich gut, ist sicher ein schöner Zeitvertreib gewesen! c:

**Xorianator**

Sieht schick aus (aber korrekt ist das ja nicht :D)
€: Komme übrigens auf ein paar mehr FPS, habe 13 FPS

**alpines**

Läuft bei mir auch schneller (17-18 FPS) aber entspricht dennoch nicht der Realität, Xorianator hats ja bereits verlinkt.

**UEZ**

Die FPS im Screenshot beziehen sich auf $iStep = 1.

Was ist die Realität?...

**UEZ**

Kleines Update auf v1.5 -> Cloud Layer hinzugefügt.

Läuft ca. mit 9~10 FPS bei $iStep = 3. GDI+ ist so lahhhhhmmmmmm..........

**autoiter**

Der neue Effekt sieht ganz fabelhaft aus!
PS: $iStep 4 ist mein Favorit.

**UEZ**

@autoiter Danke für dein Feedback.

Und weil's so schön war, v1.6 hochgeladen.

**Oscar**

Erstmal: wieder mal eine tolle GDI+-Animation von Dir! Erde, Wolken, Mond sieht toll aus und läuft bei mir mit ca. 17 FPS.

Aber astronomisch nicht ganz korrekt. Zum einen besitzt der Mond eine Eigenrotation (man sieht von der Erde aus immer den gleichen Teil des Mondes) und zum anderen dreht er sich anders herum um die Erde (in die Richtung, wie sich die Erde um sich selbst dreht). Gut vom Abstand (Erde <-> Mond) wollen wir mal absehen, das lässt sich in den Größen nicht auf dem Monitor darstellen.

**UEZ**

Zitat von Oscar

Erstmal: wieder mal eine tolle GDI+-Animation von Dir! Erde, Wolken, Mond sieht toll aus und läuft bei mir mit ca. 17 FPS.

Aber astronomisch nicht ganz korrekt. Zum einen besitzt der Mond eine Eigenrotation (man sieht von der Erde aus immer den gleichen Teil des Mondes) und zum anderen dreht er sich anders herum um die Erde (in die Richtung, wie sich die Erde um sich selbst dreht). Gut vom Abstand (Erde <-> Mond) wollen wir mal absehen, das lässt sich in den Größen nicht auf dem Monitor darstellen.

Danke für dein Feedback. Den Mond noch mit einer Rotation zu animieren, würde wohl zur einer Slideshow führen, zumindest auf meiner Kiste, daher ohne die Animation. Die Richtung ist ganz einfach zu ändern -> $z -= 0.5 in der Do / Until Schleife!

Die Animation sollte auch eher zur "Unterhaltung" dienen und nicht eine physikalisch / mathematisch korrekte Animation simulieren. Dafür fehlen die schnellen Grafikfunktionen und meine Mathe / Physik Kenntnisse.

**eukalyptus**

Sehr schönes Script!

deaktiviere mal die Drawfunktion der Erde und lass nur die Wolken anzeigen -> aus diesem Effekt kann man bestimmt nochwas machen.

evtl kannst du die Geschwindigkeit noch etwas erhöhen, wenn du die Scheiben folgendermassen zeichnest:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)


Global $iWidth = 620
Global $iHeight = 620
Global $hGui = GUICreate("GDI+", $iWidth, $iHeight)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")


_GDIPlus_Startup()
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
Global $hBmp_Buffer = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
Global $hGfx_Buffer = _GDIPlus_ImageGetGraphicsContext($hBmp_Buffer)
_GDIPlus_GraphicsSetSmoothingMode($hGfx_Buffer, 2)
_GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF000000)
GUIRegisterMsg($WM_PAINT, "WM_PAINT")
GUISetState()


_Draw()


While Sleep(10)
WEnd




Func _Draw($iSteps = 18)
	_GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF000000)
	Local $hBrush = _GDIPlus_BrushCreateSolid(0x0500FF00)
	Local $hBrush2 = _GDIPlus_BrushCreateSolid(0xFF00FF00)


	Local $fPI2 = ATan(1) * 2
	Local $fA, $fX
	For $i = 0 To $iSteps - 1
		$fA = $i / $iSteps * $fPI2
		$fX = Cos($fA) * 300
		_GDIPlus_GraphicsFillEllipse($hGfx_Buffer, 310 - $fX, 310 - $fX, $fX * 2, $fX * 2, $hBrush)
		_GDIPlus_GraphicsFillEllipse($hGfx_Buffer, 310 + $fX, 310 + Sin($fA) * 300, 4, 4, $hBrush2)
	Next


	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_BrushDispose($hBrush2)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
EndFunc   ;==>_Draw




Func WM_PAINT($hWnd, $uMsgm, $wParam, $lParam)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_PAINT


Func _Exit()
	_GDIPlus_GraphicsDispose($hGfx_Buffer)
	_GDIPlus_BitmapDispose($hBmp_Buffer)
	_GDIPlus_GraphicsDispose($hGraphics)
	_GDIPlus_Shutdown()
	Exit
EndFunc   ;==>_Exit

Alles anzeigen

Zumindest stell ich mir vor, dass man mit weniger Zeichenoperationen ein ähnlich gutes Ergebnis bekommt...
(vielleicht lieg ich aber auch nur komplett daneben...)

lgE

**Oscar**

Oh, gerade erst gesehen, dass es eine neue Version gibt.
Die v1.7 ist jetzt viel schneller: 23-24 FPS.
Und die Enterprise ist auch nicht schlecht, allerdings ruckelt sie etwas beim Vorbeiflug.
Klasse wäre es natürlich, wenn sie in der Animation dann auf Warp-Geschwindigkeit gehen würde.

**water**

Echt cooles Skript! Wenn Du jemanden erzählst, dass das mit einer interpretierten Skriptsprache gemacht wurde, dann fällt der glatt vom Hocker

**alpines**

Zitat von water

Echt cooles Skript! Wenn Du jemanden erzählst, dass das mit einer interpretierten Skriptsprache gemacht wurde, dann fällt der glatt vom Hocker

Ich möchte ja nichts schlecht reden aber von der Scriptsprache wurde hier nicht sehr viel verwendet. Das sind fast ausschließlich WinAPI- und GdiPlus-Funktionen.
Der Code sollte in C nicht groß anders ausschauen (bis auf die Erstellung der GUI). Das ist ja der einzige Punkt der hier von AutoIt wirklich verwendet wird.

**water**

Hast eh recht. Aber das ganze Drumrum (Loops, Aufruf der DLLs ...) macht AutoIt.

**UEZ**

@eukalyptus: danke für den Tipp. Ich werde schauen, ob man den Effekt auch so darstellen kann.

Zitat von eukalyptus

deaktiviere mal die Drawfunktion der Erde und lass nur die Wolken anzeigen -> aus diesem Effekt kann man bestimmt nochwas machen.

Sieht ja echt klasse aus. Mal sehen, wie das Ganze aussieht, wenn man anstelle der Wolken die Erde als transparentes Bild nimmt.
Btw, lange nichts mehr von dir gehört.

Zitat von Oscar

Und die Enterprise ist auch nicht schlecht, allerdings ruckelt sie etwas beim Vorbeiflug.
Klasse wäre es natürlich, wenn sie in der Animation dann auf Warp-Geschwindigkeit gehen würde.

Das Ruckeln liegt wohl an der GDI+ Funktion. Mal sehen, ob man das auch anders machen kann. Bezüglich der Warp-Geschwindigkeit - da kann mal auch was machen.

Zitat von alpines

Ich möchte ja nichts schlecht reden aber von der Scriptsprache wurde hier nicht sehr viel verwendet. Das sind fast ausschließlich WinAPI- und GdiPlus-Funktionen.
Der Code sollte in C nicht groß anders ausschauen (bis auf die Erstellung der GUI). Das ist ja der einzige Punkt der hier von AutoIt wirklich verwendet wird.

Nun ja, aber nichtsdestotrotz ist die Animation mit AutoIt geschrieben, d.h. für mich, dass AutoIt nicht nur automatisieren kann, sondern viel mehr. Btw, mit FreeBasic ist die FPS genau so lahm. Ergo, es liegt an GDI+...

@water: danke für dein Feedback

**UEZ**

Zitat von eukalyptus

deaktiviere mal die Drawfunktion der Erde und lass nur die Wolken anzeigen -> aus diesem Effekt kann man bestimmt nochwas machen.

Ich habe die jetzt die Textur ersetzt durch eine Earth Map ersetzt.

Resultat mit dem alten Code.

NO1 :-)

Schöne GDIPlus Animation!!!