Code Kata - Happy Numbers

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi Leute,

hier mal was für zwischendurch, die "Happy Numbers" Code Kata.

💡 Ziel: Ist es einen Algorithmus, bestehend aus einer oder mehreren Funktionen zu schreiben, womit erkannt wird ob eine gegebene Zahl "happy" ist oder nicht 😁 .

Ein "glückliche" Zahl ist eine Zahl, bei der die Summe der Quadrate ihrer Ziffern auf die Dauer 1 ergibt.
Beispiel für Zahl 19: 19 -> 1^2 + 9^2 = 82 -> 8^2 + 2^2 = 68 -> 6^2 + 8^2 = 100 -> 1^2 + 0^2 + 0^2 = 1

🥈 Teil 1: Entwickle die Funktion(en) und lass dir 19 -> 1 :) mit ConsoleWrite() bspw. ausgeben.
🥇 Teil 2: Lass dir alle "happy numbers" im Bereich von 1 bis 100 ausgeben (analog wie bei Teil 1).

⚡ Rahmenbedingungen:

Versuche es möglichst komplett ohne Hilfsmittel und ohne Google Suche.
Zeitliche Vorstellung für diese kleine Challenge ist um die 30 min.
Wenn du eine Lösung hast und diese hier postest, dann bitte den Code in Spoiler einbinden, damit jeder selbst entscheiden kann ob er die Lösungsvariante der Anderen sehen möchte oder nicht 😉 .

Ich bin gespannt auf eure Lösungen und wünsche happy coding 👍 .

Viele Grüße

Sven

**Xorianator**

Da kommen Erinnerungen hoch ... War bei uns im 1. Semester eine Programmieraufgabe.

**UEZ**

Mal was anderes...

Hier mein Lösungsvorschlag:

Spoiler anzeigen

AutoIt

;coded by UEZ
Func HN($n, $iDepth = 0)
    If $n = 0 Or $n = 2 Or $n = 4 Or $n = 20 Or $n = 42 Or $n = 145 Or $iDepth > 16 Then Return 0
    If $n = 1 Then Return 1
    Local $i, $a = StringRegExp($n, "\d", 3), $sum = 0
    For $i = 0 To UBound($a) - 1
        $sum += $a[$i] * $a[$i]
    Next
    If $sum = 1 Then Return 1
    Return HN($sum, $iDepth + 1)
EndFunc

For $i = 0 To 100
    ConsoleWrite("Zahl " & $i & " ist Happy: " & HN($i) & @CRLF)
Next

Alles anzeigen

**chesstiger**

Das hat mich grad auch gecatcht.

Spoiler anzeigen

Code

Func happy($iNum)
    ;$iNum is an integer from 1 to 100
    If $iNum = 1 Then Return 1
    If $iNum = 20 Then Return 0
    Local $aNum = StringSplit(String($iNum), "", 3)
    Local $i, $iSum = 0
    For $i = 0 To UBound($aNum) - 1
        $iSum += Int($aNum[$i])^2
    Next
    Return happy($iSum)
EndFunc

For $i = 1 To 100
    If happy($i) Then ConsoleWrite($i & " -> 1 :)" & @CRLF)
Next

Alles anzeigen

Bevor jemand fragt: Die 20 in Zeile 4 ist quasi experimentell ermittelt. Alle Zahlen im Bereich 1-100 laufen entweder auf 1 hinaus oder enthalten (periodisch) eine 20.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi zusammen,

Xorianator ja das ist eine ganze Weile her 😅 , bei mir länger als bei dir wenn deine Geburtsangabe stimmt. Jedoch wurde damals auf "agile" oder "clean code" nur wenig eingegangen.
Egal [...], ich denke du kommst sicherlich noch mit deinem Lösungsvorschlag "um die Ecke" oder 🤞 ?

UEZ Korrekt 👍 , kurz und äh, kurz 😂 .

chesstiger Korrekt 👍 , ebenfalls kurz und doch ein wenig anders.

Hier mal mein Lösungsansatz:

Spoiler anzeigen

Den Preis für Code-Effizienz verdient dieser sicherlich nicht 😔 , aber vielleicht Punkte ich in Sachen Lesbarkeit/Verständlichkeit?

AutoIt

Func _isHappyNumbers($iNumber)
    Local $iIterationsToCheck = 15

    For $i = 1 To $iIterationsToCheck Step 1
        Local $iResult = _getSumOfDigitsSquares($iNumber)

        If $iResult == 1 Then
            Return True
        EndIf

        $iNumber = $iResult
    Next

    Return False
