Barcode in Variable scannen ohne den Inhalt irgendwo anzuzeigen

Zitat von gert_nrw_71

ich suche eine Möglichkeit über AutoIT die Eingabe über einen Barcodescanner direkt in eine Variable zu speichern, ohne über eine Inputbox oder sonstige Eingabefelde zu gehen.

Ich habe bisher nur mit einem Barcodescanner gearbeitet. Aber egal, ob über Bluetooth oder USB angeschlossen - er wird als Eingabegerät behandelt.

Das erfordert somit, dass vor dem Übertragen des Scanner Speichers (oder dem direkten Scan) sich der Cursor in einem Eingabefeld befindet.

Alternativ kann man (zumindest bei meinem Scanner) einen Hotkey vor dem Übertragen der Daten senden lassen. Damit öffne ich z.B. eine Excel Tabelle, in die dann alle Daten des Scanners in die Zellen einer Spalte untereinander eingetragen werden.

Soweit mir bisher bekannt ist, benötigt der Scanner ein Eingabefeld in einem aktiven Fenster um seine Daten zu übertragen. Da geht nix mit im Hintergrund arbeiten.

Hi,

Für den Rechner ist der Scanner, je nach Konfiguration, nichts weiter als eine Tastatur.

Du musst also nur die Tastaturcodes abfragen, Oscar hat hier ein entsprechendes Script vorgestellt.

Ich benutze, da in meiner Anwendung Scanner und Tastatur gleichzeitig verwendet werden können, am Scanner einen identifizierenden Präfix, der nicht ohne weiteres per Tastatur dargestellt werden kann, ich nutze ASCII-Code 220 oder sonst einen esoterischen Code. Der Postfix ist CRLF.

In der Anwendung wird jetzt bspw. von Anwender A ein Text eingegeben, gleichzeitig scannt Anwender B einen Barcode.

Der Tastaturevent wird ausgewertet, jeder "normale" Tastaturcode wird nicht beachtet, d.h. an die Anwendung weitergegeben.

Erkennt das Script im Tastaturevent den Präfix (ASCII 220), dann ist alles bis zum irgendwann folgenden CRLF der eingescannte Code.

So kann man auch mehrere Scanner gleichzeitig an einem Rechner betreiben, das Script weist dann die Scancodes anhand des (logischerweise je Scanner unterschiedlichen) Präfix der entsprechenden Software und deren Inputfeldern oder anderen Eingabecontrols zu.

Aber das musst du individuell auf deine Anwendung anpassen...

Moin.

Wir haben einen Scanner der wird via USB einfach zur Tastatur dazu "gesteckt".
Wenn ich dann z. B. einen Code einscannen möchte, gehe ich auf das Feld wo der eingescannte Wert stehen soll.

Wir haben aber auch einen Scanner, der scannt, sobald ein Scanncode in Reichweite ist. Das wird aber über eine zum Scanner mitgelieferten Treiber.

Schreib uns doch mal welchen Scanner verwendet wird? Dann kann man im Netz nämlich sehen, was möglich ist und ob es dafür evtl. eine "Schnittestellenbeschreibung" gibt.

gert_nrw_71: Du wirst entweder ein sichtbares Inputfeld benötigen oder du musst, was BugFix schon vorgeschlagen hat, versuchen mit einem angehängten Prefix (Scanner konfiguration) UND einem versteckten Inputfeld arbeiten.

Zitat von Zebra

Sie können ein Präfix oder Postfix verwenden, um Tastencodes wie Sonderzeichen, Wagenrücklauf oder Tabulatorzeichen vor oder nach den Strichcodedaten hinzuzufügen.

Letzteres habe ich noch nie probiert, könnte mir auch vorstellen das es von der zeitlichen Abfolge Probleme geben könnte aber das Prinzip würde ich mir so vorstellen:

;Wenn ? als prefix konfiguriert ist.
HotKeySet("?", "Scan")

Func Scan()
Local Const $LastFocus = _WinAPI_GetFocus()
    _WinAPI_SetFocus($ScanBox)
    sleep(500); um sicher 
    $deineVariable = GUICtrlRead($ScanBox)
    GUICtrlSetData($ScanBox, "")
    _WinAPI_SetFocus($LastFocus)
EndFunc

Ich würde daher mal behaupten der beste Weg wäre ein sichtbares Inputfeld.

Ansonsten schau dir das mal an: https://www.autoitscript.com/forum/topic/18…f-com-port-udf/

