Code Kata - Galgenraten

**Mars**

Zitat von AspirinJunkie

Die Anzahl der Versuche richtet sich nach dem zufällig ausgewähltem Wort:
Mein Vorschlag (mit nicht ganz trivialer Stochastik) zur Berechnung der Anzahl der Fehlversuche wäre daher hierzu folgender:

Da habe ich direkt an folgende Methode gedacht:
Die Entropie eines Worts ist (ungefähr) proportional zur Anzahl Bits, die eine Huffman-Kodierung (mit einem Tree der mit Wahrscheinlichkeiten für deutsche Buchstaben erstellt wurde) von diesem Wort ergibt. Mit unseren bereits implementierten Huffman-Kodierern sollte das trivial machbar sein (bzw. einfach mit der Entropieformel und der Wahrscheinlichkeitsverteilung der Buchstaben, den Kodierer braucht man ja nicht).

Ein Problem ist natürlich, dass beim Galgenraten automatisch "alle" Vorkommen des Buchstabens und nicht nur das erste aufgedeckt werden, sodass die reine Entropie hier einen "zu großen" Wert liefert. Vermutlich reicht es das Wort auf die ersten Vorkommnisse zusammenzustauchen: "vorkommnisse" -> "vorkmnise", und dann die Entropie zu berechnen. Der Wert dafür müsste eigentlich ein guter Indikator dafür sein wie kompliziert es ist das Wort "zufällig, aber mit dem Wissen über die Buchstabenverteilung" zu erraten.

In deiner stochastischen Analyse gehst du von einer Gleichverteilung der Buchstaben aus. Das sollte ein wenig zu kleine Ergebnisse liefern. Vielleicht kann man das irgendwie kombinieren und den "Ultimativen Galgenraten Versuchsanzahl Abschätzer" entwickeln

lg

M

**AspirinJunkie**

Ich dachte schon ich übertreibe bisschen mit meinem Anspruch das etwas fundierter zu berechnen aber ich hatte wie so oft nicht mit dir gerechnet...

Zitat von Mars

In deiner stochastischen Analyse gehst du von einer Gleichverteilung der Buchstaben aus. Das ist quasi "genau in die andere Richtung" und sollte ein wenig zu kleine Ergebnisse liefern.

Ja das stimmt tatsächlich und ging mir auch durch den Kopf.
Das habe ich allerdings überhaupt nicht in Angriff genommen, da ich schon mit der einfacheren Stochastik hier zu kämpfen hatte.
Das Problem ist nämlich kniffliger als man erst annimmt. Das Problem ist, dass die Anzahl der Versuche nicht fest ist, sondern nur bei Fehlversuchen gezählt werden.
Am Ende habe ich einen Ansatz gefunden, welcher halbwegs stimmen sollte aber der Einfachheit halber, habe ich auch hier einen bestimmten Aspekt unterschlagen so dass die Wahrscheinlichkeiten nicht die 100% korrekten darstellen.
Um deine Erweiterung mit den Buchstabenhäufigkeiten noch zu verkomplizieren mal noch ein anderer Gedanke hierzu:
Prinzipiell müsste man erst einmal ermitteln mit welcher Wahrscheinlichkeit Nutzer Buchstaben zufällig auswählen.
Dies unterscheidet sich ja noch von der tatsächlichen Buchstabenhäufigkeit für die es bereits hinreichende empirische Daten gibt.

**Mars**

(Ich habe meinen Beitrag noch 5x editiert, aber da war die Antwort schon da )

Je komplizierter desto besser. Hmm... stimmt. Die Entropie muss auch noch an anderer Stelle ergänzt werden, weil die "Ziehungen" nicht unabhängig voneinander sind (es ist ja eine Ziehung ohne Zurücklegen) was in der Entropie nicht berücksichtigt wird... (also Wahrscheinlichkeitsverteilung nach jedem Schritt renormieren). Und dann noch das mit den Fehlversuchen die man erst weiß nachdem man danebenlag... Und die Wahrscheinlichkeitsverteilung von Nutzereingaben die sich von der üblichen Buchstabenhäufigkeit unterscheidet...