EndFunc

Func _getSumOfDigitsSquares($iNumber)
    Local $iDigitsCount = StringLen($iNumber)
    Local $iSum

    For $j = 1 To $iDigitsCount Step 1
        $iSum += _getSquare($iNumber, $j)
    Next

    Return $iSum
EndFunc

Func _getSquare($iNumber, $iStart)
    Return StringMid($iNumber, $iStart, 1) ^ 2
EndFunc

For $i = 1 To 100 Step 1
    If _isHappyNumbers($i) Then
        ConsoleWrite($i & ' -> 1 :)' & @CRLF)
    EndIf
Next

Alles anzeigen

Viele Grüße
Sven

Yjuq

Hi, ich schreibe nicht mehr viel in AutoIt. Daher ist meine ursprüngliche Lösung in Lua. Ich habe jedoch den Code nach AutoIt übersetzt nachdem ich fertig war.

Lua 5.4 Skript: Alle "Happy Numbers" von 1 bis 10'000'000 in ca. 8 Sekunden in eine Text Datei.

AutoIt Skript: Alle "Happy Numbers" von 1 bis 100'000 in ca. 8 Sekunden in die Konsole.

Spoiler anzeigen

AutoIt

Func isHappy($n)
    Local $r, $s, $x = $n

    While ($x <> 1) And ($x <> 4)
        $s = 0
        $n = $x

        While $n > 0
            $r = Mod($n, 10)
            $s += $r ^ 2
            $n = Floor($n / 10)
        WEnd

        $x = $s
    WEnd

    Return $x = 1
EndFunc

For $i = 1 To 100000
    If isHappy($i) Then
        ConsoleWrite($i & @CRLF)
    EndIf
Next

Alles anzeigen

Code

local function isHappy(n)
    local r, s
    local x = n

    while (x ~= 1) and (x ~= 4) do
        s = 0
        n = x
        
        while n > 0 do
            r = n % 10
            s = s + r * r
            n = n // 10
        end
        
        x = s
    end

    return x == 1
end

local file = io.open("happy_yjuq.txt", "w+")
for i = 1, 10000000 do
    if isHappy(i) then
        file:write(i, "\n")
    end
end
file:flush()
file:close()

Alles anzeigen

chesstiger

Spoiler anzeigen

Zitat von chesstiger

Bevor jemand fragt: Die 20 in Zeile 4 ist quasi experimentell ermittelt. Alle Zahlen im Bereich 1-100 laufen entweder auf 1 hinaus oder enthalten (periodisch) eine 20.

Tatsächlich ist es so dass jede Zahl entweder auf 1 ended oder in diese Zahlenloop sich verläuft:
4, 16, 37, 58, 89, 145, 42, 20, 4

Deine 20 ist dabei. Demnach ist deine Lösung ebenfalls korrekt. Man kann also gegen einer dieser Zahlen prüfen.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi Yjuq ,

auch dein Lösungsvorschlag liefert das korrekte Ergebnis 👍 .

Sowohl bei Zahlen von 1 bis 100, aber auch bei 1 bis 10000 bspw. => dies gilt für alle bisherigen Lösungen 😀 .
Bisher ist deine Variante auch die schnellste bei bspw. 10000 in meinem Test.
Eine Optimierung würde jedoch in einem Folgeschritt folgen, daher nicht relevant für die Aufgabenstellung.

Danke für's Mitmachen.

Viele Grüße
Sven

Yjuq

Zitat von SOLVE-SMART

Eine Optimierung würde jedoch in einem Folgeschritt folgen, daher nicht relevant für die Aufgabenstellung.

Falls du daran denkst ggf. bereits gefundene Zahlen zwischenzuspeichern um den Rechenaufwand zu minimieren -> Das klappt nicht. Es stellt sich heraus (zumindest was ich dazu versucht hatte) dass dies langsamer ist und zusätzlich Speicher im RAM benötigt. Zumindest mit den Lösungsansätzen welche ich versucht hatte. Es ist schneller die Zahlen einfach neu zu berechnen.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi Yjuq ,

Zitat von Yjuq

Falls du daran denkst ggf. bereits gefundene Zahlen zwischenzuspeichern um den Rechenaufwand zu minimieren -> Das klappt nicht. [...]

Okay, spannend das du bereits einige Tests gemacht hast 👍 . In erster Linie geht es um die Aufgabenstellung nicht um Performanz oder ähnliches - dennoch gut zu wissen, Danke.

Viele Grüße

Sven

**chesstiger**

