Outlookex Schriftgröße ändern

Windi

Hi Moombas und water ,

wollte mich nochmal melden,
Ich hatte mit dem Sohn, Office 2021 Pro + im Netz rausgesucht (ca 30-40 € Einzellizenz).
Jetzt kommt er und will Linux installieren. (Ich habe nichts gegen Linux)

Sie können nur Sofware bedienen z.B. Branchensoftware.
Sie sind nicht in der Lage eine Exceltabelle auszudrucken die ich ihnen per Mail gesendet habe.

PC mit W10 hat er gesagt: "Da gibt es nur noch bis 2025 Updates" stimmt aber es gibt ja auch noch W11.
Sofware im Betrieb:
Office 2003
Branchensoftware (Wein)
Lexware Buchhaltung
Datev Schlüssel zum Steuerberater.

Es ist ein Familienbetrieb ohne Angestellte.
Vater, Mutter und Sohn (Single).

Was soll ich dazu sagen, (am besten nichts).

Er soll sich einen suchen der ihm Linux installiert und die ganzen Programme zum laufen bringt.

Euch beiden nochmals vielen Dank
und alles Gute.

Gruß Werner

(Ps. hab dabei doch mal wieder was dazu gelernt von euch beiden)

**Moombas**

Ich persönlich würde exakt prüfen lassen ob jede erforderliche Software auf dem Linux-System laufen würde (zum Preis vom Office 2021 sage ich jetzt nix, da kommt man noch weiter drunter :P).
Besonders auf die Zukunft gesehen. Auch eine W11 Lizenz (wenn überhaupt erforderlich und nicht einfach per Upgrade machbar) ist nicht sonderlich teuer (Quicksearch: 9-20€ für die Pro Version).

Ich denke das es insbesondere bei der Branchensoftware zu Problemen kommen könnte.

Ansonsten viel Spaß

Windi

Office 2021 gabs natürlich unter 15 € das wollte er nicht (es war genau dasselbe Office 2021 Prof. plus). Da sind bestimmt Viren drin bei dem Preis hat er gesagt.

Er hatte noch eine andere Quelle für 42 €.

Von W11 hab ich ihm auch die Preise gesagt (wie du 9-20€ für die Pro Version).

Er ist überzeugt von Linux und da gibt es für jedes Programm einen Konverter.

Zitat

Ich denke das es insbesondere bei der Branchensoftware zu Problemen kommen könnte.

Das gleiche habe ich auch gesagt.

Den Spaß habe ich, wenn er das Office 2021 installiert. Das geht 100 % schief.

Ich helfe, wirklich gerne im Freundeskreis, aber der Sohn hat 0 Ahnung und weiß alles besser.

Hab gesagt, wenn es nicht klappt sollen sie sich melden. Damit bin ich aus der Sache raus.

Und ob ich dann Zeit habe überlege ich mir noch (sie sind sehr schwierig).

Gruß Werner

**Moombas**

Beratungsresistente lasse ich im Zweifelsfall auflaufen und das "Siehste, habe ich doch gesagt." verkniefe ich mir dann auch nicht

Auch wenn sie es irgendwann hin bekommen, stelle ich gerne den zeitlichen Mehraufwand durch ihre "Lösung" in den Raum^^

Ich bin ja so gemein.

Windi

Genau so!

Ich merke wir verstehen uns!

Windi

gestern kam der Anruf!

Ganz kleinlaut, ich kriege die Office Installation nicht hin.

Hab's ihm dann drauf gemacht.

Jetzt geht es weiter.

Ich komme mit dem HTML Kram nicht klar.

Vielleicht kann ja mal einer drüberschauen.

So solte es aussehen!

Es wir immer ein Block eingefügt und keine einzelne Zeilen.

Hier ein Ausschnitt des Scriptes:

AutoIt

; Array heißt $aWeine
Global Const $Cols = 0, $Rows = 0
Global $AlleArtikel = _ArrayToString($aWeine, " " )

;MsgBox(0,"Alle Artikel", $AlleArtikel)

For $Col = 0 to $Cols - 1
    $AlleArtikel &= '<th>' & $aWeine[0][$Col] & '</th>'
Next

$AlleArtikel &= '</tr>'

For $Row = 1 to $Rows - 1
    $AlleArtikel &= '<tr>'

    For $Col = 0 to $Cols - 1
        $AlleArtikel &= '<td>' & $aWeine[$Row][$Col] & '</td>'
    Next

    $AlleArtikel &= '</tr>'
Next

$AlleArtikel &= '</table>'