Ich glaube das wird mir zu kompliziert.

**Schnuffel**

und ich dachte wir proggen mal ein "kleines" Spielchen

PS: Eure Ansätze der Wahrscheinlichkeit geht weit über das geforderte Ziel hinaus und schreckt mögliche Interessenten eher ab.

Ich hatte das "nur nebenbei" und auch nur mit einem Auge gelesen und umgesetzt.
Wenn ihr mit solchen Ansätzen um die Ecke kommt crasht Ihr m.M.n. die Aufgabe und ich verabschiede mich wieder aus dem Kontest.

**Mars**

Das ist doch alles nur Spaß

**Moombas**

Hmm, ich komme nicht drumrum das ich durchaus auch über einen dynamisch berechneten Wert für die Versuche nachgedacht habe, es aber verworfen habe und bei Stochastik wäre ich definitiv raus

**Alina**

Ich liebe dieses Game. Früher haben wir es (sinngemäß) übersetz als "Rateklaus" genannt.

BananaJoe

Zitat von Schnuffel

...
PS: Eure Ansätze der Wahrscheinlichkeit geht weit über das geforderte Ziel hinaus und schreckt mögliche Interessenten eher ab.
...

Ich bin momentan beruflich sehr eingespannt, so dass ich nicht mitmachen kann, aber ich finde so etwas immer sehr inspirierend.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von MojoeB

^^^ich habe mir grad eben erst dein video angesehen hoffe dich stört die gui nicht^^.

Hi MojoeB 👋 , erstmal auch dir Danke für deine Einsendung.
Ich habe mir weder deinen Code noch die GUI angeschaut, bin mir aber sicher das es mich nicht stören wird 😅 .

Ich melde mich bei Gelegenheit mit einer zusammenfassenden Auswertung. Bitte nicht zu viel dazu erwarten, es soll nur ein paar Dinge beleuchten und keine akademische Analyse werden 😂 . Also, Danke und bis später.

Viele Grüße
Sven

**Kanashius**

Ich hab mich jetzt auch mal an die GUI gemacht
Vielleicht habt ihr ja mehr Glueck als ich

AutoIt

#AutoIt3Wrapper_Change2CUI=y
#pragma compile(Console, true)
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <WinAPISysWin.au3>
Opt("GUIOnEventMode", 1)

Global $bConsole = false ; Change to True to enable console mode
Global $bGui = true, $bShowFps = False, $mData[]

If $bGui Then
	_startGui()
Else
	_startConsoleGame()
EndIf

Func _WordList()
    Local Const $aList[] = _
        [ _
            'autoit', _
            'c#', _
            'go', _
            'java', _
            'javascript', _
            'matlab', _
            'php', _
            'python', _
            'ruby', _
            'sql' _
        ]

    Return $aList
EndFunc


Func _startConsoleGame()
	While True
		_startGame(_initGame())
		If @error Then ExitLoop
		$sRequest = _readInput($bConsole, "Möchtest du nocheinmal spielen? Ja (y) or Nein (n)?")
		If $sRequest<>"y" Then ExitLoop
	WEnd
EndFunc