Das Makes Variante schneller ist, war zu erwarten. Grundsätzlich lassen sich rekursive Algorithmen immer sehr schön schreiben und lesen... Aber in der Ausführung sind fast immer iterative Verfahren überlegen. Dazu ist der Overhead bei rekursiven Funktionsaufrufen zu groß.

**UEZ**

Und RegEx ist langsamer als die StringSplit Funktion.

Benchmark nach der Reihenfolge der Beiträge:

AutoIt

#Region UEZ
Func HN($n, $iDepth = 0)
    If $n = 0 Or $n = 2 Or $n = 4 Or $n = 20 Or $n = 42 Or $n = 145 Or $iDepth > 12 Then Return 0
    If $n = 1 Then Return 1
    Local $i, $a = StringRegExp($n, "\d", 3), $sum = 0
    For $i = 0 To UBound($a) - 1
        $sum += $a[$i] * $a[$i]
    Next
    If $sum = 1 Then Return 1
    Return HN($sum, $iDepth + 1)
EndFunc
#EndRegion

#Region chesstiger
Func happy($iNum)
    ;$iNum is an integer from 1 to 100
    If $iNum = 1 Then Return 1
    If $iNum = 20 Then Return 0
    Local $aNum = StringSplit(String($iNum), "", 3)
    Local $i, $iSum = 0
    For $i = 0 To UBound($aNum) - 1
        $iSum += Int($aNum[$i])^2
    Next
    Return happy($iSum)
EndFunc
#EndRegion

#Region SOLVE-SMART
Func _isHappyNumbers($iNumber)
    Local $iIterationsToCheck = 15

    For $i = 1 To $iIterationsToCheck Step 1
        Local $iResult = _getSumOfDigitsSquares($iNumber)

        If $iResult == 1 Then
            Return True
        EndIf

        $iNumber = $iResult
    Next

    Return False
EndFunc

Func _getSumOfDigitsSquares($iNumber)
    Local $iDigitsCount = StringLen($iNumber)
    Local $iSum

    For $j = 1 To $iDigitsCount Step 1
        $iSum += _getSquare($iNumber, $j)
    Next

    Return $iSum
EndFunc

Func _getSquare($iNumber, $iStart)
    Return StringMid($iNumber, $iStart, 1) ^ 2
EndFunc
#EndRegion

#Region Yjuq
Func isHappy($n)
    Local $r, $s, $x = $n

    While ($x <> 1) And ($x <> 4)
        $s = 0
        $n = $x

        While $n > 0
            $r = Mod($n, 10)
            $s += $r ^ 2
            $n = Floor($n / 10)
        WEnd

        $x = $s
    WEnd

    Return $x = 1
EndFunc
#EndRegion

Global $t = TimerInit(), $e, $durchlauf = 75000
ConsoleWrite("Starte jeweils " & $durchlauf & " Durchläufe..." & @CRLF)

For $i = 1 To $durchlauf
    HN($i)
Next
$e = TimerDiff($t)
ConsoleWrite("UEZ Laufzeit: " & $e & " ms" & @CRLF)

 $t = TimerInit()
For $i = 1 To $durchlauf
    happy($i)
Next
$e = TimerDiff($t)
ConsoleWrite("chesstiger Laufzeit: " & $e & " ms" & @CRLF)

 $t = TimerInit()
For $i = 1 To $durchlauf
    _isHappyNumbers($i)
Next
$e = TimerDiff($t)
ConsoleWrite("SOLVE-SMART Laufzeit: " & $e & " ms" & @CRLF)

 $t = TimerInit()
For $i = 1 To $durchlauf
    isHappy($i)
Next
$e = TimerDiff($t)
ConsoleWrite("Yjuq Laufzeit: " & $e & " ms" & @CRLF)

Alles anzeigen

Rekursionen sind i.d.R. einfacher zu implementieren -> kürzerer Code, aber langsamer.

BananaJoe

Da so wenige mitmachen, trage ich halt auch mal was dazu bei. Da die Aufgabenstellung war "von 1 bis 100" kann meine Version auch nur eine begrenzte Anzahl machen (nur bis 3-stellig, also max. 999)

AutoIt

; Aufgabe siehe: https://autoit.de/thread/87593-code-kata-happy-numbers/?postID=706072#post706072
#include <Array.au3>

_HN()