; Mail zusammen bauen
; Betreff funktioniert
Global $Betreff = "Von Shop: " & $RechAdress

;MsgBox(0,"Betreff", $Betreff)

; Erstelle das E-Mail-Element
$FontSize = $FontSize / $DefaultFontsize
Local $oItems = _
    _OL_ItemCreate($oOutlook, $olMailItem, "*\\" & $MailFolder1 & "\", "", _
    "Subject=" & $Betreff, "BodyFormat=" & $olFormatHTML, 'HTMLBody= <p style="font-size:' & $FontSize & 'em">' & $AlleArtikel & "</p>", "To=" & $To)

Alles anzeigen

Vielen Dank

Werner

**Moombas**

Ein kurzes Beispiel wäre hier:

AutoIt

Opt('MustDeclareVars', 1)
#include<Array.au3>
; Array heißt $aWeine
;~ Global $AlleArtikel = _ArrayToString($aWeine, " ")
Global $aWeine[2][3] = [['02', 1, '2021er Silvaner, trocken'],['01', 1, '2022er']]
;MsgBox(0,"Alle Artikel", $AlleArtikel)
_ArrayDisplay($aWeine)
;~ For $Col = 0 to $Cols - 1 ;wird nur benötigt wenn die Spalten überschriften haben
;~ $AlleArtikel &= '<th>' & $aWeine[0][$Col] & '</th>'
;~ Next
Global $Tabelle = '<table>'
    For $Row = 0 to Ubound($aWeine, $UBOUND_ROWS) - 1
        $Tabelle &= '<tr>'
        For $Col = 0 to Ubound($aWeine, $UBOUND_COLUMNS) - 1
            $Tabelle &= '<td>' & $aWeine[$Row][$Col] & '</td>'
        Next
        $Tabelle &= '</tr>'
    Next
    $Tabelle &= '</table>'
ConsoleWrite($Tabelle & @CRLF)
;Ergebnis: <table><tr><td>02</td><td>1</td><td>2021er Silvaner, trocken</td></tr><tr><td>01</td><td>1</td><td>2022er</td></tr></table>

Alles anzeigen

**Moombas**

Kleine Verbesserung:

Ich würd das ganze in eine separate Funktion auslagern:

AutoIt

;....
; Array heißt $aWeine
$AlleArtikel &= _Generate_HTML_Table($aWeine, False)

; Mail zusammen bauen
; Betreff funktioniert
Global $Betreff = "Von Shop: " & $RechAdress
;MsgBox(0,"Betreff", $Betreff)

; Erstelle das E-Mail-Element
$FontSize = $FontSize / $DefaultFontsize
Local $oItems = _OL_ItemCreate($oOutlook, $olMailItem, "*\\" & $MailFolder1 & "\", "", _
"Subject=" & $Betreff, "BodyFormat=" & $olFormatHTML, 'HTMLBody= <p style="font-size:' & $FontSize & 'em">' & $AlleArtikel & "</p>", "To=" & $To)

;...


Func _Generate_HTML_Table(Const $aArray, Const $Headline = True)
Local Const $Rows = Ubound($aArray, $UBOUND_ROWS) - 1, $Cols = Ubound($aArray, $UBOUND_COLUMNS) - 1
Local $Start = 0
Local $table = '<table>'
	If $Headline then
		$Start = 1
		For $Col = 0 to $Cols
			$table &= '<th>' & $aArray[0][$Col] & '</th>'
		Next
	EndIf
	For $Row = $Start to $Rows
		$table &= '<tr>'
		For $Col = 0 to $Cols
			$table &= '<td>' & $aArray[$Row][$Col] & '</td>'
		Next
		$table &= '</tr>'
	Next
	$table &= '</table>'
	Return $table
EndFunc

Alles anzeigen

Windi

Moombas vielen Dank!

Habe mich für Version 1 entschieden.

Ich möchte es ohne Funktionen machen (ist leichter für mich).

Vor allem wenn es mal geädert werden muss.

Die Überschrift hat nicht funkioniert, habe sie in das Array eingefügt, war für mich leichter.

Wie bekomme ich eine Trennlinie zwischen den Artikel?

Wenn ich dass so mache verschiebt sich alles:

AutoIt

Global $Linie = "_____________________________________"
Global $Tabelle = '<table>'

For $Row = 0 to Ubound($aWeine, $UBOUND_ROWS) - 1
    $Tabelle &= '<tr>'
    
    For $Col = 0 to Ubound($aWeine, $UBOUND_COLUMNS) - 1
        $Tabelle &= '<td>' & $aWeine[$Row][$Col] & '</td>'
    Next

    $Tabelle &= '<tr>'
    $Tabelle &= '<td>' & $Linie & '</td></tr>'