Func _startGui()
	_GDIPlus_Startup()
	_startNewGuiGame()
	$mData["width"] = 800
	$mData["height"] = 600
	$mData["hwnd"] = GUICreate("Galgenraten", $mData.width, $mData.height)
	GUISetOnEvent($GUI_EVENT_CLOSE, "_close", $mData.hwnd)
	GUISetState(@SW_SHOW, $mData.hwnd)

	Local $iInputWidth = 300, $iBtnWidth = 70, $iGap = 5, $iRowWidth = $iInputWidth+$iBtnWidth*2+$iGap*2, $iInputHeight = $mData.height-100
	$mData["gallowsStartX"] = $mData.width/2
	$mData["gallowsStartY"] = $mData.height-$iInputHeight-$iGap
	$mData["gallowsStrength"] = 10
	$mData["inputSend"] = GUICtrlCreateInput("", ($mData.width-$iRowWidth)/2, $iInputHeight, $iInputWidth, 35)
	GUICtrlSetState($mData.inputSend, $GUI_FOCUS)
	GUICtrlSetFont(-1,20)
	GUICtrlSetBkColor(-1, 0x00BB00)
	$mData["btnSend"] = GUICtrlCreateButton("Send", ($mData.width-$iRowWidth)/2+$iInputWidth+$iGap, $iInputHeight, $iBtnWidth, 35)
	GUICtrlSetFont(-1,20)
	GUICtrlSetBkColor(-1, 0x00BB00)
	GUICtrlSetOnEvent($mData.btnSend, "_letterSend")
	$mData["btnNew"] = GUICtrlCreateButton("New", ($mData.width-$iRowWidth)/2+$iInputWidth+$iGap*2+$iBtnWidth, $iInputHeight, $iBtnWidth, 35)
	GUICtrlSetBkColor(-1, 0x00BB00)
	GUICtrlSetFont(-1,20)
	GUICtrlSetOnEvent($mData.btnNew, "_startNewGuiGame")
	Local $arAccellerators = [["{ENTER}", $mData.btnSend]]
	GUISetAccelerators($arAccellerators)


	$mData["graphicGui"] = _GDIPlus_GraphicsCreateFromHWND($mData.hwnd)
	$mData["bitmap"] = _GDIPlus_BitmapCreateFromGraphics($mData.width, $mData.height, $mData.graphicGui)
	$mData["graphic"] = _GDIPlus_ImageGetGraphicsContext($mData.bitmap)
	_GDIPlus_GraphicsSetSmoothingMode($mData.graphic, 2)
	$mData["bgBitmap"] = _GDIPlus_BitmapCreateFromGraphics($mData.width, $mData.height, $mData.graphic)
	$mData["bgGraphic"] = _GDIPlus_ImageGetGraphicsContext($mData.bgBitmap)
	_GDIPlus_GraphicsSetSmoothingMode($mData.bgGraphic, 2)
	$mData["penGarrows"] = _GDIPlus_PenCreate(0xFFBB8800, Int($mData.gallowsStrength))
	$mData["penPerson"] = _GDIPlus_PenCreate(0xFF000000, Int($mData.gallowsStrength/2))
	$mData["brushGras"] = _GDIPlus_BrushCreateSolid(0xFF00BB00)
	$mData["brushSun"] = _GDIPlus_BrushCreateSolid(0xFFFFFFF00)
	$mData["brushClouds"] = _GDIPlus_BrushCreateSolid(0xFFEEEEEE)
	$mData["brushRed"] = _GDIPlus_BrushCreateSolid(0xFFFF0000)
	_drawBackground($mData)
	_updateDrawingRegion($mData)

	Local $mDrawData[]
	$mData["drawData"] = $mDrawData
	$mData["drawData"]["sec"] = @SEC
	$mData["drawData"]["frames"] = 0
	$mData["drawData"]["oldFrames"] = 0

	While True
		If $mData.drawData.sec<>@SEC Then
			$mData.drawData.oldFrames = $mData.drawData.frames
			$mData.drawData.frames = 0
			$mData.drawData.sec = @SEC
		EndIf
		; _drawBackground($mData) ; look at the cool background randomization :P
		_drawGui($mData)
		$mData.drawData.frames += 1
	WEnd
EndFunc

Func _startNewGuiGame()
	Local $mGameData = _initGame()
	$mData["gameData"] = $mGameData
	$mData.gameData.left = 10
	$mData["gameData"]["success"] = False
	GUICtrlSetState($mData.inputSend, $GUI_ENABLE)
	GUICtrlSetState($mData.btnSend, $GUI_ENABLE)
	GUICtrlSetState($mData.inputSend, $GUI_FOCUS)
EndFunc