Func _HN()

    Local $nHN = 0
    Local $hTimer = TimerInit()

    For $i = 1 To 100
        ; ConsoleWrite('+> Number: ' & $i & @CRLF)
        Local $aNumbers[0] ; Initialize new for each number
        $nHN = _HappyNumber($i, $aNumbers)
        If $nHN = 1 Then ConsoleWrite($i & @CRLF)
    Next
    Local $fDiff = TimerDiff($hTimer)

    MsgBox(0, '', 'Time: ' & $fDiff / 1000 & ' Seconds' & @CRLF & @CRLF & 'Happy numbers are in the console')
    Return SetError(0, 0, 1)

EndFunc   ;==>_HN

Func _HappyNumber($nNumber, ByRef $aNumbers)

    Local $nLeft = 0
    Local $nMiddle = 0
    Local $nRight = 0

    ; Base
    If $nNumber = 1 Then Return 1

    ; Recursion
    If StringLen(String($nNumber)) = 1 Then
        If _ArraySearch($aNumbers, $nNumber) <> -1 Then ; Number is already in Array
            Return 0
        Else
            _ArrayAdd($aNumbers, $nNumber)
        EndIf
        $nNumber = _HappyNumber($nNumber * $nNumber, $aNumbers)

    ElseIf StringLen(String($nNumber)) = 2 Then
        $nLeft = Int($nNumber / 10)
        $nRight = Mod($nNumber, 10)
        If _ArraySearch($aNumbers, $nNumber) <> - 1 Then
            Return 0
        Else
            _ArrayAdd($aNumbers, $nNumber)
        EndIf
        $nNumber = _HappyNumber($nLeft * $nLeft + $nRight * $nRight, $aNumbers)

    ElseIf StringLen(String($nNumber)) = 3 Then
        $nLeft = Int($nNumber / 100)
        $nMiddle = Mod(Int($nNumber / 10), 10)
        $nRight = Mod($nNumber, 10)
        If _ArraySearch($aNumbers, $nNumber) <> -1 Then
            Return 0
        Else
            _ArrayAdd($aNumbers, $nNumber)
        EndIf
        $nNumber = _HappyNumber($nLeft * $nLeft + $nMiddle * $nMiddle + $nRight * $nRight, $aNumbers)

    Else
        ConsoleWrite('+> Number > 999' & @CRLF)
    EndIf

    If $nNumber = 1 Then Return 1

EndFunc   ;==>_HappyNumber

Alles anzeigen

Lambdax

Könnte hinhauen

Spoiler anzeigen

Code

For $i = 1 To 100
    If _IsHappyNumber($i) Then ConsoleWrite($i & " -> 1" & @CRLF)
Next

Func _IsHappyNumber($nNum)
    ; do until result is 1 or result is repeated
    Do
        Assign($nNum, True, 1)
        $nNum = __NumArrayQ2(StringSplit(String($nNum), '', 1))
    Until $nNum == 1 Or Eval($nNum)

    If $nNum == 1 Then Return True
    Return False
EndFunc

Func __NumArrayQ2(Const $arNums)
    Local $nResult = 0
    For $i = 1 To $arNums[0]
        $nResult += Int($arNums[$i]) ^ 2
    Next
    Return $nResult
EndFunc

Alles anzeigen

**Andy**

Hi zusammen,

zunächst muss ich sagen, dass ich noch nie von diesen "Happy Numbers" gehört hatte^^

Daher bin ich mal völlig unvoreingenommen an diese ganze Sache herangegangen.

Wie einige von euch sicherlich wissen, schwärme ich für die "brotlose Kunst" aka Grafikspielereien und oldschool Assemblerprogrammierung, und so war mein Ziel, die Daten der "Happy Numbers" als Bitmap darzustellen.

OT Das habe ich mir übrigens bei diversen "Hackings" von unbekannten Daten angewöhnt, da findet man die interessantesten Sachen. Wer darüber mehr erfahren will, bitte per PN.

Diese Bitmap wäre dann nichts weiter als eine LUT (LookUpTabelle), die Frage ob eine Zahl im Wertebereich Happy oder Unhappy ist beschränkt sich dann nur noch auf eine Abfrage des Pixels an dieser Adresse.....

Also sollte eine Bitmap erstellt werden, in der jede Happy Number ein gesetztes Pixel ist. Fehlte nur noch der Algorithmus^^

Der "offensichtliche" Weg für mich war, die Zahlen von 1 bis 9 hinzuschreiben und dann die "Folge" nach Vorschrift zu erstellen, die dann hoffentlich zur 1 (Zahl ist Happy) führt.....oder eben nicht (Zahl ist Unhappy).

