Kalkulator mit festen Variablen

#include "ListViewEditInput.au3"
#include <GuiListView.au3>
#include <WinAPISys.au3>
#include <WinAPIvkeysConstants.au3>
Opt("GuiOnEventMode",1)

Global $iWidth = 800, $iHeight = 600, $iSpace = 5, $iColumnWidth = 120, $iControlHeight = 25

Global $hGui = GUICreate("Calculator", $iWidth, $iHeight, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "_close")

Global $iListView = GUICtrlCreateListView("Item|Anzahl|Preis|Gesamt", $iSpace, $iSpace, $iWidth-$iSpace*2, $iHeight-$iSpace*4-$iControlHeight)
Global $iListViewMenu = GUICtrlCreateContextMenu($iListView)
Local $iListViewMenuDelete = GUICtrlCreateMenuItem("Löschen", $iListViewMenu)
GUICtrlSetOnEvent($iListViewMenuDelete, "_deleteSelectedItem")
Global $iLeftCol = $iWidth-$iColumnWidth*3-$iSpace*2-5
_GUICtrlListView_SetColumnWidth($iListView, 0, $iLeftCol)
_GUICtrlListView_SetColumnWidth($iListView, 1, $iColumnWidth)
_GUICtrlListView_SetColumnWidth($iListView, 2, $iColumnWidth)
_GUICtrlListView_SetColumnWidth($iListView, 3, $iColumnWidth)
__ListViewEditInput_ListViewAdd($hGui, $iListView, "0,1,2")
__ListViewEditInput_RegisterFunction($iListView, "_edited", "changed")

Global $iTop = $iHeight-$iSpace*4-$iControlHeight+$iSpace*2, $iLeft = $iSpace, $iLabelWidth=40, $iButtonWidth=50
GUICtrlCreateLabel("Name:", $iLeft, $iTop+5, $iLabelWidth, $iControlHeight)
$iLeft += $iLabelWidth
Global $iInputItemNameWidth = $iWidth-$iSpace*4-$iButtonWidth-$iLabelWidth*2-$iColumnWidth
Global $iInputItemName = GUICtrlCreateInput("", $iLeft, $iTop, $iInputItemNameWidth, $iControlHeight)
$iLeft += $iSpace+$iInputItemNameWidth
GUICtrlCreateLabel("Preis:", $iLeft, $iTop+5, $iLabelWidth, $iControlHeight)
$iLeft += $iLabelWidth
Global $iInputPrice = GUICtrlCreateInput("", $iLeft, $iTop, $iColumnWidth, $iControlHeight)
$iLeft += $iSpace+$iColumnWidth
Global $iButtonAdd = GUICtrlCreateButton("Add", $iWidth-$iSpace-$iButtonWidth, $iTop, $iButtonWidth, $iControlHeight)
GUICtrlSetOnEvent($iButtonAdd, "_addItem")
;__ListViewEditInput_RegisterFunction($iListView, "_canceled", "canceled")

_open()
GUISetState(@SW_SHOW, $hGui)

While Sleep(10)
WEnd

Func _deleteSelectedItem()
	_GUICtrlListView_DeleteItemsSelected($iListView)
EndFunc

Func _open()
	Local $hFile = FileOpen("data", BitOR(0,128))
	If Not @error Then
		Local $arData = StringSplit(FileRead($hFile),@crlf, BitOR(1,2))
		For $i=0 to UBound($arData)-1 step 1
			If $arData[$i]<>"" Then GUICtrlCreateListViewItem($arData[$i], $iListView)
		Next
	EndIf
EndFunc

Func _close()
	Local $hFile = FileOpen("data", BitOR(2,8,128))
	For $i=0 to _GUICtrlListView_GetItemCount($iListView)-1 Step 1
		If $i<>0 Then FileWrite($hFile, @crlf)
		For $j=0 to _GUICtrlListView_GetColumnCount($iListView)-1 Step 1
			If $j<>0 Then FileWrite($hFile, "|")
			FileWrite($hFile, _GUICtrlListView_GetItemText($iListView, $i, $j))
		Next
	Next
	FileClose($hFile)
	exit
EndFunc

Func _addItem()
	Local $sName = GUICtrlRead($iInputItemName)
	Local $sPrice = StringReplace(GUICtrlRead($iInputPrice), ",", ".")
	GUICtrlCreateListViewItem($sName&"|1|"&$sPrice&"|"&$sPrice, $iListView)
EndFunc

Func _edited($hListView, $iIndex, $iSubIndex)
	Local $iAmount = Int(_GUICtrlListView_GetItemText($hListView, $iIndex, 1))
	Local $iPrice = Number(StringReplace(_GUICtrlListView_GetItemText($hListView, $iIndex, 2), ",", "."))
	_GUICtrlListView_SetItemText($hListView, $iIndex, Round($iAmount*$iPrice, 2), 3)
EndFunc

; Die folgenden beiden Zeilen sind nur dazu da, dass dein Code
; ein paar Checks besteht, bevor er ausgeführt wird. Dies kann dir
; dabei helfen, von Anfang an Fehler zu vermeiden.
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

; Erster Funktionsaufruf (Hauptfunktion). Dies ist nicht verpflichtend,
; doch damit kannst du u.a. die Nutzung von zu vielen globale Variablen
; vermeiden.
_Main()

Func _Main()
    _PrintSimpleCalc()
EndFunc

Func _PrintSimpleCalc()
    ; Die folgenden Variablen sind in einem lokalem
    ; Scope, du könntest also auch "Local" weg lassen.
    ; Dies gilt allerdings als nicht empfohlen und unschön.
    ; Ebenfalls optional ist "Const", was für Konstanten steht.

    Local Const $iAmount        = 13
    Local Const $iPrice         = 0.99 ; Es muss der Punkt genutzt werden, nicht das Komma.
    Local Const $iResult        = $iAmount * $iPrice ; Normale Multiplikation.

    Local Const $iRoundedResult = Round($iAmount * $iPrice, 1)
    Local Const $iFloorResult   = Floor($iAmount * $iPrice)
    Local Const $iCeilingResult = Ceiling($iAmount * $iPrice)

    _Print('Ergebnis:               ' & $iResult)
    _Print('Gerundetes Ergebnis:    ' & $iRoundedResult)
    _Print('Abgerundetes Ergebnis:  ' & $iFloorResult)
    _Print('Aufgerundetes Ergebnis: ' & $iCeilingResult)
EndFunc

; Hilfsfunktion um nicht jedes Mal @CRLF (was übrigens ein Makro ist)
; machen zu müssen. Später kannst du dir auch gern "StringFormat()" anschauen.
Func _Print($sText)
    ConsoleWrite($sText & @CRLF)
EndFunc