Func _letterSend()
	Local $sInput = StringLower(GUICtrlRead($mData.inputSend))
	GUICtrlSetData($mData.inputSend, "")
	If $sInput<>"" And Not $mData.gameData.success Then
		If StringLen($sInput)>1 Then
			If StringLower($mData.gameData.word)=$sInput Then
				$mData.gameData.success = True
				$mData.gameData.left = 0
			Else
				$mData.gameData.left -= 1
			EndIf
		Else
			If Not MapExists($mData.gameData.tries, $sInput) Then
				$mData["gameData"]["tries"][$sInput] = $sInput
				If Not StringInStr(StringLower($mData.gameData.word), $sInput) Then $mData.gameData.left -= 1
			EndIf
		EndIf
		If _isWordGuessed($mData.gameData) Then
			$mData.gameData.success = True
			$mData.gameData.left = 0
		EndIf
	EndIf
	If $mData.gameData.success or $mData.gameData.left = 0 Then
		GUICtrlSetState($mData.inputSend, $GUI_DISABLE)
		GUICtrlSetState($mData.btnSend, $GUI_DISABLE)
	EndIf
EndFunc

Func _updateDrawingRegion(ByRef $mData)
	Local $hRegion = _GDIPlus_RegionCreateFromRect(0, 0, $mData.width, $mData.height)
	Local $hChild = _WinAPI_GetWindow($mData.hwnd, $GW_CHILD)
	Local $aRect
	Do
		$aRect = ControlGetPos($hChild, "", 0)
		_GDIPlus_RegionCombineRect($hRegion, $aRect[0], $aRect[1], $aRect[2], $aRect[3], 3)
		$hChild = _WinAPI_GetWindow($hChild, $GW_HWNDNEXT)
	Until Not $hChild
	_GDIPlus_GraphicsSetClipRegion($mData.graphicGui, $hRegion)
	_GDIPlus_RegionDispose($hRegion)
EndFunc

Func _drawGui(ByRef $mData)
	_GDIPlus_GraphicsDrawImageRect($mData.graphic, $mData.bgBitmap, 0, 0, $mData.width, $mData.height)
	Local $iGallowsHeight = $mData.height*0.3, $iGallowsWidth = $mData.width*0.15
	If Not $mData.gameData.success Then
		If $mData.gameData.left < 10 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $mData.gallowsStartX, $mData.gallowsStartY+1, $mData.gallowsStartX, $mData.gallowsStartY-$iGallowsHeight, $mData.penGarrows)
		If $mData.gameData.left < 9 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $mData.gallowsStartX-$mData.gallowsStrength/2, $mData.gallowsStartY-$iGallowsHeight, $mData.gallowsStartX+$iGallowsWidth-$mData.gallowsStrength/2, $mData.gallowsStartY-$iGallowsHeight, $mData.penGarrows)
		If $mData.gameData.left < 8 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $mData.gallowsStartX+$iGallowsWidth-$mData.gallowsStrength, $mData.gallowsStartY-$iGallowsHeight, $mData.gallowsStartX+$iGallowsWidth-$mData.gallowsStrength, $mData.gallowsStartY-$iGallowsHeight*0.8, $mData.penGarrows)
		If $mData.gameData.left < 7 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $mData.gallowsStartX, $mData.gallowsStartY-$iGallowsHeight+$iGallowsHeight*0.2, $mData.gallowsStartX+$iGallowsHeight*0.2,$mData.gallowsStartY-$iGallowsHeight, $mData.penGarrows)
	EndIf
	Local $iPersonMid = $mData.gallowsStartX+$iGallowsWidth-$mData.gallowsStrength, $iPersonTop = $mData.gallowsStartY-$iGallowsHeight*0.8, $iFactor = 0
	If $mData.gameData.success Then
		$iPersonMid = $mData.gallowsStartX
		$iFactor = 0.2
	ElseIf $mData.gameData.left = 0 Then
		_GDIPlus_GraphicsFillEllipse($mData.graphic, $iPersonMid-$iGallowsHeight*0.1, $iPersonTop, $iGallowsHeight*0.2, $iGallowsHeight*0.2, $mData.brushRed)
	EndIf
	If $mData.gameData.left < 6 Then _GDIPlus_GraphicsDrawEllipse($mData.graphic, $iPersonMid-$iGallowsHeight*0.1, $iPersonTop, $iGallowsHeight*0.2, $iGallowsHeight*0.2, $mData.penPerson)
	If $mData.gameData.left < 5 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $iPersonMid, $iPersonTop+$iGallowsHeight*0.2, $iPersonMid, $iPersonTop+$iGallowsHeight*0.6, $mData.penPerson)
	If $mData.gameData.left < 4 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $iPersonMid, $iPersonTop+$iGallowsHeight*0.6, $iPersonMid-$iGallowsWidth*0.2, $iPersonTop+$iGallowsHeight*0.8, $mData.penPerson)
	If $mData.gameData.left < 3 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $iPersonMid, $iPersonTop+$iGallowsHeight*0.6, $iPersonMid+$iGallowsWidth*0.2, $iPersonTop+$iGallowsHeight*0.8, $mData.penPerson)
	If $mData.gameData.left < 2 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $iPersonMid, $iPersonTop+$iGallowsHeight*0.3+$iGallowsWidth*$iFactor, $iPersonMid-$iGallowsWidth*0.2, $iPersonTop+$iGallowsHeight*0.5-$iGallowsHeight*$iFactor, $mData.penPerson)
	If $mData.gameData.left < 1 Then _GDIPlus_GraphicsDrawLine($mData.graphic, $iPersonMid, $iPersonTop+$iGallowsHeight*0.3+$iGallowsWidth*$iFactor, $iPersonMid+$iGallowsWidth*0.2, $iPersonTop+$iGallowsHeight*0.5-$iGallowsHeight*$iFactor, $mData.penPerson)

	Local $iLetterWidth = $mData.height*0.066, $iLetterMid = Int($mData.width/2), $iLetters = StringLen($mData.gameData.word), $iLetterLeft = $iLetterMid - Int(($iLetterWidth*$iLetters)/2)
	For $i=0 To Ubound($mData.gameData.letters)-1 Step 1
		Local $sString = MapExists($mData.gameData.tries, $mData.gameData.letters[$i])?$mData.gameData.letters[$i]:"_"
		If $mData.gameData.left = 0 Then $sString = $mData.gameData.letters[$i]
		_GDIPlus_GraphicsDrawString($mData.graphic, $sString, $iLetterLeft+$i*$iLetterWidth, $mData.height*0.2, Default, $mData.height*0.033)
	Next

	If $bShowFps Then _GDIPlus_GraphicsDrawString($mData.graphic, $mData.drawData.oldFrames, $mData.width-5-8*StringLen($mData.drawData.oldFrames), 5)
	_GDIPlus_GraphicsDrawImageRect($mData.graphicGui, $mData.bitmap, 0, 0, $mData.width, $mData.height)