Dabei hatte ich festgestellt, dass die "Zwischensummen" (der Quadrate der Ziffern) unweigerlich ebenfalls Happy bzw. Unhappy sind, da sie ja in direkter Folge auf Happy bzw. Unhappy hinauslaufen.

Man muss also während der Ermittlung der Folge nur die aktuell ermittelte Quadratsumme auf Happy bzw. Unhappy überprüfen, um diese "Folge" frühzeitig abbrechen zu können.

Bei Beispielsweise der 6 ergeben sich die Quadratsummen 36, 45, 41, 17, 50 ..... !!!BÄM!!!

50 wird in der Folge zu nichts anderem als 5²+0² aufgelöst. 5 ist aber bereits Unhappy, daraus folgt, dass 6 auch Unhappy sein muss. Desweitern sind 36, 45, 41, 17 auch Unhappy.

Ist eine Zahl Happy, dann sind definitiv sämtliche Quadratsummen auf dem Weg zur 1 auch Happy!

Dann kam ich auf die Idee, diese Quadratsummen in ein Array einzutragen (aka Bitmap^^) und entsprechend zu markieren.

Jede Zahl, die als Happy ermittelt wurde, wird im Array als 1 markiert ($array[happyzahl]=1), jede Unhappy Zahl als ihren Wert ($array[unhappyzahl]=unhappyzahl)

Ich stellte fest, dass die maximale Größe einer einzelnen Quadratsumme höchstens die Summe aus der Anzahl der Ziffern multipliziert mit dem Quadrat der größten Ziffer, also 9, sein kann.

Bsp. Eine Zahl hat 14 Ziffern, die größte Ziffer ist 9, das zum Quadrat ist 81, das mal 14 ergibt 1134.

Man braucht also "nur" beim Test einer 14-stelligen Ziffer ein Array mit 1134 Feldern....

Innerhalb dieses Arrays müssen nur noch die Indizes mit 1 für Happy und mit Zahl für Unhappy gesetzt werden (s.o) und tadaaa, im Algorithmus wird bei Zahlen von 1135 bis 99999999999999 nur noch EINE EINZIGE QUADRATSUMME (die immer kleiner ist als 1134) gebildet, aus der man dann ermittelt, ob diese Zahl dann Happy oder Unhappy ist!

Ich hatte dafür eine rekursive Funktion _IsHappy() geschrieben, im Endeffekt bedeutet das, dass spätestens ab der Zahl 1135 die Rekursion im ersten Schritt verlassen wird! Und das IMMER, egal wie groß die Zahl wird, es wird immer nur die Berechnung der ersten Quadratsummenzahl benötigt um per Lookup im Array sofort auf Happy bzw. Unhappy zu kommen....

Und dann wurde es spannend!!!

Ich erstellte eine Bitmap von 1000x1000 Pixeln (jaja, ermittelt wurden die Happy Numbers von 1 bis eine Million) und markierte nur die ermittelten Happy Numbers mit einem farbigen "rosa" Pixel.

