Ordner mit laufender Nummer

Zitat von cybexz

Was muss ich ändern damit die NUmmer egal was ich eingebe immer fortlaufend ist?

Du könntest die Nummer z.B. in eine kleine Textdatei (sinnvoll wäre eine INI-Datei) schreiben.

Mit https://autoit.de/onlinehilfe/on…ons/IniRead.htm liest Du den aktuellen Wert, setzt den Zähler +1 (ggf. noch als String mit führenden Nullen umformatieren) und speicherst ihn mit https://autoit.de/onlinehilfe/on…ns/IniWrite.htm wieder ab.

Hi cybexz , willkommen im Forum 👋 .

Musashi hat ganz recht mit der Idee eine INI zu nutzen. Ist eine von mehreren Möglichkeiten, doch in AutoIt sehr einfach und effektiv.
Als kleine Hilfestellung könnte dieser INI Beitrag dienen. Vielleicht hilft es dir ja.

Viele Grüße
Sven

Zunächst einmal machst du auch eine doppelte Erstellung einer Variable (Zeile 5 und 8). Zeile in Zeile 5 auf 0 setzen, Zeile 8 weg lassen.
Dann bedenke bitte, wenn dies dein komplettes Skript ist, das "Local" hier die falsche Wahl ist, sondern "Global" genutzt werden muss, da alle Variablen außerhalb einer Funktion "Global" sind.

Dann ist der Hinweis von Musashi Gold richtig (da einfach umzusetzen).

Dann noch das Format der Nummer, wenn du führende Nullen willst, damit die Sortierung nachher auch passt, verwende StringFormat("%05s", $iNummer), wobei die 5 hier die Anzahl der Stellen angibt.

Ich würde zudem empfehlen eine Fehlerprüfung einzubauen für das Ordner erstellen. Wenn du dafür Hilfe brauchst wie man das machen kann, gerne einfach fragen.

Die Frage, die ich mir noch Stelle, soll das immer nur 1mal durchlaufen und sich danach beenden oder willst du das so lange durchlaufen lassen bis der Benutzer auf "Cancel" drückt oder keine Eingabe macht (oder ein anderer Indikator zutrifft)?

Moin,

weil Du Dich noch in einem frühen Stadium befindest möchte ich Folgendes anmerken:

P202400001
Solltest Du vorhaben, das Jahr in die Nummer aufzunehmen, wäre das 'doppelt gemoppelt', weil das Jahr ja schon im Datum steht ($sDatum = (@YEAR & "-" & @MON & "-" & @MDAY)). Außerdem musst Du dann bedenken, dass Du die laufende Nummer beim ersten Start in 2025 wieder auf 1 setzen musst.

Wofür brauchst Du diese Nummer überhaupt?

Grüße, Velted

Moin Moombas,

Zitat von Moombas

Zunächst einmal machst du auch eine doppelte Erstellung einer Variable (Zeile 5 und 8). Zeile in Zeile 5 auf 0 setzen, Zeile 8 weg lassen.

Wenn man das macht, wird die jeweils erste Datei mit 0 geschrieben. Ich glaube nicht, dass das sein soll.

Zitat von Moombas

Dann bedenke bitte, wenn dies dein komplettes Skript ist, das "Local" hier die falsche Wahl ist, sondern "Global" genutzt werden muss, ...

"muss" ist falsch, weil "Lokale" Variable im "global scope" automatisch "Global" sind. Es schafft allerdings Klarheit.

In etwa so?

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.16.1
 Author:         myName

 Script Function:
	Template AutoIt script.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here
; Variablen definieren
Local $sKundenname = InputBox("WerbaPlast Projekt", "Bitte geben Sie den Kundennamen ein:")
Local $sBasisPfad = "C:\Pfad\Zu\Deinen\Ordnern\" ; Ändere den Pfad entsprechend
Local $sDatum = (@YEAR & "-" & @MON & "-" & @MDAY)