EndFunc

Func _drawBackground(ByRef $mData)
	_GDIPlus_GraphicsClear($mData.bgGraphic, 0xFF33BBFF)
	; hills
	Local $iHills = 5, $iHillsHeight = $mData.height*0.25, $iHillsStart = $mData.height - $iHillsHeight, $iHillWidth = Int($mData.width/$iHills), $iHillMaxHeight = $mData.height*0.05
	If Mod($iHillMaxHeight, 2)>0 Then $iHills+=1 ; make sure amount of hills is odd
	Local $arHillPoints[5+$iHills*2][2]
	$arHillPoints[0][0] = UBound($arHillPoints)-1
	$arHillPoints[1][0] = -10
	$arHillPoints[1][1] = $iHillsStart
	$arHillPoints[UBound($arHillPoints)-3][0] = $mData.width + 10
	$arHillPoints[UBound($arHillPoints)-3][1] = $iHillsStart
	$arHillPoints[UBound($arHillPoints)-2][0] = $mData.width + 10
	$arHillPoints[UBound($arHillPoints)-2][1] = $mData.height + 10
	$arHillPoints[UBound($arHillPoints)-1][0] = -10
	$arHillPoints[UBound($arHillPoints)-1][1] = $mData.height + 10
	For $i=2 to UBound($arHillPoints)-4 Step 2
		Local $iLeft = (($i-2)/2)*$iHillWidth
		$arHillPoints[$i][0] = Random($iLeft-Int($iHillWidth*0.1), $iLeft+Int($iHillWidth*0.1), 1)
		$arHillPoints[$i][1] = $iHillsStart
		$arHillPoints[$i+1][0] = Random($arHillPoints[$i][0] + ($iHillWidth/2) -Int($iHillWidth*0.1), $arHillPoints[$i][0] + ($iHillWidth/2) +Int($iHillWidth*0.1), 1)
		$arHillPoints[$i+1][1] = $iHillsStart-Random(Int($iHillMaxHeight*0.2), Int($iHillMaxHeight*0.6), 1)
	Next
	Local $iMidHill = 1+Int((UBound($arHillPoints)-4)/2)
	$arHillPoints[$iMidHill][0] = (($iMidHill-2)/2)*$iHillWidth
	$arHillPoints[$iMidHill][1] = $iHillsStart
	$arHillPoints[$iMidHill+1][0] = $arHillPoints[$iMidHill][0] + ($iHillWidth/2)
	$arHillPoints[$iMidHill+1][1] = $iHillsStart-$iHillMaxHeight
	$mData.gallowsStartX = $arHillPoints[$iMidHill+1][0]
	$mData.gallowsStartY = $arHillPoints[$iMidHill+1][1]
	_GDIPlus_GraphicsFillClosedCurve($mData.bgGraphic, $arHillPoints, $mData.brushGras)

	; sun
	Local $iSunRadius = $mData.width*0.1, $iSunGap = 20 ; percent
	_GDIPlus_GraphicsFillEllipse($mData.bgGraphic, $mData.width-$iSunRadius-$iSunGap, $iSunGap, $iSunRadius, $iSunRadius, $mData.brushSun)

	; clouds
	Local $iClouds = 3, $iCloudWidth = (($mData.width-$iSunRadius-$iSunGap*2)/$iClouds), $iCloudGap = $mData.height*0.083, $iCloudRadius = $mData.width*0.03, $iCloudWidth2=$iCloudWidth/2, $iCloudWidth3=$iCloudWidth/4
	For $i=0 to $iClouds-1 Step 1
		For $j=0 to 7 Step 1
			Local $iX = $i*$iCloudWidth+$iCloudWidth2-$iCloudGap/2
			Local $iY = $iCloudGap
			Local $iWidth = $iCloudRadius*3
			Local $iHeight = $iCloudRadius
			_GDIPlus_GraphicsFillEllipse($mData.bgGraphic, Random($iX-$iCloudWidth3,$iX+$iCloudWidth3,1), $iY+Random(0,$iCloudRadius,1), $iWidth, $iHeight, $mData.brushClouds)
		Next
	Next
