Dec2Binary Rechner

**alpines** · 19. August 2013

Hi,

ich hab mich mal an einen Dezimal- zu Binärzahlenrechner gesetzt ohne die entsprechenden Funktionen wie z.B. Binary / Dec zu verwenden.
Das Script arbeitet mit dem Horner-Schema, wer das nicht kennt der liest in dem Spoiler hier drunter weiter.

Horner-Schema - Erklärung

Da ich keine Funktion für eine Ganzzahldivision in AutoIt fand, oder ich bin einfach zu blind, hab ich es anders umformuliert.
Hoffentlich ist alles verständlich genug!

Hab die Stringfunctions jetzt mit Int ersetzt, läuft schneller und sauberer!

Horner-Schema - Dezimal zu Binär - die Umrechnung

Ich freu mich wenns euch gefällt, und ich freu mich wenns euch nicht gefällt und ihr mir Kritik da lässt, also haut in die Tasten!

Vielen Dank für euer Feedback!

**chesstiger** · 19. August 2013

Die Ganzzahldivision / Division mit Rest nennt sich in AutoIt sowie in der Mathematik Modulo-Rechnung (AutoIt-Funktion Mod) (Edit: Okay, nicht ganz, das ist die Rechenoperation, die den Rest zurückgibt).

Für das eigentliche Ergebnis der Mod-Rechnung Mod(x, y) einfach Int(x/y).

Sonst sehr schön. Mit Zahlensystemen rumspielen macht Spaß.

lg

**alpines** · 19. August 2013

Freut mich
Naja, die Ganzzahldivision hab ich mir halt selber geschrieben und die passt ja jetzt auch so

James · 19. August 2013

Am Anfang der Funktion wäre $iDecimal *= -1 oder Abs() vielleicht besser als StringTrimLeft, du willst ja nicht die Fehleranfälligkeit von AutoIt beim Umwandeln von Datentypen durch sinnloses Hin- und Herwandeln unterstützen.

**alpines** · 19. August 2013

Danke, hab ich sofort ergänzt.

**AspirinJunkie** · 19. August 2013

Zitat von alpines

Da ich keine Funktion für eine Ganzzahldivision in AutoIt fand, [...]

Wenn du noch das StringTrimRight(wandelt die Integerzahl implizit in einen String) durch ein Int() (Bei Abs() bleibt es eine Gleitkommazahl) ersetzt bleibt $iDecimal in der Funktion konsistent vom Typ Integer.
Dann kannst du Int($iDecimal / 2) durch BitShift($iDecimal,1) ersetzen was einer Integerdivision durch 2 entspricht.

**alpines** · 19. August 2013

So, ich bedanke mich für euer Feedback!

Ich hab jetzt das letzte Script hochgeladen, hab vergessen bei dem einen noch das eine StringTrim wegzumachen.
Alles sollte jetzt ein bisschen schneller laufen und hoffentlich zuversichtlicher und schöner!

BinDannMalWeg · 20. August 2013

Vielleicht auch interessant: Ich hab vor langer Zeit mal ein Script zum erzeugen von Normalformen (DNF & KNF) geschrieben...

Spoiler anzeigen

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=icon.ico
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
Opt("GUIOnEventMode", 1)
Global $iBit

