AutoIt-Hackathon #1 "Mitarbeiter-ID" abgeschlossen

Global $LineStart = @ScriptLineNumber
Func _CreateID($aUserdata)
	Local $Return
	$Return = StringLeft(StringReplace($aUserdata[2], "-", "") & "99999", 5) & _
			StringMid($aUserdata[3], 9, 1) & _
			($aUserdata[4] = "W" ? (StringMid($aUserdata[3], 4, 1) + 5 ) & StringMid($aUserdata[3], 5, 1) : StringMid($aUserdata[3], 4, 2)) & _
			StringMid($aUserdata[3], 1, 2) & _
			StringRight($aUserdata[3], 1) & _
			StringLeft($aUserdata[0], 2) & ($aUserdata[1] = "" ? 99 : StringLeft($aUserdata[1], 2))
	Local $iQuersumme = 0
	For $iChar In StringToASCIIArray($Return)
		$iQuersumme += $iChar
	Next	
	Do 
		$iQuersummeAlt = $iQuersumme
		$iQuersumme = 0
		For $iZiffer In StringSplit($iQuersummeAlt, "",2)
			$iQuersumme += $iZiffer
		Next
	Until StringLen($iQuersumme) < 2
	$Return &= $iQuersumme
	Return $Return
EndFunc   ;==>_CreateID
Global $LineEnd = @ScriptLineNumber

Func _CreateID($aUserdata)
	Local $Return
	$Return = StringLeft($aUserdata[2] & '99999', 5)
	$Return &= StringLeft(StringRight(StringSplit($aUserdata[3], '.', 2)[2], 2), 1)
	$Return &= StringRight('0' & StringSplit($aUserdata[3], '.', 2)[1] + 50 * ($aUserdata[4] = 'W'), 2)
	$Return &= StringSplit($aUserdata[3], '.', 2)[0]
	$Return &= StringRight(StringSplit($aUserdata[3], '.', 2)[2], 1)
	$Return &= StringLeft($aUserdata[0], 1) & ($aUserdata[1] ? StringLeft($aUserdata[1], 1) : '9')
	Local $q = 0, $a = StringSplit($Return, '', 2)
	For $i = 0 To UBound($a) - 1 Step 1
		$a[$i] = Asc($a[$i])
	Next
	While UBound($a) > 1
		For $i = 0 To UBound($a) - 1 Step 1
			$q += $a[$i]
		Next
		$a = StringSplit($q, '', 2)
		$q = 0
	WEnd
	$Return &= $a[0]
	Return $Return
EndFunc

Func _CreateID($aUserdata)
	Local $Return
	Local $Return = StringLeft(StringReplace($aUserdata[2], "-", ""), 5)
	While StringLen($Return)<5
		$Return &= "9"
	WEnd
	Local $arBirthDate = StringRegExp($aUserdata[3], "(\d+).(\d+).\d{2}(\d)(\d)", 1)
	$Return &= $arBirthDate[2]
	If $aUserdata[4]="M" Then
		$Return &= $arBirthDate[1]
	Else
		$Return &= Int($arBirthDate[1])+50
	EndIf
	$Return &= $arBirthDate[0]
	$Return &= $arBirthDate[3]
	$Return &= StringLeft($aUserdata[0], 2)
	Local $sVName2 = StringLeft($aUserdata[1], 2)
	While StringLen($sVName2)<2
		$sVName2 &= "9"
	WEnd
	$Return &= $sVName2
	Local $iChecksum = 0
	Local $arChars = StringSplit($Return, "", 1+2)
	For $i=0 To UBound($arChars)-1 Step 1
		$iChecksum += Asc($arChars[$i])
	Next
	While StringLen($iChecksum)>1
		Local $arLetters = StringSplit($iChecksum, "", 1+2)
		Local $iNewSum = 0
		For $i=0 To UBound($arLetters)-1 Step 1
			$iNewSum += Int($arLetters[$i])
		Next
		$iChecksum = $iNewSum
	WEnd
	$Return &= $iChecksum
	Return $Return
EndFunc   ;==>_CreateID