AutoIt-typisch erfolgte die "Berechnung" recht langsam, aber immerhin etliche Faktoren schneller als mit der von (bisher schnellsten _IsHappyNumber()-Funktion vom geschätzten Kollegen Yjuq!

Mir fielen sofort "Muster" im Bild auf! OHA! Seht ihr auch diese "Fensterkreuze"?

Als ich dann die obere linke Ecke stark vergrößerte, wunderte ich mich noch mehr!

Fällt euch auch auf, dass die Happy Pixel an der Diagonale von oben links nach unten rechts gespiegelt sind!?

Was nichts anderes bedeutet, als dass NUR BEI DER HÄLFTE der Zahlen überhaupt der Status "Happy" ermittelt werden muss....

Beispiel: In der obersten Pixelzeile sieht man von links die "Happy Pixel" 1, 7,10,13 usw. (in der Bitmap ist das erste Pixel an Adresse 0!)

Das bedeutet, in der linken Pixelspalte von oben ist ebenfalls das 1te, 7te,10te,13te usw. Pixel gesetzt.

Wenn also an den Koordinaten (x,y) ein Happy Pixel ist, dann auch das an der Koordinate (y,x).

Anbei mein unoptimiertes und auf die schnelle hingehacktes Script zur Ermittlung der "Happy Numbers" incl. Erstellung der 1000x1000 Bitmap...ich werde mich morgen mal an die Beschleunigung machen...

Im abschließenden Arraydisplay wird das Array angezeigt, welches zur Ermittlung der Happy Numbers erstellt wurde.

Ist der Feldinhalt 1, dann ist die Indexzahl Happy, ansonsten der Feldinhalt (Indexzahl ist Unhappy)

Nach schließen des Arraydisplay kann man mit der Maus in der Grafik die Positionen der Pixel anfahren und im Tooltip die dort "gespeicherte" Zahl ermittelt aus den Koordinaten erfahren, der Farbwert des Pixels bestimmt dann, ob die Zahl Happy (Pixelfarbe hat nicht Hintergrundfarbe) oder Unhappy ist (Pixelfarbe hat Hintergrundfarbe)

AutoIt

;AlignComment=40
#include <Array.au3>
#include <WinAPIGdi.au3>
#include <WinAPIGdiDC.au3>


$w = 1000                                ;Breite und Höhe der Bitmap
$h = $w                                  ;für das Beispiel quadratisch

$ret = DllCall("kernel32.dll", "uint", "SetPriorityClass", "hwnd", _WinAPI_GetCurrentProcess(), "dword", 0x00000080) ;zum Benchmarken die Threadpriorität auf "hoch" setzen

$len = StringLen(String($w * $h))        ;Anzahl Ziffern
$happyflag = 0
$happynumbers = 0

Global $maxarray = 81 * $len + 1         ;maximale Groesse der Summe der Quadrate bei dieser Anzahl Ziffern
Global $sieb[$maxarray]                  ;wenn position im Sieb=1 dann ist dieser index "happy", ansonsten wird die rekursion beim Treffer einer unhappy zahl abgebrochen
Global $temp[16], $maxrecurs = 0         ;innerhalb der Rekursion gespeicherte summen


$sieb[1] = 1                             ;Vorbelegung Happy
$sieb[4] = 4                             ;Vorbelegung Unhappy. bei 4 ist die erste Folge mit Endlosschleife, eine Berechnung hätte nur für diese eine Zahl massiven Geschwindigkeitsverlust in der Rekursion bedeutet

AutoItSetOption("MouseCoordMode", 2)
AutoItSetOption("PixelCoordMode", 2)
;~ AutoItSetOption("GUICoordMode",2)

$hgui = GUICreate("", $w, $h)
$hdc = _WinAPI_GetDC($hgui)
$hwnd = WinGetHandle($hgui)
WinSetTitle($hgui, "", "Happy Numbers  0 - " & $w * $h - 1)
$guibkcolor = 0xFFFFFF                   ;hintergrund weiß
$Happycolor = 0xFF00FF                   ;farbe "rosa"^^
GUISetBkColor($guibkcolor, $hwnd)
GUISetState()

$time = TimerInit()

;zuerst das sieb füllen
For $i = 1 To $maxarray - 1              ;erst das maxarray füllen
    If _ishappy($i) Then                 ;happynumber gefunden....
        $sieb[$i] = 1                    ;happynumber ins Sieb eintragen
        For $z = 1 To $maxrecurs         ;alle in den rekursionen gefundene zahlen merken
            $sieb[$temp[$z]] = 1         ;diese Zahl ist auch happy weil führt in der Folge zu 1
        Next
    Else                                 ;keine happynumber gefunden
        $sieb[$i] = $i                   ;dann Zahl als zahl im index ins sieb eintragen
        For $z = 1 To $maxrecurs         ;alle in den rekursionen gefundene zahlen merken
            $sieb[$temp[$z]] = $temp[$z] ;diese Zahl ist auch happy weil führt in der Folge zu 1
        Next
    EndIf
    $maxrecurs = 0                       ;für den nächsten durchlauf löschen
    ;_ArrayDisplay($sieb)
Next


;dann die Grafik erstellen
For $y = 0 To $h - 1                     ;y-koordinate, Bitmaps sind nullbasiert!!
    For $x = $y To $w - 1                ;x-kooedinate ab y heisst nur Bereich über der diagonale
        $i = $y * $w + $x                ;Zahlen von 0 bis $w*$h-1

        ;Quadratsumme der Zahl bilden
        $a = StringSplit($i, "", 2)      ;einzelne ziffern in array
        $quadsum = 0                     ;summe der quadrate der einzelnen ziffern
        For $t = 0 To UBound($a) - 1     ;array nullbasiert
            $m = Number($a[$t])          ;schneller, als von AutoIt casten lassen!
            $quadsum += $m * $m
        Next

        If $sieb[$quadsum] = 1 Then      ;happy gefunden
            $happynumbers += 1           ;...und eins erhöhen
            _WinAPI_SetPixel($hdc, $x, $y, $Happycolor) ;pixel setzen
            If $x <> $y Then             ;der Bereich unter der diagonale
                $happynumbers += 1
                ;$i2 = $x * $w + $y       ;ishappy!!!!
                _WinAPI_SetPixel($hdc, $y, $x, $Happycolor) ;0x00FF00)  ;Farbe ändern um die beiden Bereiche zu trennen
            Else                         ;x=y => Diagonale
                _WinAPI_SetPixel($hdc, $y, $x, 0x0000FF) ;spiegelachse diagonal einfärben
            EndIf
        EndIf
    Next
