Benutzerinteraktion via Console

hipfzwirgel

Hallo Gemeinde,

eines meiner Programme kann man sowohl mit GUI starten, als auch mit commandline parametern.

Wird es mit Commandline Parametern gestartet, gebe ich Meldungen des Proggis mit _WinAPI_WriteConsole aus.

Ich müsste jetzt nachträglich den Benutzer fragen ob er eine Aktion starten möchte oder nicht. Etwa so:

Code

_WinAPI_WriteConsole($hConsole, @CRLF & " MinimalLength-Option is set, which prevents the Passwort from being deleted!!! " & @CRLF & " Should the option be deactivated (restarting the computer is then mandatory)?" & @CRLF & "enter y or n:")

Gibt es eine Möglichkeit via _WinAPI, die Benutzereingabe auszulesen und zu verarbeiten?
Ich konnte zwar in der MSDN-Bibliothek etwas über ReadConsole finden(https://learn.microsoft.com/en-us/windows/console/readconsole) aber nichts dazu in AutoIt

p.s.: ConsoleWrite und -read gehen hier nicht, da das Proggi NICHT als Consolen-Anwendung kompiliert ist!

**water**

Eine MsgBox scheidet auch aus?
Die Auswahl des Benutzers kannst Du dann ja zur Dokumentation auf der Konsole ausgeben.

**Schnuffel**

manchmal ist die allgemeine Beschreibung dessen, was erreicht werden soll hilfreicher.

So mancher hatte hier schon Ideen, auf die der Thread-Ersteller nie gekommen wäre.

Dazu braucht es aber den Blick auf das Problem und nicht auf die bereits eingeschränkte Lösungsfindung des Thread Erstellers.

**Andy**

Zitat von Schnuffel

Dazu braucht es aber den Blick auf das Problem und nicht auf die bereits eingeschränkte Lösungsfindung des Thread Erstellers.

Das nennt man das XY-Problem: https://de.wikipedia.org/wiki/XY-Problem

hipfzwirgel

hallo zusammen,

dann will ich nochmal das Problem beschreiben:

Mein Programm ist als exe kompiliert und kann sowohl per GUI-Version als auch in einer CMD-Konsole mit Commandline-Parametern
gestartet werden.

Nun ist es so, das eine Bios-Option (Minimal lenght) das Löschen des Biospasswortes verhindert. Der User soll also auf Consolenebene
bestätigen können, dass das Proggi diese Option deaktivieren soll um dann einen Reboot des Rechners durch zu führen.

Der Stand meines Codings ist, dass nach der Benutzereingabe auf o.a. WinApi-Frage, der Fehler kommt,
y' is not recognized as an internal or external command, operable program or batch file.

Mir ist klar warum. Die Eingabe interagiert mit der Console und nicht mit dem ausgeführten Programm. Leider finde ich
genau hierfür aber keine Lösung. Eine Inputbox habe ich schon getestet, sieht aber echt schlecht aus...

AutoIt

_WinAPI_WriteConsole($hConsole, @CRLF & " MinimalLength-Option is set, which prevents the bios lock from being deleted!!! " & @CRLF & " Should the option be deactivated (restarting the computer is then mandatory)?")
_WinAPI_WriteConsole($hConsole, @CRLF & " Enter [y] for deactivating ML-option or [n] for cancel: " & @CRLF) ; $hConsole ist das Handle der CMD-Session

; Benutzereingabe lesen

; Buffer erstellen, um die Eingabe zu speichern
Local $tBuffer = DllStructCreate("wchar[256]")  ; Buffer für 256 Zeichen
Local $dwCharsRead = DllStructCreate("dword")   ; Anzahl der gelesenen Zeichen

; Benutzereingabe über die WinAPI-Funktion ReadConsole lesen
DllCall("Kernel32.dll", "bool", "ReadConsoleW", "handle", $hConsoleinput, "ptr", DllStructGetPtr($tBuffer), "dword", 256, "ptr", dllStructGetPtr($dwCharsRead), "ptr", 0)

; $hConsoleinput ist das Inputhandle der CMD-Session (Const $STD_INPUT_HANDLE = -10 _ $hConsoleinput = _WinAPI_GetStdHandle(0)    ; Standard-Input)

; Anzahl der gelesenen Zeichen abrufen
Local $iCharsRead = DllStructGetData($dwCharsRead, 1)

; String aus dem Buffer extrahieren und abschneiden
Local $sInput = DllStructGetData($tBuffer, 1)
$sInput = StringLeft($sInput, $iCharsRead - 2)  ; Entferne das abschließende CRLF
MsgBox(0, "ausgabe Input", $sInput) ; hier kommt kein Inhalt, da die Eingabe eben mit der CMD-Console interagiert.

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von hipfzwirgel

Eine Inputbox habe ich schon getestet, sieht aber echt schlecht aus...

Soll heißen das Design der InputBox gefällt dir nicht oder die InputBox an sich geht nicht?

Vorschlag:
Du lässt den Nutzer das Öffnen des Programms doch sowieso schon mit Parametern zu. Warum dann nicht einen weiteren Parameter der die Option ...

Zitat von hipfzwirgel

eine Bios-Option (Minimal lenght) das Löschen des Biospasswortes verhindert

... deaktiviert. Fertig 😅 .

Viele Grüße
Sven

hipfzwirgel

Hallo Solve-Smart,

da das Proggi ja in einer CMD-Console läuft, finde ich sieht es einfach komisch aus, wenn dann eine Inputbox
aufpoppt. Noch dazu, dass diese warum auch immer, nicht wie in der Hilfe steht default zentriert auf ging, sondern
i-wo auf dem Desktop...

hm, das mit dem Parameter wäre eine Möglichkeit. Danke für die Idee.

Vielleicht hat jemand trotzdem eine Idee wie ich die Benutzereingabe "umleiten" kann...

**Schnuffel**

Also, wenn du ein Programm als Gui Version kompilierst dann ist trotz Aufruf aus einer Konsole heraus das Programm ein GUI Programm.

Zitat

Mein Programm ist als exe kompiliert und kann sowohl per GUI-Version als auch in einer CMD-Konsole mit Commandline-Parametern
gestartet werden.

Ich verstehe den Aufbau noch nicht, dass du ein Gui Programm dann in der Konsole interagieren lassen willst.
Du kannst ja gerne deine exe mit Parametern über eine Konsole starten, aber danach wäre eine Abfrage mit einer MSgBox doch der richtigere Weg.

Zitat

und warum muss es WinApi ... Dingsbums sein?
Wird es mit Commandline Parametern gestartet, gebe ich Meldungen des Proggis mit _WinAPI_WriteConsole aus.

**Schnuffel**

und wenn alle Stricke reißen und der User auf biegen und brechen ein Konsolenfenster braucht (warum auch immer)

dann bau dir eine 2. GUI und mach das Eingabefenster als Edit Control Background schwarz. (sry, der musste sein)

hipfzwirgel

Hallo Schnuffel,

das Proggi muss im Windows OS funktionieren, in Windows PE und eben als ConsolenProgramm um vollautomatisiertes Ändern oder Löschen
des BIOS-Passwortes(wir reden hier u.U. von mehreren hundert Rechnern...) zu ermöglichen. Die Möglichkeit das Proggi
mit Commandline-Parametern zu starten wurde bereits in einige unserer IT-Prozesse integriert.

Die genannte BIOS-Option verhindert das Löschen des BIOS-Passwortes. Also ist die Interaktion mit demjenigen der das Proggi ausführt notwendig.
Das Seltsame ist ja, das die Interaktion grundsätzlich funktioniert. Nur finde ich keine Lösung die "Einmischung" der Console zu verhindern...

Im Übrigen kam die Hilfe WinAPi zu benutzen hier aus dem Forum, da ConsoleWrite/Read in diesem Falle ja nicht funktioniert, weil das Proggi ja ein GUI-Programm ist.

Ich werde nun die Idee von Solvesmart verfolgen und einen weiteren Parameter dafür nutzen.

Evtl. weiss ja doch noch jemand eine Lösung?

hipfzwirgel

Hallo Gemeinde,

dank des Schwester-Forums autoitscript.com ist die Lösung gefunden:

AutoIt

					_WinAPI_AttachConsole()
					Local $hConsoleOut = _WinAPI_GetStdHandle(1)

					Local $sMessage = "Enter [y] for deactivating MinimalLength-Option or [n] for cancel:" & @CRLF & @CRLF
					_WinAPI_WriteConsole($hConsoleOut, $sMessage)
					Local $hKBProc = DllCallbackRegister(KeyProc, "long", "int;wparam;lparam")
					$hKBHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hKBProc), _WinAPI_GetModuleHandle(0))

					While Sleep(100)
						Switch $iResp
							Case 1 ; Userinput n = no

								_WinAPI_WriteConsole($hConsoleOut, "Deactivating the Minimal-Length-Option was denied." & @CRLF & @CRLF & "Program is exiting in 3 seconds")
								Sleep(3000)
								Send("{ENTER}")
								Exit
							Case 2 ; Userinput y = Yes

								_WinAPI_WriteConsole($hConsoleOut, "Deactivating the Minimal-Length-Option is started")
								EraseMinlen()  ; Ruft die Funktion EraseMinLen auf
								ExitLoop
							Case 3
								ExitLoop
						EndSwitch
					WEnd

					_WinAPI_UnhookWindowsHookEx($hKBHook)
					DllCallbackFree($hKBProc)
					
					;### zusätzlich wird die KeyProc func benötigt... ####
					
					Func KeyProc($nCode, $wParam, $lParam)

						If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hKBHook, $nCode, $wParam, $lParam)
						Local $tKeyHook = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)

						If $wParam = $WM_KEYDOWN Then
							Switch $tKeyHook.vkCode
								Case 0x59, 0x4E ; y / n
									$iResp = $tKeyHook.vkCode = 0x4E ? 1 : 2
									Return 1
								Case 0x0D
									$iResp = 3
								Case Else
									Return 1
							EndSwitch
						EndIf
						Return _WinAPI_CallNextHookEx($hKBHook, $nCode, $wParam, $lParam)

					EndFunc   ;==>KeyProc

Alles anzeigen

Damit lässt sich mit der Console wunderbar interagieren auch von hier aus noch ein herzliches Dankeschön
an Nine von https://www.autoitscript.com/forum/topic/21…exe-with-a-cmd/

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)