EndFunc

Func _close()
	_GDIPlus_BrushDispose($mData.brushGras)
	_GDIPlus_BrushDispose($mData.brushSun)
	_GDIPlus_BrushDispose($mData.brushClouds)
	_GDIPlus_BrushDispose($mData.brushRed)
	_GDIPlus_PenDispose($mData.penGarrows)
	_GDIPlus_PenDispose($mData.penPerson)
	_GDIPlus_BitmapDispose($mData.bitmap)
	_GDIPlus_GraphicsDispose($mData.graphic)
	_GDIPlus_GraphicsDispose($mData.graphicGui)
	_GDIPlus_Shutdown()
	GUIDelete($mData.hwnd)
	Exit
EndFunc

Func _initGame()
	Local $mGameData[]
	$mGameData["word"] = _selectWord()
	$mGameData["letters"] = StringSplit(StringLower($mGameData.word), "", BitOR(1,2))
	Local $mTries[]
	$mGameData["tries"] = $mTries
	$mGameData["left"] = StringLen($mGameData.word)*2
	return $mGameData
EndFunc

Func _startGame(ByRef $mGameData)
	ConsoleWrite("+---------------+"&@crlf)
	ConsoleWrite("|--GALGENRATEN--|"&@crlf)
	ConsoleWrite("+---------------+"&@crlf&@crlf)

	ConsoleWrite("Errate ein Wort mit "&StringLen($mGameData.word)&" Buchstaben "&_generateOutput($mGameData)&" , aus der Kategorie Software Entwicklung."&@crlf)
	ConsoleWrite("Du hast "&$mGameData.left&" Versuche, jeder falsche Buchstabe reduziert deine Versuche."&@crlf)

	Local $bSuccess = False
	While $mGameData.left>=0
		Local $sInput = _requestNextLetter($bConsole)
		If @error Then Return SetError(1, @error&":"&@extended, -1)
		$sInput = StringLower($sInput)
		If StringLen($sInput)>1 Then
			If StringLower($mGameData.word)=StringLower($sInput) Then
				$bSuccess = True
				ExitLoop
			EndIf
			$mGameData.left-=1
		Else
			If Not MapExists($mGameData.tries, $sInput) Then
				$mGameData["tries"][$sInput] = $sInput
				If Not StringInStr(StringLower($mGameData.word), StringLower($sInput)) Then $mGameData.left-=1
			EndIf
		EndIf
		If _isWordGuessed($mGameData) Then
			$bSuccess = True
			ExitLoop
		EndIf
		If $mGameData.left>=0 Then ConsoleWrite("Wort: "&_generateOutput($mGameData)&"("&$mGameData.left&" Versuche noch)"&@crlf)
	WEnd
	ConsoleWrite(@crlf)
	If $bSuccess Then
		ConsoleWrite("Gewonnen! "&$mGameData.left&" Versuche übrig, gut gemacht."&@crlf)
	Else
		ConsoleWrite("Verloren! Das gesuchte Wort war """&$mGameData.word&"""."&@crlf)
	EndIf
EndFunc

Func _isWordGuessed(ByRef $mGameData)
	For $i=0 To Ubound($mGameData.letters)-1 Step 1
		If Not MapExists($mGameData.tries, $mGameData.letters[$i]) Then return False
	Next
	return True
EndFunc

Func _generateOutput(ByRef $mGameData)
	Local $sResult = ""
	For $i=0 To Ubound($mGameData.letters)-1 Step 1
		If $i<>0 Then $sResult&=" "
		$sResult&=MapExists($mGameData.tries, $mGameData.letters[$i])?$mGameData.letters[$i]:"_"
	Next
	return $sResult
EndFunc

Func _selectWord()
	Local $arWords = _WordList()
	return $arWords[Random(0 ,UBound($arWords)-1 , 1)]
EndFunc

Func _requestNextLetter($bConsole=False)
	Local $sResult = _readInput($bConsole)
	If @error Then return SetError(1, @error, "")
	While $sResult = ""
		$sResult = _readInput($bConsole, "Es muss mindestens ein Zeichen eingegeben werden. Versuch es noch einmal: ")
		If @error Then return SetError(1, @error, "")
	WEnd
	return $sResult
EndFunc

Func _readInput($bConsole=False, $sText=Default, $sTitle=Default)
	If $sText = Default Then $sText = "Gib einen Buchstaben oder ein Wort ein: "
	If $sTitle = Default Then $sTitle = "Galgenraten"
	If $bConsole Then
		ConsoleWrite($sText)
		Local $sInput = ""
		While sleep(100)
			$sInput = ConsoleRead()
			If @error Then
				ConsoleWriteError("Error reading from console input. Maybe the console does not provide an STDIN."&@crlf)
				return SetError(1, 0, "")
			EndIf
			If @extended > 0 Then ExitLoop
		WEnd
		return StringReplace($sInput, @crlf, "")
	Else
		return InputBox($sTitle, $sText)
	EndIf
EndFunc

Alles anzeigen

**Moombas**

Ich habe bei der GUI bewusst auf den "echten Galgen" verzichtet, da dies noch sehr weit greifende Anpassungen erfordern würde, besonders wenn die Anzahl der Versuche dynamisch ist.

MojoeB

@ Kanashius

cool :)! mit _GDIPlus_ hab ich noch nie gearbeitet.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Ach wie kreativ ihr doch seid 👌 . Richtig cool dies so zu beobachten, wie aus 'ner kleinen "Übung", wieder einmal solche ... "ich kann das auch noch ausbauen und dann so" ... Aktionen entstehen. Danke und Lob an alle hier Teilnehmenden 🤝 .

Ein Feedback zum bisher gezeigten folgt auch noch sobald es die Zeit hergibt und ich den Fokus wieder darauf setzen kann.
Einen angenehmen Abend euch allen noch.

Viele Grüße
Sven

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)