Next

$Tabelle &= '</table>'

Alles anzeigen

Bevor die Tabelle in die Mail eingefügt wird müssen noch ein paar Variablen eingefügt werden.

z.B. $Rechnungsadresse, $Lieferadresse usw.

Kannst du mir da ein Beispiel geben!

Wie du oben siehst, hab ich kein Plan von HTML.

Hab auch alle Dateien von water durchsucht, ist aber für meine 71 Jahre und wenig englisch Kentnisse mehrere Nummern zu groß.

**water**

Füge <hr> für eine horizontale Linie ein (hr steht für horizontal rule).
Siehe unter Selfhtml.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Guten Abend Werner Windi 👋 ,

ich befürchte der Vorschlag von water mit der Trennlinie wird in HTML Tabellen nicht klappen.
Dafür gibt es Styling, was man da anwendet. Ich fange gar nicht erst groß mit CSS an (das ist der Begriff dazu), ich zeige dir hier einfach nur eine abgewandelte Variante von Moombas Code oben - also mit einem Tabellen-Rahmen.

Vielleicht erhoffst du dir sowas?

AutoIt

Opt('MustDeclareVars', 1)

#include-once
#include <Array.au3>
#include <WinAPIConv.au3>

; Array heißt $aWeine
;~ Global $AlleArtikel = _ArrayToString($aWeine, " ")

Global $aWeine[][3] = _
    [ _
        ['02', '1', '2021er Silvaner, trocken'], _
        ['01', '1', '2022er Gutenberger´s Winzerschoppen, lieblich'], _
        ['04', '1', '2021er Müller-Thurgau u. Silvaner, lieblich'], _
        ['08', '1', '2022er Blauer Spätburgunder Rosé, lieblich'], _
        ['07', '1', '2022er Rotling, halbtrocken'] _
    ]

;MsgBox(0,"Alle Artikel", $AlleArtikel)

_ArrayDisplay($aWeine)

;~ For $Col = 0 to $Cols - 1 ;wird nur benötigt wenn die Spalten überschriften haben
;~     $AlleArtikel &= '<th>' & $aWeine[0][$Col] & '</th>'
;~ Next

Global $Wert, $Rahmen = 'style="border: 1px solid black;"' ; Tabellen-Rahmen in schwarz
Global $Tabelle = '<table>'

For $Row = 0 to Ubound($aWeine, $UBOUND_ROWS) - 1
    $Tabelle &= '<tr>'

    For $Col = 0 to Ubound($aWeine, $UBOUND_COLUMNS) - 1
        $Wert = BinaryToString(StringToBinary($aWeine[$Row][$Col] & @LF, 4), 1) ; Somit sind Umlaute oder Zeichen wie "´" okay

        $Tabelle &= '<td ' & $Rahmen & '>' & $Wert & '</td>'
    Next

    $Tabelle &= '</tr>'
Next

$Tabelle &= '</table>'

ConsoleWrite($Tabelle & @CRLF)

#cs
; Ergebnis:
<table><tr><td style="border: 1px solid black;">02
</td><td style="border: 1px solid black;">1
</td><td style="border: 1px solid black;">2021er Silvaner, trocken
</td></tr><tr><td style="border: 1px solid black;">01
</td><td style="border: 1px solid black;">1
</td><td style="border: 1px solid black;">2022er Gutenberger´s Winzerschoppen, lieblich
</td></tr><tr><td style="border: 1px solid black;">04
</td><td style="border: 1px solid black;">1
</td><td style="border: 1px solid black;">2021er Müller-Thurgau u. Silvaner, lieblich
</td></tr><tr><td style="border: 1px solid black;">08
</td><td style="border: 1px solid black;">1
</td><td style="border: 1px solid black;">2022er Blauer Spätburgunder Rosé, lieblich
</td></tr><tr><td style="border: 1px solid black;">07
</td><td style="border: 1px solid black;">1
</td><td style="border: 1px solid black;">2022er Rotling, halbtrocken
</td></tr></table>
#ce

Alles anzeigen

💡 Ist nur ein ganz grobes Beispiel. Der Code ist stark verbesserungwürdig, doch vielleicht hilft es ja schon.

Viele Grüße
Sven

Windi

Guten Abend water und Sven SOLVE-SMART,

vielen Dank für Eure Vorschläge.

Ich werde mal versuchen wie weit ich komme.