; GUI erstellen
$Form1 = GUICreate("NF Generator", 354, 253, -1, -1)
$Label1 = GUICtrlCreateLabel("Eingänge:", 8, 10, 62, 20)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
$Input1 = GUICtrlCreateInput("1", 80, 8, 41, 24, BitOR($GUI_SS_DEFAULT_INPUT, $ES_CENTER, $ES_NUMBER))
GUICtrlSetLimit(-1, 3)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
$Button1 = GUICtrlCreateButton("Okay", 144, 8, 75, 25)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
$ListView1 = GUICtrlCreateListView("", 8, 40, 210, 206, Default, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
$Button2 = GUICtrlCreateButton("Generieren", 224, 64, 123, 33)
GUICtrlSetFont(-1, 10, 800, 0, "Arial")
GUICtrlSetState(-1, $GUI_DISABLE)
$Label2 = GUICtrlCreateLabel("DNF", 232, 144, 30, 18)
GUICtrlSetFont(-1, 10, 800, 0, "Arial")
$Label3 = GUICtrlCreateLabel("KNF", 232, 208, 30, 20)
GUICtrlSetFont(-1, 10, 800, 0, "Arial")
$Input2 = GUICtrlCreateInput("", 224, 120, 121, 24)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
$Input3 = GUICtrlCreateInput("", 224, 184, 121, 24)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
$Button3 = GUICtrlCreateButton("Kopieren", 288, 144, 59, 25)
GUICtrlSetFont(-1, 8, 400, 0, "Arial")
$Button4 = GUICtrlCreateButton("Kopieren", 288, 208, 59, 25)
GUICtrlSetFont(-1, 8, 400, 0, "Arial")

GUISetState(@SW_SHOW)

; GUI-Events
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUICtrlSetOnEvent($Button1, "_Button_Okay")
GUICtrlSetOnEvent($Button2, "_Button_Generate")
GUICtrlSetOnEvent($Button3, "_Button_Copy_DNF")
GUICtrlSetOnEvent($Button4, "_Button_Copy_KNF")

While True ; Endlosschleife
Sleep(500)
WEnd

Func _Button_Okay()
$iBit = GUICtrlRead($Input1)
If $iBit > 0 And $iBit < 27 Then
GUICtrlSetState($Button1, $GUI_DISABLE)
GUICtrlSetState($Input1, $GUI_DISABLE)
GUICtrlSetState($Label1, $GUI_DISABLE)
GUICtrlSetState($Button2, $GUI_ENABLE)
_GUICtrlListView_BeginUpdate($ListView1)
_GUICtrlListView_AddColumn($ListView1, "Ausgang", 60)
For $i = 0 To $iBit - 1
_GUICtrlListView_AddColumn($ListView1, Chr(97 + $i), 20)
Next
For $i = 0 To 2 ^ $iBit - 1
$aBinary = GUICtrlCreateListViewItem("An" & StringRegExpReplace(_AddZeros(_DecToBinary($i), $iBit), "(.)", "|\1"), $ListView1)
Next
_GUICtrlListView_EndUpdate($ListView1)
Else
MsgBox(64, "NF Generator", "Es sind nur 1 bis 26 Eingänge erlaubt!", 5)
EndIf
EndFunc ;==>_Button_Okay

Func _Button_Generate()
Local $aAusgang[2 ^ $iBit], $aEingange[$iBit]
For $i = 0 To $iBit - 1
$aEingange[$i] = Chr(97 + $i)
Next
For $i = 0 To 2 ^ $iBit - 1
If _GUICtrlListView_GetItemChecked($ListView1, $i) Then
$aAusgang[$i] = 1
Else
$aAusgang[$i] = 0
EndIf
Next
GUICtrlSetData($Input2, _GenNF($aEingange, $aAusgang, True))
GUICtrlSetData($Input3, _GenNF($aEingange, $aAusgang, False))
EndFunc ;==>_Button_Generate

Func _Button_Copy_DNF()
ClipPut(GUICtrlRead($Input2))
EndFunc ;==>_Button_Copy_DNF

Func _Button_Copy_KNF()
ClipPut(GUICtrlRead($Input3))
EndFunc ;==>_Button_Copy_KNF

Func _Export_Excel()

EndFunc ;==>_Export_Excel

Func _AddZeros($sBinary, $iLen)
While (StringLen($sBinary) < $iLen)
$sBinary = 0 & $sBinary
WEnd
Return $sBinary
EndFunc ;==>_AddZeros

Func _DecToBinary($i)
Local $sBinary
Do
If Mod($i, 2) Then
$sBinary = 1 & $sBinary
$i = ($i - 1) / 2
Else
$sBinary = 0 & $sBinary
$i /= 2
EndIf
Until $i = 0
Return $sBinary
EndFunc ;==>_DecToBinary

Func _GenNF($aIn, $aOut, $bDNF = True)
Local $sNF, $aBinary, $iResultToUse, $iNumberToInvert, $sLinkInBrackets, $sLinkOutBrackets
If $bDNF Then
$sNF = "DNF = "
$iResultToUse = 1
$iNumberToInvert = 0
$sLinkInBrackets = " AND "
$sLinkOutBrackets = " OR "
Else
$sNF = "KNF = "
$iResultToUse = 0
$iNumberToInvert = 1
$sLinkInBrackets = " OR "
$sLinkOutBrackets = " AND "
EndIf

For $i = 0 To UBound($aOut) - 1
If $aOut[$i] = $iResultToUse Then
$aBinary = StringSplit(_AddZeros(_DecToBinary($i), UBound($aIn)), "", 2)
$sNF &= "("
For $y = 0 To UBound($aBinary) - 1
If $aBinary[$y] = $iNumberToInvert Then $sNF &= "-"
$sNF &= $aIn[$y] & $sLinkInBrackets
Next
$sNF = StringTrimRight($sNF, StringLen($sLinkInBrackets))
$sNF &= ")" & $sLinkOutBrackets
EndIf
Next

$sNF = StringTrimRight($sNF, StringLen($sLinkOutBrackets))
Return $sNF
EndFunc ;==>_GenNF

Func _Exit()
GUIDelete($Form1)
Exit
EndFunc ;==>_Exit

Es enthält auch die Dezimal zu Binär Umrechung.

x0r · 9. Oktober 2013

Zitat

Stell dir die Zahl 15 vor, die wäre im Binärsystem 111.

Die Binärrechnung möchte ich jetzt nicht erklären, weil es dazu viel bessere Beiträge gibt als ich schreiben kann

Also, man hat die Zahl 15. Die 15 teilt man durch 2 und erhält (wir
nutzen die Ganzzahldivision - keine Dließkommazahldivision) den Rest 1.

Dann nimmt man das Ergebnis (7) und teilt es wieder durch 2 bis man bei 0 ist.

Ich werde Ganzzahldivision durch ein \ kennzeichnen.

15 \ 2 = 7 Rest 1.

7 \ 2 = 3 Rest 1.

3 \ 2 = 1 Rest 1.

1 \ 2 = 0 Rest 0.

Nun nehmen wir die Reste von unten nach oben und hängen sie an den
anderen dran: 0111. Die 0 kann man weglassen, weil sie ganz links steht.

0111 = 111 und wie wir vorhin festgestellt haben ist 111 in binär 15 in dezimal.

Alles anzeigen

ist das wirklich so?

111 = 7
1111 = 15

das sagt sogar dein programm
(screenshot)

**alpines** · 9. Oktober 2013

Mein Fehler

1 \ 2 = 0 R 1!

Ich hab ausversehen die 0 dahingeschrieben, ich korrigier das mal schnell, aber danke das du es bemerkt hast.

x0r · 9. Oktober 2013

kein thema, hab dir auch ne msg in der sb geschrieben, aber da schaust vermutlich nich wirklich rein

den fehler mit dem 1/2=0 hatte ich schonmal bei dec 2 hex und hab mich gewundert, warum nicht das raus kam, was eigentlich sollte

**alpines** · 9. Oktober 2013

Ich habs jetzt erst bemerkt das du mir das geschrieben hast, tut mir leid aber jetzt passt es ja.
Bin nebenbei die ganze Zeit in SciTE ein bisschen rumtippen, deshalb merk ich sowas nicht so schnell

**Mars** · 9. Oktober 2013

Dazu gabs auch schonmal einen Geschwindigkeitsvergleich.
Und wenn ich mich nicht irre war die folgende Variante so ziemlich die schnellste:

Spoiler anzeigen

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Version=Beta
#AutoIt3Wrapper_Icon=..\InconTransfer32.ico
#AutoIt3Wrapper_UseUpx=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

;~ #include <WindowsConstants.au3>
;~ #include <EditConstants.au3>
;~ #include <WinApi.au3>

Global $a[256]
_ArrayFuellen()

$hWnd=GUICreate('Echtzeit Binärumwandlung',600,300,-1)
$hInputEdit=GUICtrlCreateEdit('',0,0,600,150,4096+64)
$hOutputEdit=GUICtrlCreateEdit('',0,150,600,135,2048+64)
GUICtrlSetFont(-1, 6, 400, 0 , 'Courier New', 5)
$hLabel = GUICtrlCreateLabel('', 5, 285, 600, 15)
GUIRegisterMsg(0x0111,"WM_COMMAND")
GUISetState(@SW_SHOW)

While Not (GUIGetMsg() = -3)
WEnd

Func WM_COMMAND($hWinHandle,$iMsg,$wParam,$lParam)
Local $t
If _WinAPI_HiWord($wParam)=0x300 And _WINAPI_LoWord($wParam)=$hInputEdit Then
Local $read = GUICtrlRead($hInputEdit)
If Not StringReplace(StringReplace($read, '0', ''), '1', '') Then
$t = TimerInit()
$bEncrypted=_BinToString($read)
$t = TimerDiff($t)
GUICtrlSetData($hOutputEdit,$bEncrypted)
GUICtrlSetData($hLabel, 'Binär -> String - ' & Round($t*1000) & ' µs')
Else
$t = TimerInit()
$bEncrypted=_StringToBin($read)
$t = TimerDiff($t)
GUICtrlSetData($hLabel, 'String -> Binär - ' & Round($t*1000) & ' µs')
GUICtrlSetData($hOutputEdit,$bEncrypted)
EndIf
EndIf
EndFunc

Func _WinAPI_HiWord($iLong)
Return BitShift($iLong, 16)
EndFunc ;==>_WinAPI_HiWord

Func _WinAPI_LoWord($iLong)
Return BitAND($iLong, 0xFFFF)
EndFunc ;==>_WinAPI_LoWord

Func _StringToBin($s) ; String rein, Nullen und Einsen raus !
Local $h = StringTrimLeft(StringToBinary($s), 2), $r
For $i = 1 To StringLen($s) * 2 Step 2 ; 1 Zeichen -> 2 Hex
$r &= $a['0x' & StringMid($h, $i, 2)]
Next
Return $r
EndFunc ;==>_StringToBin

Func _BinToString($b) ; Nullen und Einsen rein, String raus !
Local $s
For $i = 1 To StringLen($b) Step 8 ; 1 Zeichen -> 8 Bit
Switch Int(StringMid($b, $i, 4))
Case 0
$s &= '0'
Case 1
$s &= '1'
Case 10
$s &= '2'
Case 11
$s &= '3'
Case 100
$s &= '4'
Case 101
$s &= '5'
Case 110
$s &= '6'
Case 111
$s &= '7'
Case 1000
$s &= '8'
Case 1001
$s &= '9'
Case 1010
$s &= 'A'
Case 1011
$s &= 'B'
Case 1100
$s &= 'C'
Case 1101
$s &= 'D'
Case 1110
$s &= 'E'
Case 1111
$s &= 'F'
EndSwitch
Switch Int(StringMid($b, $i+4, 4))
Case 0
$s &= '0'
Case 1
$s &= '1'
Case 10
$s &= '2'
Case 11
$s &= '3'
Case 100
$s &= '4'
Case 101
$s &= '5'
Case 110
$s &= '6'
Case 111
$s &= '7'
Case 1000
$s &= '8'
Case 1001
$s &= '9'
Case 1010
$s &= 'A'
Case 1011
$s &= 'B'
Case 1100
$s &= 'C'
Case 1101
$s &= 'D'
Case 1110
$s &= 'E'
Case 1111
$s &= 'F'
EndSwitch
Next
Return BinaryToString('0x' & $s)
EndFunc ;==>_BinToString

Func _DecToBin($iD) ; Modulomethode -> Nicht sehr schnell. Unwichtig, da sie nur zum Initialisieren von 0 bis 255 genutzt wird.
Local $sR
Do
$sR = Mod($iD, 2) & $sR
$iD = Floor($iD / 2)
Until $iD = 0
Return StringRight('0000000' & $sR, ; Es werden 8 Stellen ausgegeben !
EndFunc ;==>_DecToBin

Func _ArrayFuellen() ; Damit alle Werte von 0 bis 255 direkt vorliegen und keine Berechnungen nötig sind.
For $i = 0 To 255 Step 1
$a[$i] = _DecToBin($i)
Next
EndFunc ;==>_ArrayFuellen

**alpines** · 9. Oktober 2013

Den Geschwindigkeitsvergleich dazu hab ich nicht gesehen aber in dem Script das du gepostet hast wird ja nicht richtig "gerechnet".
Es gibt sehr viele Methoden um die Zahlen umzuwandeln, da brauch man sich darum nicht zu streiten.

**Mars** · 9. Oktober 2013

Rechnen braucht ja auch Zeit
Wer weniger rechnet ist schneller fertig
Hatte aber eine Alte Version des Skripts, es gab noch eine schnellere. Da ich mich aber noch an die Änderungen erinnern kann (so in etwa jedenfalls) hab ich das grade mal eingebaut.

Spoiler anzeigen

Global $a[256], $c[11111112]
_ArrayFuellen()

$hWnd=GUICreate('Echtzeit Binärumwandlung',600,300,-1)
$hInputEdit=GUICtrlCreateEdit('',0,0,600,150,4096+64)
$hOutputEdit=GUICtrlCreateEdit('',0,150,600,135,2048+64)
GUICtrlSetFont(-1, 6, 400, 0 , 'Courier New', 5)
$hLabel = GUICtrlCreateLabel('', 5, 285, 600, 15)
GUIRegisterMsg(0x0111,'WM_COMMAND')
GUISetState(@SW_SHOW)

While Not (GUIGetMsg() = -3)
WEnd

Func WM_COMMAND($hWinHandle,$iMsg,$wParam,$lParam)
Local $t
If _WinAPI_HiWord($wParam)=0x300 And _WINAPI_LoWord($wParam)=$hInputEdit Then
Local $read = GUICtrlRead($hInputEdit)
If Not StringReplace(StringReplace($read, '0', ''), '1', '') Then
$t = TimerInit()
$bEncrypted=_BinToString($read)
$t = TimerDiff($t)
GUICtrlSetData($hOutputEdit,$bEncrypted)
GUICtrlSetData($hLabel, 'Binär -> String - ' & Round($t*1000) & ' µs')
Else
$t = TimerInit()
$bEncrypted=_StringToBin($read)
$t = TimerDiff($t)
GUICtrlSetData($hLabel, 'String -> Binär - ' & Round($t*1000) & ' µs')
GUICtrlSetData($hOutputEdit,$bEncrypted)
EndIf
EndIf
EndFunc

Func _WinAPI_HiWord($iLong)
Return BitShift($iLong, 16)
EndFunc ;==>_WinAPI_HiWord

Func _WinAPI_LoWord($iLong)
Return BitAND($iLong, 0xFFFF)
EndFunc ;==>_WinAPI_LoWord

Func _StringToBin($s) ; String rein, Nullen und Einsen raus !
Local $h = StringToBinary($s), $r
For $i = 3 To StringLen($s) * 2 + 2 Step 2 ; 1 Zeichen -> 2 Hex
$r &= $a['0x' & StringMid($h, $i, 2)]
Next
Return $r
EndFunc ;==>_StringToBin

Func _BinToString($b) ; Nullen und Einsen rein, String raus !
Local $s
For $i = 1 To StringLen($b) Step 8 ; 1 Zeichen -> 8 Bit
$s &= $c[Int(StringMid($b, $i, 8))]
Next
Return BinaryToString('0x' & $s)
EndFunc ;==>_BinToString

Func _DecToBin($iD) ; Modulomethode -> Nicht sehr schnell. Unwichtig, da sie nur zum Initialisieren von 0 bis 255 genutzt wird.
Local $sR
Do
$sR = Mod($iD, 2) & $sR
$iD = Floor($iD / 2)
Until $iD = 0
Return StringRight('0000000' & $sR, ; Es werden 8 Stellen ausgegeben !
EndFunc ;==>_DecToBin

Func _ArrayFuellen() ; Damit alle Werte von 0 bis 255 direkt vorliegen und keine Berechnungen nötig sind.
For $i = 0 To 255 Step 1
$a[$i] = _DecToBin($i)
Next
For $i = 16 To 255 Step 1
$c[Int(_DecToBin($i))] = Hex($i, 2)
Next
EndFunc ;==>_ArrayFuellen

**Andy** · 9. Oktober 2013

Hi,
die Funktion führt zu einem Überlauffehler, wenn die eingegebene Zahl > 64 Bit ist...
Input: 999999999999999999999999999999999999999999999
Output
Die Dezimalzahl 9223372036854775807 ist als binäre Zahl: 1000000000000000000000000000000000000000000000001111111111111111.

**alpines** · 9. Oktober 2013

Man kann es auch übertreiben

x0r · 10. Oktober 2013

da hab ich wieder was ausgegraben.. tut mir fast ein bissl leid jetz

**alpines** · 10. Oktober 2013

Dann musst du auch den Kopf dafür hinhalten

Teilen