Func _CreateID($aUserdata)
	Local Enum $FIRSTNAME, $SECONDNAME, $LASTNAME, $DAYOFBIRTH, $GENDER
	Local $sReturn = "", $aASCII, $sASCII = ""
	$sReturn &= StringReplace(StringFormat("%-5.5s", StringReplace($aUserdata[$LASTNAME], "-", "")), " ", "9")
	$sReturn &= StringMid($aUserdata[$DAYOFBIRTH], 9, 1)
	$sReturn &= StringFormat("%02d", StringMid($aUserdata[$DAYOFBIRTH], 4, 2) + ($aUserdata[$GENDER] = "W") * 50)
	$sReturn &= StringMid($aUserdata[$DAYOFBIRTH], 1, 2)
	$sReturn &= StringMid($aUserdata[$DAYOFBIRTH], 10, 1)
	$sReturn &= StringReplace(StringFormat("%-2.2s%-2.2s", $aUserdata[$FIRSTNAME], $aUserdata[$SECONDNAME]), " ", "9")
	$aASCII = StringToASCIIArray($sReturn)
	For $s In $aASCII
		$sASCII &= $s
	Next
	$sReturn &= calcCrossSum($sASCII)
	Return $sReturn
EndFunc   ;==>_CreateID

Func calcCrossSum($sInput)
	$iSum = 0
	$aDigits = StringSplit($sInput, "", 3)
	For $sDigit In $aDigits
		$iSum += $sDigit
	Next
	Return ($iSum > 9) ? calcCrossSum($iSum) : $iSum
EndFunc

Global $LineStart = @ScriptLineNumber
Func _CreateID($aUserdata)
	Local $Return
	$nachname = StringReplace($aUserdata[2], "+", "") & "99999"  ; BINDESTRICH "IGNORIERT"...das hat mich 30 Minuten gekostet um von 90% auf 100% zu kommen!
	$nachname = StringLeft($nachname, 5)
	$jahr = StringRight($aUserdata[3], 2)
	$jahr = StringLeft($jahr, 1)
	$monat = StringMid($aUserdata[3], 4, 2)
	If $aUserdata[4] = "W" Then $monat = String(Number($monat) + 50)
	$tag = StringLeft($aUserdata[3], 2)
	$jahreszahl = StringRight($aUserdata[3], 1)
	$anfang = StringLeft($aUserdata[0], 1) & StringLeft($aUserdata[1], 1) & "99"
	$anfang = StringLeft($anfang, 2)
	$string = $nachname & $jahr & $monat & $tag & $jahreszahl & $anfang
	$quersumme = $string
	$z = 0
	For $i = 1 To StringLen($quersumme)
		$z = $z + Asc(StringMid($quersumme, $i, 1))
	Next
	while StringLen($quersumme) > 1
		$quersumme = $z
		$z = 0
		For $i = 1 To StringLen($quersumme)
			$z = $z + StringMid($quersumme, $i, 1)
		Next
	wend
	$Return = $string & $quersumme
	Return $Return
EndFunc   ;==>_CreateID
Global $LineEnd = @ScriptLineNumber

#include <String.au3>
Global $LineStart = @ScriptLineNumber
Func _CreateID($aUserdata)
    Local $Return
    Local $mUser[]
          $mUser.Firstname       = $aUserdata[0]
          $mUser.SecondFirstname = $aUserdata[1]
          $mUser.Lastname        = $aUserdata[2]
          $mUser.BirthDate       = $aUserdata[3]
          $mUser.Gender          = $aUserdata[4]
          $Return &= _FirstFiveCharacters($mUser.Lastname)
          $Return &= _SixthCharacter($mUser.BirthDate)
          $Return &= _SeventhAndEighthCharacters($mUser.BirthDate, $mUser.Gender)
          $Return &= _NinthAndTenthCharacters($mUser.BirthDate)
          $Return &= _EleventhCharacter($mUser.BirthDate)
          $Return &= _TwelfthToFifteenthCharacters($mUser.Firstname, $mUser.SecondFirstname)
          $Return &= _SixteenthCharacter($Return)
    Return $Return
EndFunc
Func _FirstFiveCharacters($sLastname)
    $sLastname = _RemoveHyphen($sLastname)
    $sLastname = _FillWithNines($sLastname, 5)
    Return StringLeft($sLastname, 5)
EndFunc
Func _RemoveHyphen($sLastname)
    Return StringReplace($sLastname, '-', '')