Werde mich bestimmt nochmal melden.

Viele Grüße

Werner

Windi

Hi Sven,

Hab den Wert auf 1),1) gesetzt.

Jetzt sind die Umlaute verschwunden.

$Wert = BinaryToString(StringToBinary($aWeine[$Row][$Col] & @LF, 1), 1) ; Somit sind Umlaute oder Zeichen wie "´" okay

Danke das war genau das was ich gesucht habe.

Gruß Werner

**Moombas**

Hier mal eine aktualisierte Funktion (mit den entsprechenden Einwänden von water und SOLVE-SMART ), einfach weil ich dabei bleibe das du mit einer Funktion flexibler für spätere Anpassungen bist:

AutoIt

Opt('MustDeclareVars', 1)
#include<Array.au3>

Global $aWeine[2][3] = [['02', 1, '2021er Silvaner, trocken'],['01', 1, '2022er']]

;~ ConsoleWrite(_Generate_HTML_Table($aWeine, False) & @CRLF); Tabelle ohne Rahmen und ohne Überschrift mit Default Farben etc.
;~ ConsoleWrite(_Generate_HTML_Table($aWeine, True, 'White', 1, 'solid', 'red', 'no', 10, 'black'));Tabelle mit weißer Schrift, Überschrift, schwarzem Hintergrund, rotem Rahmen mit runden Ecken. Sieht schueßlich aus, soll aber nur zeigen was passiert.
ConsoleWrite(_Generate_HTML_Table($aWeine, True, 'black', 1, 'solid', 'black', 'collapse'));Dies sollte die Tabelle so erzeugen wie du es möchtest