;wenn zaehler.ini noch nicht vorhanden ist
If Not FileExists($sBasisPfad & "zaehler.ini") Then IniWrite($sBasisPfad & "zaehler.ini", "nummer", "neu", "1")

;einlesen der laufenfen nummer aus der ini Datei
Local $iNummer = IniRead($sBasisPfad & "zaehler.ini", "nummer", "neu", "")

; Erstelle den neuen Ordner
Local $sNeuerOrdner = $sBasisPfad & $sKundenname & "_" & $sDatum & "_" & $iNummer
DirCreate($sNeuerOrdner)

; Erstelle den Unterordner "dxf"
DirCreate($sNeuerOrdner & "\dxf")

;einen zähler hoch in der ini
$iNummer = $iNummer+1
$iNummer2 = StringFormat("%05s", $iNummer)
IniWrite($sBasisPfad & "zaehler.ini", "nummer", "neu", $iNummer2)

MsgBox(0, "Ordner erstellt", "Der Ordner wurde erfolgreich erstellt: " & $sNeuerOrdner)

Zitat von Velted

Moin Moombas,

Wenn man das macht, wird die jeweils erste Datei mit 0 geschrieben. Ich glaube nicht, dass das sein soll.

Hmm, ich weiß was du meinst, ist aber in seinem aktuellen Skript der Fall:

;...
Local $iNummer = 1

; Zähle bereits existierende Ordner
Local $iNummer = 0
;...

Davon bin ich ausgegangen aber du hast Recht, soll es mit 1 beginnen, nur Zeile 5 weg lassen

Zitat von Velted

"muss" ist falsch, weil "Lokale" Variable im "global scope" automatisch "Global" sind. Es schafft allerdings Klarheit.

Ja, daher sage ich "muss", weil man sonst durchaus sich wundern könnte das es Nebeneffekte gibt, die bei gleichen Variablennamen (global/local) auftreten können oder eben etwas sonst nicht klappt.
Daher lieber "muss" es ordentlich definieren anstatt "kann" und dann später alles Nacharbeiten etc. bei der Fehlersuche.

Zitat von cybexz

mein Problem ist die laufende NUmmer ich schaffe es das der Ordner richtig erstellt wird, der zweite erstellte Ordner mit gleichen NAMEN hat dann die 00002.

Stelle ich aber einen anderen NAmen ein beginnt wieder die 00001.

Was muss ich ändern damit die NUmmer egal was ich eingebe immer fortlaufend ist?

Hier muss nochmal genau nachgefragt werden:
Du möchtest die Fortzählung der Suffix-Zahl unabhängig vom Namenspräfix haben - korrekt?
Also wenn man 2 mal "Test" als Namen wählt und 1 mal "Spaß", dann möchtest du folgende 3 Ordner:

• Test_2024-12-09_00001
• Test_2024-12-09_00002
• Spaß_2024-12-09_00003

Die noch nicht ganz geklärte Frage wäre dann noch folgende: Soll diese Nummer auch unabhängig vom Datumsteil sein?
Also beginnt die Zählung mit jedem Datum neu oder wird sie auch datumsübergreifend fortgeführt?

Zur Umsetzung bist du eigentlich gar nicht so weit weg gewesen bisher.
Aktuell hast du nur die Ordner auf Existenz geprüft, welche dem aktuellen Namensschema entsprechen.
Daher wird logischerweise nur die Höchste Nummer für diese Namen ermittelt.

Was du also anpassen müsstest, wäre die Ermittlung der höchsten Nummer so zu gestalten, dass über alle existieren Ordner im Verzeichnis gesucht wird.
Hier kannst du dann entweder den Datumsteil noch mit berücksichtigen - oder eben nicht - je nach dem was gewünscht ist.

umgesetzt:

; Variablen definieren
Global $sKundenname = InputBox("WerbaPlast Projekt", "Bitte geben Sie den Kundennamen ein:")
Global $sBasisPfad = "C:\Pfad\Zu\Deinen\Ordnern" ; Ändere den Pfad entsprechend
Global $sDatum = (@YEAR & "-" & @MON & "-" & @MDAY)