Schau mal in meinen Post vom 15.09.2021:

emulierte Tastatureingabe eines RFID-Scanners in Variable schreiben

emulierte Tastatureingabe eines RFID-Scanners in Variable schreiben

Da wird das Thema behandelt. Bei mir ist es halt ein RFID-Scanner gewesen. Dieser ist aber auch als "Tastatur" konfiguriert.

Ob das Einlesen eines QR-Codes in ein Textfeld abgeschlossen ist werte ich so aus:

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $lParam
    $iIDFrom = _WinAPI_LoWord($wParam)
    $iCode = _WinAPI_HiWord($wParam)

    Switch $iIDFrom
        Case $idCode ; Edit HW-Sacn

            Switch $iCode
                Case $EN_UPDATE

            If StringRegExp(ControlGetText($hWnd, '', $iIDFrom), 'S/N: .*' & @CRLF) Then     ; $hWnd = Textfeld in das eingelesen wird, 'S/N: .*' & @CRLF = der Text(letzte Zeile) der die Ausgewertung initiiert.  
...

Hoffe das hilft weiter

Moombas:
Prä- / Postfix

Das habe ich gemeint, als ich schrieb, das er uns bitte sein Scannermodel nennen möchte.
Ich weiß, das bei uns bei dem einen PC wo der eine Scanner angeschlossen ist, ist ein Postfix irgendwo drinne. Leider habe ich das Script derzeitig nicht zur Verfügung, aber irgendwo bei meinen Beiträgen müsste was zu finden sein. Wenn ich z. B. in einer Exceltabelle Daten einscannen möchte, brauche ich nur einscannen, das <Enter und das springen in die nächste Zelle wurde via Postfix gesteuert. Und das habe ich auch so, das es in eine Textdatei gespeichert wird.
Meine erste Lsg. damals war ein unsichtbares Inputfeld in das gescannt wurde und immer wenn etwas in dem Feld war hat das Script Enter gedrückt. Ich muss sehen, wenn ich wieder Auto fahren darf, das ich es mal raus suche. Hier bei mir ging es um Handscanne für den Strichcode der z. B. auf Lebensmittel eingescannt wird.

Reden wir nun von so einen Scanner oder über RFID Scanner?

Zitat von Alina

Reden wir nun von so einen Scanner oder über RFID Scanner?

Eigentlich egal, wenn beide eine USB-Tastatur emulieren.

Das Problem, bei gleichzeitiger Benutzung von Scanner und normaler Tastatur ist, dass man erkennen muss, welche Eingabe woher kommt.

Wenn der Scanner ein Prä-/Postfix sendet, kann man alle Eingaben vom Prä- bis zum Postfix abfangen (Tastatur-Hook) und entsprechend verwenden. Andy hat das oben bereits erwähnt.

Moin,

hat schon mal jemand versucht, die Scannereingaben über _WinAPI_RegisterRawInputDevices() abzugreifen? Ich habe leider keinen Barcodescanner und kann das nicht probieren.

Zitat von Velted

versucht, die Scannereingaben über _WinAPI_RegisterRawInputDevices() abzugreifen?

Habe ich nicht.

Die Bsp. zu der Funktion sind eine (in meinen Augen) etwas komplizierte Form eines Hooks. All das, was dort getan wird, erledigt man üblicherweise mit einem Hook.

Aber ja: Da mit einem Hook der Keyboard-Input abgefangen werden kann, lässt sich das sicher auch mit obiger Funktion erledigen.

Der Vorteil läge für mich darin, dass sich die Eingaben einem bestimmten Gerät zuordnen lassen. Vermischungen mit anderen Eingaben können so vermieden werden.

Zitat von Velted

hat schon mal jemand versucht, die Scannereingaben über _WinAPI_RegisterRawInputDevices() abzugreifen?

Das ließ mir keine Ruhe!

Die Idee ist gut, weil man damit auch ohne Präfix auskommt. Ich habe mal ein Script erstellt:

#include <APISysConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

; hier muss der DeviceName von eurem Scanner drinstehen
; beim auskommentieren von Zeile 47 wird der DeviceName beim scannen angezeigt.
Global $g_sDevName = '\\?\HID#VID_13BA&PID_0018#6&238b7016&0&0000#{884b96c3-56ef-11d1-bc8c-00a0c91405dd}'