;Parameter Erklärung (alle bis auf den ersten sind Optional!):
;1: Das Array mit allen Daten incl. Überschrift falls notwendig
;2: Definiert ob eine Überschrift vorhanden ist. Default: True (mit Überschirft). Bei False: keine Überschrift
;3: Die Farbe der Schrift. Default: Schwarz (black)
;4: Die Dicke des Rahmens. Default: 0 = kein Rahmen
;5: Die Art des Rahmens. Default: solid (weitere Arten findest du z.B. hier: https://www.w3schools.com/html/html_table_borders.asp)
;6: Die Farbe des Rahmens. Default: Schwarz (black)
;7: Rahmenlinien verschmelzen. Default: collapse (ja, verschmelzen, sonst: kannst du hier z.B. "no" nutzen damit dies nicht passiert)
;8: Radius des Rahmens für Runde Ecken. Default: 0 = keine Rundungen Achtung: Funktioniert nicht für den äußersten Rahmen, der bleibt eckig, wenn collapse an ist (Parameter 7)!
;9: Hintergrundfarbe der Zellen. Default: Weiß (white)
;Es wäre laut HTML noch mehr möglich aber ich denke damit sind 95% der normalen Anwendungsfälle abgedeckt.
Func _Generate_HTML_Table(Const $aArray, Const $Headline = True, Const $FontColor = 'black', Const $Border = 0, Const $Borderstyle = 'solid', Const $BorderColor = 'black', Const $Collapse = 'collapse', Const $Radius = 0, $Background = 'white')
Local Const $Rows = Ubound($aArray, $UBOUND_ROWS) - 1, $Cols = Ubound($aArray, $UBOUND_COLUMNS) - 1
Local Const $style = 'style="color: ' & $FontColor & ';border: ' & $Border & 'px ' & $Borderstyle &' ' & $Bordercolor &'; border-collapse: ' & $Collapse & '; border-radius: ' & $Radius & 'px; background: ' & $Background & '"'
Local $Value, $Start = 0
Local $table = '<table ' & $style & '>' & @CRLF
	If $Headline then
		$Start = 1
		$table &= @TAB & '<tr>' & @CRLF
		For $Col = 0 to $Cols
			$table &= @TAB & @TAB & '<th ' & $style & '>' & $aArray[0][$Col] & '</th>' & @CRLF
		Next
		$table &= @TAB & '</tr>' & @CRLF
	EndIf

	For $Row = $Start to $Rows
		$table &= @TAB & '<tr>' & @CRLF
		For $Col = 0 to $Cols
			$Value  = BinaryToString(StringToBinary($aArray[$Row][$Col], 4), 1)
			$table &= @TAB & @TAB & '<td ' & $style & '>' & $Value & '</td>' & @CRLF
		Next
		$table &= @TAB & '</tr>' & @CRLF
	Next
	$table &= '</table>' & @CRLF
	Return $table
EndFunc

Alles anzeigen

Ausgabe:

Code

<table style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">
    <tr>
        <th style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">02</th>
        <th style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">1</th>
        <th style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">2021er Silvaner, trocken</th>
    </tr>
    <tr>
        <td style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">01</td>
        <td style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">1</td>
        <td style="color: black;border: 1px solid black; border-collapse: collapse; border-radius: 0px; background: white">2022er</td>
    </tr>
</table>

Alles anzeigen

Windi

Vielen Dank euch 3!

Schaue es mir an.

Gruß Werner

Windi

Moin,

hab immer noch ein Problem mit HTML.

Wie kriege ich:

Spalte 0 zentriert,

Spalte 1, 3, 4 rechtsbündig formatiert.

Habe schon einiges probiert komme aber nicht weiter.

Vielleicht kann sich ja mal einer das anschauen.

Viele Grüße

Werner

Opt('MustDeclareVars', 1)

#include-once
#include <Array.au3>
#include <WinAPIConv.au3>

; Array heißt $aWeine
Global $aWeine[][5] = _
[ _
['02', '1 ', '2021er Silvaner, trocken ' , ' 5,00 €' , ' 5,00 €' ], _
['01', '10 ', '2022er Gutenberger´s Winzerschoppen, lieblich', ' 5,00 €' , ' 50,00 €' ], _
['04', '100 ', '2021er Müller-Thurgau u. Silvaner, lieblich', ' 5,00 €' , ' 500,00 €' ], _
['08', '1000 ', '2022er Blauer Spätburgunder Rosé, lieblich', ' 5,00 €' , ' 5000,00 €' ], _
['07', '1 ', '2022er Rotling, halbtrocken', ' 10,00 €' , ' 10,00 €' ] _
]

;MsgBox(0,"Alle Artikel", $AlleArtikel)

_ArrayDisplay($aWeine)

;~ For $Col = 0 to $Cols - 1 ;wird nur benötigt wenn die Spalten überschriften haben
;~ $AlleArtikel &= '<th>' & $aWeine[0][$Col] & '</th>'
;~ Next

Global $Wert, $Rahmen = 'style="border: 1px solid black;"' ; Tabellen-Rahmen in schwarz
Global $Tabelle = '<table>'

; Tabelle
For $Row = 0 to Ubound($aWeine, $UBOUND_ROWS) - 1
$Tabelle &= '<tr>'

For $Col = 0 to Ubound($aWeine, $UBOUND_COLUMNS) - 1
$Wert = BinaryToString(StringToBinary($aWeine[$Row][$Col] & @LF, 1), 1) ; Somit sind Umlaute oder Zeichen wie "´" okay
;MsgBox(0,"", $Wert)
If $Col = 1 then $Wert = '<td> <align=right>' & $Wert
;MsgBox(0,"", $Col)

$Tabelle &= '<td ' & $Rahmen & '>' & $Wert & '</td>'

$Tabelle &= '</table></h'
ConsoleWrite($Tabelle & @CRLF)

**Schnuffel**

versuch mal in Zeile 37 das Argument innerhalb von "td" zu deklarieren:

nicht:

AutoIt

'<td> <align=right>'

sondern

AutoIt

'<td align=right>'

Windi

Danke,

das hatte ich auch schon probiert aber dann geht der Rahmen kaputt.

,

**Schnuffel**

naja, seh dir dein Ergebnis an und versuche zu ergründen, wie html das parsen würde...

</td><td style="border: 1px solid black;"><td align=right>1 </td>

ich denke da ssollte eher sowas stehen:

</td><td style="border: 1px solid black;" align=right>1 </td>

vielleicht musst du den "Zusammenbau deines html codes überdenken ...

wenn du einen neuen td-Tag anfängst sind die Browser heutzutage so schlau und schließen den vorhergehenden, sollte das schließende </td> mal fehlen

**Schnuffel**

Beispiel für deine For-Schleife:

AutoIt

	For $Col = 0 To UBound($aWeine, $UBOUND_COLUMNS) - 1
		$Wert = BinaryToString(StringToBinary($aWeine[$Row][$Col] & @LF, 1), 1) ; Somit sind Umlaute oder Zeichen wie "´" okay
		If $Col = 0 Then
			$Tabelle &= '<td style="border: 1px solid black;text-align: center;">' & $Wert & '</td>'
		Else
			$Tabelle &= '<td style="border: 1px solid black;text-align: right;">' & $Wert & '</td>'
		EndIf
	Next

Ob der @LF in deinem Wert so passt kann ich spontan nicht beurteilen

so sieht es bei mir aus:

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)