EndFunc
Func _FillWithNines($sLastname, $i)
    If StringLen($sLastname) >= $i Then
        Return $sLastname
    EndIf
    $sLastname &= _StringRepeat('9', $i - StringLen($sLastname))
    Return $sLastname
EndFunc
Func _SixthCharacter($sBirthDate)
    Return StringMid($sBirthDate, 9, 1)
EndFunc
Func _SeventhAndEighthCharacters($sBirthDate, $sGender)
    If $sGender == 'W' Then
        Return (StringMid($sBirthDate, 4, 1) + 5) & StringMid($sBirthDate, 5, 1)
    EndIf
    Return StringMid($sBirthDate, 4, 2)
EndFunc
Func _NinthAndTenthCharacters($sBirthDate)
    Return StringMid($sBirthDate, 1, 2)
EndFunc
Func _EleventhCharacter($sBirthDate)
    Return StringRight($sBirthDate, 1)
EndFunc
Func _TwelfthToFifteenthCharacters($sFirstname, $sSecondFirstname)
    If StringLen($sSecondFirstname) > 1 Then
        Return StringLeft($sFirstname, 2) & StringLeft($sSecondFirstname, 2)
    EndIf
    Return StringLeft($sFirstname, 2) & _FillWithNines($sSecondFirstname, 2)
EndFunc
Func _SixteenthCharacter($sString)
    Local Const $aChars = StringToASCIIArray($sString)
    Local $sASCII
	For $sChar In $aChars
		$sASCII &= $sChar
	Next
    Return _BuildVerifierNumber($sASCII)
EndFunc
Func _BuildVerifierNumber($sString)
	Local Const $aDigits = StringSplit($sString, '', 2)
	Local $iSum = 0
	For $sDigit In $aDigits
		$iSum += $sDigit
	Next
    If $iSum <= 9 Then
        Return $iSum
    EndIf
    Return _BuildVerifierNumber($iSum)
EndFunc
Global $LineEnd = @ScriptLineNumber

#include <Array.au3>

Global $LineStart = @ScriptLineNumber
Func _CreateID(Const $aUserdata)
Local Const $Vorname 		= 0
Local Const $ZweiterVorname = 1
Local Const $Nachname 		= 2
Local Const $Geburtsdatum 	= 3
Local Const $Geschlecht 	= 4
Local $Return
;~ 	Zeichen 1-5
	$Return = StringLeft(StringReplace($aUserdata[$Nachname], '-', ''), 5)
	For $i = 1 to 5-StringLen($Return)
		$Return &= '9'
	Next
;~ 	Zeichen 6
	$Return &= Stringmid($aUserdata[$Geburtsdatum], 9, 1)
;~ 	Zeichen 7-8
	If $aUserdata[$Geschlecht] = 'M' then
		$Return &= StringSplit($aUserdata[$Geburtsdatum], '.')[2]
	ElseIf $aUserdata[$Geschlecht] = 'W' then
		$Return &= Number(StringSplit($aUserdata[$Geburtsdatum], '.')[2]) + 50
	Else
		Return False
	EndIf
;~ 	Zeichen 9-10
	$Return &= StringSplit($aUserdata[$Geburtsdatum], '.')[1]
;~ 	Zeichen 11
	$Return &= StringRight($aUserdata[$Geburtsdatum], 1)
;~ 	Zeichen 12-15
	$Return &= StringLeft($aUserdata[$Vorname], 2) & StringLeft($aUserdata[$ZweiterVorname], 2)
	For $i = 1 to 15-Stringlen($Return)
		$Return &= '9'
	Next
;~ 	Zeichen 16
	$Return &= _Pruefziffer($Return)
;~	Consolewrite($Return & @CRLF)

	Return $Return
EndFunc   ;==>_CreateID

Func _Pruefziffer(Const $String)
Local $Return = 0
Local $aArray = StringToASCIIArray($String)
	While 1
		For $Row = 0 to UBound($aArray, $UBOUND_ROWS)-1
			$Return += $aArray[$Row]
		Next
		If $Return <= 9 then ExitLoop
		$aArray = StringSplit($Return, '', $STR_NOCOUNT)
		$Return = 0
	WEnd
	Return $Return
EndFunc

Global $LineEnd = @ScriptLineNumber