Global $g_hForm = GUICreate('BarcodeScanner', 300, 120)
Global $g_idLabel = GUICtrlCreateLabel('', 5, 5, 290, 30) ; fuer die Ausgabe vom Barcode-Scanner
GUICtrlSetFont(-1, 16)
Global $g_idInput = GUICtrlCreateInput('', 5, 40, 290, 30) ; zum testen ein Input, fuer eine Eingabe von der Tastatur
GUICtrlSetFont(-1, 16)
Global $g_idDummy = GUICtrlCreateInput('', 0, 0, 0, 0) ; Dummy-Input, um die Scannereingabe umzulenken

Local $tRID = DllStructCreate($tagRAWINPUTDEVICE)
DllStructSetData($tRID, 'UsagePage', 0x01)
DllStructSetData($tRID, 'Usage', 0x06)
DllStructSetData($tRID, 'Flags', $RIDEV_INPUTSINK)
DllStructSetData($tRID, 'hTarget', $g_hForm)
_WinAPI_RegisterRawInputDevices($tRID)

GUIRegisterMsg($WM_INPUT, 'WM_INPUT')
GUISetState(@SW_SHOW)
GUICtrlSetState($g_idInput, $GUI_FOCUS)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_INPUT($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam
    Local Static $sBuffer = ''
    Local $devType, $devName, $tRIM, $tText, $hFocus
    Switch $hWnd
        Case $g_hForm
            $tRIM = DllStructCreate($tagRAWINPUTHEADER)
            If _WinAPI_GetRawInputData($lParam, $tRIM, DllStructGetSize($tRIM), $RID_HEADER) Then
                $devType = $tRIM.Type
            Else
                ConsoleWrite("Device Header Retrieval Failed" & @CRLF)
                Return
            EndIf
            $tText = DllStructCreate('wchar data[256]')
            If _WinAPI_GetRawInputDeviceInfo($tRIM.hDevice, $tText, 256, $RIDI_DEVICENAME) Then
                $devName = $tText.data
;~                 ConsoleWrite(StringFormat("DevName: '%s'\r\n", $devName))
            Else
                ConsoleWrite('Device Name Retrieval Failed' & @CRLF)
            EndIf
            If $devName = $g_sDevName Then ; hier wird getestet, ob die Eingabe vom Barcode-Scanner kommt
                If $devType = $RIM_TYPEKEYBOARD Then ; sicherstellen, dass eine Tastatur-Emulation erfolgt
                    GUICtrlSetState($g_idDummy, $GUI_FOCUS) ; Focus auf das Dummy-Input setzen
                    $tRIM = DllStructCreate($tagRAWINPUTKEYBOARD)
                    If _WinAPI_GetRawInputData($lParam, $tRIM, DllStructGetSize($tRIM), $RID_INPUT) Then
                        If $tRIM.Message = $WM_KEYUP Then ; wenn KEYUP
                            If $tRIM.VKey = 13 Then ; wenn VKey = 13 (@CR) wird bei meinem Barcode-Scanner als Postfix gesendet (evtl. anpassen)
                                GUICtrlSetData($g_idLabel, $sBuffer) ; Buffer im Label anzeigen
                                $sBuffer = '' ; Buffer leeeren, fuer naechsten Code
                                ConsoleWrite('--- New Code ---' & @CRLF) ; nur zum debuggen
                                GUICtrlSetState($g_idInput, $GUI_FOCUS) ; Focus wieder auf das Input fuer die Tastatur
                            Else ; alle anderen Zeichen werden in den Buffer uebernommen
                                $sBuffer &= Chr($tRIM.VKey)
                                ConsoleWrite('Char: ' & Chr($tRIM.VKey) & @CRLF) ; nur zum debuggen
                            EndIf
                        EndIf
                    EndIf
                EndIf
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_INPUT

Ich habe nur nicht herausbekommen, wie man die Zeichen (die man vom Scanner abfängt) aus dem Tastaturpuffer löschen kann. Sie werden immer an das aktive Input-Control gesendet (auch bei einem "Return 0").

Deswegen habe ich einen Workaround mit einem Dummy-Input eingebaut.

So funktionieren zumindest beide Eingaben "gleichzeitig".

Zitat von gert_nrw_71

Was ist eigentlich ein Hook ?

Die wörtliche Übersetzung trifft es ganz gut: Haken.

Ein Hook hakt sich z.B. in den Nachrichtenstrom zwischen Tastatur und System ein. Jetzt kann man jede Tastatureingabe abfangen, manipulieren oder verwerfen, bevor diese normal das System erreicht.

Bsp.: Taste "ä" wird gedrückt. In der Hook Prozedur wird dieses Event verworfen und stattdessen an das System die Tastenfolge "ae" geleitet.

Ich hatte vor Jahren mal einige Hook-Bsp. gepostet. Sollte über die Suche auffindbar sein.

Zitat von gert_nrw_71

da die Eingabe über eine Inputbox erfolgt ?

Das ist falsch!

Bei meinem Script ist das Input nur zur Verdeutlichung, dass zusätzlich auch noch eine Eingabe per Tastatur möglich ist.

Der Barcode befindet sich komplett in der Variable $sBuffer, nachdem das Postfix gesendet wurde (siehe Kommentare im Script).

Was Du dann damit machst, liegt nur bei Dir.

Hallo Oscar,

Zitat

Ich habe nur nicht herausbekommen, wie man die Zeichen (die man vom Scanner abfängt) aus dem Tastaturpuffer löschen kann.

mit Return -1 vielleicht...

Func _KeyProc($nCode, $wParam, $lParam)

    If Not $g_bScanActiv Then Return _WinAPI_CallNextHookEx($g_hHook, $nCode, $wParam, $lParam)
    Local $tKEYHOOKS, $sChar
    $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($g_hHook, $nCode, $wParam, $lParam)
    If $wParam = $WM_KEYDOWN Then
        $sChar = Chr($tKEYHOOKS.vkCode)
        If StringRegExp($sChar, '[0-9]') Then ; $sChar kann jetzt nur "0 - 9" enthalten (nicht von NUMPAD-Eingabe)
            $g_sAusweisNr &= $sChar ; Speichern der einzelnen Zeichen in $g_sAusweisNr zur kompletten Ausweisnr die immer aus 6 Zahlen besteht
            If StringLen($g_sAusweisNr) = 6 Then ; AusweisNr kpl. eingelesen
                $g_bScanActiv = False ; Key-Hook pausiert
                GUICtrlSendToDummy($g_DummyStartCheck) ; Ctrl "$g_DummyStartCheck" wird befeuert und dessen hinterlegte Aktion gestartet
                GUICtrlSetState($g_btScan, $GUI_ENABLE) ; Button zum Starten Scan freigeben
            EndIf
        Else ; irgendein Nicht-Ziffer Zeichen - FEHLER
            $g_sAusweisNr = '' ; $g_sAusweisNr leeren
            $g_bScanActiv = False ; Key-Hook pausiert, User muss aktiv Scanvorgang neu starten
            GUICtrlSetState($g_btScan, $GUI_ENABLE) ; Button zum Starten Scan freigeben
            GUICtrlSendToDummy($g_DummyError) ; Ctrl "$g_DummyError" wird befeuert und dessen hinterlegte Aktion gestartet
        EndIf
        Return -1 ; Eingabe wird nicht an das System weitergeleitet
    EndIf
    Return _WinAPI_CallNextHookEx($g_hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc

Mir wurde nach dem Scannen das letzte eingescannte Zeichen immer in das nächste aktive Eingabefeld geschrieben, egal ob im Programm oder wenn ich danach z.B. ein Browser.- oder Editorfenster öffnete.
Erst mit Return -1 hörte das auf.

Zitat von hipfzwirgel

mit Return -1 vielleicht...

Probiere mal _WinAPI_SetKeyboardState und sende damit ein leeres 256-Byte Array.

Zitat von BugFix

Probiere mal _WinAPI_SetKeyboardState und sende damit ein leeres 256-Byte Array.

Nee, weder "-1" noch das leere Array verhindern das durchreichen der Zeichen.

Zitat von Oscar

Nee, weder "-1" noch das leere Array verhindern das durchreichen der Zeichen.

Ich hab mal gesucht, in einem C64-Forum habe ich Folgendes gefunden:

LDA #$00
STA $C6

will clear the buffer.

Ich habe keine Ahnung was und wie auf C64 programmiert wurde. Aber vllt. hat da jemand nen Plan und kann das umsetzen.

Zitat von BugFix

Ich habe keine Ahnung was und wie auf C64 programmiert wurde. Aber vllt. hat da jemand nen Plan und kann das umsetzen.

Das ist Assembler-Code und beim C64 konnte man damit direkt auf den Speicher zugreifen.

Aber ich glaube kaum, dass das hier weiter hilft.