Next
$m = TimerDiff($time)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $m = ' & $m & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $happynumbers = ' & $happynumbers & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

_ArrayDisplay($sieb)
AutoItSetOption("MouseCoordMode", 2)
AutoItSetOption("PixelCoordMode", 2)

While GUIGetMsg() <> -3
    $posx = MouseGetPos(0)
    $posy = MouseGetPos(1)
    If $posx > 0 And $posy > 0 And $posx <= $w And $posy <= $h Then
        $col = PixelGetColor($posx, $posy, $hwnd)
        $zahl = ($posy - 1) * $w + ($posx - 1)
        ToolTip("x = " & $posx - 1 & @CRLF & _
                "y = " & $posy - 1 & @CRLF & _
                "Zahl  " & $zahl & " ist " & ($col <> $guibkcolor ? "Happy" : "Unhappy"))
    Else
        ToolTip("")
    EndIf
WEnd



Func _ishappy($zahl)                     ;nur um das sieb zu füllen
    $maxrecurs += 1                      ;rekursionstiefe
    $a = StringSplit($zahl, "", 2)       ;einzelne ziffern in array
    $quadsum = 0                         ;summe der quadrate der einzelnen ziffern
    For $t = 0 To UBound($a) - 1         ;array nullbasiert
        $m = Number($a[$t])              ;schneller, als von AutoIt casten lassen!
        $quadsum += $m * $m
    Next
    $temp[$maxrecurs] = $quadsum
    If $sieb[$quadsum] = 1 Then Return True ;happy gefunden
    If $sieb[$quadsum] = $quadsum Then Return False ;bereits als unhappy markiert
    Return _ishappy($quadsum)
EndFunc                                  ;==>_ishappy

Alles anzeigen

//EDIT

Script aktualisiert, es wird nun zuerst das Sieb mit den Happy/Unhappy Zahlen gefüllt, danach muss für jede Zahl nur noch die Quadratsumme ermittelt werden, die der Index für das Sieb ist.

**UEZ**

Coole Analyse Andy ! Die Tatsache der Spiegelung ist definitiv ein Booster bezgl. Performance (keine Impfung ). Mir kam intuitiv die Rekursion als Lösung in den Kopf, aber das Ganze grafisch darzustellen, war mit nicht eingefallen.

**Musashi**

Andy : Wirklich eine coole Analyse . Danke zudem, dass Du die Herleitung so ausführlich beschrieben hast.

**Andy**

Hehe....die "Aufgabe" hat mich an die µ-It hier im Forum erinnert....das ist bestimmt schon 10 Jahre her, oder?!

So etwas sollte/könnte man wieder mal aufleben lassen.

BTT:

Zitat von UEZ

Die Tatsache der Spiegelung ist definitiv ein Booster bezgl. Performance

Ja, mich hat gewundert, dass das noch keiner gemacht hatte, ich habe jedenfalls keine Info darüber gefunden. Daten "grafisch" zu analysieren ist ein uralter Hut, "früher" hatte ich bei Analysen von fremden Programmen einfach die gesamte (*-EXE-) Datei in eine Bitmap gemapped (omg, was ein Wortspiel^^) und diese Bitmap per Programm in diversen Pixelbreiten anzeigen lassen. Da hat man dann feine Sachen gefunden, Zeichensätze, eingebundene Bilder uvm.

Im vorliegenden Fall war ich aber echt überrascht, diese Muster zu finden...naja, wenn man mal bissl nachdenkt, dann ist ja auch klar wo die herkommen.

Die Idee mit dem "kleinen" Array habe ich mir bei einem eigenen Script, dem erweiterten Primzahlensieb (auch ein µ-It gewesen) abgeschaut, mit LUT geht vieles viel schneller und trotz meines biblischen Alters und fortschreitendem Gehirnschwund fallen mir doch noch so manche Tricks ein

Jedenfalls hats Spass gemacht! Danke auch dafür an @SOLVE-SMART!