; Höchste bisher vergebene Ordnernummer ermitteln
Global $iNummer, $iMaxNummer = 0, $sOrdner
Global $hFFFF = FileFindFirstFile($sBasisPfad & "\*" & $sDatum & "_*")
Do ; alle Ordnernamen mit dieser Struktur einzeln durchgehen
	$sOrdner = FileFindNextFile($hFFFF)
	If @error Then ExitLoop ; keine Dateien mehr übrig
	If Not @extended Then ContinueLoop ; nur Ordner - keine Dateien

	; Nummer aus dem Dateinamen extrahieren (geht auch z.b. mit StringRegExp)
	$iNummer = Number(StringTrimLeft($sOrdner, StringInStr($sOrdner, "_", 1, -1)))
	If $iNummer > $iMaxNummer Then $iMaxNummer = $iNummer
Until 0

; Erstelle den neuen Ordner
Global $sNeuerOrdner = StringFormat("%s\\%s_%s_%05d", $sBasisPfad, $sKundenname, $sDatum, $iMaxNummer + 1)
DirCreate($sNeuerOrdner)

; Erstelle den Unterordner "dxf"
DirCreate($sNeuerOrdner & "\dxf")

MsgBox(0, "Ordner erstellt", "Der Ordner wurde erfolgreich erstellt: " & $sNeuerOrdner)

Zitat von cybexz

Nein die Zählung ist Datumsübergreifend, also quasi immer weiter.

Dann musst du wie gesagt, noch das Datum aus dem Pattern bei FileFindFirstFile entfernen.
So wie es jetzt dasteht ist es Datumsabhängig.

Wenn sicher gestellt ist das in dem Zielordner keine anderen Verzeichnisse vorhanden sind, kann man mit _FileListToArray ($sBasisPfad, "*." ,2 ) die Anzahl der Ordner ermitteln und dadurch die nächste freie fortlaufende Nummer ermitteln.

Bei ein paar hundert Verzeichnissen wird das egal sein, überhaupt wenn sie lokal liegen, aber wenn das mal auf einen Fileshare liegt von dem ich durch einen VPN-Tunnel auf die Firmendaten zugreiffe und dort liegen einige 10000 Ordner könnte das einen gewissen Geschwindigkeitsvorteil bringen...

lg
Racer

Zitat von Racer

Wenn sicher gestellt ist das in dem Zielordner keine anderen Verzeichnisse vorhanden sind, kann man mit _FileListToArray ($sBasisPfad, "*." ,2 ) die Anzahl der Ordner ermitteln und dadurch die nächste freie fortlaufende Nummer ermitteln.

Bei ein paar hundert Verzeichnissen wird das egal sein, überhaupt wenn sie lokal liegen, aber wenn das mal auf einen Fileshare liegt von dem ich durch einen VPN-Tunnel auf die Firmendaten zugreiffe und dort liegen einige 10000 Ordner könnte das einen gewissen Geschwindigkeitsvorteil bringen...

lg
Racer

Ich würde (aber das ist meine bescheidene Meinung ohne Hintergründe zu kennen), so oder so für jeden Kunden einen Unterordner erstellen und dort dann die Dateien ablegen. Dann ist es eine saubere Ordnung und minimiert die Anzahl der Dokumente enorm die in einem Ordner liegen.

Bin da voll bei Dir Moombas, aber manchmal muss man sich nach der Decke strecke. So manche Vorgaben von Andere provozieren bei mir auch immer nur ein Kopfschütteln....

Daher habe ich das ganze etwas eingeschränkt:

Zitat von Moombas

...ohne Hintergründe zu kennen...

Also ich würde die Nummer einfach in eine *.ini schreiben.

Das ist:

1) Ordner unabhängig

2) SpeicherMedium unabhängig

3) Flexibel, da man jederzeit die "Start Nummer" ändern kann

usw. usw.

Peter