Ich habe das zum Anlass genommen, wieder mehr mit AutoIt zu machen, hab noch soooo viele Sachen offen, OpenCL und OpenCV, und nicht zuletzt Assembler, habe letzte Woche Kontakt mit Jungs und Mädels aus Jülich gehabt, das ist da wo die RICHTIG DICKEN KISTEN stehen und die werden auch mit auf der letzten Rille optimierten Programmen gefüttert, ggf. werde ich mir da mal den letzten Schliff holen. Die frei verfügbaren Unterlagen dort sichern mir schon die Wochenendlektüre fürs ganze Jahr^^

Wen es interessiert https://www.fz-juelich.de/SharedDocs/Mel…jurecapt16.html

Forschungszentrum Jülich - JSC - Presentations in courses and talks - Slides of the Seminar on Modular Supercomputing Architectures (MSA)

uvm....

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi Leute,

BananaJoe und Lambdax auch eure Lösungsvorschläge liefern das korrekte Ergebnis 👍 . Danke für die weiteren Varianten und an sich für's Mitmachen.

Zitat von BananaJoe

Da die Aufgabenstellung war "von 1 bis 100" kann meine Version auch nur eine begrenzte Anzahl machen (nur bis 3-stellig, also max. 999)

Ich finde es gut, dass du die Problemstellung zunächst so angegangen bist, wie die Aufgabe es verlangte 😀 , auch wenn ein Umbau nötig ist um mit den anderen Versionen mitzuhalten - dennoch sehr "Agile", nice 👍 .

Nun zu dir Andy :

Deine Bezeichnugn "Märchenonkel" klingt super, wird dir aber nicht gerecht - du bist mehr 😁 .
Im ersten Augenblick war ich sprachlos wie viel Kreativität, Energie und Erfahrung in dir und in den Anderen hier stecken => #wow! #ErfürchtigSchauend 😇 .
Nachdem ich deinen Beitrag ein zweites Mal gelesen hatte war ich noch überraschter, denn dein Ansatz/die Umsetzung war absolut verständlich und nachvollziehbar erläutert #HutAb!

Zitat von Andy

Die Idee mit dem "kleinen" Array habe ich mir bei einem eigenen Script, dem erweiterten Primzahlensieb (auch ein µ-It gewesen) abgeschaut, mit LUT geht vieles viel schneller und trotz meines biblischen Alters und fortschreitendem Gehirnschwund fallen mir doch noch so manche Tricks ein [...]

Was soll man dazu sagen? Einfach Danke, konnte herzhaft darüber lachen 😂 👍 .

Zitat von Andy

Jedenfalls hats Spass gemacht! Danke auch dafür an SOLVE-SMART!
Ich habe das zum Anlass genommen, wieder mehr mit AutoIt zu machen [...]

Bitteschön, das freut mich ehrlich ganz besonders!

Viele Grüße

Sven

**Andy**

Hi zusammen....

so ist das mit den Beweihräucherungen....taugt alles nix^^

Ich hatte im vorgestellten Script beim "Verschönern" irrtümlich 3 Zeilen gelöscht....was das Script in seiner Lauffähigkeit zwar nicht beeinflusste, aber die Idee dahinter völlig gegen die Wand fuhr!

Die fehlenden Zeilen waren genau die Schleife, welche die in der Rekursion gefundenen NICHT HAPPY - Zahlen in das Array eintragen.....

AutoIt

        Else                             ;keine happynumber gefunden
            If $i < $maxarray Then
                $sieb[$i] = $i           ;dann Zahl als zahl im index ins sieb eintragen
                For $z = 1 To $maxrecurs ;alle in den rekursionen gefundene zahlen merken
                    $sieb[$temp[$z]] = $temp[$z] ;diese Zahl ist nicht auch nicht happy weil führt in der Folge nicht zu 1
                Next
            EndIf
        EndIf

Ich hab das jetzt im Post ergänzt, wenn man das _Arraydisplay() einkommentiert , sieht man den Unterschied zu vorher...shame on me...aber an euch noch mehr weil es keiner gemerkt hat

//EDIT

Da es sinnvoll ist, erst das Sieb zu füllen und danach erst die Grafik zu erstellen habe ich mich entschlossen, das Script im Post #14 upzugraden.

Was zur annähernden Verdopplung der Geschwindigkeit geführt hat....

**Musashi**

Zitat von Andy

Ich hab das jetzt im Post ergänzt, wenn man das _Arraydisplay() einkommentiert , sieht man den Unterschied zu vorher...shame on me...aber an euch noch mehr weil es keiner gemerkt hat

Wir waren wohl alle noch zu sehr vor Ehrfurcht erstarrt .

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)